lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 STDOUT->autoflush(1);
  12 STDERR->autoflush(1);
  13 require Danga::Socket;
  14 require POSIX;
  15 require PublicInbox::Listener;
  16 my @CMD;
  17 my $set_user;
  18 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  19 my $worker_processes = 1;
  20 my @listeners;
  21 my %pids;
  22 my %listener_names;
  23 my $reexec_pid;
  24 my $cleanup;
  25 my ($uid, $gid);
  26 END { $cleanup->() if $cleanup };
  27
  28 sub daemon_prepare ($) {
  29         my ($default_listen) = @_;
  30         @CMD = ($0, @ARGV);
  31         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  32                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  33         my %opts = (
  34                 'l|listen=s' => \@cfg_listen,
  35                 '1|stdout=s' => \$stdout,
  36                 '2|stderr=s' => \$stderr,
  37                 'W|worker-processes=i' => \$worker_processes,
  38                 'P|pid-file=s' => \$pid_file,
  39                 'u|user=s' => \$user,
  40                 'g|group=s' => \$group,
  41                 'D|daemonize' => \$daemonize,
  42         );
  43         GetOptions(%opts) or die "bad command-line args\n";
  44
  45         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  46                 die "--pid-file cannot end with '.oldbin'\n";
  47         }
  48         @listeners = inherit();
  49         # ignore daemonize when inheriting
  50         $daemonize = undef if scalar @listeners;
  51
  52         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  53
  54         foreach my $l (@cfg_listen) {
  55                 next if $listener_names{$l}; # already inherited
  56                 my (%o, $sock_pkg);
  57                 if (index($l, '/') == 0) {
  58                         $sock_pkg = 'IO::Socket::UNIX';
  59                         eval "use $sock_pkg";
  60                         die $@ if $@;
  61                         %o = (Type => SOCK_STREAM, Peer => $l);
  62                         if (-S $l) {
  63                                 my $c = $sock_pkg->new(%o);
  64                                 if (!defined($c) && $!{ECONNREFUSED}) {
  65                                         unlink $l or die
  66 "failed to unlink stale socket=$l: $!\n";
  67                                 } # else: let the bind fail
  68                         }
  69                         $o{Local} = delete $o{Peer};
  70                 } else {
  71                         $sock_pkg = 'IO::Socket::INET6'; # works for IPv4, too
  72                         eval "use $sock_pkg";
  73                         die $@ if $@;
  74                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
  75                 }
  76                 $o{Listen} = 1024;
  77                 my $prev = umask 0000;
  78                 my $s = eval { $sock_pkg->new(%o) };
  79                 warn "error binding $l: $!\n" unless $s;
  80                 umask $prev;
  81
  82                 if ($s) {
  83                         $listener_names{sockname($s)} = $s;
  84                         push @listeners, $s;
  85                 }
  86         }
  87         die "No listeners bound\n" unless @listeners;
  88 }
  89
  90 sub daemonize () {
  91         chdir '/' or die "chdir failed: $!";
  92         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
  93
  94         return unless (defined $pid_file || defined $group || defined $user
  95                         || $daemonize);
  96
  97         require Net::Server::Daemonize;
  98
  99         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 100         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 101         if (defined $group) {
 102                 $gid = Net::Server::Daemonize::get_gid($group);
 103                 $gid = (split /\s+/, $gid)[0];
 104         } elsif (defined $uid) {
 105                 $gid = (getpwuid($uid))[3];
 106         }
 107
 108         # We change users in the worker to ensure upgradability,
 109         # The upgrade will create the ".oldbin" pid file in the
 110         # same directory as the given pid file.
 111         $uid and $set_user = sub {
 112                 $set_user = undef;
 113                 Net::Server::Daemonize::set_user($uid, $gid);
 114         };
 115
 116         if ($daemonize) {
 117                 my ($pid, $err) = do_fork();
 118                 die "could not fork: $err\n" unless defined $pid;
 119                 exit if $pid;
 120
 121                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 122                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 123                 POSIX::setsid();
 124                 ($pid, $err) = do_fork();
 125                 die "could not fork: $err\n" unless defined $pid;
 126                 exit if $pid;
 127         }
 128         if (defined $pid_file) {
 129                 write_pid($pid_file);
 130                 my $unlink_pid = $$;
 131                 $cleanup = sub {
 132                         $cleanup = undef; # avoid cyclic reference
 133                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 134                 };
 135         }
 136 }
 137
 138 sub worker_quit () {
 139         # killing again terminates immediately:
 140         exit unless @listeners;
 141
 142         $_->close foreach @listeners; # call Danga::Socket::close
 143         @listeners = ();
 144
 145         # give slow clients 30s to finish reading/writing whatever
 146         Danga::Socket->AddTimer(30, sub { exit });
 147
 148         # drop idle connections and try to quit gracefully
 149         Danga::Socket->SetPostLoopCallback(sub {
 150                 my ($dmap, undef) = @_;
 151                 my $n = 0;
 152
 153                 foreach my $s (values %$dmap) {
 154                         if ($s->can('busy') && $s->busy) {
 155                                 $n = 1;
 156                         } else {
 157                                 # close as much as possible, early as possible
 158                                 $s->close;
 159                         }
 160                 }
 161                 $n; # true: loop continues, false: loop breaks
 162         });
 163 }
 164
 165 sub reopen_logs {
 166         if ($stdout) {
 167                 open STDOUT, '>>', $stdout or
 168                         warn "failed to redirect stdout to $stdout: $!\n";
 169                 STDOUT->autoflush(1);
 170                 do_chown($stdout);
 171         }
 172         if ($stderr) {
 173                 open STDERR, '>>', $stderr or
 174                         warn "failed to redirect stderr to $stderr: $!\n";
 175                 STDERR->autoflush(1);
 176                 do_chown($stderr);
 177         }
 178 }
 179
 180 sub sockname ($) {
 181         my ($s) = @_;
 182         my $addr = getsockname($s) or return;
 183         my ($host, $port) = host_with_port($addr);
 184         "$host:$port";
 185 }
 186
 187 sub host_with_port ($) {
 188         my ($addr) = @_;
 189         my ($port, $host);
 190
 191         # this eval will die on Unix sockets:
 192         eval {
 193                 if (length($addr) >= 28) {
 194                         require Socket6;
 195                         ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 196                         $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 197                         $host = "[$host]";
 198                 } else {
 199                         ($port, $host) = Socket::sockaddr_in($addr);
 200                         $host = Socket::inet_ntoa($host);
 201                 }
 202         };
 203         $@ ? ('127.0.0.1', 0) : ($host, $port);
 204 }
 205
 206 sub inherit () {
 207         return () if ($ENV{LISTEN_PID} || 0) != $$;
 208         my $fds = $ENV{LISTEN_FDS} or return ();
 209         my $end = $fds + 2; # LISTEN_FDS_START - 1
 210         my @rv = ();
 211         foreach my $fd (3..$end) {
 212                 my $s = IO::Handle->new_from_fd($fd, 'r');
 213                 if (my $k = sockname($s)) {
 214                         $listener_names{$k} = $s;
 215                         push @rv, $s;
 216                 } else {
 217                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 218                 }
 219         }
 220         @rv
 221 }
 222
 223 sub upgrade () {
 224         if ($reexec_pid) {
 225                 warn "upgrade in-progress: $reexec_pid\n";
 226                 return;
 227         }
 228         if (defined $pid_file) {
 229                 if ($pid_file =~ /\.oldbin\z/) {
 230                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 231                         return;
 232                 }
 233                 unlink_pid_file_safe_ish($$, $pid_file);
 234                 $pid_file .= '.oldbin';
 235                 write_pid($pid_file);
 236         }
 237         my ($pid, $err) = do_fork();
 238         unless (defined $pid) {
 239                 warn "fork failed: $err\n";
 240                 return;
 241         }
 242         if ($pid == 0) {
 243                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 244                 $ENV{LISTEN_FDS} = scalar @listeners;
 245                 $ENV{LISTEN_PID} = $$;
 246                 foreach my $s (@listeners) {
 247                         my $fl = fcntl($s, F_GETFD, 0);
 248                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 249                 }
 250                 exec @CMD;
 251                 die "Failed to exec: $!\n";
 252         }
 253         $reexec_pid = $pid;
 254 }
 255
 256 sub kill_workers ($) {
 257         my ($s) = @_;
 258
 259         while (my ($pid, $id) = each %pids) {
 260                 kill $s, $pid;
 261         }
 262 }
 263
 264 sub do_fork () {
 265         my $new = POSIX::SigSet->new;
 266         $new->fillset;
 267         my $old = POSIX::SigSet->new;
 268         POSIX::sigprocmask(&POSIX::SIG_BLOCK, $new, $old) or die "SIG_BLOCK: $!";
 269         my $pid = fork;
 270         my $err = $!;
 271         POSIX::sigprocmask(&POSIX::SIG_SETMASK, $old) or die "SIG_SETMASK: $!";
 272         ($pid, $err);
 273 }
 274
 275 sub upgrade_aborted ($) {
 276         my ($p) = @_;
 277         warn "reexec PID($p) died with: $?\n";
 278         $reexec_pid = undef;
 279         return unless $pid_file;
 280
 281         my $file = $pid_file;
 282         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 283         unlink_pid_file_safe_ish($$, $pid_file);
 284         $pid_file = $file;
 285         eval { write_pid($pid_file) };
 286         warn $@, "\n" if $@;
 287 }
 288
 289 sub reap_children () {
 290         while (1) {
 291                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 292                 if (defined $reexec_pid && $p == $reexec_pid) {
 293                         upgrade_aborted($p);
 294                 } elsif (defined(my $id = delete $pids{$p})) {
 295                         warn "worker[$id] PID($p) died with: $?\n";
 296                 } elsif ($p > 0) {
 297                         warn "unknown PID($p) reaped: $?\n";
 298                 } else {
 299                         return;
 300                 }
 301         }
 302 }
 303
 304 sub unlink_pid_file_safe_ish ($$) {
 305         my ($unlink_pid, $file) = @_;
 306         return unless defined $unlink_pid && $unlink_pid == $$;
 307
 308         open my $fh, '<', $file or return;
 309         defined(my $read_pid = <$fh>) or return;
 310         chomp $read_pid;
 311         if ($read_pid == $unlink_pid) {
 312                 Net::Server::Daemonize::unlink_pid_file($file);
 313         }
 314 }
 315
 316 sub master_loop {
 317         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 318         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 319         IO::Handle::blocking($w, 0);
 320         my $set_workers = $worker_processes;
 321         my @caught;
 322         my $master_pid = $$;
 323         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 324                 $SIG{$s} = sub {
 325                         return if $$ != $master_pid;
 326                         push @caught, $s;
 327                         syswrite($w, '.');
 328                 };
 329         }
 330         reopen_logs();
 331         # main loop
 332         while (1) {
 333                 while (my $s = shift @caught) {
 334                         if ($s eq 'USR1') {
 335                                 reopen_logs();
 336                                 kill_workers($s);
 337                         } elsif ($s eq 'USR2') {
 338                                 upgrade();
 339                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 340                                 # drops pipes and causes children to die
 341                                 exit
 342                         } elsif ($s eq 'WINCH') {
 343                                 $worker_processes = 0;
 344                         } elsif ($s eq 'HUP') {
 345                                 $worker_processes = $set_workers;
 346                                 kill_workers($s);
 347                         } elsif ($s eq 'TTIN') {
 348                                 if ($set_workers > $worker_processes) {
 349                                         ++$worker_processes;
 350                                 } else {
 351                                         $worker_processes = ++$set_workers;
 352                                 }
 353                         } elsif ($s eq 'TTOU') {
 354                                 if ($set_workers > 0) {
 355                                         $worker_processes = --$set_workers;
 356                                 }
 357                         } elsif ($s eq 'CHLD') {
 358                                 reap_children();
 359                         }
 360                 }
 361
 362                 my $n = scalar keys %pids;
 363                 if ($n > $worker_processes) {
 364                         while (my ($k, $v) = each %pids) {
 365                                 kill('TERM', $k) if $v >= $worker_processes;
 366                         }
 367                         $n = $worker_processes;
 368                 }
 369                 foreach my $i ($n..($worker_processes - 1)) {
 370                         my ($pid, $err) = do_fork();
 371                         if (!defined $pid) {
 372                                 warn "failed to fork worker[$i]: $err\n";
 373                         } elsif ($pid == 0) {
 374                                 $set_user->() if $set_user;
 375                                 return $p0; # run normal work code
 376                         } else {
 377                                 warn "PID=$pid is worker[$i]\n";
 378                                 $pids{$pid} = $i;
 379                         }
 380                 }
 381                 # just wait on signal events here:
 382                 sysread($r, my $buf, 8);
 383         }
 384         exit # never gets here, just for documentation
 385 }
 386
 387 sub daemon_loop ($$) {
 388         my ($refresh, $post_accept) = @_;
 389         my $parent_pipe;
 390         if ($worker_processes > 0) {
 391                 $refresh->(); # preload by default
 392                 $parent_pipe = master_loop(); # returns if in child process
 393                 my $fd = fileno($parent_pipe);
 394                 Danga::Socket->AddOtherFds($fd => sub { kill('TERM', $$) } );
 395         } else {
 396                 reopen_logs();
 397                 $set_user->() if $set_user;
 398                 $SIG{USR2} = sub { worker_quit() if upgrade() };
 399                 $refresh->();
 400         }
 401         $uid = $gid = undef;
 402         reopen_logs();
 403         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 404         $SIG{USR1} = *reopen_logs;
 405         $SIG{HUP} = $refresh;
 406         # this calls epoll_create:
 407         @listeners = map {
 408                 PublicInbox::Listener->new($_, $post_accept)
 409         } @listeners;
 410         Danga::Socket->EventLoop;
 411         $parent_pipe = undef;
 412 }
 413
 414
 415 sub run ($$$) {
 416         my ($default, $refresh, $post_accept) = @_;
 417         daemon_prepare($default);
 418         daemonize();
 419         daemon_loop($refresh, $post_accept);
 420 }
 421
 422 sub do_chown ($) {
 423         my ($path) = @_;
 424         if (defined $uid and !chown($uid, $gid, $path)) {
 425                 warn "could not chown $path: $!\n";
 426         }
 427 }
 428
 429 sub write_pid ($) {
 430         my ($path) = @_;
 431         Net::Server::Daemonize::create_pid_file($path);
 432         do_chown($path);
 433 }
 434
 435 1;