lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 STDOUT->autoflush(1);
  12 STDERR->autoflush(1);
  13 require Danga::Socket;
  14 require POSIX;
  15 require PublicInbox::Listener;
  16 my @CMD;
  17 my $set_user;
  18 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  19 my $worker_processes = 1;
  20 my @listeners;
  21 my %pids;
  22 my %listener_names;
  23 my $reexec_pid;
  24 my $cleanup;
  25 my ($uid, $gid);
  26 END { $cleanup->() if $cleanup };
  27
  28 sub daemon_prepare ($) {
  29         my ($default_listen) = @_;
  30         @CMD = ($0, @ARGV);
  31         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  32                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  33         my %opts = (
  34                 'l|listen=s' => \@cfg_listen,
  35                 '1|stdout=s' => \$stdout,
  36                 '2|stderr=s' => \$stderr,
  37                 'W|worker-processes=i' => \$worker_processes,
  38                 'P|pid-file=s' => \$pid_file,
  39                 'u|user=s' => \$user,
  40                 'g|group=s' => \$group,
  41                 'D|daemonize' => \$daemonize,
  42         );
  43         GetOptions(%opts) or die "bad command-line args\n";
  44
  45         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  46                 die "--pid-file cannot end with '.oldbin'\n";
  47         }
  48         @listeners = inherit();
  49         # ignore daemonize when inheriting
  50         $daemonize = undef if scalar @listeners;
  51
  52         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  53
  54         foreach my $l (@cfg_listen) {
  55                 next if $listener_names{$l}; # already inherited
  56                 my (%o, $sock_pkg);
  57                 if (index($l, '/') == 0) {
  58                         $sock_pkg = 'IO::Socket::UNIX';
  59                         eval "use $sock_pkg";
  60                         die $@ if $@;
  61                         %o = (Type => SOCK_STREAM, Peer => $l);
  62                         if (-S $l) {
  63                                 my $c = $sock_pkg->new(%o);
  64                                 if (!defined($c) && $!{ECONNREFUSED}) {
  65                                         unlink $l or die
  66 "failed to unlink stale socket=$l: $!\n";
  67                                 } # else: let the bind fail
  68                         }
  69                         $o{Local} = delete $o{Peer};
  70                 } else {
  71                         $sock_pkg = 'IO::Socket::INET6'; # works for IPv4, too
  72                         eval "use $sock_pkg";
  73                         die $@ if $@;
  74                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
  75                 }
  76                 $o{Listen} = 1024;
  77                 my $prev = umask 0000;
  78                 my $s = eval { $sock_pkg->new(%o) };
  79                 warn "error binding $l: $!\n" unless $s;
  80                 umask $prev;
  81
  82                 if ($s) {
  83                         $listener_names{sockname($s)} = $s;
  84                         push @listeners, $s;
  85                 }
  86         }
  87         die "No listeners bound\n" unless @listeners;
  88 }
  89
  90 sub daemonize () {
  91         chdir '/' or die "chdir failed: $!";
  92         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
  93
  94         return unless (defined $pid_file || defined $group || defined $user
  95                         || $daemonize);
  96
  97         require Net::Server::Daemonize;
  98
  99         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 100         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 101         if (defined $group) {
 102                 $gid = Net::Server::Daemonize::get_gid($group);
 103                 $gid = (split /\s+/, $gid)[0];
 104         } elsif (defined $uid) {
 105                 $gid = (getpwuid($uid))[3];
 106         }
 107
 108         # We change users in the worker to ensure upgradability,
 109         # The upgrade will create the ".oldbin" pid file in the
 110         # same directory as the given pid file.
 111         $uid and $set_user = sub {
 112                 Net::Server::Daemonize::set_user($uid, $gid);
 113         };
 114
 115         if ($daemonize) {
 116                 my ($pid, $err) = do_fork();
 117                 die "could not fork: $err\n" unless defined $pid;
 118                 exit if $pid;
 119
 120                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 121                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 122                 POSIX::setsid();
 123                 ($pid, $err) = do_fork();
 124                 die "could not fork: $err\n" unless defined $pid;
 125                 exit if $pid;
 126         }
 127         if (defined $pid_file) {
 128                 write_pid($pid_file);
 129                 my $unlink_pid = $$;
 130                 $cleanup = sub {
 131                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 132                 };
 133         }
 134 }
 135
 136 sub worker_quit () {
 137         # killing again terminates immediately:
 138         exit unless @listeners;
 139
 140         $_->close foreach @listeners; # call Danga::Socket::close
 141         @listeners = ();
 142
 143         # give slow clients 30s to finish reading/writing whatever
 144         Danga::Socket->AddTimer(30, sub { exit });
 145
 146         # drop idle connections and try to quit gracefully
 147         Danga::Socket->SetPostLoopCallback(sub {
 148                 my ($dmap, undef) = @_;
 149                 my $n = 0;
 150
 151                 foreach my $s (values %$dmap) {
 152                         if ($s->can('busy') && $s->busy) {
 153                                 $n = 1;
 154                         } else {
 155                                 # close as much as possible, early as possible
 156                                 $s->close;
 157                         }
 158                 }
 159                 $n; # true: loop continues, false: loop breaks
 160         });
 161 }
 162
 163 sub reopen_logs {
 164         if ($stdout) {
 165                 open STDOUT, '>>', $stdout or
 166                         warn "failed to redirect stdout to $stdout: $!\n";
 167                 STDOUT->autoflush(1);
 168                 do_chown($stdout);
 169         }
 170         if ($stderr) {
 171                 open STDERR, '>>', $stderr or
 172                         warn "failed to redirect stderr to $stderr: $!\n";
 173                 STDERR->autoflush(1);
 174                 do_chown($stderr);
 175         }
 176 }
 177
 178 sub sockname ($) {
 179         my ($s) = @_;
 180         my $addr = getsockname($s) or return;
 181         my ($host, $port) = host_with_port($addr);
 182         "$host:$port";
 183 }
 184
 185 sub host_with_port ($) {
 186         my ($addr) = @_;
 187         my ($port, $host);
 188
 189         # this eval will die on Unix sockets:
 190         eval {
 191                 if (length($addr) >= 28) {
 192                         require Socket6;
 193                         ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 194                         $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 195                         $host = "[$host]";
 196                 } else {
 197                         ($port, $host) = Socket::sockaddr_in($addr);
 198                         $host = Socket::inet_ntoa($host);
 199                 }
 200         };
 201         $@ ? ('127.0.0.1', 0) : ($host, $port);
 202 }
 203
 204 sub inherit () {
 205         return () if ($ENV{LISTEN_PID} || 0) != $$;
 206         my $fds = $ENV{LISTEN_FDS} or return ();
 207         my $end = $fds + 2; # LISTEN_FDS_START - 1
 208         my @rv = ();
 209         foreach my $fd (3..$end) {
 210                 my $s = IO::Handle->new_from_fd($fd, 'r');
 211                 if (my $k = sockname($s)) {
 212                         $listener_names{$k} = $s;
 213                         push @rv, $s;
 214                 } else {
 215                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 216                 }
 217         }
 218         @rv
 219 }
 220
 221 sub upgrade () {
 222         if ($reexec_pid) {
 223                 warn "upgrade in-progress: $reexec_pid\n";
 224                 return;
 225         }
 226         if (defined $pid_file) {
 227                 if ($pid_file =~ /\.oldbin\z/) {
 228                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 229                         return;
 230                 }
 231                 unlink_pid_file_safe_ish($$, $pid_file);
 232                 $pid_file .= '.oldbin';
 233                 write_pid($pid_file);
 234         }
 235         my ($pid, $err) = do_fork();
 236         unless (defined $pid) {
 237                 warn "fork failed: $err\n";
 238                 return;
 239         }
 240         if ($pid == 0) {
 241                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 242                 $ENV{LISTEN_FDS} = scalar @listeners;
 243                 $ENV{LISTEN_PID} = $$;
 244                 foreach my $s (@listeners) {
 245                         my $fl = fcntl($s, F_GETFD, 0);
 246                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 247                 }
 248                 exec @CMD;
 249                 die "Failed to exec: $!\n";
 250         }
 251         $reexec_pid = $pid;
 252 }
 253
 254 sub kill_workers ($) {
 255         my ($s) = @_;
 256
 257         while (my ($pid, $id) = each %pids) {
 258                 kill $s, $pid;
 259         }
 260 }
 261
 262 sub do_fork () {
 263         my $new = POSIX::SigSet->new;
 264         $new->fillset;
 265         my $old = POSIX::SigSet->new;
 266         POSIX::sigprocmask(&POSIX::SIG_BLOCK, $new, $old) or die "SIG_BLOCK: $!";
 267         my $pid = fork;
 268         my $err = $!;
 269         POSIX::sigprocmask(&POSIX::SIG_SETMASK, $old) or die "SIG_SETMASK: $!";
 270         ($pid, $err);
 271 }
 272
 273 sub upgrade_aborted ($) {
 274         my ($p) = @_;
 275         warn "reexec PID($p) died with: $?\n";
 276         $reexec_pid = undef;
 277         return unless $pid_file;
 278
 279         my $file = $pid_file;
 280         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 281         unlink_pid_file_safe_ish($$, $pid_file);
 282         $pid_file = $file;
 283         eval { write_pid($pid_file) };
 284         warn $@, "\n" if $@;
 285 }
 286
 287 sub reap_children () {
 288         while (1) {
 289                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 290                 if (defined $reexec_pid && $p == $reexec_pid) {
 291                         upgrade_aborted($p);
 292                 } elsif (defined(my $id = delete $pids{$p})) {
 293                         warn "worker[$id] PID($p) died with: $?\n";
 294                 } elsif ($p > 0) {
 295                         warn "unknown PID($p) reaped: $?\n";
 296                 } else {
 297                         return;
 298                 }
 299         }
 300 }
 301
 302 sub unlink_pid_file_safe_ish ($$) {
 303         my ($unlink_pid, $file) = @_;
 304         return unless defined $unlink_pid && $unlink_pid == $$;
 305
 306         open my $fh, '<', $file or return;
 307         defined(my $read_pid = <$fh>) or return;
 308         chomp $read_pid;
 309         if ($read_pid == $unlink_pid) {
 310                 Net::Server::Daemonize::unlink_pid_file($file);
 311         }
 312 }
 313
 314 sub master_loop {
 315         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 316         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 317         IO::Handle::blocking($w, 0);
 318         my $set_workers = $worker_processes;
 319         my @caught;
 320         my $master_pid = $$;
 321         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 322                 $SIG{$s} = sub {
 323                         return if $$ != $master_pid;
 324                         push @caught, $s;
 325                         syswrite($w, '.');
 326                 };
 327         }
 328         reopen_logs();
 329         # main loop
 330         while (1) {
 331                 while (my $s = shift @caught) {
 332                         if ($s eq 'USR1') {
 333                                 reopen_logs();
 334                                 kill_workers($s);
 335                         } elsif ($s eq 'USR2') {
 336                                 upgrade();
 337                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 338                                 # drops pipes and causes children to die
 339                                 exit
 340                         } elsif ($s eq 'WINCH') {
 341                                 $worker_processes = 0;
 342                         } elsif ($s eq 'HUP') {
 343                                 $worker_processes = $set_workers;
 344                                 kill_workers($s);
 345                         } elsif ($s eq 'TTIN') {
 346                                 if ($set_workers > $worker_processes) {
 347                                         ++$worker_processes;
 348                                 } else {
 349                                         $worker_processes = ++$set_workers;
 350                                 }
 351                         } elsif ($s eq 'TTOU') {
 352                                 if ($set_workers > 0) {
 353                                         $worker_processes = --$set_workers;
 354                                 }
 355                         } elsif ($s eq 'CHLD') {
 356                                 reap_children();
 357                         }
 358                 }
 359
 360                 my $n = scalar keys %pids;
 361                 if ($n > $worker_processes) {
 362                         while (my ($k, $v) = each %pids) {
 363                                 kill('TERM', $k) if $v >= $worker_processes;
 364                         }
 365                         $n = $worker_processes;
 366                 }
 367                 foreach my $i ($n..($worker_processes - 1)) {
 368                         my ($pid, $err) = do_fork();
 369                         if (!defined $pid) {
 370                                 warn "failed to fork worker[$i]: $err\n";
 371                         } elsif ($pid == 0) {
 372                                 $set_user->() if $set_user;
 373                                 return $p0; # run normal work code
 374                         } else {
 375                                 warn "PID=$pid is worker[$i]\n";
 376                                 $pids{$pid} = $i;
 377                         }
 378                 }
 379                 # just wait on signal events here:
 380                 sysread($r, my $buf, 8);
 381         }
 382         exit # never gets here, just for documentation
 383 }
 384
 385 sub daemon_loop ($$) {
 386         my ($refresh, $post_accept) = @_;
 387         my $parent_pipe;
 388         if ($worker_processes > 0) {
 389                 $refresh->(); # preload by default
 390                 $parent_pipe = master_loop(); # returns if in child process
 391                 my $fd = fileno($parent_pipe);
 392                 Danga::Socket->AddOtherFds($fd => sub { kill('TERM', $$) } );
 393         } else {
 394                 reopen_logs();
 395                 $set_user->() if $set_user;
 396                 $SIG{USR2} = sub { worker_quit() if upgrade() };
 397                 $refresh->();
 398         }
 399         $uid = $gid = undef;
 400         reopen_logs();
 401         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 402         $SIG{USR1} = *reopen_logs;
 403         $SIG{HUP} = $refresh;
 404         # this calls epoll_create:
 405         @listeners = map {
 406                 PublicInbox::Listener->new($_, $post_accept)
 407         } @listeners;
 408         Danga::Socket->EventLoop;
 409         $parent_pipe = undef;
 410 }
 411
 412
 413 sub run ($$$) {
 414         my ($default, $refresh, $post_accept) = @_;
 415         daemon_prepare($default);
 416         daemonize();
 417         daemon_loop($refresh, $post_accept);
 418 }
 419
 420 sub do_chown ($) {
 421         my ($path) = @_;
 422         if (defined $uid and !chown($uid, $gid, $path)) {
 423                 warn "could not chown $path: $!\n";
 424         }
 425 }
 426
 427 sub write_pid ($) {
 428         my ($path) = @_;
 429         Net::Server::Daemonize::create_pid_file($path);
 430         do_chown($path);
 431 }
 432
 433 1;