lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 STDOUT->autoflush(1);
  11 STDERR->autoflush(1);
  12 require Danga::Socket;
  13 require POSIX;
  14 require PublicInbox::Listener;
  15 my @CMD;
  16 my $set_user;
  17 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  18 my $worker_processes = 1;
  19 my @listeners;
  20 my %pids;
  21 my %listener_names;
  22 my $reexec_pid;
  23 my $cleanup;
  24 my ($uid, $gid);
  25 END { $cleanup->() if $cleanup };
  26
  27 sub daemon_prepare ($) {
  28         my ($default_listen) = @_;
  29         @CMD = ($0, @ARGV);
  30         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  31                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  32         my %opts = (
  33                 'l|listen=s' => \@cfg_listen,
  34                 '1|stdout=s' => \$stdout,
  35                 '2|stderr=s' => \$stderr,
  36                 'W|worker-processes=i' => \$worker_processes,
  37                 'P|pid-file=s' => \$pid_file,
  38                 'u|user=s' => \$user,
  39                 'g|group=s' => \$group,
  40                 'D|daemonize' => \$daemonize,
  41         );
  42         GetOptions(%opts) or die "bad command-line args\n";
  43
  44         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  45                 die "--pid-file cannot end with '.oldbin'\n";
  46         }
  47         @listeners = inherit();
  48         # ignore daemonize when inheriting
  49         $daemonize = undef if scalar @listeners;
  50
  51         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  52
  53         foreach my $l (@cfg_listen) {
  54                 next if $listener_names{$l}; # already inherited
  55                 require IO::Socket::INET6; # works for IPv4, too
  56                 my %o = (
  57                         LocalAddr => $l,
  58                         ReuseAddr => 1,
  59                         Proto => 'tcp',
  60                 );
  61                 if (my $s = IO::Socket::INET6->new(%o)) {
  62                         $listener_names{sockname($s)} = $s;
  63                         push @listeners, $s;
  64                 } else {
  65                         warn "error binding $l: $!\n";
  66                 }
  67         }
  68         die "No listeners bound\n" unless @listeners;
  69 }
  70
  71 sub daemonize () {
  72         chdir '/' or die "chdir failed: $!";
  73         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
  74
  75         return unless (defined $pid_file || defined $group || defined $user
  76                         || $daemonize);
  77
  78         require Net::Server::Daemonize;
  79
  80         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
  81         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
  82         if (defined $group) {
  83                 $gid = Net::Server::Daemonize::get_gid($group);
  84                 $gid = (split /\s+/, $gid)[0];
  85         } elsif (defined $uid) {
  86                 $gid = (getpwuid($uid))[3];
  87         }
  88
  89         # We change users in the worker to ensure upgradability,
  90         # The upgrade will create the ".oldbin" pid file in the
  91         # same directory as the given pid file.
  92         $uid and $set_user = sub {
  93                 Net::Server::Daemonize::set_user($uid, $gid);
  94         };
  95
  96         if ($daemonize) {
  97                 my ($pid, $err) = do_fork();
  98                 die "could not fork: $err\n" unless defined $pid;
  99                 exit if $pid;
 100
 101                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 102                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 103                 POSIX::setsid();
 104                 ($pid, $err) = do_fork();
 105                 die "could not fork: $err\n" unless defined $pid;
 106                 exit if $pid;
 107         }
 108         if (defined $pid_file) {
 109                 write_pid($pid_file);
 110                 my $unlink_pid = $$;
 111                 $cleanup = sub {
 112                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 113                 };
 114         }
 115 }
 116
 117 sub worker_quit () {
 118         # killing again terminates immediately:
 119         exit unless @listeners;
 120
 121         @listeners = ();
 122
 123         # give slow clients 30s to finish reading/writing whatever
 124         Danga::Socket->AddTimer(30, sub { exit });
 125
 126         # drop idle connections and try to quit gracefully
 127         Danga::Socket->SetPostLoopCallback(sub {
 128                 my ($dmap, undef) = @_;
 129                 my $n = 0;
 130
 131                 foreach my $s (values %$dmap) {
 132                         if ($s->can('busy') && $s->busy) {
 133                                 $n = 1;
 134                         } else {
 135                                 # close as much as possible, early as possible
 136                                 $s->close;
 137                         }
 138                 }
 139                 $n; # true: loop continues, false: loop breaks
 140         });
 141 }
 142
 143 sub reopen_logs {
 144         if ($stdout) {
 145                 open STDOUT, '>>', $stdout or
 146                         warn "failed to redirect stdout to $stdout: $!\n";
 147                 STDOUT->autoflush(1);
 148                 do_chown($stdout);
 149         }
 150         if ($stderr) {
 151                 open STDERR, '>>', $stderr or
 152                         warn "failed to redirect stderr to $stderr: $!\n";
 153                 STDERR->autoflush(1);
 154                 do_chown($stderr);
 155         }
 156 }
 157
 158 sub sockname ($) {
 159         my ($s) = @_;
 160         my $n = getsockname($s) or return;
 161         my ($port, $addr);
 162         if (length($n) >= 28) {
 163                 require Socket6;
 164                 ($port, $addr) = Socket6::unpack_sockaddr_in6($n);
 165         } else {
 166                 ($port, $addr) = Socket::sockaddr_in($n);
 167         }
 168         if (length($addr) == 4) {
 169                 $n = Socket::inet_ntoa($addr)
 170         } else {
 171                 $n = '['.Socket6::inet_ntop(Socket6::AF_INET6(), $addr).']';
 172         }
 173         $n .= ":$port";
 174 }
 175
 176 sub inherit () {
 177         return () if ($ENV{LISTEN_PID} || 0) != $$;
 178         my $fds = $ENV{LISTEN_FDS} or return ();
 179         my $end = $fds + 2; # LISTEN_FDS_START - 1
 180         my @rv = ();
 181         foreach my $fd (3..$end) {
 182                 my $s = IO::Handle->new;
 183                 $s->fdopen($fd, 'r');
 184                 if (my $k = sockname($s)) {
 185                         $listener_names{$k} = $s;
 186                         push @rv, $s;
 187                 } else {
 188                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 189                 }
 190         }
 191         @rv
 192 }
 193
 194 sub upgrade () {
 195         if ($reexec_pid) {
 196                 warn "upgrade in-progress: $reexec_pid\n";
 197                 return;
 198         }
 199         if (defined $pid_file) {
 200                 if ($pid_file =~ /\.oldbin\z/) {
 201                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 202                         return;
 203                 }
 204                 unlink_pid_file_safe_ish($$, $pid_file);
 205                 $pid_file .= '.oldbin';
 206                 write_pid($pid_file);
 207         }
 208         my ($pid, $err) = do_fork();
 209         unless (defined $pid) {
 210                 warn "fork failed: $err\n";
 211                 return;
 212         }
 213         if ($pid == 0) {
 214                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 215                 $ENV{LISTEN_FDS} = scalar @listeners;
 216                 $ENV{LISTEN_PID} = $$;
 217                 foreach my $s (@listeners) {
 218                         my $fl = fcntl($s, F_GETFD, 0);
 219                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 220                 }
 221                 exec @CMD;
 222                 die "Failed to exec: $!\n";
 223         }
 224         $reexec_pid = $pid;
 225 }
 226
 227 sub kill_workers ($) {
 228         my ($s) = @_;
 229
 230         while (my ($pid, $id) = each %pids) {
 231                 kill $s, $pid;
 232         }
 233 }
 234
 235 sub do_fork () {
 236         my $new = POSIX::SigSet->new;
 237         $new->fillset;
 238         my $old = POSIX::SigSet->new;
 239         POSIX::sigprocmask(&POSIX::SIG_BLOCK, $new, $old) or die "SIG_BLOCK: $!";
 240         my $pid = fork;
 241         my $err = $!;
 242         POSIX::sigprocmask(&POSIX::SIG_SETMASK, $old) or die "SIG_SETMASK: $!";
 243         ($pid, $err);
 244 }
 245
 246 sub upgrade_aborted ($) {
 247         my ($p) = @_;
 248         warn "reexec PID($p) died with: $?\n";
 249         $reexec_pid = undef;
 250         return unless $pid_file;
 251
 252         my $file = $pid_file;
 253         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 254         unlink_pid_file_safe_ish($$, $pid_file);
 255         $pid_file = $file;
 256         eval { write_pid($pid_file) };
 257         warn $@, "\n" if $@;
 258 }
 259
 260 sub reap_children () {
 261         while (1) {
 262                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 263                 if (defined $reexec_pid && $p == $reexec_pid) {
 264                         upgrade_aborted($p);
 265                 } elsif (defined(my $id = delete $pids{$p})) {
 266                         warn "worker[$id] PID($p) died with: $?\n";
 267                 } elsif ($p > 0) {
 268                         warn "unknown PID($p) reaped: $?\n";
 269                 } else {
 270                         return;
 271                 }
 272         }
 273 }
 274
 275 sub unlink_pid_file_safe_ish ($$) {
 276         my ($unlink_pid, $file) = @_;
 277         return unless defined $unlink_pid && $unlink_pid == $$;
 278
 279         open my $fh, '<', $file or return;
 280         defined(my $read_pid = <$fh>) or return;
 281         chomp $read_pid;
 282         if ($read_pid == $unlink_pid) {
 283                 Net::Server::Daemonize::unlink_pid_file($file);
 284         }
 285 }
 286
 287 sub master_loop {
 288         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 289         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 290         IO::Handle::blocking($w, 0);
 291         my $set_workers = $worker_processes;
 292         my @caught;
 293         my $master_pid = $$;
 294         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 295                 $SIG{$s} = sub {
 296                         return if $$ != $master_pid;
 297                         push @caught, $s;
 298                         syswrite($w, '.');
 299                 };
 300         }
 301         reopen_logs();
 302         # main loop
 303         while (1) {
 304                 while (my $s = shift @caught) {
 305                         if ($s eq 'USR1') {
 306                                 reopen_logs();
 307                                 kill_workers($s);
 308                         } elsif ($s eq 'USR2') {
 309                                 upgrade();
 310                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 311                                 # drops pipes and causes children to die
 312                                 exit
 313                         } elsif ($s eq 'WINCH') {
 314                                 $worker_processes = 0;
 315                         } elsif ($s eq 'HUP') {
 316                                 $worker_processes = $set_workers;
 317                                 kill_workers($s);
 318                         } elsif ($s eq 'TTIN') {
 319                                 if ($set_workers > $worker_processes) {
 320                                         ++$worker_processes;
 321                                 } else {
 322                                         $worker_processes = ++$set_workers;
 323                                 }
 324                         } elsif ($s eq 'TTOU') {
 325                                 if ($set_workers > 0) {
 326                                         $worker_processes = --$set_workers;
 327                                 }
 328                         } elsif ($s eq 'CHLD') {
 329                                 reap_children();
 330                         }
 331                 }
 332
 333                 my $n = scalar keys %pids;
 334                 if ($n > $worker_processes) {
 335                         while (my ($k, $v) = each %pids) {
 336                                 kill('TERM', $k) if $v >= $worker_processes;
 337                         }
 338                         $n = $worker_processes;
 339                 }
 340                 foreach my $i ($n..($worker_processes - 1)) {
 341                         my ($pid, $err) = do_fork();
 342                         if (!defined $pid) {
 343                                 warn "failed to fork worker[$i]: $err\n";
 344                         } elsif ($pid == 0) {
 345                                 $set_user->() if $set_user;
 346                                 return $p0; # run normal work code
 347                         } else {
 348                                 warn "PID=$pid is worker[$i]\n";
 349                                 $pids{$pid} = $i;
 350                         }
 351                 }
 352                 # just wait on signal events here:
 353                 sysread($r, my $buf, 8);
 354         }
 355         exit # never gets here, just for documentation
 356 }
 357
 358 sub daemon_loop ($$) {
 359         my ($refresh, $post_accept) = @_;
 360         my $parent_pipe;
 361         if ($worker_processes > 0) {
 362                 $refresh->(); # preload by default
 363                 $parent_pipe = master_loop(); # returns if in child process
 364                 my $fd = fileno($parent_pipe);
 365                 Danga::Socket->AddOtherFds($fd => sub { kill('TERM', $$) } );
 366         } else {
 367                 reopen_logs();
 368                 $set_user->() if $set_user;
 369                 $SIG{USR2} = sub { worker_quit() if upgrade() };
 370                 $refresh->();
 371         }
 372         $uid = $gid = undef;
 373         reopen_logs();
 374         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 375         $SIG{USR1} = *reopen_logs;
 376         $SIG{HUP} = $refresh;
 377         # this calls epoll_create:
 378         PublicInbox::Listener->new($_, $post_accept) for @listeners;
 379         Danga::Socket->EventLoop;
 380         $parent_pipe = undef;
 381 }
 382
 383
 384 sub run ($$$) {
 385         my ($default, $refresh, $post_accept) = @_;
 386         daemon_prepare($default);
 387         daemonize();
 388         daemon_loop($refresh, $post_accept);
 389 }
 390
 391 sub do_chown ($) {
 392         my ($path) = @_;
 393         if (defined $uid and !chown($uid, $gid, $path)) {
 394                 warn "could not chown $path: $!\n";
 395         }
 396 }
 397
 398 sub write_pid ($) {
 399         my ($path) = @_;
 400         Net::Server::Daemonize::create_pid_file($path);
 401         do_chown($path);
 402 }
 403
 404 1;