lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 STDOUT->autoflush(1);
  12 STDERR->autoflush(1);
  13 require Danga::Socket;
  14 require POSIX;
  15 require PublicInbox::Listener;
  16 my @CMD;
  17 my $set_user;
  18 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  19 my $worker_processes = 1;
  20 my @listeners;
  21 my %pids;
  22 my %listener_names;
  23 my $reexec_pid;
  24 my $cleanup;
  25 my ($uid, $gid);
  26 END { $cleanup->() if $cleanup };
  27
  28 sub daemon_prepare ($) {
  29         my ($default_listen) = @_;
  30         @CMD = ($0, @ARGV);
  31         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  32                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  33         my %opts = (
  34                 'l|listen=s' => \@cfg_listen,
  35                 '1|stdout=s' => \$stdout,
  36                 '2|stderr=s' => \$stderr,
  37                 'W|worker-processes=i' => \$worker_processes,
  38                 'P|pid-file=s' => \$pid_file,
  39                 'u|user=s' => \$user,
  40                 'g|group=s' => \$group,
  41                 'D|daemonize' => \$daemonize,
  42         );
  43         GetOptions(%opts) or die "bad command-line args\n";
  44
  45         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  46                 die "--pid-file cannot end with '.oldbin'\n";
  47         }
  48         @listeners = inherit();
  49         # ignore daemonize when inheriting
  50         $daemonize = undef if scalar @listeners;
  51
  52         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  53
  54         foreach my $l (@cfg_listen) {
  55                 next if $listener_names{$l}; # already inherited
  56                 my (%o, $sock_pkg);
  57                 if (index($l, '/') == 0) {
  58                         $sock_pkg = 'IO::Socket::UNIX';
  59                         eval "use $sock_pkg";
  60                         die $@ if $@;
  61                         %o = (Type => SOCK_STREAM, Peer => $l);
  62                         if (-S $l) {
  63                                 my $c = $sock_pkg->new(%o);
  64                                 if (!defined($c) && $!{ECONNREFUSED}) {
  65                                         unlink $l or die
  66 "failed to unlink stale socket=$l: $!\n";
  67                                 } # else: let the bind fail
  68                         }
  69                         $o{Local} = delete $o{Peer};
  70                 } else {
  71                         # both work for IPv4, too
  72                         for $sock_pkg (qw(IO::Socket::IP IO::Socket::INET6)) {
  73                                 eval "use $sock_pkg";
  74                                 $@ or last;
  75                         }
  76                         die $@ if $@;
  77                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
  78                 }
  79                 $o{Listen} = 1024;
  80                 my $prev = umask 0000;
  81                 my $s = eval { $sock_pkg->new(%o) };
  82                 warn "error binding $l: $!\n" unless $s;
  83                 umask $prev;
  84
  85                 if ($s) {
  86                         $listener_names{sockname($s)} = $s;
  87                         push @listeners, $s;
  88                 }
  89         }
  90         die "No listeners bound\n" unless @listeners;
  91 }
  92
  93 sub daemonize () {
  94         chdir '/' or die "chdir failed: $!";
  95         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
  96
  97         return unless (defined $pid_file || defined $group || defined $user
  98                         || $daemonize);
  99
 100         eval { require Net::Server::Daemonize };
 101         if ($@) {
 102                 die
 103 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 104         }
 105
 106         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 107         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 108         if (defined $group) {
 109                 $gid = Net::Server::Daemonize::get_gid($group);
 110                 $gid = (split /\s+/, $gid)[0];
 111         } elsif (defined $uid) {
 112                 $gid = (getpwuid($uid))[3];
 113         }
 114
 115         # We change users in the worker to ensure upgradability,
 116         # The upgrade will create the ".oldbin" pid file in the
 117         # same directory as the given pid file.
 118         $uid and $set_user = sub {
 119                 $set_user = undef;
 120                 Net::Server::Daemonize::set_user($uid, $gid);
 121         };
 122
 123         if ($daemonize) {
 124                 my ($pid, $err) = do_fork();
 125                 die "could not fork: $err\n" unless defined $pid;
 126                 exit if $pid;
 127
 128                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 129                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 130                 POSIX::setsid();
 131                 ($pid, $err) = do_fork();
 132                 die "could not fork: $err\n" unless defined $pid;
 133                 exit if $pid;
 134         }
 135         if (defined $pid_file) {
 136                 write_pid($pid_file);
 137                 my $unlink_pid = $$;
 138                 $cleanup = sub {
 139                         $cleanup = undef; # avoid cyclic reference
 140                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 141                 };
 142         }
 143 }
 144
 145 sub worker_quit () {
 146         # killing again terminates immediately:
 147         exit unless @listeners;
 148
 149         $_->close foreach @listeners; # call Danga::Socket::close
 150         @listeners = ();
 151
 152         # give slow clients 30s to finish reading/writing whatever
 153         Danga::Socket->AddTimer(30, sub { exit });
 154
 155         # drop idle connections and try to quit gracefully
 156         Danga::Socket->SetPostLoopCallback(sub {
 157                 my ($dmap, undef) = @_;
 158                 my $n = 0;
 159
 160                 foreach my $s (values %$dmap) {
 161                         if ($s->can('busy') && $s->busy) {
 162                                 $n = 1;
 163                         } else {
 164                                 # close as much as possible, early as possible
 165                                 $s->close;
 166                         }
 167                 }
 168                 $n; # true: loop continues, false: loop breaks
 169         });
 170 }
 171
 172 sub reopen_logs {
 173         if ($stdout) {
 174                 open STDOUT, '>>', $stdout or
 175                         warn "failed to redirect stdout to $stdout: $!\n";
 176                 STDOUT->autoflush(1);
 177                 do_chown($stdout);
 178         }
 179         if ($stderr) {
 180                 open STDERR, '>>', $stderr or
 181                         warn "failed to redirect stderr to $stderr: $!\n";
 182                 STDERR->autoflush(1);
 183                 do_chown($stderr);
 184         }
 185 }
 186
 187 sub sockname ($) {
 188         my ($s) = @_;
 189         my $addr = getsockname($s) or return;
 190         my ($host, $port) = host_with_port($addr);
 191         if ($port == 0 && $host eq '127.0.0.1') {
 192                 my ($path) = Socket::sockaddr_un($addr);
 193                 return $path;
 194         }
 195         "$host:$port";
 196 }
 197
 198 sub host_with_port ($) {
 199         my ($addr) = @_;
 200         my ($port, $host);
 201
 202         # this eval will die on Unix sockets:
 203         eval {
 204                 if (length($addr) >= 28) {
 205                         require Socket6;
 206                         ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 207                         $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 208                         $host = "[$host]";
 209                 } else {
 210                         ($port, $host) = Socket::sockaddr_in($addr);
 211                         $host = Socket::inet_ntoa($host);
 212                 }
 213         };
 214         $@ ? ('127.0.0.1', 0) : ($host, $port);
 215 }
 216
 217 sub inherit () {
 218         return () if ($ENV{LISTEN_PID} || 0) != $$;
 219         my $fds = $ENV{LISTEN_FDS} or return ();
 220         my $end = $fds + 2; # LISTEN_FDS_START - 1
 221         my @rv = ();
 222         foreach my $fd (3..$end) {
 223                 my $s = IO::Handle->new_from_fd($fd, 'r');
 224                 if (my $k = sockname($s)) {
 225                         $listener_names{$k} = $s;
 226                         push @rv, $s;
 227                 } else {
 228                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 229                 }
 230         }
 231         @rv
 232 }
 233
 234 sub upgrade () {
 235         if ($reexec_pid) {
 236                 warn "upgrade in-progress: $reexec_pid\n";
 237                 return;
 238         }
 239         if (defined $pid_file) {
 240                 if ($pid_file =~ /\.oldbin\z/) {
 241                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 242                         return;
 243                 }
 244                 unlink_pid_file_safe_ish($$, $pid_file);
 245                 $pid_file .= '.oldbin';
 246                 write_pid($pid_file);
 247         }
 248         my ($pid, $err) = do_fork();
 249         unless (defined $pid) {
 250                 warn "fork failed: $err\n";
 251                 return;
 252         }
 253         if ($pid == 0) {
 254                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 255                 $ENV{LISTEN_FDS} = scalar @listeners;
 256                 $ENV{LISTEN_PID} = $$;
 257                 foreach my $s (@listeners) {
 258                         my $fl = fcntl($s, F_GETFD, 0);
 259                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 260                 }
 261                 exec @CMD;
 262                 die "Failed to exec: $!\n";
 263         }
 264         $reexec_pid = $pid;
 265 }
 266
 267 sub kill_workers ($) {
 268         my ($s) = @_;
 269
 270         while (my ($pid, $id) = each %pids) {
 271                 kill $s, $pid;
 272         }
 273 }
 274
 275 sub do_fork () {
 276         my $new = POSIX::SigSet->new;
 277         $new->fillset;
 278         my $old = POSIX::SigSet->new;
 279         POSIX::sigprocmask(&POSIX::SIG_BLOCK, $new, $old) or die "SIG_BLOCK: $!";
 280         my $pid = fork;
 281         my $err = $!;
 282         POSIX::sigprocmask(&POSIX::SIG_SETMASK, $old) or die "SIG_SETMASK: $!";
 283         ($pid, $err);
 284 }
 285
 286 sub upgrade_aborted ($) {
 287         my ($p) = @_;
 288         warn "reexec PID($p) died with: $?\n";
 289         $reexec_pid = undef;
 290         return unless $pid_file;
 291
 292         my $file = $pid_file;
 293         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 294         unlink_pid_file_safe_ish($$, $pid_file);
 295         $pid_file = $file;
 296         eval { write_pid($pid_file) };
 297         warn $@, "\n" if $@;
 298 }
 299
 300 sub reap_children () {
 301         while (1) {
 302                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 303                 if (defined $reexec_pid && $p == $reexec_pid) {
 304                         upgrade_aborted($p);
 305                 } elsif (defined(my $id = delete $pids{$p})) {
 306                         warn "worker[$id] PID($p) died with: $?\n";
 307                 } elsif ($p > 0) {
 308                         warn "unknown PID($p) reaped: $?\n";
 309                 } else {
 310                         return;
 311                 }
 312         }
 313 }
 314
 315 sub unlink_pid_file_safe_ish ($$) {
 316         my ($unlink_pid, $file) = @_;
 317         return unless defined $unlink_pid && $unlink_pid == $$;
 318
 319         open my $fh, '<', $file or return;
 320         defined(my $read_pid = <$fh>) or return;
 321         chomp $read_pid;
 322         if ($read_pid == $unlink_pid) {
 323                 Net::Server::Daemonize::unlink_pid_file($file);
 324         }
 325 }
 326
 327 sub master_loop {
 328         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 329         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 330         IO::Handle::blocking($w, 0);
 331         my $set_workers = $worker_processes;
 332         my @caught;
 333         my $master_pid = $$;
 334         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 335                 $SIG{$s} = sub {
 336                         return if $$ != $master_pid;
 337                         push @caught, $s;
 338                         syswrite($w, '.');
 339                 };
 340         }
 341         reopen_logs();
 342         # main loop
 343         while (1) {
 344                 while (my $s = shift @caught) {
 345                         if ($s eq 'USR1') {
 346                                 reopen_logs();
 347                                 kill_workers($s);
 348                         } elsif ($s eq 'USR2') {
 349                                 upgrade();
 350                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 351                                 # drops pipes and causes children to die
 352                                 exit
 353                         } elsif ($s eq 'WINCH') {
 354                                 $worker_processes = 0;
 355                         } elsif ($s eq 'HUP') {
 356                                 $worker_processes = $set_workers;
 357                                 kill_workers($s);
 358                         } elsif ($s eq 'TTIN') {
 359                                 if ($set_workers > $worker_processes) {
 360                                         ++$worker_processes;
 361                                 } else {
 362                                         $worker_processes = ++$set_workers;
 363                                 }
 364                         } elsif ($s eq 'TTOU') {
 365                                 if ($set_workers > 0) {
 366                                         $worker_processes = --$set_workers;
 367                                 }
 368                         } elsif ($s eq 'CHLD') {
 369                                 reap_children();
 370                         }
 371                 }
 372
 373                 my $n = scalar keys %pids;
 374                 if ($n > $worker_processes) {
 375                         while (my ($k, $v) = each %pids) {
 376                                 kill('TERM', $k) if $v >= $worker_processes;
 377                         }
 378                         $n = $worker_processes;
 379                 }
 380                 foreach my $i ($n..($worker_processes - 1)) {
 381                         my ($pid, $err) = do_fork();
 382                         if (!defined $pid) {
 383                                 warn "failed to fork worker[$i]: $err\n";
 384                         } elsif ($pid == 0) {
 385                                 $set_user->() if $set_user;
 386                                 return $p0; # run normal work code
 387                         } else {
 388                                 warn "PID=$pid is worker[$i]\n";
 389                                 $pids{$pid} = $i;
 390                         }
 391                 }
 392                 # just wait on signal events here:
 393                 sysread($r, my $buf, 8);
 394         }
 395         exit # never gets here, just for documentation
 396 }
 397
 398 sub daemon_loop ($$) {
 399         my ($refresh, $post_accept) = @_;
 400         my $parent_pipe;
 401         if ($worker_processes > 0) {
 402                 $refresh->(); # preload by default
 403                 $parent_pipe = master_loop(); # returns if in child process
 404                 my $fd = fileno($parent_pipe);
 405                 Danga::Socket->AddOtherFds($fd => *worker_quit);
 406         } else {
 407                 reopen_logs();
 408                 $set_user->() if $set_user;
 409                 $SIG{USR2} = sub { worker_quit() if upgrade() };
 410                 $refresh->();
 411         }
 412         $uid = $gid = undef;
 413         reopen_logs();
 414         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 415         $SIG{USR1} = *reopen_logs;
 416         $SIG{HUP} = $refresh;
 417         # this calls epoll_create:
 418         @listeners = map {
 419                 PublicInbox::Listener->new($_, $post_accept)
 420         } @listeners;
 421         Danga::Socket->EventLoop;
 422         $parent_pipe = undef;
 423 }
 424
 425
 426 sub run ($$$) {
 427         my ($default, $refresh, $post_accept) = @_;
 428         daemon_prepare($default);
 429         daemonize();
 430         daemon_loop($refresh, $post_accept);
 431 }
 432
 433 sub do_chown ($) {
 434         my ($path) = @_;
 435         if (defined $uid and !chown($uid, $gid, $path)) {
 436                 warn "could not chown $path: $!\n";
 437         }
 438 }
 439
 440 sub write_pid ($) {
 441         my ($path) = @_;
 442         Net::Server::Daemonize::create_pid_file($path);
 443         do_chown($path);
 444 }
 445
 446 1;