lib/PublicInbox/Eml.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Lazy MIME parser, it still slurps the full message but keeps short
   5 # lifetimes.  Unlike Email::MIME, it doesn't pre-split multipart
   6 # messages or do any up-front parsing of headers besides splitting
   7 # the header string from the body.
   8 #
   9 # Contains ideas and code from Email::Simple and Email::MIME
  10 # (Perl Artistic License, GPL-1+)
  11 #
  12 # This aims to replace Email::MIME for our purposes, similar API
  13 # but internal field names are differ if they're not 100%-compatible.
  14 #
  15 # Includes some proposed fixes for Email::MIME:
  16 # - header-less sub parts - https://github.com/rjbs/Email-MIME/issues/14
  17 # - "0" as boundary - https://github.com/rjbs/Email-MIME/issues/63
  18 #
  19 # $self = {
  20 #       bdy => scalar ref for body (may be undef),
  21 #       hdr => scalar ref for header,
  22 #       crlf => "\n" or "\r\n" (scalar, not a ref),
  23 #
  24 #       # filled in during ->each_part
  25 #       ct => hash ref returned by parse_content_type
  26 # }
  27 package PublicInbox::Eml;
  28 use strict;
  29 use v5.10.1;
  30 use Carp qw(croak);
  31 use Encode qw(find_encoding); # stdlib
  32 use Text::Wrap qw(wrap); # stdlib, we need Perl 5.6+ for $huge
  33 use MIME::Base64 3.05; # Perl 5.10.0 / 5.9.2
  34 use MIME::QuotedPrint 3.05; # ditto
  35
  36 my $MIME_Header = find_encoding('MIME-Header');
  37
  38 use PublicInbox::EmlContentFoo qw(parse_content_type parse_content_disposition);
  39 $PublicInbox::EmlContentFoo::STRICT_PARAMS = 0;
  40
  41 our $mime_parts_limit = 1000; # same as SpamAssassin (not in postfix AFAIK)
  42
  43 # the rest of the limit names are taken from postfix:
  44 our $mime_nesting_limit = 20; # seems enough, Perl sucks, here
  45 our $mime_boundary_length_limit = 2048; # same as postfix
  46 our $header_size_limit = 102400; # same as postfix
  47
  48 my %MIME_ENC = (qp => \&enc_qp, base64 => \&encode_base64);
  49 my %MIME_DEC = (qp => \&dec_qp, base64 => \&decode_base64);
  50 $MIME_ENC{quotedprint} = $MIME_ENC{'quoted-printable'} = $MIME_ENC{qp};
  51 $MIME_DEC{quotedprint} = $MIME_DEC{'quoted-printable'} = $MIME_DEC{qp};
  52 $MIME_ENC{$_} = \&identity_codec for qw(7bit 8bit binary);
  53
  54 my %DECODE_ADDRESS = map {
  55         ($_ => 1, "Resent-$_" => 1)
  56 } qw(From To Cc Sender Reply-To Bcc);
  57 my %DECODE_FULL = (
  58         Subject => 1,
  59         'Content-Description' => 1,
  60         'Content-Type' => 1, # not correct, but needed, oh well
  61 );
  62 our %STR_TYPE = (text => 1);
  63 our %STR_SUBTYPE = (plain => 1, html => 1);
  64
  65 # message/* subtypes we descend into
  66 our %MESSAGE_DESCEND = (
  67         news => 1, # RFC 1849 (obsolete, but archives are forever)
  68         rfc822 => 1, # RFC 2046
  69         rfc2822 => 1, # gmime handles this (but not rfc5322)
  70         global => 1, # RFC 6532
  71 );
  72
  73 my %re_memo;
  74 sub re_memo ($) {
  75         my ($k) = @_;
  76         # Do not normalize $k with lc/uc; instead strive to keep
  77         # capitalization in our codebase consistent.
  78         $re_memo{$k} ||= qr/^\Q$k\E:[ \t]*([^\n]*\r?\n # 1st line
  79                                         # continuation lines:
  80                                         (?:[^:\n]*?[ \t]+[^\n]*\r?\n)*)
  81                                         /ismx
  82 }
  83
  84 sub hdr_truncate ($) {
  85         my $len = length($_[0]);
  86         substr($_[0], $header_size_limit, $len) = '';
  87         my $end = rindex($_[0], "\n");
  88         if ($end >= 0) {
  89                 ++$end;
  90                 substr($_[0], $end, $len) = '';
  91                 warn "header of $len bytes truncated to $end bytes\n";
  92         } else {
  93                 $_[0] = '';
  94                 warn <<EOF
  95 header of $len bytes without `\\n' within $header_size_limit ignored
  96 EOF
  97         }
  98 }
  99
 100 # compatible with our uses of Email::MIME
 101 sub new {
 102         my $ref = ref($_[1]) ? $_[1] : \(my $cpy = $_[1]);
 103         # substr() can modify the first arg in-place and to avoid
 104         # memcpy/memmove on a potentially large scalar.  It does need
 105         # to make a copy for $hdr, though.  Idea stolen from Email::Simple.
 106
 107         # We also prefer index() on common LFLF emails since it's faster
 108         # and re scan can bump RSS by length($$ref) on big strings
 109         if (index($$ref, "\r\n") < 0 && (my $pos = index($$ref, "\n\n")) >= 0) {
 110                 # likely on *nix
 111                 my $hdr = substr($$ref, 0, $pos + 2, ''); # sv_chop on $$ref
 112                 chop($hdr); # lower SvCUR
 113                 hdr_truncate($hdr) if length($hdr) > $header_size_limit;
 114                 bless { hdr => \$hdr, crlf => "\n", bdy => $ref }, __PACKAGE__;
 115         } elsif ($$ref =~ /\r?\n(\r?\n)/s) {
 116                 my $hdr = substr($$ref, 0, $+[0], ''); # sv_chop on $$ref
 117                 substr($hdr, -(length($1))) = ''; # lower SvCUR
 118                 hdr_truncate($hdr) if length($hdr) > $header_size_limit;
 119                 bless { hdr => \$hdr, crlf => $1, bdy => $ref }, __PACKAGE__;
 120         } elsif ($$ref =~ /^[a-z0-9-]+[ \t]*:/ims && $$ref =~ /(\r?\n)\z/s) {
 121                 # body is optional :P
 122                 my $hdr = substr($$ref, 0, $header_size_limit + 1);
 123                 hdr_truncate($hdr) if length($hdr) > $header_size_limit;
 124                 bless { hdr => \$hdr, crlf => $1 }, __PACKAGE__;
 125         } else { # nothing useful
 126                 my $hdr = $$ref = '';
 127                 bless { hdr => \$hdr, crlf => "\n" }, __PACKAGE__;
 128         }
 129 }
 130
 131 sub new_sub {
 132         my (undef, $ref) = @_;
 133         # special case for messages like <85k5su9k59.fsf_-_@lola.goethe.zz>
 134         $$ref =~ /\A(\r?\n)/s or return new(undef, $ref);
 135         my $hdr = substr($$ref, 0, $+[0], ''); # sv_chop on $$ref
 136         bless { hdr => \$hdr, crlf => $1, bdy => $ref }, __PACKAGE__;
 137 }
 138
 139 # same output as Email::Simple::Header::header_raw, but we extract
 140 # headers on-demand instead of parsing them into a list which
 141 # requires O(n) lookups anyways
 142 sub header_raw {
 143         my $re = re_memo($_[1]);
 144         my @v = (${ $_[0]->{hdr} } =~ /$re/g);
 145         for (@v) {
 146                 # for compatibility w/ Email::Simple::Header,
 147                 s/\s+\z//s;
 148                 s/\A\s+//s;
 149                 s/\r?\n[ \t]*/ /gs;
 150         }
 151         wantarray ? @v : $v[0];
 152 }
 153
 154 # pick the first Content-Type header to match Email::MIME behavior.
 155 # It's usually the right one based on historical archives.
 156 sub ct ($) {
 157         # PublicInbox::EmlContentFoo::content_type:
 158         $_[0]->{ct} //= parse_content_type(header($_[0], 'Content-Type'));
 159 }
 160
 161 # returns a queue of sub-parts iff it's worth descending into
 162 sub mp_descend ($$) {
 163         my ($self, $nr) = @_; # or $once for top-level
 164         my $ct = ct($self);
 165         my $type = lc($ct->{type});
 166         if ($type eq 'message' && $MESSAGE_DESCEND{lc($ct->{subtype})}) {
 167                 my $nxt = new(undef, body_raw($self));
 168                 $self->{-call_cb} = $nxt->{is_submsg} = 1;
 169                 return [ $nxt ];
 170         }
 171         return if $type ne 'multipart';
 172         my $bnd = $ct->{attributes}->{boundary} // return; # single-part
 173         return if $bnd eq '' || length($bnd) >= $mime_boundary_length_limit;
 174         $bnd = quotemeta($bnd);
 175
 176         # this is a multipart message that didn't get descended into in
 177         # public-inbox <= 1.5.0, so ensure we call the user callback for
 178         # this part to not break PSGI downloads.
 179         $self->{-call_cb} = $self->{is_submsg};
 180
 181         # "multipart" messages can exist w/o a body
 182         my $bdy = ($nr ? delete($self->{bdy}) : \(body_raw($self))) or return;
 183
 184         # Cut at the the first epilogue, not subsequent ones.
 185         # *sigh* just the regexp match alone seems to bump RSS by
 186         # length($$bdy) on a ~30M string:
 187         my $epilogue_missing;
 188         if ($$bdy =~ /(?:\r?\n)?^--$bnd--[ \t]*\r?$/sm) {
 189                 substr($$bdy, $-[0]) = '';
 190         } else {
 191                 $epilogue_missing = 1;
 192         }
 193
 194         # *Sigh* split() doesn't work in-place and return CoW strings
 195         # because Perl wants to "\0"-terminate strings.  So split()
 196         # again bumps RSS by length($$bdy)
 197
 198         # Quiet warning for "Complex regular subexpression recursion limit"
 199         # in case we get many empty parts, it's harmless in this case
 200         no warnings 'regexp';
 201         my ($pre, @parts) = split(/(?:\r?\n)?(?:^--$bnd[ \t]*\r?\n)+/ms,
 202                                 $$bdy,
 203                                 # + 3 since we don't want the last part
 204                                 # processed to include any other excluded
 205                                 # parts ($nr starts at 1, and I suck at math)
 206                                 $mime_parts_limit + 3 - $nr);
 207
 208         if (@parts) { # the usual path if we got this far:
 209                 undef $bdy; # release memory ASAP if $nr > 0
 210
 211                 # compatibility with Email::MIME
 212                 $parts[-1] =~ s/\n\r?\n\z/\n/s if $epilogue_missing;
 213
 214                 # ignore empty parts
 215                 @parts = map { new_sub(undef, \$_) } grep /[^ \t\r\n]/s, @parts;
 216
 217                 # Keep "From: someone..." from preamble in old,
 218                 # buggy versions of git-send-email, otherwise drop it
 219                 # There's also a case where quoted text showed up in the
 220                 # preamble
 221                 # <20060515162817.65F0F1BBAE@citi.umich.edu>
 222                 unshift(@parts, new_sub(undef, \$pre)) if index($pre, ':') >= 0;
 223                 return \@parts;
 224         }
 225         # "multipart", but no boundary found, treat as single part
 226         $self->{bdy} //= $bdy;
 227         undef;
 228 }
 229
 230 # $p = [ \@parts, $depth, $idx ]
 231 # $idx[0] grows as $depth grows, $idx[1] == $p->[-1] == current part
 232 # (callers need to be updated)
 233 # \@parts is a queue which empties when we're done with a parent part
 234
 235 # same usage as PublicInbox::MsgIter::msg_iter
 236 # $cb - user-supplied callback sub
 237 # $arg - user-supplied arg (think pthread_create)
 238 # $once - unref body scalar during iteration
 239 # $all - used by IMAP server, only
 240 sub each_part {
 241         my ($self, $cb, $arg, $once, $all) = @_;
 242         my $p = mp_descend($self, $once // 0) or
 243                                         return $cb->([$self, 0, 1], $arg);
 244
 245         $cb->([$self, 0, 0], $arg) if ($all || $self->{-call_cb}); # rare
 246
 247         $p = [ $p, 0 ];
 248         my @s; # our virtual stack
 249         my $nr = 0;
 250         while ((scalar(@{$p->[0]}) || ($p = pop @s)) &&
 251                         ++$nr <= $mime_parts_limit) {
 252                 ++$p->[-1]; # bump index
 253                 my (undef, @idx) = @$p;
 254                 @idx = (join('.', @idx));
 255                 my $depth = ($idx[0] =~ tr/././) + 1;
 256                 my $sub = shift @{$p->[0]};
 257                 if ($depth < $mime_nesting_limit &&
 258                                 (my $nxt = mp_descend($sub, $nr))) {
 259                         push(@s, $p) if scalar @{$p->[0]};
 260                         $p = [ $nxt, @idx, 0 ];
 261                         ($all || $sub->{-call_cb}) and
 262                                 $cb->([$sub, $depth, @idx], $arg);
 263                 } else { # a leaf node
 264                         $cb->([$sub, $depth, @idx], $arg);
 265                 }
 266         }
 267 }
 268
 269 sub enc_qp {
 270         # prevent MIME::QuotedPrint from encoding CR as =0D since it's
 271         # against RFCs and breaks MUAs
 272         $_[0] =~ s/\r\n/\n/sg;
 273         encode_qp($_[0], "\r\n");
 274 }
 275
 276 sub dec_qp {
 277         # RFC 2822 requires all lines to end in CRLF, though... :<
 278         $_[0] = decode_qp($_[0]);
 279         $_[0] =~ s/\n/\r\n/sg;
 280         $_[0]
 281 }
 282
 283 sub identity_codec { $_[0] }
 284
 285 ########### compatibility section for existing Email::MIME uses #########
 286
 287 sub header_obj {
 288         bless { hdr => $_[0]->{hdr}, crlf => $_[0]->{crlf} }, __PACKAGE__;
 289 }
 290
 291 sub subparts {
 292         my ($self) = @_;
 293         my $parts = mp_descend($self, 0) or return ();
 294         my $bnd = ct($self)->{attributes}->{boundary} // die 'BUG: no boundary';
 295         my $bdy = $self->{bdy};
 296         if ($$bdy =~ /\A(.*?)(?:\r?\n)?^--\Q$bnd\E[ \t]*\r?$/sm) {
 297                 $self->{preamble} = $1;
 298         }
 299         if ($$bdy =~ /^--\Q$bnd\E--[ \t]*\r?\n(.+)\z/sm) {
 300                 $self->{epilogue} = $1;
 301         }
 302         @$parts;
 303 }
 304
 305 sub parts_set {
 306         my ($self, $parts) = @_;
 307
 308         # we can't fully support what Email::MIME does,
 309         # just what our filter code needs:
 310         my $bnd = ct($self)->{attributes}->{boundary} // die <<EOF;
 311 ->parts_set not supported for single-part messages
 312 EOF
 313         my $crlf = $self->{crlf};
 314         my $fin_bnd = "$crlf--$bnd--$crlf";
 315         $bnd = "$crlf--$bnd$crlf";
 316         ${$self->{bdy}} = join($bnd,
 317                                 delete($self->{preamble}) // '',
 318                                 map { $_->as_string } @$parts
 319                                 ) .
 320                                 $fin_bnd .
 321                                 (delete($self->{epilogue}) // '');
 322         undef;
 323 }
 324
 325 sub body_set {
 326         my ($self, $body) = @_;
 327         my $bdy = $self->{bdy} = ref($body) ? $body : \$body;
 328         if (my $cte = header_raw($self, 'Content-Transfer-Encoding')) {
 329                 my $enc = $MIME_ENC{lc($cte)} or croak("can't encode `$cte'");
 330                 $$bdy = $enc->($$bdy); # in-place
 331         }
 332         undef;
 333 }
 334
 335 sub body_str_set {
 336         my ($self, $str) = @_;
 337         my $cs = ct($self)->{attributes}->{charset} //
 338                 croak('body_str was given, but no charset is defined');
 339         my $enc = find_encoding($cs) // croak "unknown encoding `$cs'";
 340         my $tmp;
 341         {
 342                 my @w;
 343                 local $SIG{__WARN__} = sub { push @w, @_ };
 344                 $tmp = $enc->encode($str, Encode::FB_WARN);
 345                 croak(@w) if @w;
 346         };
 347         body_set($self, \$tmp);
 348 }
 349
 350 sub content_type { scalar header($_[0], 'Content-Type') }
 351
 352 # we only support raw header_set
 353 sub header_set {
 354         my ($self, $pfx, @vals) = @_;
 355         my $re = re_memo($pfx);
 356         my $hdr = $self->{hdr};
 357         return $$hdr =~ s!$re!!g if !@vals;
 358         $pfx .= ': ';
 359         my $len = 78 - length($pfx);
 360         @vals = map {;
 361                 # folding differs from Email::Simple::Header,
 362                 # we favor tabs for visibility (and space savings :P)
 363                 if (length($_) >= $len && (/\n[^ \t]/s || !/\n/s)) {
 364                         local $Text::Wrap::columns = $len;
 365                         local $Text::Wrap::huge = 'overflow';
 366                         $pfx . wrap('', "\t", $_) . $self->{crlf};
 367                 } else {
 368                         $pfx . $_ . $self->{crlf};
 369                 }
 370         } @vals;
 371         $$hdr =~ s!$re!shift(@vals) // ''!ge; # replace current headers, first
 372         $$hdr .= join('', @vals); # append any leftovers not replaced
 373         # wantarray ? @_[2..$#_] : $_[2]; # Email::Simple::Header compat
 374         undef; # we don't care for the return value
 375 }
 376
 377 # note: we only call this method on Subject
 378 sub header_str_set {
 379         my ($self, $name, @vals) = @_;
 380         for (@vals) {
 381                 next unless /[^\x20-\x7e]/;
 382                 # 39: int((75 - length("Subject: =?UTF-8?B?".'?=') ) / 4) * 3;
 383                 s/(.{1,39})/
 384                         my $x = $1;
 385                         utf8::encode($x); # to octets
 386                         '=?UTF-8?B?'.encode_base64($x, '').'?='
 387                 /xges;
 388         }
 389         header_set($self, $name, @vals);
 390 }
 391
 392 sub mhdr_decode ($) {
 393         eval { $MIME_Header->decode($_[0], Encode::FB_DEFAULT) } // $_[0];
 394 }
 395
 396 sub filename {
 397         my $dis = header_raw($_[0], 'Content-Disposition');
 398         my $attrs = parse_content_disposition($dis)->{attributes};
 399         my $fn = $attrs->{filename};
 400         $fn = ct($_[0])->{attributes}->{name} if !defined($fn) || $fn eq '';
 401         (defined($fn) && $fn =~ /=\?/) ? mhdr_decode($fn) : $fn;
 402 }
 403
 404 sub xs_addr_str { # helper for ->header / ->header_str
 405         for (@_) { # array from header_raw()
 406                 next unless /=\?/;
 407                 my @g = parse_email_groups($_); # [ foo => [ E::A::X, ... ]
 408                 for (my $i = 0; $i < @g; $i += 2) {
 409                         if (defined($g[$i]) && $g[$i] =~ /=\?/) {
 410                                 $g[$i] = mhdr_decode($g[$i]);
 411                         }
 412                         my $addrs = $g[$i + 1];
 413                         for my $eax (@$addrs) {
 414                                 for my $m (qw(phrase comment)) {
 415                                         my $v = $eax->$m;
 416                                         $eax->$m(mhdr_decode($v)) if
 417                                                         $v && $v =~ /=\?/;
 418                                 }
 419                         }
 420                 }
 421                 $_ = format_email_groups(@g);
 422         }
 423 }
 424
 425 eval {
 426         require Email::Address::XS;
 427         Email::Address::XS->import(qw(parse_email_groups format_email_groups));
 428         1;
 429 } or do {
 430         # fallback to just decoding everything, because parsing
 431         # email addresses correctly w/o C/XS is slow
 432         %DECODE_FULL = (%DECODE_FULL, %DECODE_ADDRESS);
 433         %DECODE_ADDRESS = ();
 434 };
 435
 436 *header = \&header_str;
 437 sub header_str {
 438         my ($self, $name) = @_;
 439         my @v = header_raw($self, $name);
 440         if ($DECODE_ADDRESS{$name}) {
 441                 xs_addr_str(@v);
 442         } elsif ($DECODE_FULL{$name}) {
 443                 for (@v) {
 444                         $_ = mhdr_decode($_) if /=\?/;
 445                 }
 446         }
 447         wantarray ? @v : $v[0];
 448 }
 449
 450 sub body_raw { ${$_[0]->{bdy} // \''}; }
 451
 452 sub body {
 453         my $raw = body_raw($_[0]);
 454         my $cte = header_raw($_[0], 'Content-Transfer-Encoding') or return $raw;
 455         ($cte) = ($cte =~ /([a-zA-Z0-9\-]+)/) or return $raw; # For S/MIME, etc
 456         my $dec = $MIME_DEC{lc($cte)} or return $raw;
 457         $dec->($raw);
 458 }
 459
 460 sub body_str {
 461         my ($self) = @_;
 462         my $ct = ct($self);
 463         my $cs = $ct->{attributes}->{charset} // do {
 464                 ($STR_TYPE{$ct->{type}} && $STR_SUBTYPE{$ct->{subtype}}) and
 465                         return body($self);
 466                 croak("can't get body as a string for ",
 467                         join("\n\t", header_raw($self, 'Content-Type')));
 468         };
 469         my $enc = find_encoding($cs) or croak "unknown encoding `$cs'";
 470         my $tmp = body($self);
 471         # workaround https://rt.cpan.org/Public/Bug/Display.html?id=139622
 472         my @w;
 473         local $SIG{__WARN__} = sub { push @w, @_ };
 474         my $ret = $enc->decode($tmp, Encode::FB_WARN);
 475         croak(@w) if @w;
 476         $ret;
 477 }
 478
 479 sub as_string {
 480         my ($self) = @_;
 481         my $ret = ${ $self->{hdr} };
 482         return $ret unless defined($self->{bdy});
 483         $ret .= $self->{crlf};
 484         $ret .= ${$self->{bdy}};
 485 }
 486
 487 # Unlike Email::MIME::charset_set, this only changes the parsed
 488 # representation of charset used for search indexing and HTML display.
 489 # This does NOT affect what ->as_string returns.
 490 sub charset_set {
 491         ct($_[0])->{attributes}->{charset} = $_[1];
 492 }
 493
 494 sub crlf { $_[0]->{crlf} // "\n" }
 495
 496 sub raw_size {
 497         my ($self) = @_;
 498         my $len = length(${$self->{hdr}});
 499         defined($self->{bdy}) and
 500                 $len += length(${$self->{bdy}}) + length($self->{crlf});
 501         $len;
 502 }
 503
 504 # warnings to ignore when handling spam mailboxes and maybe other places
 505 sub warn_ignore {
 506         my $s = "@_";
 507         # Email::Address::XS warnings
 508         $s =~ /^Argument contains empty /
 509         || $s =~ /^Element at index [0-9]+.*? contains /
 510         # PublicInbox::MsgTime
 511         || $s =~ /^bogus TZ offset: .+?, ignoring and assuming \+0000/
 512         || $s =~ /^bad Date: .+? in /
 513         # Encode::Unicode::UTF7
 514         || $s =~ /^Bad UTF7 data escape at /
 515 }
 516
 517 # this expects to be RHS in this assignment: "local $SIG{__WARN__} = ..."
 518 sub warn_ignore_cb {
 519         my $cb = $SIG{__WARN__} // \&CORE::warn;
 520         sub { $cb->(@_) unless warn_ignore(@_) }
 521 }
 522
 523 sub willneed { re_memo($_) for @_ }
 524
 525 willneed(qw(From To Cc Date Subject Content-Type In-Reply-To References
 526                 Message-ID X-Alt-Message-ID));
 527
 528 1;