lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 use Cwd qw/abs_path/;
  12 STDOUT->autoflush(1);
  13 STDERR->autoflush(1);
  14 use PublicInbox::DS qw(now);
  15 require PublicInbox::EvCleanup;
  16 require POSIX;
  17 require PublicInbox::Listener;
  18 require PublicInbox::ParentPipe;
  19 my @CMD;
  20 my $set_user;
  21 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  22 my $worker_processes = 1;
  23 my @listeners;
  24 my %pids;
  25 my %listener_names; # sockname => IO::Handle
  26 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  27 my $reexec_pid;
  28 my $cleanup;
  29 my ($uid, $gid);
  30 my ($default_cert, $default_key);
  31 END { $cleanup->() if $cleanup };
  32
  33 sub tls_listen ($$$) {
  34         my ($scheme, $sockname, $opt_str) = @_;
  35         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  36         require PublicInbox::TLS;
  37         my $o = {};
  38         # allow ',' as delimiter since '&' is shell-unfriendly
  39         foreach (split(/[,&]/, $opt_str)) {
  40                 my ($k, $v) = split(/=/, $_, 2);
  41                 push @{$o->{$k} ||= []}, $v;
  42         }
  43
  44         # key may be a part of cert.  At least
  45         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  46         $o->{cert} //= [ $default_cert ];
  47         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  48         my %ctx_opt = (SSL_server => 1);
  49         # parse out hostname:/path/to/ mappings:
  50         foreach my $k (qw(cert key)) {
  51                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  52                 foreach my $path (@{$o->{$k}}) {
  53                         my $host = '';
  54                         $path =~ s/\A([^:]+):// and $host = $1;
  55                         $x->{$host} = $path;
  56                 }
  57         }
  58         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  59                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  60         $tls_opt{"$scheme://$sockname"} = {
  61                 SSL_server => 1,
  62                 SSL_startHandshake => 0,
  63                 SSL_reuse_ctx => $ctx
  64         };
  65 }
  66
  67 sub daemon_prepare ($) {
  68         my ($default_listen) = @_;
  69         @CMD = ($0, @ARGV);
  70         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  71                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  72         my %opts = (
  73                 'l|listen=s' => \@cfg_listen,
  74                 '1|stdout=s' => \$stdout,
  75                 '2|stderr=s' => \$stderr,
  76                 'W|worker-processes=i' => \$worker_processes,
  77                 'P|pid-file=s' => \$pid_file,
  78                 'u|user=s' => \$user,
  79                 'g|group=s' => \$group,
  80                 'D|daemonize' => \$daemonize,
  81                 'cert=s' => \$default_cert,
  82                 'key=s' => \$default_key,
  83         );
  84         GetOptions(%opts) or die "bad command-line args\n";
  85
  86         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  87                 die "--pid-file cannot end with '.oldbin'\n";
  88         }
  89         @listeners = inherit();
  90         # ignore daemonize when inheriting
  91         $daemonize = undef if scalar @listeners;
  92
  93         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  94
  95         foreach my $l (@cfg_listen) {
  96                 my $orig = $l;
  97                 my $scheme = '';
  98                 $l =~ s!\A([^:]+)://!! and $scheme = $1;
  99                 if ($l =~ s!/?\?(.+)\z!!) {
 100                         tls_listen($scheme, $l, $1);
 101                 } elsif (defined($default_cert)) {
 102                         tls_listen($scheme, $l, '');
 103                 } elsif ($scheme =~ /\A(?:nntps|https)\z/) {
 104                         die "$orig specified w/o cert=\n";
 105                 }
 106                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 107
 108                 next if $listener_names{$l}; # already inherited
 109                 my (%o, $sock_pkg);
 110                 if (index($l, '/') == 0) {
 111                         $sock_pkg = 'IO::Socket::UNIX';
 112                         eval "use $sock_pkg";
 113                         die $@ if $@;
 114                         %o = (Type => SOCK_STREAM, Peer => $l);
 115                         if (-S $l) {
 116                                 my $c = $sock_pkg->new(%o);
 117                                 if (!defined($c) && $!{ECONNREFUSED}) {
 118                                         unlink $l or die
 119 "failed to unlink stale socket=$l: $!\n";
 120                                 } # else: let the bind fail
 121                         }
 122                         $o{Local} = delete $o{Peer};
 123                 } else {
 124                         # both work for IPv4, too
 125                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 126                                 $sock_pkg = $_;
 127                                 eval "use $sock_pkg";
 128                                 $@ or last;
 129                         }
 130                         die $@ if $@;
 131                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 132                 }
 133                 $o{Listen} = 1024;
 134                 my $prev = umask 0000;
 135                 my $s = eval { $sock_pkg->new(%o) };
 136                 warn "error binding $l: $! ($@)\n" unless $s;
 137                 umask $prev;
 138
 139                 if ($s) {
 140                         $listener_names{sockname($s)} = $s;
 141                         push @listeners, $s;
 142                 }
 143         }
 144         die "No listeners bound\n" unless @listeners;
 145 }
 146
 147 sub check_absolute ($$) {
 148         my ($var, $val) = @_;
 149         if (defined $val && index($val, '/') != 0) {
 150                 die
 151 "--$var must be an absolute path when using --daemonize: $val\n";
 152         }
 153 }
 154
 155 sub daemonize () {
 156         if ($daemonize) {
 157                 foreach my $i (0..$#ARGV) {
 158                         my $arg = $ARGV[$i];
 159                         next unless -e $arg;
 160                         $ARGV[$i] = abs_path($arg);
 161                 }
 162                 check_absolute('stdout', $stdout);
 163                 check_absolute('stderr', $stderr);
 164                 check_absolute('pid-file', $pid_file);
 165
 166                 chdir '/' or die "chdir failed: $!";
 167         }
 168
 169         return unless (defined $pid_file || defined $group || defined $user
 170                         || $daemonize);
 171
 172         eval { require Net::Server::Daemonize };
 173         if ($@) {
 174                 die
 175 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 176         }
 177
 178         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 179         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 180         if (defined $group) {
 181                 $gid = Net::Server::Daemonize::get_gid($group);
 182                 $gid = (split /\s+/, $gid)[0];
 183         } elsif (defined $uid) {
 184                 $gid = (getpwuid($uid))[3];
 185         }
 186
 187         # We change users in the worker to ensure upgradability,
 188         # The upgrade will create the ".oldbin" pid file in the
 189         # same directory as the given pid file.
 190         $uid and $set_user = sub {
 191                 $set_user = undef;
 192                 Net::Server::Daemonize::set_user($uid, $gid);
 193         };
 194
 195         if ($daemonize) {
 196                 my $pid = fork;
 197                 die "could not fork: $!\n" unless defined $pid;
 198                 exit if $pid;
 199
 200                 open(STDIN, '+<', '/dev/null') or
 201                                         die "redirect stdin failed: $!\n";
 202                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 203                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 204                 POSIX::setsid();
 205                 $pid = fork;
 206                 die "could not fork: $!\n" unless defined $pid;
 207                 exit if $pid;
 208         }
 209         if (defined $pid_file) {
 210                 write_pid($pid_file);
 211                 my $unlink_pid = $$;
 212                 $cleanup = sub {
 213                         $cleanup = undef; # avoid cyclic reference
 214                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 215                 };
 216         }
 217 }
 218
 219
 220 sub worker_quit {
 221         my ($reason) = @_;
 222         # killing again terminates immediately:
 223         exit unless @listeners;
 224
 225         $_->close foreach @listeners; # call PublicInbox::DS::close
 226         @listeners = ();
 227         $reason->close if ref($reason) eq 'PublicInbox::ParentPipe';
 228
 229         my $proc_name;
 230         my $warn = 0;
 231         # drop idle connections and try to quit gracefully
 232         PublicInbox::DS->SetPostLoopCallback(sub {
 233                 my ($dmap, undef) = @_;
 234                 my $n = 0;
 235                 my $now = now();
 236
 237                 foreach my $s (values %$dmap) {
 238                         $s->can('busy') or next;
 239                         if ($s->busy($now)) {
 240                                 ++$n;
 241                         } else {
 242                                 # close as much as possible, early as possible
 243                                 $s->close;
 244                         }
 245                 }
 246                 if ($n) {
 247                         if (($warn + 5) < now()) {
 248                                 warn "$$ quitting, $n client(s) left\n";
 249                                 $warn = now();
 250                         }
 251                         unless (defined $proc_name) {
 252                                 $proc_name = (split(/\s+/, $0))[0];
 253                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 254                         }
 255                         $0 = "$proc_name quitting, $n client(s) left";
 256                 }
 257                 $n; # true: loop continues, false: loop breaks
 258         });
 259 }
 260
 261 sub reopen_logs {
 262         if ($stdout) {
 263                 open STDOUT, '>>', $stdout or
 264                         warn "failed to redirect stdout to $stdout: $!\n";
 265                 STDOUT->autoflush(1);
 266                 do_chown($stdout);
 267         }
 268         if ($stderr) {
 269                 open STDERR, '>>', $stderr or
 270                         warn "failed to redirect stderr to $stderr: $!\n";
 271                 STDERR->autoflush(1);
 272                 do_chown($stderr);
 273         }
 274 }
 275
 276 sub sockname ($) {
 277         my ($s) = @_;
 278         my $addr = getsockname($s) or return;
 279         my ($host, $port) = host_with_port($addr);
 280         if ($port == 0 && $host eq '127.0.0.1') {
 281                 my ($path) = Socket::sockaddr_un($addr);
 282                 return $path;
 283         }
 284         "$host:$port";
 285 }
 286
 287 sub unpack_ipv6 ($) {
 288         my ($addr) = @_;
 289         my ($port, $host);
 290
 291         # Socket.pm in Perl 5.14+ supports IPv6:
 292         eval {
 293                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 294                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 295         };
 296
 297         if ($@) {
 298                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 299                 # Socket6, so it may be installed on our system, already
 300                 # (otherwise die here):
 301                 require Socket6;
 302
 303                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 304                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 305         }
 306         ($host, $port);
 307 }
 308
 309 sub host_with_port ($) {
 310         my ($addr) = @_;
 311         my ($port, $host);
 312
 313         # this eval will die on Unix sockets:
 314         eval {
 315                 if (length($addr) >= 28) {
 316                         ($host, $port) = unpack_ipv6($addr);
 317                         $host = "[$host]";
 318                 } else {
 319                         ($port, $host) = Socket::sockaddr_in($addr);
 320                         $host = Socket::inet_ntoa($host);
 321                 }
 322         };
 323         $@ ? ('127.0.0.1', 0) : ($host, $port);
 324 }
 325
 326 sub inherit () {
 327         return () if ($ENV{LISTEN_PID} || 0) != $$;
 328         my $fds = $ENV{LISTEN_FDS} or return ();
 329         my $end = $fds + 2; # LISTEN_FDS_START - 1
 330         my @rv = ();
 331         foreach my $fd (3..$end) {
 332                 my $s = IO::Handle->new_from_fd($fd, 'r');
 333                 if (my $k = sockname($s)) {
 334                         $listener_names{$k} = $s;
 335                         push @rv, $s;
 336                 } else {
 337                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 338                 }
 339         }
 340         @rv
 341 }
 342
 343 sub upgrade () {
 344         if ($reexec_pid) {
 345                 warn "upgrade in-progress: $reexec_pid\n";
 346                 return;
 347         }
 348         if (defined $pid_file) {
 349                 if ($pid_file =~ /\.oldbin\z/) {
 350                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 351                         return;
 352                 }
 353                 unlink_pid_file_safe_ish($$, $pid_file);
 354                 $pid_file .= '.oldbin';
 355                 write_pid($pid_file);
 356         }
 357         my $pid = fork;
 358         unless (defined $pid) {
 359                 warn "fork failed: $!\n";
 360                 return;
 361         }
 362         if ($pid == 0) {
 363                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 364                 $ENV{LISTEN_FDS} = scalar @listeners;
 365                 $ENV{LISTEN_PID} = $$;
 366                 foreach my $s (@listeners) {
 367                         my $fl = fcntl($s, F_GETFD, 0);
 368                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 369                 }
 370                 exec @CMD;
 371                 die "Failed to exec: $!\n";
 372         }
 373         $reexec_pid = $pid;
 374 }
 375
 376 sub kill_workers ($) {
 377         my ($s) = @_;
 378
 379         while (my ($pid, $id) = each %pids) {
 380                 kill $s, $pid;
 381         }
 382 }
 383
 384 sub upgrade_aborted ($) {
 385         my ($p) = @_;
 386         warn "reexec PID($p) died with: $?\n";
 387         $reexec_pid = undef;
 388         return unless $pid_file;
 389
 390         my $file = $pid_file;
 391         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 392         unlink_pid_file_safe_ish($$, $pid_file);
 393         $pid_file = $file;
 394         eval { write_pid($pid_file) };
 395         warn $@, "\n" if $@;
 396 }
 397
 398 sub reap_children () {
 399         while (1) {
 400                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 401                 if (defined $reexec_pid && $p == $reexec_pid) {
 402                         upgrade_aborted($p);
 403                 } elsif (defined(my $id = delete $pids{$p})) {
 404                         warn "worker[$id] PID($p) died with: $?\n";
 405                 } elsif ($p > 0) {
 406                         warn "unknown PID($p) reaped: $?\n";
 407                 } else {
 408                         return;
 409                 }
 410         }
 411 }
 412
 413 sub unlink_pid_file_safe_ish ($$) {
 414         my ($unlink_pid, $file) = @_;
 415         return unless defined $unlink_pid && $unlink_pid == $$;
 416
 417         open my $fh, '<', $file or return;
 418         local $/ = "\n";
 419         defined(my $read_pid = <$fh>) or return;
 420         chomp $read_pid;
 421         if ($read_pid == $unlink_pid) {
 422                 Net::Server::Daemonize::unlink_pid_file($file);
 423         }
 424 }
 425
 426 sub master_loop {
 427         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 428         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 429
 430         if ($^O eq 'linux') { # 1031: F_SETPIPE_SZ = 1031
 431                 fcntl($_, 1031, 4096) for ($w, $p1);
 432         }
 433
 434         IO::Handle::blocking($w, 0);
 435         my $set_workers = $worker_processes;
 436         my @caught;
 437         my $master_pid = $$;
 438         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 439                 $SIG{$s} = sub {
 440                         return if $$ != $master_pid;
 441                         push @caught, $s;
 442                         syswrite($w, '.');
 443                 };
 444         }
 445         reopen_logs();
 446         # main loop
 447         my $quit = 0;
 448         while (1) {
 449                 while (my $s = shift @caught) {
 450                         if ($s eq 'USR1') {
 451                                 reopen_logs();
 452                                 kill_workers($s);
 453                         } elsif ($s eq 'USR2') {
 454                                 upgrade();
 455                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 456                                 exit if $quit++;
 457                                 kill_workers($s);
 458                         } elsif ($s eq 'WINCH') {
 459                                 if (-t STDIN || -t STDOUT || -t STDERR) {
 460                                         warn
 461 "ignoring SIGWINCH since we are not daemonized\n";
 462                                         $SIG{WINCH} = 'IGNORE';
 463                                 } else {
 464                                         $worker_processes = 0;
 465                                 }
 466                         } elsif ($s eq 'HUP') {
 467                                 $worker_processes = $set_workers;
 468                                 kill_workers($s);
 469                         } elsif ($s eq 'TTIN') {
 470                                 if ($set_workers > $worker_processes) {
 471                                         ++$worker_processes;
 472                                 } else {
 473                                         $worker_processes = ++$set_workers;
 474                                 }
 475                         } elsif ($s eq 'TTOU') {
 476                                 if ($set_workers > 0) {
 477                                         $worker_processes = --$set_workers;
 478                                 }
 479                         } elsif ($s eq 'CHLD') {
 480                                 reap_children();
 481                         }
 482                 }
 483
 484                 my $n = scalar keys %pids;
 485                 if ($quit) {
 486                         exit if $n == 0;
 487                         $set_workers = $worker_processes = $n = 0;
 488                 }
 489
 490                 if ($n > $worker_processes) {
 491                         while (my ($k, $v) = each %pids) {
 492                                 kill('TERM', $k) if $v >= $worker_processes;
 493                         }
 494                         $n = $worker_processes;
 495                 }
 496                 foreach my $i ($n..($worker_processes - 1)) {
 497                         my $pid = fork;
 498                         if (!defined $pid) {
 499                                 warn "failed to fork worker[$i]: $!\n";
 500                         } elsif ($pid == 0) {
 501                                 $set_user->() if $set_user;
 502                                 return $p0; # run normal work code
 503                         } else {
 504                                 warn "PID=$pid is worker[$i]\n";
 505                                 $pids{$pid} = $i;
 506                         }
 507                 }
 508                 # just wait on signal events here:
 509                 sysread($r, my $buf, 8);
 510         }
 511         exit # never gets here, just for documentation
 512 }
 513
 514 sub tls_start_cb ($$) {
 515         my ($opt, $orig_post_accept) = @_;
 516         sub {
 517                 my ($io, $addr, $srv) = @_;
 518                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 519                 $orig_post_accept->($ssl, $addr, $srv);
 520         }
 521 }
 522
 523 sub daemon_loop ($$$) {
 524         my ($refresh, $post_accept, $nntpd) = @_;
 525         PublicInbox::EvCleanup::enable(); # early for $refresh
 526         my %post_accept;
 527         while (my ($k, $v) = each %tls_opt) {
 528                 if ($k =~ s!\A(?:nntps|https)://!!) {
 529                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 530                 } elsif ($nntpd) { # STARTTLS, $k eq '' is OK
 531                         $nntpd->{accept_tls} = $v;
 532                 }
 533         }
 534         my $parent_pipe;
 535         if ($worker_processes > 0) {
 536                 $refresh->(); # preload by default
 537                 my $fh = master_loop(); # returns if in child process
 538                 $parent_pipe = PublicInbox::ParentPipe->new($fh, *worker_quit);
 539         } else {
 540                 reopen_logs();
 541                 $set_user->() if $set_user;
 542                 $SIG{USR2} = sub { worker_quit('USR2') if upgrade() };
 543                 $refresh->();
 544         }
 545         $uid = $gid = undef;
 546         reopen_logs();
 547         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 548         $SIG{USR1} = *reopen_logs;
 549         $SIG{HUP} = $refresh;
 550         $SIG{CHLD} = 'DEFAULT';
 551         $SIG{$_} = 'IGNORE' for qw(USR2 TTIN TTOU WINCH);
 552         # this calls epoll_create:
 553         @listeners = map {
 554                 PublicInbox::Listener->new($_,
 555                                 $post_accept{sockname($_)} || $post_accept)
 556         } @listeners;
 557         PublicInbox::DS->EventLoop;
 558         $parent_pipe = undef;
 559 }
 560
 561
 562 sub run ($$$;$) {
 563         my ($default, $refresh, $post_accept, $nntpd) = @_;
 564         daemon_prepare($default);
 565         daemonize();
 566         daemon_loop($refresh, $post_accept, $nntpd);
 567 }
 568
 569 sub do_chown ($) {
 570         my ($path) = @_;
 571         if (defined $uid and !chown($uid, $gid, $path)) {
 572                 warn "could not chown $path: $!\n";
 573         }
 574 }
 575
 576 sub write_pid ($) {
 577         my ($path) = @_;
 578         Net::Server::Daemonize::create_pid_file($path);
 579         do_chown($path);
 580 }
 581
 582 1;