lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Daemon; # empty class :p
   4
   5 # contains common daemon code for the nntpd server.
   6 # This may be used for read-only IMAP server if we decide to implement it.
   7 package main;
   8 use strict;
   9 use warnings;
  10 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  11 require Danga::Socket;
  12 require POSIX;
  13 require PublicInbox::Listener;
  14 my @CMD;
  15 my $set_user;
  16 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  17 my $worker_processes = 1;
  18 my @listeners;
  19 my %pids;
  20 my %listener_names;
  21 my $reexec_pid;
  22 my $cleanup;
  23 my ($uid, $gid);
  24 END { $cleanup->() if $cleanup };
  25
  26 sub daemon_prepare ($) {
  27         my ($default_listen) = @_;
  28         @CMD = ($0, @ARGV);
  29         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  30                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  31         my %opts = (
  32                 'l|listen=s' => \@cfg_listen,
  33                 '1|stdout=s' => \$stdout,
  34                 '2|stderr=s' => \$stderr,
  35                 'W|worker-processes=i' => \$worker_processes,
  36                 'P|pid-file=s' => \$pid_file,
  37                 'u|user=s' => \$user,
  38                 'g|group=s' => \$group,
  39                 'D|daemonize' => \$daemonize,
  40         );
  41         GetOptions(%opts) or die "bad command-line args\n";
  42
  43         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  44                 die "--pid-file cannot end with '.oldbin'\n";
  45         }
  46         @listeners = inherit();
  47         # ignore daemonize when inheriting
  48         $daemonize = undef if scalar @listeners;
  49
  50         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  51
  52         foreach my $l (@cfg_listen) {
  53                 next if $listener_names{$l}; # already inherited
  54                 require IO::Socket::INET6; # works for IPv4, too
  55                 my %o = (
  56                         LocalAddr => $l,
  57                         ReuseAddr => 1,
  58                         Proto => 'tcp',
  59                 );
  60                 if (my $s = IO::Socket::INET6->new(%o)) {
  61                         $listener_names{sockname($s)} = $s;
  62                         push @listeners, $s;
  63                 } else {
  64                         warn "error binding $l: $!\n";
  65                 }
  66         }
  67         die 'No listeners bound' unless @listeners;
  68 }
  69
  70 sub daemonize () {
  71         chdir '/' or die "chdir failed: $!\n";
  72         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!\n";
  73
  74         return unless (defined $pid_file || defined $group || defined $user
  75                         || $daemonize);
  76
  77         require Net::Server::Daemonize;
  78
  79         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
  80         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
  81         if (defined $group) {
  82                 $gid = Net::Server::Daemonize::get_gid($group);
  83                 $gid = (split /\s+/, $gid)[0];
  84         } elsif (defined $uid) {
  85                 $gid = (getpwuid($uid))[3];
  86         }
  87
  88         # We change users in the worker to ensure upgradability,
  89         # The upgrade will create the ".oldbin" pid file in the
  90         # same directory as the given pid file.
  91         $uid and $set_user = sub {
  92                 Net::Server::Daemonize::set_user($uid, $gid);
  93         };
  94
  95         if ($daemonize) {
  96                 my ($pid, $err) = do_fork();
  97                 die "could not fork: $err\n" unless defined $pid;
  98                 exit if $pid;
  99
 100                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 101                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 102                 POSIX::setsid();
 103                 ($pid, $err) = do_fork();
 104                 die "could not fork: $err\n" unless defined $pid;
 105                 exit if $pid;
 106         }
 107         if (defined $pid_file) {
 108                 write_pid($pid_file);
 109                 my $unlink_pid = $$;
 110                 $cleanup = sub {
 111                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 112                 };
 113         }
 114 }
 115
 116 sub worker_quit () {
 117         # killing again terminates immediately:
 118         exit unless @listeners;
 119
 120         @listeners = ();
 121
 122         # give slow clients 30s to finish reading/writing whatever
 123         Danga::Socket->AddTimer(30, sub { exit });
 124
 125         # drop idle connections and try to quit gracefully
 126         Danga::Socket->SetPostLoopCallback(sub {
 127                 my ($dmap, undef) = @_;
 128                 my $n = 0;
 129
 130                 foreach my $s (values %$dmap) {
 131                         if ($s->can('busy') && $s->busy) {
 132                                 $n = 1;
 133                         } else {
 134                                 # close as much as possible, early as possible
 135                                 $s->close;
 136                         }
 137                 }
 138                 $n; # true: loop continues, false: loop breaks
 139         });
 140 }
 141
 142 sub reopen_logs {
 143         if ($stdout) {
 144                 open STDOUT, '>>', $stdout or
 145                         warn "failed to redirect stdout to $stdout: $!\n";
 146                 STDOUT->autoflush(1);
 147                 do_chown($stdout);
 148         }
 149         if ($stderr) {
 150                 open STDERR, '>>', $stderr or
 151                         warn "failed to redirect stderr to $stderr: $!\n";
 152                 STDERR->autoflush(1);
 153                 do_chown($stderr);
 154         }
 155 }
 156
 157 sub sockname ($) {
 158         my ($s) = @_;
 159         my $n = getsockname($s) or return;
 160         my ($port, $addr);
 161         if (length($n) >= 28) {
 162                 require Socket6;
 163                 ($port, $addr) = Socket6::unpack_sockaddr_in6($n);
 164         } else {
 165                 ($port, $addr) = Socket::sockaddr_in($n);
 166         }
 167         if (length($addr) == 4) {
 168                 $n = Socket::inet_ntoa($addr)
 169         } else {
 170                 $n = '['.Socket6::inet_ntop(Socket6::AF_INET6(), $addr).']';
 171         }
 172         $n .= ":$port";
 173 }
 174
 175 sub inherit () {
 176         return () if ($ENV{LISTEN_PID} || 0) != $$;
 177         my $fds = $ENV{LISTEN_FDS} or return ();
 178         my $end = $fds + 2; # LISTEN_FDS_START - 1
 179         my @rv = ();
 180         foreach my $fd (3..$end) {
 181                 my $s = IO::Handle->new;
 182                 $s->fdopen($fd, 'r');
 183                 if (my $k = sockname($s)) {
 184                         $listener_names{$k} = $s;
 185                         push @rv, $s;
 186                 } else {
 187                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 188                 }
 189         }
 190         @rv
 191 }
 192
 193 sub upgrade () {
 194         if ($reexec_pid) {
 195                 warn "upgrade in-progress: $reexec_pid\n";
 196                 return;
 197         }
 198         if (defined $pid_file) {
 199                 if ($pid_file =~ /\.oldbin\z/) {
 200                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 201                         return;
 202                 }
 203                 unlink_pid_file_safe_ish($$, $pid_file);
 204                 $pid_file .= '.oldbin';
 205                 write_pid($pid_file);
 206         }
 207         my ($pid, $err) = do_fork();
 208         unless (defined $pid) {
 209                 warn "fork failed: $err\n";
 210                 return;
 211         }
 212         if ($pid == 0) {
 213                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 214                 $ENV{LISTEN_FDS} = scalar @listeners;
 215                 $ENV{LISTEN_PID} = $$;
 216                 foreach my $s (@listeners) {
 217                         my $fl = fcntl($s, F_GETFD, 0);
 218                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 219                 }
 220                 exec @CMD;
 221                 die "Failed to exec: $!\n";
 222         }
 223         $reexec_pid = $pid;
 224 }
 225
 226 sub kill_workers ($) {
 227         my ($s) = @_;
 228
 229         while (my ($pid, $id) = each %pids) {
 230                 kill $s, $pid;
 231         }
 232 }
 233
 234 sub do_fork () {
 235         my $new = POSIX::SigSet->new;
 236         $new->fillset;
 237         my $old = POSIX::SigSet->new;
 238         POSIX::sigprocmask(&POSIX::SIG_BLOCK, $new, $old) or
 239                                 die "SIG_BLOCK: $!\n";
 240         my $pid = fork;
 241         my $err = $!;
 242         POSIX::sigprocmask(&POSIX::SIG_SETMASK, $old) or
 243                                 die "SIG_SETMASK: $!\n";
 244         ($pid, $err);
 245 }
 246
 247 sub upgrade_aborted ($) {
 248         my ($p) = @_;
 249         warn "reexec PID($p) died with: $?\n";
 250         $reexec_pid = undef;
 251         return unless $pid_file;
 252
 253         my $file = $pid_file;
 254         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file\n";
 255         unlink_pid_file_safe_ish($$, $pid_file);
 256         $pid_file = $file;
 257         eval { write_pid($pid_file) };
 258         warn $@, "\n" if $@;
 259 }
 260
 261 sub reap_children () {
 262         while (1) {
 263                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 264                 if (defined $reexec_pid && $p == $reexec_pid) {
 265                         upgrade_aborted($p);
 266                 } elsif (defined(my $id = delete $pids{$p})) {
 267                         warn "worker[$id] PID($p) died with: $?\n";
 268                 } elsif ($p > 0) {
 269                         warn "unknown PID($p) reaped: $?\n";
 270                 } else {
 271                         return;
 272                 }
 273         }
 274 }
 275
 276 sub unlink_pid_file_safe_ish ($$) {
 277         my ($unlink_pid, $file) = @_;
 278         return unless defined $unlink_pid && $unlink_pid == $$;
 279
 280         open my $fh, '<', $file or return;
 281         defined(my $read_pid = <$fh>) or return;
 282         chomp $read_pid;
 283         if ($read_pid == $unlink_pid) {
 284                 Net::Server::Daemonize::unlink_pid_file($file);
 285         }
 286 }
 287
 288 sub master_loop {
 289         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!\n";
 290         pipe(my ($r, $w)) or die "failed to create self-pipe: $!\n";
 291         IO::Handle::blocking($w, 0);
 292         my $set_workers = $worker_processes;
 293         my @caught;
 294         my $master_pid = $$;
 295         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 296                 $SIG{$s} = sub {
 297                         return if $$ != $master_pid;
 298                         push @caught, $s;
 299                         syswrite($w, '.');
 300                 };
 301         }
 302         reopen_logs();
 303         # main loop
 304         while (1) {
 305                 while (my $s = shift @caught) {
 306                         if ($s eq 'USR1') {
 307                                 reopen_logs();
 308                                 kill_workers($s);
 309                         } elsif ($s eq 'USR2') {
 310                                 upgrade();
 311                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 312                                 # drops pipes and causes children to die
 313                                 exit
 314                         } elsif ($s eq 'WINCH') {
 315                                 $worker_processes = 0;
 316                         } elsif ($s eq 'HUP') {
 317                                 $worker_processes = $set_workers;
 318                                 kill_workers($s);
 319                         } elsif ($s eq 'TTIN') {
 320                                 if ($set_workers > $worker_processes) {
 321                                         ++$worker_processes;
 322                                 } else {
 323                                         $worker_processes = ++$set_workers;
 324                                 }
 325                         } elsif ($s eq 'TTOU') {
 326                                 if ($set_workers > 0) {
 327                                         $worker_processes = --$set_workers;
 328                                 }
 329                         } elsif ($s eq 'CHLD') {
 330                                 reap_children();
 331                         }
 332                 }
 333
 334                 my $n = scalar keys %pids;
 335                 if ($n > $worker_processes) {
 336                         while (my ($k, $v) = each %pids) {
 337                                 kill('TERM', $k) if $v >= $worker_processes;
 338                         }
 339                         $n = $worker_processes;
 340                 }
 341                 foreach my $i ($n..($worker_processes - 1)) {
 342                         my ($pid, $err) = do_fork();
 343                         if (!defined $pid) {
 344                                 warn "failed to fork worker[$i]: $err\n";
 345                         } elsif ($pid == 0) {
 346                                 $set_user->() if $set_user;
 347                                 return $p0; # run normal work code
 348                         } else {
 349                                 warn "PID=$pid is worker[$i]\n";
 350                                 $pids{$pid} = $i;
 351                         }
 352                 }
 353                 # just wait on signal events here:
 354                 sysread($r, my $buf, 8);
 355         }
 356         exit # never gets here, just for documentation
 357 }
 358
 359 sub daemon_loop ($$) {
 360         my ($refresh, $post_accept) = @_;
 361         my $parent_pipe;
 362         if ($worker_processes > 0) {
 363                 $parent_pipe = master_loop(); # returns if in child process
 364                 my $fd = fileno($parent_pipe);
 365                 Danga::Socket->AddOtherFds($fd => sub { kill('TERM', $$) } );
 366         } else {
 367                 reopen_logs();
 368                 $set_user->() if $set_user;
 369                 $SIG{USR2} = sub { worker_quit() if upgrade() };
 370         }
 371         $uid = $gid = undef;
 372         reopen_logs();
 373         $refresh->();
 374         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 375         $SIG{USR1} = *reopen_logs;
 376         $SIG{HUP} = $refresh;
 377         # this calls epoll_create:
 378         PublicInbox::Listener->new($_, $post_accept) for @listeners;
 379         Danga::Socket->EventLoop;
 380         $parent_pipe = undef;
 381 }
 382
 383
 384 sub daemon_run ($$$) {
 385         my ($default, $refresh, $post_accept) = @_;
 386         daemon_prepare($default);
 387         daemonize();
 388         daemon_loop($refresh, $post_accept);
 389 }
 390
 391 sub do_chown ($) {
 392         my ($path) = @_;
 393         if (defined $uid and !chown($uid, $gid, $path)) {
 394                 warn "could not chown $path: $!\n";
 395         }
 396 }
 397
 398 sub write_pid ($) {
 399         my ($path) = @_;
 400         Net::Server::Daemonize::create_pid_file($path);
 401         do_chown($path);
 402 }
 403
 404 1;