lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 use Cwd qw/abs_path/;
  12 STDOUT->autoflush(1);
  13 STDERR->autoflush(1);
  14 use PublicInbox::DS qw(now);
  15 require PublicInbox::EvCleanup;
  16 require POSIX;
  17 require PublicInbox::Listener;
  18 require PublicInbox::ParentPipe;
  19 my @CMD;
  20 my $set_user;
  21 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  22 my $worker_processes = 1;
  23 my @listeners;
  24 my %pids;
  25 my %listener_names; # sockname => IO::Handle
  26 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  27 my $reexec_pid;
  28 my $cleanup;
  29 my ($uid, $gid);
  30 my ($default_cert, $default_key);
  31 END { $cleanup->() if $cleanup };
  32 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps' );
  33 my %KNOWN_STARTTLS = ( 119 => 'nntp' );
  34
  35 sub accept_tls_opt ($) {
  36         my ($opt_str) = @_;
  37         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  38         require PublicInbox::TLS;
  39         my $o = {};
  40         # allow ',' as delimiter since '&' is shell-unfriendly
  41         foreach (split(/[,&]/, $opt_str)) {
  42                 my ($k, $v) = split(/=/, $_, 2);
  43                 push @{$o->{$k} ||= []}, $v;
  44         }
  45
  46         # key may be a part of cert.  At least
  47         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  48         $o->{cert} //= [ $default_cert ];
  49         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  50         my %ctx_opt = (SSL_server => 1);
  51         # parse out hostname:/path/to/ mappings:
  52         foreach my $k (qw(cert key)) {
  53                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  54                 foreach my $path (@{$o->{$k}}) {
  55                         my $host = '';
  56                         $path =~ s/\A([^:]+):// and $host = $1;
  57                         $x->{$host} = $path;
  58                 }
  59         }
  60         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  61                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  62         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  63 }
  64
  65 sub daemon_prepare ($) {
  66         my ($default_listen) = @_;
  67         @CMD = ($0, @ARGV);
  68         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  69                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  70         my %opts = (
  71                 'l|listen=s' => \@cfg_listen,
  72                 '1|stdout=s' => \$stdout,
  73                 '2|stderr=s' => \$stderr,
  74                 'W|worker-processes=i' => \$worker_processes,
  75                 'P|pid-file=s' => \$pid_file,
  76                 'u|user=s' => \$user,
  77                 'g|group=s' => \$group,
  78                 'D|daemonize' => \$daemonize,
  79                 'cert=s' => \$default_cert,
  80                 'key=s' => \$default_key,
  81         );
  82         GetOptions(%opts) or die "bad command-line args\n";
  83
  84         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  85                 die "--pid-file cannot end with '.oldbin'\n";
  86         }
  87         @listeners = inherit();
  88
  89         # allow socket-activation users to set certs once and not
  90         # have to configure each socket:
  91         my @inherited_names = keys(%listener_names) if defined($default_cert);
  92
  93         # ignore daemonize when inheriting
  94         $daemonize = undef if scalar @listeners;
  95
  96         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  97
  98         foreach my $l (@cfg_listen) {
  99                 my $orig = $l;
 100                 my $scheme = '';
 101                 if ($l =~ s!\A([^:]+)://!!) {
 102                         $scheme = $1;
 103                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 104                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 105                         $scheme = $s if defined $s;
 106                 }
 107                 if ($l =~ s!/?\?(.+)\z!!) {
 108                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 109                 } elsif (defined($default_cert)) {
 110                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 111                 } elsif ($scheme =~ /\A(?:nntps|https)\z/) {
 112                         die "$orig specified w/o cert=\n";
 113                 }
 114                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 115
 116                 next if $listener_names{$l}; # already inherited
 117                 my (%o, $sock_pkg);
 118                 if (index($l, '/') == 0) {
 119                         $sock_pkg = 'IO::Socket::UNIX';
 120                         eval "use $sock_pkg";
 121                         die $@ if $@;
 122                         %o = (Type => SOCK_STREAM, Peer => $l);
 123                         if (-S $l) {
 124                                 my $c = $sock_pkg->new(%o);
 125                                 if (!defined($c) && $!{ECONNREFUSED}) {
 126                                         unlink $l or die
 127 "failed to unlink stale socket=$l: $!\n";
 128                                 } # else: let the bind fail
 129                         }
 130                         $o{Local} = delete $o{Peer};
 131                 } else {
 132                         # both work for IPv4, too
 133                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 134                                 $sock_pkg = $_;
 135                                 eval "use $sock_pkg";
 136                                 $@ or last;
 137                         }
 138                         die $@ if $@;
 139                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 140                 }
 141                 $o{Listen} = 1024;
 142                 my $prev = umask 0000;
 143                 my $s = eval { $sock_pkg->new(%o) };
 144                 warn "error binding $l: $! ($@)\n" unless $s;
 145                 umask $prev;
 146
 147                 if ($s) {
 148                         $listener_names{sockname($s)} = $s;
 149                         push @listeners, $s;
 150                 }
 151         }
 152
 153         # cert/key options in @cfg_listen takes precedence when inheriting,
 154         # but map well-known inherited ports if --listen isn't specified
 155         # at all
 156         for my $sockname (@inherited_names) {
 157                 $sockname =~ /:([0-9]+)\z/ or next;
 158                 if (my $scheme = $KNOWN_TLS{$1}) {
 159                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 160                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 161                         next if $tls_opt{"$scheme://$sockname"};
 162                         $tls_opt{''} ||= accept_tls_opt('');
 163                 }
 164         }
 165
 166         die "No listeners bound\n" unless @listeners;
 167 }
 168
 169 sub check_absolute ($$) {
 170         my ($var, $val) = @_;
 171         if (defined $val && index($val, '/') != 0) {
 172                 die
 173 "--$var must be an absolute path when using --daemonize: $val\n";
 174         }
 175 }
 176
 177 sub daemonize () {
 178         if ($daemonize) {
 179                 foreach my $i (0..$#ARGV) {
 180                         my $arg = $ARGV[$i];
 181                         next unless -e $arg;
 182                         $ARGV[$i] = abs_path($arg);
 183                 }
 184                 check_absolute('stdout', $stdout);
 185                 check_absolute('stderr', $stderr);
 186                 check_absolute('pid-file', $pid_file);
 187
 188                 chdir '/' or die "chdir failed: $!";
 189         }
 190
 191         return unless (defined $pid_file || defined $group || defined $user
 192                         || $daemonize);
 193
 194         eval { require Net::Server::Daemonize };
 195         if ($@) {
 196                 die
 197 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 198         }
 199
 200         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 201         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 202         if (defined $group) {
 203                 $gid = Net::Server::Daemonize::get_gid($group);
 204                 $gid = (split /\s+/, $gid)[0];
 205         } elsif (defined $uid) {
 206                 $gid = (getpwuid($uid))[3];
 207         }
 208
 209         # We change users in the worker to ensure upgradability,
 210         # The upgrade will create the ".oldbin" pid file in the
 211         # same directory as the given pid file.
 212         $uid and $set_user = sub {
 213                 $set_user = undef;
 214                 Net::Server::Daemonize::set_user($uid, $gid);
 215         };
 216
 217         if ($daemonize) {
 218                 my $pid = fork;
 219                 die "could not fork: $!\n" unless defined $pid;
 220                 exit if $pid;
 221
 222                 open(STDIN, '+<', '/dev/null') or
 223                                         die "redirect stdin failed: $!\n";
 224                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 225                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 226                 POSIX::setsid();
 227                 $pid = fork;
 228                 die "could not fork: $!\n" unless defined $pid;
 229                 exit if $pid;
 230         }
 231         if (defined $pid_file) {
 232                 write_pid($pid_file);
 233                 my $unlink_pid = $$;
 234                 $cleanup = sub {
 235                         $cleanup = undef; # avoid cyclic reference
 236                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 237                 };
 238         }
 239 }
 240
 241
 242 sub worker_quit {
 243         my ($reason) = @_;
 244         # killing again terminates immediately:
 245         exit unless @listeners;
 246
 247         $_->close foreach @listeners; # call PublicInbox::DS::close
 248         @listeners = ();
 249         $reason->close if ref($reason) eq 'PublicInbox::ParentPipe';
 250
 251         my $proc_name;
 252         my $warn = 0;
 253         # drop idle connections and try to quit gracefully
 254         PublicInbox::DS->SetPostLoopCallback(sub {
 255                 my ($dmap, undef) = @_;
 256                 my $n = 0;
 257                 my $now = now();
 258
 259                 foreach my $s (values %$dmap) {
 260                         $s->can('busy') or next;
 261                         if ($s->busy($now)) {
 262                                 ++$n;
 263                         } else {
 264                                 # close as much as possible, early as possible
 265                                 $s->close;
 266                         }
 267                 }
 268                 if ($n) {
 269                         if (($warn + 5) < now()) {
 270                                 warn "$$ quitting, $n client(s) left\n";
 271                                 $warn = now();
 272                         }
 273                         unless (defined $proc_name) {
 274                                 $proc_name = (split(/\s+/, $0))[0];
 275                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 276                         }
 277                         $0 = "$proc_name quitting, $n client(s) left";
 278                 }
 279                 $n; # true: loop continues, false: loop breaks
 280         });
 281 }
 282
 283 sub reopen_logs {
 284         if ($stdout) {
 285                 open STDOUT, '>>', $stdout or
 286                         warn "failed to redirect stdout to $stdout: $!\n";
 287                 STDOUT->autoflush(1);
 288                 do_chown($stdout);
 289         }
 290         if ($stderr) {
 291                 open STDERR, '>>', $stderr or
 292                         warn "failed to redirect stderr to $stderr: $!\n";
 293                 STDERR->autoflush(1);
 294                 do_chown($stderr);
 295         }
 296 }
 297
 298 sub sockname ($) {
 299         my ($s) = @_;
 300         my $addr = getsockname($s) or return;
 301         my ($host, $port) = host_with_port($addr);
 302         if ($port == 0 && $host eq '127.0.0.1') {
 303                 my ($path) = Socket::sockaddr_un($addr);
 304                 return $path;
 305         }
 306         "$host:$port";
 307 }
 308
 309 sub unpack_ipv6 ($) {
 310         my ($addr) = @_;
 311         my ($port, $host);
 312
 313         # Socket.pm in Perl 5.14+ supports IPv6:
 314         eval {
 315                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 316                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 317         };
 318
 319         if ($@) {
 320                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 321                 # Socket6, so it may be installed on our system, already
 322                 # (otherwise die here):
 323                 require Socket6;
 324
 325                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 326                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 327         }
 328         ($host, $port);
 329 }
 330
 331 sub host_with_port ($) {
 332         my ($addr) = @_;
 333         my ($port, $host);
 334
 335         # this eval will die on Unix sockets:
 336         eval {
 337                 if (length($addr) >= 28) {
 338                         ($host, $port) = unpack_ipv6($addr);
 339                         $host = "[$host]";
 340                 } else {
 341                         ($port, $host) = Socket::sockaddr_in($addr);
 342                         $host = Socket::inet_ntoa($host);
 343                 }
 344         };
 345         $@ ? ('127.0.0.1', 0) : ($host, $port);
 346 }
 347
 348 sub inherit () {
 349         return () if ($ENV{LISTEN_PID} || 0) != $$;
 350         my $fds = $ENV{LISTEN_FDS} or return ();
 351         my $end = $fds + 2; # LISTEN_FDS_START - 1
 352         my @rv = ();
 353         foreach my $fd (3..$end) {
 354                 my $s = IO::Handle->new_from_fd($fd, 'r');
 355                 if (my $k = sockname($s)) {
 356                         $listener_names{$k} = $s;
 357                         push @rv, $s;
 358                 } else {
 359                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 360                 }
 361         }
 362         @rv
 363 }
 364
 365 sub upgrade () {
 366         if ($reexec_pid) {
 367                 warn "upgrade in-progress: $reexec_pid\n";
 368                 return;
 369         }
 370         if (defined $pid_file) {
 371                 if ($pid_file =~ /\.oldbin\z/) {
 372                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 373                         return;
 374                 }
 375                 unlink_pid_file_safe_ish($$, $pid_file);
 376                 $pid_file .= '.oldbin';
 377                 write_pid($pid_file);
 378         }
 379         my $pid = fork;
 380         unless (defined $pid) {
 381                 warn "fork failed: $!\n";
 382                 return;
 383         }
 384         if ($pid == 0) {
 385                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 386                 $ENV{LISTEN_FDS} = scalar @listeners;
 387                 $ENV{LISTEN_PID} = $$;
 388                 foreach my $s (@listeners) {
 389                         my $fl = fcntl($s, F_GETFD, 0);
 390                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 391                 }
 392                 exec @CMD;
 393                 die "Failed to exec: $!\n";
 394         }
 395         $reexec_pid = $pid;
 396 }
 397
 398 sub kill_workers ($) {
 399         my ($s) = @_;
 400
 401         while (my ($pid, $id) = each %pids) {
 402                 kill $s, $pid;
 403         }
 404 }
 405
 406 sub upgrade_aborted ($) {
 407         my ($p) = @_;
 408         warn "reexec PID($p) died with: $?\n";
 409         $reexec_pid = undef;
 410         return unless $pid_file;
 411
 412         my $file = $pid_file;
 413         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 414         unlink_pid_file_safe_ish($$, $pid_file);
 415         $pid_file = $file;
 416         eval { write_pid($pid_file) };
 417         warn $@, "\n" if $@;
 418 }
 419
 420 sub reap_children () {
 421         while (1) {
 422                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 423                 if (defined $reexec_pid && $p == $reexec_pid) {
 424                         upgrade_aborted($p);
 425                 } elsif (defined(my $id = delete $pids{$p})) {
 426                         warn "worker[$id] PID($p) died with: $?\n";
 427                 } elsif ($p > 0) {
 428                         warn "unknown PID($p) reaped: $?\n";
 429                 } else {
 430                         return;
 431                 }
 432         }
 433 }
 434
 435 sub unlink_pid_file_safe_ish ($$) {
 436         my ($unlink_pid, $file) = @_;
 437         return unless defined $unlink_pid && $unlink_pid == $$;
 438
 439         open my $fh, '<', $file or return;
 440         local $/ = "\n";
 441         defined(my $read_pid = <$fh>) or return;
 442         chomp $read_pid;
 443         if ($read_pid == $unlink_pid) {
 444                 Net::Server::Daemonize::unlink_pid_file($file);
 445         }
 446 }
 447
 448 sub master_loop {
 449         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 450         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 451
 452         if ($^O eq 'linux') { # 1031: F_SETPIPE_SZ = 1031
 453                 fcntl($_, 1031, 4096) for ($w, $p1);
 454         }
 455
 456         IO::Handle::blocking($w, 0);
 457         my $set_workers = $worker_processes;
 458         my @caught;
 459         my $master_pid = $$;
 460         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 461                 $SIG{$s} = sub {
 462                         return if $$ != $master_pid;
 463                         push @caught, $s;
 464                         syswrite($w, '.');
 465                 };
 466         }
 467         reopen_logs();
 468         # main loop
 469         my $quit = 0;
 470         while (1) {
 471                 while (my $s = shift @caught) {
 472                         if ($s eq 'USR1') {
 473                                 reopen_logs();
 474                                 kill_workers($s);
 475                         } elsif ($s eq 'USR2') {
 476                                 upgrade();
 477                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 478                                 exit if $quit++;
 479                                 kill_workers($s);
 480                         } elsif ($s eq 'WINCH') {
 481                                 if (-t STDIN || -t STDOUT || -t STDERR) {
 482                                         warn
 483 "ignoring SIGWINCH since we are not daemonized\n";
 484                                         $SIG{WINCH} = 'IGNORE';
 485                                 } else {
 486                                         $worker_processes = 0;
 487                                 }
 488                         } elsif ($s eq 'HUP') {
 489                                 $worker_processes = $set_workers;
 490                                 kill_workers($s);
 491                         } elsif ($s eq 'TTIN') {
 492                                 if ($set_workers > $worker_processes) {
 493                                         ++$worker_processes;
 494                                 } else {
 495                                         $worker_processes = ++$set_workers;
 496                                 }
 497                         } elsif ($s eq 'TTOU') {
 498                                 if ($set_workers > 0) {
 499                                         $worker_processes = --$set_workers;
 500                                 }
 501                         } elsif ($s eq 'CHLD') {
 502                                 reap_children();
 503                         }
 504                 }
 505
 506                 my $n = scalar keys %pids;
 507                 if ($quit) {
 508                         exit if $n == 0;
 509                         $set_workers = $worker_processes = $n = 0;
 510                 }
 511
 512                 if ($n > $worker_processes) {
 513                         while (my ($k, $v) = each %pids) {
 514                                 kill('TERM', $k) if $v >= $worker_processes;
 515                         }
 516                         $n = $worker_processes;
 517                 }
 518                 foreach my $i ($n..($worker_processes - 1)) {
 519                         my $pid = fork;
 520                         if (!defined $pid) {
 521                                 warn "failed to fork worker[$i]: $!\n";
 522                         } elsif ($pid == 0) {
 523                                 $set_user->() if $set_user;
 524                                 return $p0; # run normal work code
 525                         } else {
 526                                 warn "PID=$pid is worker[$i]\n";
 527                                 $pids{$pid} = $i;
 528                         }
 529                 }
 530                 # just wait on signal events here:
 531                 sysread($r, my $buf, 8);
 532         }
 533         exit # never gets here, just for documentation
 534 }
 535
 536 sub tls_start_cb ($$) {
 537         my ($opt, $orig_post_accept) = @_;
 538         sub {
 539                 my ($io, $addr, $srv) = @_;
 540                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 541                 $orig_post_accept->($ssl, $addr, $srv);
 542         }
 543 }
 544
 545 sub daemon_loop ($$$) {
 546         my ($refresh, $post_accept, $nntpd) = @_;
 547         PublicInbox::EvCleanup::enable(); # early for $refresh
 548         my %post_accept;
 549         while (my ($k, $v) = each %tls_opt) {
 550                 if ($k =~ s!\A(?:nntps|https)://!!) {
 551                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 552                 } elsif ($nntpd) { # STARTTLS, $k eq '' is OK
 553                         $nntpd->{accept_tls} = $v;
 554                 }
 555         }
 556         my $parent_pipe;
 557         if ($worker_processes > 0) {
 558                 $refresh->(); # preload by default
 559                 my $fh = master_loop(); # returns if in child process
 560                 $parent_pipe = PublicInbox::ParentPipe->new($fh, *worker_quit);
 561         } else {
 562                 reopen_logs();
 563                 $set_user->() if $set_user;
 564                 $SIG{USR2} = sub { worker_quit('USR2') if upgrade() };
 565                 $refresh->();
 566         }
 567         $uid = $gid = undef;
 568         reopen_logs();
 569         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 570         $SIG{USR1} = *reopen_logs;
 571         $SIG{HUP} = $refresh;
 572         $SIG{CHLD} = 'DEFAULT';
 573         $SIG{$_} = 'IGNORE' for qw(USR2 TTIN TTOU WINCH);
 574         # this calls epoll_create:
 575         @listeners = map {
 576                 PublicInbox::Listener->new($_,
 577                                 $post_accept{sockname($_)} || $post_accept)
 578         } @listeners;
 579         PublicInbox::DS->EventLoop;
 580         $parent_pipe = undef;
 581 }
 582
 583
 584 sub run ($$$;$) {
 585         my ($default, $refresh, $post_accept, $nntpd) = @_;
 586         daemon_prepare($default);
 587         daemonize();
 588         daemon_loop($refresh, $post_accept, $nntpd);
 589 }
 590
 591 sub do_chown ($) {
 592         my ($path) = @_;
 593         if (defined $uid and !chown($uid, $gid, $path)) {
 594                 warn "could not chown $path: $!\n";
 595         }
 596 }
 597
 598 sub write_pid ($) {
 599         my ($path) = @_;
 600         Net::Server::Daemonize::create_pid_file($path);
 601         do_chown($path);
 602 }
 603
 604 1;