lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 use Cwd qw/abs_path/;
  12 STDOUT->autoflush(1);
  13 STDERR->autoflush(1);
  14 require Danga::Socket;
  15 require POSIX;
  16 require PublicInbox::Listener;
  17 require PublicInbox::ParentPipe;
  18 my @CMD;
  19 my $set_user;
  20 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  21 my $worker_processes = 1;
  22 my @listeners;
  23 my %pids;
  24 my %listener_names;
  25 my $reexec_pid;
  26 my $cleanup;
  27 my ($uid, $gid);
  28 END { $cleanup->() if $cleanup };
  29
  30 sub daemon_prepare ($) {
  31         my ($default_listen) = @_;
  32         @CMD = ($0, @ARGV);
  33         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  34                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  35         my %opts = (
  36                 'l|listen=s' => \@cfg_listen,
  37                 '1|stdout=s' => \$stdout,
  38                 '2|stderr=s' => \$stderr,
  39                 'W|worker-processes=i' => \$worker_processes,
  40                 'P|pid-file=s' => \$pid_file,
  41                 'u|user=s' => \$user,
  42                 'g|group=s' => \$group,
  43                 'D|daemonize' => \$daemonize,
  44         );
  45         GetOptions(%opts) or die "bad command-line args\n";
  46
  47         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  48                 die "--pid-file cannot end with '.oldbin'\n";
  49         }
  50         @listeners = inherit();
  51         # ignore daemonize when inheriting
  52         $daemonize = undef if scalar @listeners;
  53
  54         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  55
  56         foreach my $l (@cfg_listen) {
  57                 next if $listener_names{$l}; # already inherited
  58                 my (%o, $sock_pkg);
  59                 if (index($l, '/') == 0) {
  60                         $sock_pkg = 'IO::Socket::UNIX';
  61                         eval "use $sock_pkg";
  62                         die $@ if $@;
  63                         %o = (Type => SOCK_STREAM, Peer => $l);
  64                         if (-S $l) {
  65                                 my $c = $sock_pkg->new(%o);
  66                                 if (!defined($c) && $!{ECONNREFUSED}) {
  67                                         unlink $l or die
  68 "failed to unlink stale socket=$l: $!\n";
  69                                 } # else: let the bind fail
  70                         }
  71                         $o{Local} = delete $o{Peer};
  72                 } else {
  73                         # both work for IPv4, too
  74                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
  75                                 $sock_pkg = $_;
  76                                 eval "use $sock_pkg";
  77                                 $@ or last;
  78                         }
  79                         die $@ if $@;
  80                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
  81                 }
  82                 $o{Listen} = 1024;
  83                 my $prev = umask 0000;
  84                 my $s = eval { $sock_pkg->new(%o) };
  85                 warn "error binding $l: $! ($@)\n" unless $s;
  86                 umask $prev;
  87
  88                 if ($s) {
  89                         $listener_names{sockname($s)} = $s;
  90                         push @listeners, $s;
  91                 }
  92         }
  93         die "No listeners bound\n" unless @listeners;
  94 }
  95
  96 sub check_absolute ($$) {
  97         my ($var, $val) = @_;
  98         if (defined $val && index($val, '/') != 0) {
  99                 die
 100 "--$var must be an absolute path when using --daemonize: $val\n";
 101         }
 102 }
 103
 104 sub daemonize () {
 105         foreach my $i (0..$#ARGV) {
 106                 my $arg = $ARGV[$i];
 107                 next unless -e $arg;
 108                 $ARGV[$i] = abs_path($arg);
 109         }
 110         check_absolute('stdout', $stdout);
 111         check_absolute('stderr', $stderr);
 112         check_absolute('pid-file', $pid_file);
 113
 114         chdir '/' or die "chdir failed: $!";
 115         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 116
 117         return unless (defined $pid_file || defined $group || defined $user
 118                         || $daemonize);
 119
 120         eval { require Net::Server::Daemonize };
 121         if ($@) {
 122                 die
 123 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 124         }
 125
 126         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 127         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 128         if (defined $group) {
 129                 $gid = Net::Server::Daemonize::get_gid($group);
 130                 $gid = (split /\s+/, $gid)[0];
 131         } elsif (defined $uid) {
 132                 $gid = (getpwuid($uid))[3];
 133         }
 134
 135         # We change users in the worker to ensure upgradability,
 136         # The upgrade will create the ".oldbin" pid file in the
 137         # same directory as the given pid file.
 138         $uid and $set_user = sub {
 139                 $set_user = undef;
 140                 Net::Server::Daemonize::set_user($uid, $gid);
 141         };
 142
 143         if ($daemonize) {
 144                 my $pid = fork;
 145                 die "could not fork: $!\n" unless defined $pid;
 146                 exit if $pid;
 147
 148                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 149                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 150                 POSIX::setsid();
 151                 $pid = fork;
 152                 die "could not fork: $!\n" unless defined $pid;
 153                 exit if $pid;
 154         }
 155         if (defined $pid_file) {
 156                 write_pid($pid_file);
 157                 my $unlink_pid = $$;
 158                 $cleanup = sub {
 159                         $cleanup = undef; # avoid cyclic reference
 160                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 161                 };
 162         }
 163 }
 164
 165
 166 sub worker_quit {
 167         my ($reason) = @_;
 168         # killing again terminates immediately:
 169         exit unless @listeners;
 170
 171         $_->close foreach @listeners; # call Danga::Socket::close
 172         @listeners = ();
 173         $reason->close if ref($reason) eq 'PublicInbox::ParentPipe';
 174
 175         my $proc_name;
 176         my $warn = 0;
 177         # drop idle connections and try to quit gracefully
 178         Danga::Socket->SetPostLoopCallback(sub {
 179                 my ($dmap, undef) = @_;
 180                 my $n = 0;
 181
 182                 foreach my $s (values %$dmap) {
 183                         if ($s->can('busy') && $s->busy) {
 184                                 ++$n;
 185                         } else {
 186                                 # close as much as possible, early as possible
 187                                 $s->close;
 188                         }
 189                 }
 190                 if ($n) {
 191                         if (($warn + 5) < time) {
 192                                 warn "$$ quitting, $n client(s) left\n";
 193                                 $warn = time;
 194                         }
 195                         unless (defined $proc_name) {
 196                                 $proc_name = (split(/\s+/, $0))[0];
 197                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 198                         }
 199                         $0 = "$proc_name quitting, $n client(s) left";
 200                 }
 201                 $n; # true: loop continues, false: loop breaks
 202         });
 203 }
 204
 205 sub reopen_logs {
 206         if ($stdout) {
 207                 open STDOUT, '>>', $stdout or
 208                         warn "failed to redirect stdout to $stdout: $!\n";
 209                 STDOUT->autoflush(1);
 210                 do_chown($stdout);
 211         }
 212         if ($stderr) {
 213                 open STDERR, '>>', $stderr or
 214                         warn "failed to redirect stderr to $stderr: $!\n";
 215                 STDERR->autoflush(1);
 216                 do_chown($stderr);
 217         }
 218 }
 219
 220 sub sockname ($) {
 221         my ($s) = @_;
 222         my $addr = getsockname($s) or return;
 223         my ($host, $port) = host_with_port($addr);
 224         if ($port == 0 && $host eq '127.0.0.1') {
 225                 my ($path) = Socket::sockaddr_un($addr);
 226                 return $path;
 227         }
 228         "$host:$port";
 229 }
 230
 231 sub host_with_port ($) {
 232         my ($addr) = @_;
 233         my ($port, $host);
 234
 235         # this eval will die on Unix sockets:
 236         eval {
 237                 if (length($addr) >= 28) {
 238                         require Socket6;
 239                         ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 240                         $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 241                         $host = "[$host]";
 242                 } else {
 243                         ($port, $host) = Socket::sockaddr_in($addr);
 244                         $host = Socket::inet_ntoa($host);
 245                 }
 246         };
 247         $@ ? ('127.0.0.1', 0) : ($host, $port);
 248 }
 249
 250 sub inherit () {
 251         return () if ($ENV{LISTEN_PID} || 0) != $$;
 252         my $fds = $ENV{LISTEN_FDS} or return ();
 253         my $end = $fds + 2; # LISTEN_FDS_START - 1
 254         my @rv = ();
 255         foreach my $fd (3..$end) {
 256                 my $s = IO::Handle->new_from_fd($fd, 'r');
 257                 if (my $k = sockname($s)) {
 258                         $listener_names{$k} = $s;
 259                         push @rv, $s;
 260                 } else {
 261                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 262                 }
 263         }
 264         @rv
 265 }
 266
 267 sub upgrade () {
 268         if ($reexec_pid) {
 269                 warn "upgrade in-progress: $reexec_pid\n";
 270                 return;
 271         }
 272         if (defined $pid_file) {
 273                 if ($pid_file =~ /\.oldbin\z/) {
 274                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 275                         return;
 276                 }
 277                 unlink_pid_file_safe_ish($$, $pid_file);
 278                 $pid_file .= '.oldbin';
 279                 write_pid($pid_file);
 280         }
 281         my $pid = fork;
 282         unless (defined $pid) {
 283                 warn "fork failed: $!\n";
 284                 return;
 285         }
 286         if ($pid == 0) {
 287                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 288                 $ENV{LISTEN_FDS} = scalar @listeners;
 289                 $ENV{LISTEN_PID} = $$;
 290                 foreach my $s (@listeners) {
 291                         my $fl = fcntl($s, F_GETFD, 0);
 292                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 293                 }
 294                 exec @CMD;
 295                 die "Failed to exec: $!\n";
 296         }
 297         $reexec_pid = $pid;
 298 }
 299
 300 sub kill_workers ($) {
 301         my ($s) = @_;
 302
 303         while (my ($pid, $id) = each %pids) {
 304                 kill $s, $pid;
 305         }
 306 }
 307
 308 sub upgrade_aborted ($) {
 309         my ($p) = @_;
 310         warn "reexec PID($p) died with: $?\n";
 311         $reexec_pid = undef;
 312         return unless $pid_file;
 313
 314         my $file = $pid_file;
 315         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 316         unlink_pid_file_safe_ish($$, $pid_file);
 317         $pid_file = $file;
 318         eval { write_pid($pid_file) };
 319         warn $@, "\n" if $@;
 320 }
 321
 322 sub reap_children () {
 323         while (1) {
 324                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 325                 if (defined $reexec_pid && $p == $reexec_pid) {
 326                         upgrade_aborted($p);
 327                 } elsif (defined(my $id = delete $pids{$p})) {
 328                         warn "worker[$id] PID($p) died with: $?\n";
 329                 } elsif ($p > 0) {
 330                         warn "unknown PID($p) reaped: $?\n";
 331                 } else {
 332                         return;
 333                 }
 334         }
 335 }
 336
 337 sub unlink_pid_file_safe_ish ($$) {
 338         my ($unlink_pid, $file) = @_;
 339         return unless defined $unlink_pid && $unlink_pid == $$;
 340
 341         open my $fh, '<', $file or return;
 342         local $/ = "\n";
 343         defined(my $read_pid = <$fh>) or return;
 344         chomp $read_pid;
 345         if ($read_pid == $unlink_pid) {
 346                 Net::Server::Daemonize::unlink_pid_file($file);
 347         }
 348 }
 349
 350 sub master_loop {
 351         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 352         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 353         IO::Handle::blocking($w, 0);
 354         my $set_workers = $worker_processes;
 355         my @caught;
 356         my $master_pid = $$;
 357         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 358                 $SIG{$s} = sub {
 359                         return if $$ != $master_pid;
 360                         push @caught, $s;
 361                         syswrite($w, '.');
 362                 };
 363         }
 364         reopen_logs();
 365         # main loop
 366         my $quit = 0;
 367         while (1) {
 368                 while (my $s = shift @caught) {
 369                         if ($s eq 'USR1') {
 370                                 reopen_logs();
 371                                 kill_workers($s);
 372                         } elsif ($s eq 'USR2') {
 373                                 upgrade();
 374                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 375                                 exit if $quit++;
 376                                 kill_workers($s);
 377                         } elsif ($s eq 'WINCH') {
 378                                 if (-t STDIN || -t STDOUT || -t STDERR) {
 379                                         warn
 380 "ignoring SIGWINCH while connected to terminal\n";
 381                                         $SIG{WINCH} = 'IGNORE';
 382                                 } else {
 383                                         $worker_processes = 0;
 384                                 }
 385                         } elsif ($s eq 'HUP') {
 386                                 $worker_processes = $set_workers;
 387                                 kill_workers($s);
 388                         } elsif ($s eq 'TTIN') {
 389                                 if ($set_workers > $worker_processes) {
 390                                         ++$worker_processes;
 391                                 } else {
 392                                         $worker_processes = ++$set_workers;
 393                                 }
 394                         } elsif ($s eq 'TTOU') {
 395                                 if ($set_workers > 0) {
 396                                         $worker_processes = --$set_workers;
 397                                 }
 398                         } elsif ($s eq 'CHLD') {
 399                                 reap_children();
 400                         }
 401                 }
 402
 403                 my $n = scalar keys %pids;
 404                 if ($quit) {
 405                         exit if $n == 0;
 406                         $set_workers = $worker_processes = $n = 0;
 407                 }
 408
 409                 if ($n > $worker_processes) {
 410                         while (my ($k, $v) = each %pids) {
 411                                 kill('TERM', $k) if $v >= $worker_processes;
 412                         }
 413                         $n = $worker_processes;
 414                 }
 415                 foreach my $i ($n..($worker_processes - 1)) {
 416                         my $pid = fork;
 417                         if (!defined $pid) {
 418                                 warn "failed to fork worker[$i]: $!\n";
 419                         } elsif ($pid == 0) {
 420                                 $set_user->() if $set_user;
 421                                 return $p0; # run normal work code
 422                         } else {
 423                                 warn "PID=$pid is worker[$i]\n";
 424                                 $pids{$pid} = $i;
 425                         }
 426                 }
 427                 # just wait on signal events here:
 428                 sysread($r, my $buf, 8);
 429         }
 430         exit # never gets here, just for documentation
 431 }
 432
 433 sub daemon_loop ($$) {
 434         my ($refresh, $post_accept) = @_;
 435         my $parent_pipe;
 436         if ($worker_processes > 0) {
 437                 $refresh->(); # preload by default
 438                 my $fh = master_loop(); # returns if in child process
 439                 $parent_pipe = PublicInbox::ParentPipe->new($fh, *worker_quit);
 440         } else {
 441                 reopen_logs();
 442                 $set_user->() if $set_user;
 443                 $SIG{USR2} = sub { worker_quit('USR2') if upgrade() };
 444                 $refresh->();
 445         }
 446         $uid = $gid = undef;
 447         reopen_logs();
 448         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 449         $SIG{USR1} = *reopen_logs;
 450         $SIG{HUP} = $refresh;
 451         $SIG{$_} = 'DEFAULT' for qw(CHLD USR2 TTIN TTOU WINCH);
 452         # this calls epoll_create:
 453         @listeners = map {
 454                 PublicInbox::Listener->new($_, $post_accept)
 455         } @listeners;
 456         Danga::Socket->EventLoop;
 457         $parent_pipe = undef;
 458 }
 459
 460
 461 sub run ($$$) {
 462         my ($default, $refresh, $post_accept) = @_;
 463         daemon_prepare($default);
 464         daemonize();
 465         daemon_loop($refresh, $post_accept);
 466 }
 467
 468 sub do_chown ($) {
 469         my ($path) = @_;
 470         if (defined $uid and !chown($uid, $gid, $path)) {
 471                 warn "could not chown $path: $!\n";
 472         }
 473 }
 474
 475 sub write_pid ($) {
 476         my ($path) = @_;
 477         Net::Server::Daemonize::create_pid_file($path);
 478         do_chown($path);
 479 }
 480
 481 1;