lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  12 sub SO_ACCEPTFILTER () { 0x1000 }
  13 use Cwd qw/abs_path/;
  14 STDOUT->autoflush(1);
  15 STDERR->autoflush(1);
  16 use PublicInbox::DS qw(now);
  17 require PublicInbox::EvCleanup;
  18 require POSIX;
  19 require PublicInbox::Listener;
  20 require PublicInbox::ParentPipe;
  21 my @CMD;
  22 my $set_user;
  23 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  24 my $worker_processes = 1;
  25 my @listeners;
  26 my %pids;
  27 my %listener_names; # sockname => IO::Handle
  28 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  29 my $reexec_pid;
  30 my $cleanup;
  31 my ($uid, $gid);
  32 my ($default_cert, $default_key);
  33 END { $cleanup->() if $cleanup };
  34 my %KNOWN_TLS = ( 443 => 'https', 563 => 'nntps' );
  35 my %KNOWN_STARTTLS = ( 119 => 'nntp' );
  36
  37 sub accept_tls_opt ($) {
  38         my ($opt_str) = @_;
  39         # opt_str: opt1=val1,opt2=val2 (opt may repeat for multi-value)
  40         require PublicInbox::TLS;
  41         my $o = {};
  42         # allow ',' as delimiter since '&' is shell-unfriendly
  43         foreach (split(/[,&]/, $opt_str)) {
  44                 my ($k, $v) = split(/=/, $_, 2);
  45                 push @{$o->{$k} ||= []}, $v;
  46         }
  47
  48         # key may be a part of cert.  At least
  49         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  50         $o->{cert} //= [ $default_cert ];
  51         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  52         my %ctx_opt = (SSL_server => 1);
  53         # parse out hostname:/path/to/ mappings:
  54         foreach my $k (qw(cert key)) {
  55                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  56                 foreach my $path (@{$o->{$k}}) {
  57                         my $host = '';
  58                         $path =~ s/\A([^:]+):// and $host = $1;
  59                         $x->{$host} = $path;
  60                 }
  61         }
  62         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  63                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  64
  65         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  66         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  67         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  68         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  69         if ($mode && $ctx->{context}) {
  70                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  71                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  72         }
  73
  74         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  75 }
  76
  77 sub daemon_prepare ($) {
  78         my ($default_listen) = @_;
  79         @CMD = ($0, @ARGV);
  80         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  81                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  82         my %opts = (
  83                 'l|listen=s' => \@cfg_listen,
  84                 '1|stdout=s' => \$stdout,
  85                 '2|stderr=s' => \$stderr,
  86                 'W|worker-processes=i' => \$worker_processes,
  87                 'P|pid-file=s' => \$pid_file,
  88                 'u|user=s' => \$user,
  89                 'g|group=s' => \$group,
  90                 'D|daemonize' => \$daemonize,
  91                 'cert=s' => \$default_cert,
  92                 'key=s' => \$default_key,
  93         );
  94         GetOptions(%opts) or die "bad command-line args\n";
  95
  96         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  97                 die "--pid-file cannot end with '.oldbin'\n";
  98         }
  99         @listeners = inherit();
 100
 101         # allow socket-activation users to set certs once and not
 102         # have to configure each socket:
 103         my @inherited_names = keys(%listener_names) if defined($default_cert);
 104
 105         # ignore daemonize when inheriting
 106         $daemonize = undef if scalar @listeners;
 107
 108         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
 109
 110         foreach my $l (@cfg_listen) {
 111                 my $orig = $l;
 112                 my $scheme = '';
 113                 if ($l =~ s!\A([^:]+)://!!) {
 114                         $scheme = $1;
 115                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 116                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 117                         $scheme = $s if defined $s;
 118                 }
 119                 if ($l =~ s!/?\?(.+)\z!!) {
 120                         $tls_opt{"$scheme://$l"} = accept_tls_opt($1);
 121                 } elsif (defined($default_cert)) {
 122                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 123                 } elsif ($scheme =~ /\A(?:nntps|https)\z/) {
 124                         die "$orig specified w/o cert=\n";
 125                 }
 126                 # TODO: use scheme to load either NNTP.pm or HTTP.pm
 127
 128                 next if $listener_names{$l}; # already inherited
 129                 my (%o, $sock_pkg);
 130                 if (index($l, '/') == 0) {
 131                         $sock_pkg = 'IO::Socket::UNIX';
 132                         eval "use $sock_pkg";
 133                         die $@ if $@;
 134                         %o = (Type => SOCK_STREAM, Peer => $l);
 135                         if (-S $l) {
 136                                 my $c = $sock_pkg->new(%o);
 137                                 if (!defined($c) && $!{ECONNREFUSED}) {
 138                                         unlink $l or die
 139 "failed to unlink stale socket=$l: $!\n";
 140                                 } # else: let the bind fail
 141                         }
 142                         $o{Local} = delete $o{Peer};
 143                 } else {
 144                         # both work for IPv4, too
 145                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 146                                 $sock_pkg = $_;
 147                                 eval "use $sock_pkg";
 148                                 $@ or last;
 149                         }
 150                         die $@ if $@;
 151                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 152                 }
 153                 $o{Listen} = 1024;
 154                 my $prev = umask 0000;
 155                 my $s = eval { $sock_pkg->new(%o) };
 156                 warn "error binding $l: $! ($@)\n" unless $s;
 157                 umask $prev;
 158
 159                 if ($s) {
 160                         $listener_names{sockname($s)} = $s;
 161                         push @listeners, $s;
 162                 }
 163         }
 164
 165         # cert/key options in @cfg_listen takes precedence when inheriting,
 166         # but map well-known inherited ports if --listen isn't specified
 167         # at all
 168         for my $sockname (@inherited_names) {
 169                 $sockname =~ /:([0-9]+)\z/ or next;
 170                 if (my $scheme = $KNOWN_TLS{$1}) {
 171                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 172                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 173                         next if $tls_opt{"$scheme://$sockname"};
 174                         $tls_opt{''} ||= accept_tls_opt('');
 175                 }
 176         }
 177
 178         die "No listeners bound\n" unless @listeners;
 179 }
 180
 181 sub check_absolute ($$) {
 182         my ($var, $val) = @_;
 183         if (defined $val && index($val, '/') != 0) {
 184                 die
 185 "--$var must be an absolute path when using --daemonize: $val\n";
 186         }
 187 }
 188
 189 sub daemonize () {
 190         if ($daemonize) {
 191                 foreach my $i (0..$#ARGV) {
 192                         my $arg = $ARGV[$i];
 193                         next unless -e $arg;
 194                         $ARGV[$i] = abs_path($arg);
 195                 }
 196                 check_absolute('stdout', $stdout);
 197                 check_absolute('stderr', $stderr);
 198                 check_absolute('pid-file', $pid_file);
 199
 200                 chdir '/' or die "chdir failed: $!";
 201         }
 202
 203         return unless (defined $pid_file || defined $group || defined $user
 204                         || $daemonize);
 205
 206         eval { require Net::Server::Daemonize };
 207         if ($@) {
 208                 die
 209 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 210         }
 211
 212         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 213         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 214         if (defined $group) {
 215                 $gid = Net::Server::Daemonize::get_gid($group);
 216                 $gid = (split /\s+/, $gid)[0];
 217         } elsif (defined $uid) {
 218                 $gid = (getpwuid($uid))[3];
 219         }
 220
 221         # We change users in the worker to ensure upgradability,
 222         # The upgrade will create the ".oldbin" pid file in the
 223         # same directory as the given pid file.
 224         $uid and $set_user = sub {
 225                 $set_user = undef;
 226                 Net::Server::Daemonize::set_user($uid, $gid);
 227         };
 228
 229         if ($daemonize) {
 230                 my $pid = fork;
 231                 die "could not fork: $!\n" unless defined $pid;
 232                 exit if $pid;
 233
 234                 open(STDIN, '+<', '/dev/null') or
 235                                         die "redirect stdin failed: $!\n";
 236                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 237                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 238                 POSIX::setsid();
 239                 $pid = fork;
 240                 die "could not fork: $!\n" unless defined $pid;
 241                 exit if $pid;
 242         }
 243         if (defined $pid_file) {
 244                 write_pid($pid_file);
 245                 my $unlink_pid = $$;
 246                 $cleanup = sub {
 247                         $cleanup = undef; # avoid cyclic reference
 248                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 249                 };
 250         }
 251 }
 252
 253
 254 sub worker_quit {
 255         # killing again terminates immediately:
 256         exit unless @listeners;
 257
 258         $_->close foreach @listeners; # call PublicInbox::DS::close
 259         @listeners = ();
 260
 261         my $proc_name;
 262         my $warn = 0;
 263         # drop idle connections and try to quit gracefully
 264         PublicInbox::DS->SetPostLoopCallback(sub {
 265                 my ($dmap, undef) = @_;
 266                 my $n = 0;
 267                 my $now = now();
 268
 269                 foreach my $s (values %$dmap) {
 270                         $s->can('busy') or next;
 271                         if ($s->busy($now)) {
 272                                 ++$n;
 273                         } else {
 274                                 # close as much as possible, early as possible
 275                                 $s->close;
 276                         }
 277                 }
 278                 if ($n) {
 279                         if (($warn + 5) < now()) {
 280                                 warn "$$ quitting, $n client(s) left\n";
 281                                 $warn = now();
 282                         }
 283                         unless (defined $proc_name) {
 284                                 $proc_name = (split(/\s+/, $0))[0];
 285                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 286                         }
 287                         $0 = "$proc_name quitting, $n client(s) left";
 288                 }
 289                 $n; # true: loop continues, false: loop breaks
 290         });
 291 }
 292
 293 sub reopen_logs {
 294         if ($stdout) {
 295                 open STDOUT, '>>', $stdout or
 296                         warn "failed to redirect stdout to $stdout: $!\n";
 297                 STDOUT->autoflush(1);
 298                 do_chown($stdout);
 299         }
 300         if ($stderr) {
 301                 open STDERR, '>>', $stderr or
 302                         warn "failed to redirect stderr to $stderr: $!\n";
 303                 STDERR->autoflush(1);
 304                 do_chown($stderr);
 305         }
 306 }
 307
 308 sub sockname ($) {
 309         my ($s) = @_;
 310         my $addr = getsockname($s) or return;
 311         my ($host, $port) = host_with_port($addr);
 312         if ($port == 0 && $host eq '127.0.0.1') {
 313                 my ($path) = Socket::sockaddr_un($addr);
 314                 return $path;
 315         }
 316         "$host:$port";
 317 }
 318
 319 sub unpack_ipv6 ($) {
 320         my ($addr) = @_;
 321         my ($port, $host);
 322
 323         # Socket.pm in Perl 5.14+ supports IPv6:
 324         eval {
 325                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 326                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 327         };
 328
 329         if ($@) {
 330                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 331                 # Socket6, so it may be installed on our system, already
 332                 # (otherwise die here):
 333                 require Socket6;
 334
 335                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 336                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 337         }
 338         ($host, $port);
 339 }
 340
 341 sub host_with_port ($) {
 342         my ($addr) = @_;
 343         my ($port, $host);
 344
 345         # this eval will die on Unix sockets:
 346         eval {
 347                 if (length($addr) >= 28) {
 348                         ($host, $port) = unpack_ipv6($addr);
 349                         $host = "[$host]";
 350                 } else {
 351                         ($port, $host) = Socket::sockaddr_in($addr);
 352                         $host = Socket::inet_ntoa($host);
 353                 }
 354         };
 355         $@ ? ('127.0.0.1', 0) : ($host, $port);
 356 }
 357
 358 sub inherit () {
 359         return () if ($ENV{LISTEN_PID} || 0) != $$;
 360         my $fds = $ENV{LISTEN_FDS} or return ();
 361         my $end = $fds + 2; # LISTEN_FDS_START - 1
 362         my @rv = ();
 363         foreach my $fd (3..$end) {
 364                 my $s = IO::Handle->new_from_fd($fd, 'r');
 365                 if (my $k = sockname($s)) {
 366                         $listener_names{$k} = $s;
 367                         push @rv, $s;
 368                 } else {
 369                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 370                 }
 371         }
 372         @rv
 373 }
 374
 375 sub upgrade () {
 376         if ($reexec_pid) {
 377                 warn "upgrade in-progress: $reexec_pid\n";
 378                 return;
 379         }
 380         if (defined $pid_file) {
 381                 if ($pid_file =~ /\.oldbin\z/) {
 382                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 383                         return;
 384                 }
 385                 unlink_pid_file_safe_ish($$, $pid_file);
 386                 $pid_file .= '.oldbin';
 387                 write_pid($pid_file);
 388         }
 389         my $pid = fork;
 390         unless (defined $pid) {
 391                 warn "fork failed: $!\n";
 392                 return;
 393         }
 394         if ($pid == 0) {
 395                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 396                 $ENV{LISTEN_FDS} = scalar @listeners;
 397                 $ENV{LISTEN_PID} = $$;
 398                 foreach my $s (@listeners) {
 399                         my $fl = fcntl($s, F_GETFD, 0);
 400                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 401                 }
 402                 exec @CMD;
 403                 die "Failed to exec: $!\n";
 404         }
 405         $reexec_pid = $pid;
 406 }
 407
 408 sub kill_workers ($) {
 409         my ($s) = @_;
 410
 411         while (my ($pid, $id) = each %pids) {
 412                 kill $s, $pid;
 413         }
 414 }
 415
 416 sub upgrade_aborted ($) {
 417         my ($p) = @_;
 418         warn "reexec PID($p) died with: $?\n";
 419         $reexec_pid = undef;
 420         return unless $pid_file;
 421
 422         my $file = $pid_file;
 423         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 424         unlink_pid_file_safe_ish($$, $pid_file);
 425         $pid_file = $file;
 426         eval { write_pid($pid_file) };
 427         warn $@, "\n" if $@;
 428 }
 429
 430 sub reap_children () {
 431         while (1) {
 432                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 433                 if (defined $reexec_pid && $p == $reexec_pid) {
 434                         upgrade_aborted($p);
 435                 } elsif (defined(my $id = delete $pids{$p})) {
 436                         warn "worker[$id] PID($p) died with: $?\n";
 437                 } elsif ($p > 0) {
 438                         warn "unknown PID($p) reaped: $?\n";
 439                 } else {
 440                         return;
 441                 }
 442         }
 443 }
 444
 445 sub unlink_pid_file_safe_ish ($$) {
 446         my ($unlink_pid, $file) = @_;
 447         return unless defined $unlink_pid && $unlink_pid == $$;
 448
 449         open my $fh, '<', $file or return;
 450         local $/ = "\n";
 451         defined(my $read_pid = <$fh>) or return;
 452         chomp $read_pid;
 453         if ($read_pid == $unlink_pid) {
 454                 Net::Server::Daemonize::unlink_pid_file($file);
 455         }
 456 }
 457
 458 sub master_loop {
 459         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 460         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 461
 462         if ($^O eq 'linux') { # 1031: F_SETPIPE_SZ = 1031
 463                 fcntl($_, 1031, 4096) for ($w, $p1);
 464         }
 465
 466         IO::Handle::blocking($w, 0);
 467         my $set_workers = $worker_processes;
 468         my @caught;
 469         my $master_pid = $$;
 470         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 471                 $SIG{$s} = sub {
 472                         return if $$ != $master_pid;
 473                         push @caught, $s;
 474                         syswrite($w, '.');
 475                 };
 476         }
 477         reopen_logs();
 478         # main loop
 479         my $quit = 0;
 480         while (1) {
 481                 while (my $s = shift @caught) {
 482                         if ($s eq 'USR1') {
 483                                 reopen_logs();
 484                                 kill_workers($s);
 485                         } elsif ($s eq 'USR2') {
 486                                 upgrade();
 487                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 488                                 exit if $quit++;
 489                                 kill_workers($s);
 490                         } elsif ($s eq 'WINCH') {
 491                                 if (-t STDIN || -t STDOUT || -t STDERR) {
 492                                         warn
 493 "ignoring SIGWINCH since we are not daemonized\n";
 494                                         $SIG{WINCH} = 'IGNORE';
 495                                 } else {
 496                                         $worker_processes = 0;
 497                                 }
 498                         } elsif ($s eq 'HUP') {
 499                                 $worker_processes = $set_workers;
 500                                 kill_workers($s);
 501                         } elsif ($s eq 'TTIN') {
 502                                 if ($set_workers > $worker_processes) {
 503                                         ++$worker_processes;
 504                                 } else {
 505                                         $worker_processes = ++$set_workers;
 506                                 }
 507                         } elsif ($s eq 'TTOU') {
 508                                 if ($set_workers > 0) {
 509                                         $worker_processes = --$set_workers;
 510                                 }
 511                         } elsif ($s eq 'CHLD') {
 512                                 reap_children();
 513                         }
 514                 }
 515
 516                 my $n = scalar keys %pids;
 517                 if ($quit) {
 518                         exit if $n == 0;
 519                         $set_workers = $worker_processes = $n = 0;
 520                 }
 521
 522                 if ($n > $worker_processes) {
 523                         while (my ($k, $v) = each %pids) {
 524                                 kill('TERM', $k) if $v >= $worker_processes;
 525                         }
 526                         $n = $worker_processes;
 527                 }
 528                 foreach my $i ($n..($worker_processes - 1)) {
 529                         my $pid = fork;
 530                         if (!defined $pid) {
 531                                 warn "failed to fork worker[$i]: $!\n";
 532                         } elsif ($pid == 0) {
 533                                 $set_user->() if $set_user;
 534                                 return $p0; # run normal work code
 535                         } else {
 536                                 warn "PID=$pid is worker[$i]\n";
 537                                 $pids{$pid} = $i;
 538                         }
 539                 }
 540                 # just wait on signal events here:
 541                 sysread($r, my $buf, 8);
 542         }
 543         exit # never gets here, just for documentation
 544 }
 545
 546 sub tls_start_cb ($$) {
 547         my ($opt, $orig_post_accept) = @_;
 548         sub {
 549                 my ($io, $addr, $srv) = @_;
 550                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 551                 $orig_post_accept->($ssl, $addr, $srv);
 552         }
 553 }
 554
 555 sub defer_accept ($$) {
 556         my ($s, $af_name) = @_;
 557         return unless defined $af_name;
 558         if ($^O eq 'linux') {
 559                 my $x = getsockopt($s, IPPROTO_TCP, Socket::TCP_DEFER_ACCEPT());
 560                 return unless defined $x; # may be Unix socket
 561                 my $sec = unpack('i', $x);
 562                 return if $sec > 0; # systemd users may set a higher value
 563                 setsockopt($s, IPPROTO_TCP, Socket::TCP_DEFER_ACCEPT(), 1);
 564         } elsif ($^O eq 'freebsd') {
 565                 my $x = getsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER);
 566                 return if defined $x; # don't change if set
 567                 my $accf_arg = pack('a16a240', $af_name, '');
 568                 setsockopt($s, SOL_SOCKET, SO_ACCEPTFILTER, $accf_arg);
 569         }
 570 }
 571
 572 sub daemon_loop ($$$$) {
 573         my ($refresh, $post_accept, $nntpd, $af_default) = @_;
 574         PublicInbox::EvCleanup::enable(); # early for $refresh
 575         my %post_accept;
 576         while (my ($k, $v) = each %tls_opt) {
 577                 if ($k =~ s!\A(?:nntps|https)://!!) {
 578                         $post_accept{$k} = tls_start_cb($v, $post_accept);
 579                 } elsif ($nntpd) { # STARTTLS, $k eq '' is OK
 580                         $nntpd->{accept_tls} = $v;
 581                 }
 582         }
 583         my $parent_pipe;
 584         if ($worker_processes > 0) {
 585                 $refresh->(); # preload by default
 586                 my $fh = master_loop(); # returns if in child process
 587                 $parent_pipe = PublicInbox::ParentPipe->new($fh, *worker_quit);
 588         } else {
 589                 reopen_logs();
 590                 $set_user->() if $set_user;
 591                 $SIG{USR2} = sub { worker_quit() if upgrade() };
 592                 $refresh->();
 593         }
 594         $uid = $gid = undef;
 595         reopen_logs();
 596         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 597         $SIG{USR1} = *reopen_logs;
 598         $SIG{HUP} = $refresh;
 599         $SIG{CHLD} = 'DEFAULT';
 600         $SIG{$_} = 'IGNORE' for qw(USR2 TTIN TTOU WINCH);
 601         @listeners = map {;
 602                 my $tls_cb = $post_accept{sockname($_)};
 603
 604                 # NNTPS, HTTPS, HTTP, and POP3S are client-first traffic
 605                 # NNTP and POP3 are server-first
 606                 defer_accept($_, $tls_cb ? 'dataready' : $af_default);
 607
 608                 # this calls epoll_create:
 609                 PublicInbox::Listener->new($_, $tls_cb || $post_accept)
 610         } @listeners;
 611         PublicInbox::DS->EventLoop;
 612         $parent_pipe = undef;
 613 }
 614
 615
 616 sub run ($$$;$) {
 617         my ($default, $refresh, $post_accept, $nntpd) = @_;
 618         daemon_prepare($default);
 619         my $af_default = $default =~ /:8080\z/ ? 'httpready' : undef;
 620         daemonize();
 621         daemon_loop($refresh, $post_accept, $nntpd, $af_default);
 622 }
 623
 624 sub do_chown ($) {
 625         my ($path) = @_;
 626         if (defined $uid and !chown($uid, $gid, $path)) {
 627                 warn "could not chown $path: $!\n";
 628         }
 629 }
 630
 631 sub write_pid ($) {
 632         my ($path) = @_;
 633         Net::Server::Daemonize::create_pid_file($path);
 634         do_chown($path);
 635 }
 636
 637 1;