lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Daemon; # empty class :p
   4
   5 # contains common daemon code for the nntpd server.
   6 # This may be used for read-only IMAP server if we decide to implement it.
   7 package main;
   8 use strict;
   9 use warnings;
  10 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  11 require Danga::Socket;
  12 require POSIX;
  13 require PublicInbox::Listener;
  14 my @CMD;
  15 my $set_user;
  16 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  17 my $worker_processes = 0;
  18 my @listeners;
  19 my %pids;
  20 my %listener_names;
  21 my $reexec_pid;
  22 my $cleanup;
  23 END { $cleanup->() if $cleanup };
  24
  25 sub daemon_prepare ($) {
  26         my ($default_listen) = @_;
  27         @CMD = ($0, @ARGV);
  28         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  29                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  30         my %opts = (
  31                 'l|listen=s' => \@cfg_listen,
  32                 '1|stdout=s' => \$stdout,
  33                 '2|stderr=s' => \$stderr,
  34                 'W|worker-processes=i' => \$worker_processes,
  35                 'P|pid-file=s' => \$pid_file,
  36                 'u|user=s' => \$user,
  37                 'g|group=s' => \$group,
  38                 'D|daemonize' => \$daemonize,
  39         );
  40         GetOptions(%opts) or die "bad command-line args\n";
  41
  42         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  43                 die "--pid-file cannot end with '.oldbin'\n";
  44         }
  45         @listeners = inherit();
  46         # ignore daemonize when inheriting
  47         $daemonize = undef if scalar @listeners;
  48
  49         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  50
  51         foreach my $l (@cfg_listen) {
  52                 next if $listener_names{$l}; # already inherited
  53                 require IO::Socket::INET6; # works for IPv4, too
  54                 my %o = (
  55                         LocalAddr => $l,
  56                         ReuseAddr => 1,
  57                         Proto => 'tcp',
  58                 );
  59                 if (my $s = IO::Socket::INET6->new(%o)) {
  60                         $listener_names{sockname($s)} = $s;
  61                         push @listeners, $s;
  62                 } else {
  63                         warn "error binding $l: $!\n";
  64                 }
  65         }
  66         die 'No listeners bound' unless @listeners;
  67 }
  68
  69 sub daemonize () {
  70         chdir '/' or die "chdir failed: $!\n";
  71         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!\n";
  72
  73         return unless (defined $pid_file || defined $group || defined $user
  74                         || $daemonize);
  75
  76         require Net::Server::Daemonize;
  77
  78         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
  79         my $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
  80         my $gid;
  81         if (defined $group) {
  82                 $gid = Net::Server::Daemonize::get_gid($group);
  83                 $gid = (split /\s+/, $gid)[0];
  84         } elsif (defined $uid) {
  85                 $gid = (getpwuid($uid))[3];
  86         }
  87
  88         # We change users in the worker to ensure upgradability,
  89         # The upgrade will create the ".oldbin" pid file in the
  90         # same directory as the given pid file.
  91         $uid and $set_user = sub {
  92                 Net::Server::Daemonize::set_user($uid, $gid);
  93         };
  94
  95         if ($daemonize) {
  96                 my ($pid, $err) = do_fork();
  97                 die "could not fork: $err\n" unless defined $pid;
  98                 exit if $pid;
  99
 100                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 101                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 102                 POSIX::setsid();
 103                 ($pid, $err) = do_fork();
 104                 die "could not fork: $err\n" unless defined $pid;
 105                 exit if $pid;
 106         }
 107         if (defined $pid_file) {
 108                 Net::Server::Daemonize::create_pid_file($pid_file);
 109                 if ($uid and !chown($uid, $gid, $pid_file)) {
 110                         warn "could not chown $pid_file: $!\n";
 111                 }
 112                 my $unlink_pid = $$;
 113                 $cleanup = sub {
 114                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 115                 };
 116         }
 117 }
 118
 119 sub worker_quit () {
 120         # killing again terminates immediately:
 121         exit unless @listeners;
 122
 123         @listeners = ();
 124
 125         # give slow clients 30s to finish reading/writing whatever
 126         Danga::Socket->AddTimer(30, sub { exit });
 127
 128         # drop idle connections and try to quit gracefully
 129         Danga::Socket->SetPostLoopCallback(sub {
 130                 my ($dmap, undef) = @_;
 131                 my $n = 0;
 132
 133                 foreach my $s (values %$dmap) {
 134                         if ($s->can('busy') && $s->busy) {
 135                                 $n = 1;
 136                         } else {
 137                                 # close as much as possible, early as possible
 138                                 $s->close;
 139                         }
 140                 }
 141                 $n; # true: loop continues, false: loop breaks
 142         });
 143 }
 144
 145 sub reopen_logs {
 146         if ($stdout) {
 147                 open STDOUT, '>>', $stdout or
 148                         warn "failed to redirect stdout to $stdout: $!\n";
 149         }
 150         if ($stderr) {
 151                 open STDERR, '>>', $stderr or
 152                         warn "failed to redirect stderr to $stderr: $!\n";
 153         }
 154 }
 155
 156 sub sockname ($) {
 157         my ($s) = @_;
 158         my $n = getsockname($s) or return;
 159         my ($port, $addr);
 160         if (length($n) >= 28) {
 161                 require Socket6;
 162                 ($port, $addr) = Socket6::unpack_sockaddr_in6($n);
 163         } else {
 164                 ($port, $addr) = Socket::sockaddr_in($n);
 165         }
 166         if (length($addr) == 4) {
 167                 $n = Socket::inet_ntoa($addr)
 168         } else {
 169                 $n = '['.Socket6::inet_ntop(Socket6::AF_INET6(), $addr).']';
 170         }
 171         $n .= ":$port";
 172 }
 173
 174 sub inherit () {
 175         return () if ($ENV{LISTEN_PID} || 0) != $$;
 176         my $fds = $ENV{LISTEN_FDS} or return ();
 177         my $end = $fds + 2; # LISTEN_FDS_START - 1
 178         my @rv = ();
 179         foreach my $fd (3..$end) {
 180                 my $s = IO::Handle->new;
 181                 $s->fdopen($fd, 'r');
 182                 if (my $k = sockname($s)) {
 183                         $listener_names{$k} = $s;
 184                         push @rv, $s;
 185                 } else {
 186                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 187                 }
 188         }
 189         @rv
 190 }
 191
 192 sub upgrade () {
 193         if ($reexec_pid) {
 194                 warn "upgrade in-progress: $reexec_pid\n";
 195                 return;
 196         }
 197         if (defined $pid_file) {
 198                 if ($pid_file =~ /\.oldbin\z/) {
 199                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 200                         return;
 201                 }
 202                 unlink_pid_file_safe_ish($$, $pid_file);
 203                 $pid_file .= '.oldbin';
 204                 Net::Server::Daemonize::create_pid_file($pid_file);
 205         }
 206         my ($pid, $err) = do_fork();
 207         unless (defined $pid) {
 208                 warn "fork failed: $err\n";
 209                 return;
 210         }
 211         if ($pid == 0) {
 212                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 213                 $ENV{LISTEN_FDS} = scalar @listeners;
 214                 $ENV{LISTEN_PID} = $$;
 215                 foreach my $s (@listeners) {
 216                         my $fl = fcntl($s, F_GETFD, 0);
 217                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 218                 }
 219                 exec @CMD;
 220                 die "Failed to exec: $!\n";
 221         }
 222         $reexec_pid = $pid;
 223 }
 224
 225 sub kill_workers ($) {
 226         my ($s) = @_;
 227
 228         while (my ($pid, $id) = each %pids) {
 229                 kill $s, $pid;
 230         }
 231 }
 232
 233 sub do_fork () {
 234         my $new = POSIX::SigSet->new;
 235         $new->fillset;
 236         my $old = POSIX::SigSet->new;
 237         POSIX::sigprocmask(&POSIX::SIG_BLOCK, $new, $old) or
 238                                 die "SIG_BLOCK: $!\n";
 239         my $pid = fork;
 240         my $err = $!;
 241         POSIX::sigprocmask(&POSIX::SIG_SETMASK, $old) or
 242                                 die "SIG_SETMASK: $!\n";
 243         ($pid, $err);
 244 }
 245
 246 sub upgrade_aborted ($) {
 247         my ($p) = @_;
 248         warn "reexec PID($p) died with: $?\n";
 249         $reexec_pid = undef;
 250         return unless $pid_file;
 251
 252         my $file = $pid_file;
 253         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file\n";
 254         unlink_pid_file_safe_ish($$, $pid_file);
 255         $pid_file = $file;
 256         eval { Net::Server::Daemonize::create_pid_file($pid_file) };
 257         warn $@, "\n" if $@;
 258 }
 259
 260 sub reap_children () {
 261         while (1) {
 262                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 263                 if (defined $reexec_pid && $p == $reexec_pid) {
 264                         upgrade_aborted($p);
 265                 } elsif (defined(my $id = delete $pids{$p})) {
 266                         warn "worker[$id] PID($p) died with: $?\n";
 267                 } elsif ($p > 0) {
 268                         warn "unknown PID($p) reaped: $?\n";
 269                 } else {
 270                         return;
 271                 }
 272         }
 273 }
 274
 275 sub unlink_pid_file_safe_ish ($$) {
 276         my ($unlink_pid, $file) = @_;
 277         return unless defined $unlink_pid && $unlink_pid == $$;
 278
 279         open my $fh, '<', $file or return;
 280         defined(my $read_pid = <$fh>) or return;
 281         chomp $read_pid;
 282         if ($read_pid == $unlink_pid) {
 283                 Net::Server::Daemonize::unlink_pid_file($file);
 284         }
 285 }
 286
 287 sub master_loop ($) {
 288         my ($refresh) = @_;
 289         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!\n";
 290         my %pwatch = ( fileno($p0) => sub { kill('TERM', $$) } );
 291         pipe(my ($r, $w)) or die "failed to create self-pipe: $!\n";
 292         IO::Handle::blocking($w, 0);
 293         my $set_workers = $worker_processes;
 294         my @caught;
 295         my $master_pid = $$;
 296         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 297                 $SIG{$s} = sub {
 298                         return if $$ != $master_pid;
 299                         push @caught, $s;
 300                         syswrite($w, '.');
 301                 };
 302         }
 303         reopen_logs();
 304         # main loop
 305         while (1) {
 306                 while (my $s = shift @caught) {
 307                         if ($s eq 'USR1') {
 308                                 reopen_logs();
 309                                 kill_workers($s);
 310                         } elsif ($s eq 'USR2') {
 311                                 upgrade();
 312                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 313                                 # drops pipes and causes children to die
 314                                 exit
 315                         } elsif ($s eq 'WINCH') {
 316                                 $worker_processes = 0;
 317                         } elsif ($s eq 'HUP') {
 318                                 $worker_processes = $set_workers;
 319                                 $refresh->();
 320                                 kill_workers($s);
 321                         } elsif ($s eq 'TTIN') {
 322                                 if ($set_workers > $worker_processes) {
 323                                         ++$worker_processes;
 324                                 } else {
 325                                         $worker_processes = ++$set_workers;
 326                                 }
 327                         } elsif ($s eq 'TTOU') {
 328                                 if ($set_workers > 0) {
 329                                         $worker_processes = --$set_workers;
 330                                 }
 331                         } elsif ($s eq 'CHLD') {
 332                                 reap_children();
 333                         }
 334                 }
 335
 336                 my $n = scalar keys %pids;
 337                 if ($n > $worker_processes) {
 338                         while (my ($k, $v) = each %pids) {
 339                                 kill('TERM', $k) if $v >= $worker_processes;
 340                         }
 341                         $n = $worker_processes;
 342                 }
 343                 foreach my $i ($n..($worker_processes - 1)) {
 344                         my ($pid, $err) = do_fork();
 345                         if (!defined $pid) {
 346                                 warn "failed to fork worker[$i]: $err\n";
 347                         } elsif ($pid == 0) {
 348                                 $set_user->() if $set_user;
 349                                 close($_) for ($w, $r, $p1);
 350                                 Danga::Socket->AddOtherFds(%pwatch);
 351                                 return; # run normal work code
 352                         } else {
 353                                 warn "PID=$pid is worker[$i]\n";
 354                                 $pids{$pid} = $i;
 355                         }
 356                 }
 357                 # just wait on signal events here:
 358                 sysread($r, my $buf, 8);
 359         }
 360         exit # never gets here, just for documentation
 361 }
 362
 363 sub daemon_loop ($$) {
 364         my ($refresh, $post_accept) = @_;
 365         $refresh->(); # load config before forking to save work
 366         if ($worker_processes > 0) {
 367                 master_loop($refresh); # returns if in child process
 368         } else {
 369                 $set_user->() if $set_user;
 370                 $SIG{USR2} = sub { worker_quit() if upgrade() };
 371         }
 372         reopen_logs();
 373         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 374         $SIG{USR1} = *reopen_logs;
 375         $SIG{HUP} = $refresh;
 376         # this calls epoll_create:
 377         PublicInbox::Listener->new($_, $post_accept) for @listeners;
 378         Danga::Socket->EventLoop;
 379 }
 380
 381
 382 sub daemon_run ($$$) {
 383         my ($default, $refresh, $post_accept) = @_;
 384         daemon_prepare($default);
 385         daemon_loop($refresh, $post_accept);
 386 }
 387
 388 1;