lib/PublicInbox/Eml.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Lazy MIME parser, it still slurps the full message but keeps short
   5 # lifetimes.  Unlike Email::MIME, it doesn't pre-split multipart
   6 # messages or do any up-front parsing of headers besides splitting
   7 # the header string from the body.
   8 #
   9 # Contains ideas and code from Email::Simple and Email::MIME
  10 # (Perl Artistic License, GPL-1+)
  11 #
  12 # This aims to replace Email::MIME for our purposes, similar API
  13 # but internal field names are differ if they're not 100%-compatible.
  14 #
  15 # Includes some proposed fixes for Email::MIME:
  16 # - header-less sub parts - https://github.com/rjbs/Email-MIME/issues/14
  17 # - "0" as boundary - https://github.com/rjbs/Email-MIME/issues/63
  18 #
  19 # $self = {
  20 #       bdy => scalar ref for body (may be undef),
  21 #       hdr => scalar ref for header,
  22 #       crlf => "\n" or "\r\n" (scalar, not a ref),
  23 #
  24 #       # filled in during ->each_part
  25 #       ct => hash ref returned by parse_content_type
  26 # }
  27 package PublicInbox::Eml;
  28 use strict;
  29 use v5.10.1;
  30 use Carp qw(croak);
  31 use Encode qw(find_encoding decode encode); # stdlib
  32 use Text::Wrap qw(wrap); # stdlib, we need Perl 5.6+ for $huge
  33
  34 my $MIME_Header = find_encoding('MIME-Header');
  35
  36 # TODO remove these dependencies
  37 use Email::MIME::ContentType;
  38 use Email::MIME::Encodings;
  39 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  40
  41 our $MAXPARTS = 1000; # same as SpamAssassin
  42 our $MAXDEPTH = 20; # seems enough, Perl sucks, here
  43 our $MAXBOUNDLEN = 2048; # same as postfix
  44
  45 my $NO_ENCODE_RE = qr/\A(?:7bit|8bit|binary)[ \t]*(?:;|$)?/i;
  46 my %DECODE_ADDRESS = map { $_ => 1 } qw(From To Cc Sender Reply-To);
  47 my %DECODE_FULL = (
  48         Subject => 1,
  49         'Content-Description' => 1,
  50         'Content-Type' => 1, # not correct, but needed, oh well
  51 );
  52 our %STR_TYPE = (text => 1);
  53 our %STR_SUBTYPE = (plain => 1, html => 1);
  54
  55 my %re_memo;
  56 sub re_memo ($) {
  57         my ($k) = @_;
  58         # Do not normalize $k with lc/uc; instead strive to keep
  59         # capitalization in our codebase consistent.
  60         $re_memo{$k} ||= qr/^\Q$k\E:[ \t]*([^\n]*\r?\n # 1st line
  61                                         # continuation lines:
  62                                         (?:[^:\n]*?[ \t]+[^\n]*\r?\n)*)
  63                                         /ismx
  64 }
  65
  66 # compatible with our uses of Email::MIME
  67 sub new {
  68         my $ref = ref($_[1]) ? $_[1] : \(my $cpy = $_[1]);
  69         if ($$ref =~ /(?:\r?\n(\r?\n))/gs) { # likely
  70                 # This can modify $$ref in-place and to avoid memcpy/memmove
  71                 # on a potentially large $$ref.  It does need to make a
  72                 # copy for $hdr, though.  Idea stolen from Email::Simple
  73                 my $hdr = substr($$ref, 0, pos($$ref), ''); # sv_chop on $$ref
  74                 substr($hdr, -(length($1))) = ''; # lower SvCUR
  75                 bless { hdr => \$hdr, crlf => $1, bdy => $ref }, __PACKAGE__;
  76         } elsif ($$ref =~ /^[a-z0-9-]+[ \t]*:/ims && $$ref =~ /(\r?\n)\z/s) {
  77                 # body is optional :P
  78                 bless { hdr => \($$ref), crlf => $1 }, __PACKAGE__;
  79         } else { # nothing useful
  80                 my $hdr = $$ref = '';
  81                 bless { hdr => \$hdr, crlf => "\n" }, __PACKAGE__;
  82         }
  83 }
  84
  85 sub new_sub {
  86         my (undef, $ref) = @_;
  87         # special case for messages like <85k5su9k59.fsf_-_@lola.goethe.zz>
  88         $$ref =~ /\A(?:(\r?\n))/gs or goto &new;
  89         my $hdr = substr($$ref, 0, pos($$ref), ''); # sv_chop on $$ref
  90         bless { hdr => \$hdr, crlf => $1, bdy => $ref }, __PACKAGE__;
  91 }
  92
  93 # same output as Email::Simple::Header::header_raw, but we extract
  94 # headers on-demand instead of parsing them into a list which
  95 # requires O(n) lookups anyways
  96 sub header_raw {
  97         my $re = re_memo($_[1]);
  98         my @v = (${ $_[0]->{hdr} } =~ /$re/g);
  99         for (@v) {
 100                 # for compatibility w/ Email::Simple::Header,
 101                 s/\s+\z//s;
 102                 s/\A\s+//s;
 103                 s/\r?\n[ \t]*/ /gs;
 104         }
 105         wantarray ? @v : $v[0];
 106 }
 107
 108 # pick the first Content-Type header to match Email::MIME behavior.
 109 # It's usually the right one based on historical archives.
 110 sub ct ($) {
 111         # Email::MIME::ContentType::content_type:
 112         $_[0]->{ct} //= parse_content_type(header($_[0], 'Content-Type'));
 113 }
 114
 115 sub body_decode ($$) {
 116         my $cte = header_raw($_[0], 'Content-Transfer-Encoding');
 117         ($cte) = ($cte =~ /([a-zA-Z0-9\-]+)/) if $cte; # For S/MIME, etc
 118         (!$cte || $cte =~ $NO_ENCODE_RE) ?
 119                 $_[1] : Email::MIME::Encodings::decode($cte, $_[1], '7bit');
 120 }
 121
 122 # returns a queue of sub-parts iff it's worth descending into
 123 # TODO: descend into message/rfc822 parts (Email::MIME didn't)
 124 sub mp_descend ($$) {
 125         my ($self, $nr) = @_; # or $once for top-level
 126         my $bnd = ct($self)->{attributes}->{boundary} // return; # single-part
 127         return if $bnd eq '' || length($bnd) >= $MAXBOUNDLEN;
 128         $bnd = quotemeta($bnd);
 129
 130         # "multipart" messages can exist w/o a body
 131         my $bdy = ($nr ? delete($self->{bdy}) : \(body_raw($self))) or return;
 132
 133         # Cut at the the first epilogue, not subsequent ones.
 134         # *sigh* just the regexp match alone seems to bump RSS by
 135         # length($$bdy) on a ~30M string:
 136         $$bdy =~ /((?:\r?\n)?^--$bnd--[ \t]*\r?$)/gsm and
 137                 substr($$bdy, pos($$bdy) - length($1)) = '';
 138
 139         # *Sigh* split() doesn't work in-place and return CoW strings
 140         # because Perl wants to "\0"-terminate strings.  So split()
 141         # again bumps RSS by length($$bdy)
 142
 143         # Quiet warning for "Complex regular subexpression recursion limit"
 144         # in case we get many empty parts, it's harmless in this case
 145         no warnings 'regexp';
 146         my ($pre, @parts) = split(/(?:\r?\n)?(?:^--$bnd[ \t]*\r?\n)+/ms,
 147                                 $$bdy,
 148                                 # + 3 since we don't want the last part
 149                                 # processed to include any other excluded
 150                                 # parts ($nr starts at 1, and I suck at math)
 151                                 $MAXPARTS + 3 - $nr);
 152
 153         if (@parts) { # the usual path if we got this far:
 154                 undef $bdy; # release memory ASAP if $nr > 0
 155                 @parts = grep /[^ \t\r\n]/s, @parts; # ignore empty parts
 156
 157                 # Keep "From: someone..." from preamble in old,
 158                 # buggy versions of git-send-email, otherwise drop it
 159                 # There's also a case where quoted text showed up in the
 160                 # preamble
 161                 # <20060515162817.65F0F1BBAE@citi.umich.edu>
 162                 unshift(@parts, $pre) if $pre =~ /:/s;
 163                 return \@parts;
 164         }
 165         # "multipart", but no boundary found, treat as single part
 166         $self->{bdy} //= $bdy;
 167         undef;
 168 }
 169
 170 # $p = [ \@parts, $depth, $idx ]
 171 # $idx[0] grows as $depth grows, $idx[1] == $p->[-1] == current part
 172 # (callers need to be updated)
 173 # \@parts is a queue which empties when we're done with a parent part
 174
 175 # same usage as PublicInbox::MsgIter::msg_iter
 176 # $cb - user-supplied callback sub
 177 # $arg - user-supplied arg (think pthread_create)
 178 # $once - unref body scalar during iteration
 179 sub each_part {
 180         my ($self, $cb, $arg, $once) = @_;
 181         my $p = mp_descend($self, $once // 0) or
 182                                         return $cb->([$self, 0, 0], $arg);
 183         $p = [ $p, 0 ];
 184         my @s; # our virtual stack
 185         my $nr = 0;
 186         while ((scalar(@{$p->[0]}) || ($p = pop @s)) && ++$nr <= $MAXPARTS) {
 187                 ++$p->[-1]; # bump index
 188                 my (undef, @idx) = @$p;
 189                 @idx = (join('.', @idx));
 190                 my $depth = ($idx[0] =~ tr/././) + 1;
 191                 my $sub = new_sub(undef, \(shift @{$p->[0]}));
 192                 if ($depth < $MAXDEPTH && (my $nxt = mp_descend($sub, $nr))) {
 193                         push(@s, $p) if scalar @{$p->[0]};
 194                         $p = [ $nxt, @idx, 0 ];
 195                 } else { # a leaf node
 196                         $cb->([$sub, $depth, @idx], $arg);
 197                 }
 198         }
 199 }
 200
 201 ########### compatibility section for existing Email::MIME uses #########
 202
 203 sub header_obj {
 204         bless { hdr => $_[0]->{hdr}, crlf => $_[0]->{crlf} }, __PACKAGE__;
 205 }
 206
 207 sub subparts {
 208         my ($self) = @_;
 209         my $parts = mp_descend($self, 0) or return ();
 210         my $bnd = ct($self)->{attributes}->{boundary} // die 'BUG: no boundary';
 211         my $bdy = $self->{bdy};
 212         if ($$bdy =~ /\A(.*?)(?:\r?\n)?^--\Q$bnd\E[ \t]*\r?$/sm) {
 213                 $self->{preamble} = $1;
 214         }
 215         if ($$bdy =~ /^--\Q$bnd\E--[ \t]*\r?\n(.+)\z/sm) {
 216                 $self->{epilogue} = $1;
 217         }
 218         map { new_sub(undef, \$_) } @$parts;
 219 }
 220
 221 sub parts_set {
 222         my ($self, $parts) = @_;
 223
 224         # we can't fully support what Email::MIME does,
 225         # just what our filter code needs:
 226         my $bnd = ct($self)->{attributes}->{boundary} // die <<EOF;
 227 ->parts_set not supported for single-part messages
 228 EOF
 229         my $crlf = $self->{crlf};
 230         my $fin_bnd = "$crlf--$bnd--$crlf";
 231         $bnd = "$crlf--$bnd$crlf";
 232         ${$self->{bdy}} = join($bnd,
 233                                 delete($self->{preamble}) // '',
 234                                 map { $_->as_string } @$parts
 235                                 ) .
 236                                 $fin_bnd .
 237                                 (delete($self->{epilogue}) // '');
 238         undef;
 239 }
 240
 241 sub body_set {
 242         my ($self, $body) = @_;
 243         my $bdy = $self->{bdy} = ref($body) ? $body : \$body;
 244         my $cte = header_raw($self, 'Content-Transfer-Encoding');
 245         if ($cte && $cte !~ $NO_ENCODE_RE) {
 246                 $$bdy = Email::MIME::Encodings::encode($cte, $$bdy)
 247         }
 248         undef;
 249 }
 250
 251 sub body_str_set {
 252         my ($self, $body_str) = @_;
 253         my $charset = ct($self)->{attributes}->{charset} or
 254                 Carp::confess('body_str was given, but no charset is defined');
 255         body_set($self, \(encode($charset, $body_str, Encode::FB_CROAK)));
 256 }
 257
 258 sub content_type { scalar header($_[0], 'Content-Type') }
 259
 260 # we only support raw header_set
 261 sub header_set {
 262         my ($self, $pfx, @vals) = @_;
 263         my $re = re_memo($pfx);
 264         my $hdr = $self->{hdr};
 265         return $$hdr =~ s!$re!!g if !@vals;
 266         $pfx .= ': ';
 267         my $len = 78 - length($pfx);
 268         @vals = map {;
 269                 # folding differs from Email::Simple::Header,
 270                 # we favor tabs for visibility (and space savings :P)
 271                 if (length($_) >= $len && (/\n[^ \t]/s || !/\n/s)) {
 272                         local $Text::Wrap::columns = $len;
 273                         local $Text::Wrap::huge = 'overflow';
 274                         $pfx . wrap('', "\t", $_) . $self->{crlf};
 275                 } else {
 276                         $pfx . $_ . $self->{crlf};
 277                 }
 278         } @vals;
 279         $$hdr =~ s!$re!shift(@vals) // ''!ge; # replace current headers, first
 280         $$hdr .= join('', @vals); # append any leftovers not replaced
 281         # wantarray ? @_[2..$#_] : $_[2]; # Email::Simple::Header compat
 282         undef; # we don't care for the return value
 283 }
 284
 285 # note: we only call this method on Subject
 286 sub header_str_set {
 287         my ($self, $name, @vals) = @_;
 288         for (@vals) {
 289                 next unless /[^\x20-\x7e]/;
 290                 utf8::encode($_); # to octets
 291                 # 39: int((75 - length("Subject: =?UTF-8?B?".'?=') ) / 4) * 3;
 292                 s/(.{1,39})/'=?UTF-8?B?'.encode_base64($1, '').'?='/ges;
 293         }
 294         header_set($self, $name, @vals);
 295 }
 296
 297 sub mhdr_decode ($) { eval { $MIME_Header->decode($_[0]) } // $_[0] }
 298
 299 sub filename {
 300         my $dis = header_raw($_[0], 'Content-Disposition');
 301         my $attrs = parse_content_disposition($dis)->{attributes};
 302         my $fn = $attrs->{filename};
 303         $fn = ct($_[0])->{attributes}->{name} if !defined($fn) || $fn eq '';
 304         (defined($fn) && $fn =~ /=\?/) ? mhdr_decode($fn) : $fn;
 305 }
 306
 307 sub xs_addr_str { # helper for ->header / ->header_str
 308         for (@_) { # array from header_raw()
 309                 next unless /=\?/;
 310                 my @g = parse_email_groups($_); # [ foo => [ E::A::X, ... ]
 311                 for (my $i = 0; $i < @g; $i += 2) {
 312                         if (defined($g[$i]) && $g[$i] =~ /=\?/) {
 313                                 $g[$i] = mhdr_decode($g[$i]);
 314                         }
 315                         my $addrs = $g[$i + 1];
 316                         for my $eax (@$addrs) {
 317                                 for my $m (qw(phrase comment)) {
 318                                         my $v = $eax->$m;
 319                                         $eax->$m(mhdr_decode($v)) if
 320                                                         $v && $v =~ /=\?/;
 321                                 }
 322                         }
 323                 }
 324                 $_ = format_email_groups(@g);
 325         }
 326 }
 327
 328 eval {
 329         require Email::Address::XS;
 330         Email::Address::XS->import(qw(parse_email_groups format_email_groups));
 331         1;
 332 } or do {
 333         # fallback to just decoding everything, because parsing
 334         # email addresses correctly w/o C/XS is slow
 335         %DECODE_FULL = (%DECODE_FULL, %DECODE_ADDRESS);
 336         %DECODE_ADDRESS = ();
 337 };
 338
 339 *header = \&header_str;
 340 sub header_str {
 341         my ($self, $name) = @_;
 342         my @v = header_raw($self, $name);
 343         if ($DECODE_ADDRESS{$name}) {
 344                 xs_addr_str(@v);
 345         } elsif ($DECODE_FULL{$name}) {
 346                 for (@v) {
 347                         $_ = mhdr_decode($_) if /=\?/;
 348                 }
 349         }
 350         wantarray ? @v : $v[0];
 351 }
 352
 353 sub body_raw { ${$_[0]->{bdy} // \''}; }
 354
 355 sub body { body_decode($_[0], body_raw($_[0])) }
 356
 357 sub body_str {
 358         my ($self) = @_;
 359         my $ct = ct($self);
 360         my $charset = $ct->{attributes}->{charset};
 361         if (!$charset) {
 362                 if ($STR_TYPE{$ct->{type}} && $STR_SUBTYPE{$ct->{subtype}}) {
 363                         return body($self);
 364                 }
 365                 Carp::confess("can't get body as a string for ",
 366                         join("\n\t", header_raw($self, 'Content-Type')));
 367         }
 368         decode($charset, body($self), Encode::FB_CROAK);
 369 }
 370
 371 sub as_string {
 372         my ($self) = @_;
 373         my $ret = ${ $self->{hdr} };
 374         return $ret unless defined($self->{bdy});
 375         $ret .= $self->{crlf};
 376         $ret .= ${$self->{bdy}};
 377 }
 378
 379 # Unlike Email::MIME::charset_set, this only changes the parsed
 380 # representation of charset used for search indexing and HTML display.
 381 # This does NOT affect what ->as_string returns.
 382 sub charset_set {
 383         ct($_[0])->{attributes}->{charset} = $_[1];
 384 }
 385
 386 sub crlf { $_[0]->{crlf} // "\n" }
 387
 388 sub willneed { re_memo($_) for @_ }
 389
 390 willneed(qw(From To Cc Date Subject Content-Type In-Reply-To References
 391                 Message-ID X-Alt-Message-ID));
 392
 393 1;