lib/PublicInbox/Eml.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Lazy MIME parser, it still slurps the full message but keeps short
   5 # lifetimes.  Unlike Email::MIME, it doesn't pre-split multipart
   6 # messages or do any up-front parsing of headers besides splitting
   7 # the header string from the body.
   8 #
   9 # Contains ideas and code from Email::Simple and Email::MIME
  10 # (Perl Artistic License, GPL-1+)
  11 #
  12 # This aims to replace Email::MIME for our purposes, similar API
  13 # but internal field names are differ if they're not 100%-compatible.
  14 #
  15 # Includes some proposed fixes for Email::MIME:
  16 # - header-less sub parts - https://github.com/rjbs/Email-MIME/issues/14
  17 # - "0" as boundary - https://github.com/rjbs/Email-MIME/issues/63
  18 #
  19 # $self = {
  20 #       bdy => scalar ref for body (may be undef),
  21 #       hdr => scalar ref for header,
  22 #       crlf => "\n" or "\r\n" (scalar, not a ref),
  23 #
  24 #       # filled in during ->each_part
  25 #       ct => hash ref returned by parse_content_type
  26 # }
  27 package PublicInbox::Eml;
  28 use strict;
  29 use v5.10.1;
  30 use Carp qw(croak);
  31 use Encode qw(find_encoding); # stdlib
  32 use Text::Wrap qw(wrap); # stdlib, we need Perl 5.6+ for $huge
  33 use MIME::Base64 3.05; # Perl 5.10.0 / 5.9.2
  34 use MIME::QuotedPrint 3.05; # ditto
  35
  36 my $MIME_Header = find_encoding('MIME-Header');
  37
  38 use PublicInbox::EmlContentFoo qw(parse_content_type parse_content_disposition);
  39 $PublicInbox::EmlContentFoo::STRICT_PARAMS = 0;
  40
  41 our $mime_parts_limit = 1000; # same as SpamAssassin (not in postfix AFAIK)
  42
  43 # the rest of the limit names are taken from postfix:
  44 our $mime_nesting_limit = 20; # seems enough, Perl sucks, here
  45 our $mime_boundary_length_limit = 2048; # same as postfix
  46 our $header_size_limit = 102400; # same as postfix
  47
  48 my %MIME_ENC = (qp => \&enc_qp, base64 => \&encode_base64);
  49 my %MIME_DEC = (qp => \&dec_qp, base64 => \&decode_base64);
  50 $MIME_ENC{quotedprint} = $MIME_ENC{'quoted-printable'} = $MIME_ENC{qp};
  51 $MIME_DEC{quotedprint} = $MIME_DEC{'quoted-printable'} = $MIME_DEC{qp};
  52 $MIME_ENC{$_} = \&identity_codec for qw(7bit 8bit binary);
  53
  54 my %DECODE_ADDRESS = map {
  55         ($_ => 1, "Resent-$_" => 1)
  56 } qw(From To Cc Sender Reply-To Bcc);
  57 my %DECODE_FULL = (
  58         Subject => 1,
  59         'Content-Description' => 1,
  60         'Content-Type' => 1, # not correct, but needed, oh well
  61 );
  62 our %STR_TYPE = (text => 1);
  63 our %STR_SUBTYPE = (plain => 1, html => 1);
  64
  65 # message/* subtypes we descend into
  66 our %MESSAGE_DESCEND = (
  67         news => 1, # RFC 1849 (obsolete, but archives are forever)
  68         rfc822 => 1, # RFC 2046
  69         rfc2822 => 1, # gmime handles this (but not rfc5322)
  70         global => 1, # RFC 6532
  71 );
  72
  73 my %re_memo;
  74 sub re_memo ($) {
  75         my ($k) = @_;
  76         # Do not normalize $k with lc/uc; instead strive to keep
  77         # capitalization in our codebase consistent.
  78         $re_memo{$k} ||= qr/^\Q$k\E:[ \t]*([^\n]*\r?\n # 1st line
  79                                         # continuation lines:
  80                                         (?:[^:\n]*?[ \t]+[^\n]*\r?\n)*)
  81                                         /ismx
  82 }
  83
  84 sub hdr_truncate ($) {
  85         my $len = length($_[0]);
  86         substr($_[0], $header_size_limit, $len) = '';
  87         my $end = rindex($_[0], "\n");
  88         if ($end >= 0) {
  89                 ++$end;
  90                 substr($_[0], $end, $len) = '';
  91                 warn "header of $len bytes truncated to $end bytes\n";
  92         } else {
  93                 $_[0] = '';
  94                 warn <<EOF
  95 header of $len bytes without `\\n' within $header_size_limit ignored
  96 EOF
  97         }
  98 }
  99
 100 # compatible with our uses of Email::MIME
 101 sub new {
 102         my $ref = ref($_[1]) ? $_[1] : \(my $cpy = $_[1]);
 103         # substr() can modify the first arg in-place and to avoid
 104         # memcpy/memmove on a potentially large scalar.  It does need
 105         # to make a copy for $hdr, though.  Idea stolen from Email::Simple.
 106
 107         # We also prefer index() on common LFLF emails since it's faster
 108         # and re scan can bump RSS by length($$ref) on big strings
 109         if (index($$ref, "\r\n") < 0 && (my $pos = index($$ref, "\n\n")) >= 0) {
 110                 # likely on *nix
 111                 my $hdr = substr($$ref, 0, $pos + 2, ''); # sv_chop on $$ref
 112                 chop($hdr); # lower SvCUR
 113                 hdr_truncate($hdr) if length($hdr) > $header_size_limit;
 114                 bless { hdr => \$hdr, crlf => "\n", bdy => $ref }, __PACKAGE__;
 115         } elsif ($$ref =~ /\r?\n(\r?\n)/s) {
 116                 my $hdr = substr($$ref, 0, $+[0], ''); # sv_chop on $$ref
 117                 substr($hdr, -(length($1))) = ''; # lower SvCUR
 118                 hdr_truncate($hdr) if length($hdr) > $header_size_limit;
 119                 bless { hdr => \$hdr, crlf => $1, bdy => $ref }, __PACKAGE__;
 120         } elsif ($$ref =~ /^[a-z0-9-]+[ \t]*:/ims && $$ref =~ /(\r?\n)\z/s) {
 121                 # body is optional :P
 122                 my $hdr = substr($$ref, 0, $header_size_limit + 1);
 123                 hdr_truncate($hdr) if length($hdr) > $header_size_limit;
 124                 bless { hdr => \$hdr, crlf => $1 }, __PACKAGE__;
 125         } else { # just a body w/o header?
 126                 my $hdr = '';
 127                 my $eol = ($$ref =~ /(\r?\n)/) ? $1 : "\n";
 128                 bless { hdr => \$hdr, crlf => $eol, bdy => $ref }, __PACKAGE__;
 129         }
 130 }
 131
 132 sub new_sub {
 133         my (undef, $ref) = @_;
 134         # special case for messages like <85k5su9k59.fsf_-_@lola.goethe.zz>
 135         $$ref =~ /\A(\r?\n)/s or return new(undef, $ref);
 136         my $hdr = substr($$ref, 0, $+[0], ''); # sv_chop on $$ref
 137         bless { hdr => \$hdr, crlf => $1, bdy => $ref }, __PACKAGE__;
 138 }
 139
 140 # same output as Email::Simple::Header::header_raw, but we extract
 141 # headers on-demand instead of parsing them into a list which
 142 # requires O(n) lookups anyways
 143 sub header_raw {
 144         my $re = re_memo($_[1]);
 145         my @v = (${ $_[0]->{hdr} } =~ /$re/g);
 146         for (@v) {
 147                 # for compatibility w/ Email::Simple::Header,
 148                 s/\s+\z//s;
 149                 s/\A\s+//s;
 150                 s/\r?\n[ \t]*/ /gs;
 151         }
 152         wantarray ? @v : $v[0];
 153 }
 154
 155 # pick the first Content-Type header to match Email::MIME behavior.
 156 # It's usually the right one based on historical archives.
 157 sub ct ($) {
 158         # PublicInbox::EmlContentFoo::content_type:
 159         $_[0]->{ct} //= parse_content_type(header($_[0], 'Content-Type'));
 160 }
 161
 162 # returns a queue of sub-parts iff it's worth descending into
 163 sub mp_descend ($$) {
 164         my ($self, $nr) = @_; # or $once for top-level
 165         my $ct = ct($self);
 166         my $type = lc($ct->{type});
 167         if ($type eq 'message' && $MESSAGE_DESCEND{lc($ct->{subtype})}) {
 168                 my $nxt = new(undef, body_raw($self));
 169                 $self->{-call_cb} = $nxt->{is_submsg} = 1;
 170                 return [ $nxt ];
 171         }
 172         return if $type ne 'multipart';
 173         my $bnd = $ct->{attributes}->{boundary} // return; # single-part
 174         return if $bnd eq '' || length($bnd) >= $mime_boundary_length_limit;
 175         $bnd = quotemeta($bnd);
 176
 177         # this is a multipart message that didn't get descended into in
 178         # public-inbox <= 1.5.0, so ensure we call the user callback for
 179         # this part to not break PSGI downloads.
 180         $self->{-call_cb} = $self->{is_submsg};
 181
 182         # "multipart" messages can exist w/o a body
 183         my $bdy = ($nr ? delete($self->{bdy}) : \(body_raw($self))) or return;
 184
 185         # Cut at the the first epilogue, not subsequent ones.
 186         # *sigh* just the regexp match alone seems to bump RSS by
 187         # length($$bdy) on a ~30M string:
 188         my $epilogue_missing;
 189         if ($$bdy =~ /(?:\r?\n)?^--$bnd--[ \t]*\r?$/sm) {
 190                 substr($$bdy, $-[0]) = '';
 191         } else {
 192                 $epilogue_missing = 1;
 193         }
 194
 195         # *Sigh* split() doesn't work in-place and return CoW strings
 196         # because Perl wants to "\0"-terminate strings.  So split()
 197         # again bumps RSS by length($$bdy)
 198
 199         # Quiet warning for "Complex regular subexpression recursion limit"
 200         # in case we get many empty parts, it's harmless in this case
 201         no warnings 'regexp';
 202         my ($pre, @parts) = split(/(?:\r?\n)?(?:^--$bnd[ \t]*\r?\n)+/ms,
 203                                 $$bdy,
 204                                 # + 3 since we don't want the last part
 205                                 # processed to include any other excluded
 206                                 # parts ($nr starts at 1, and I suck at math)
 207                                 $mime_parts_limit + 3 - $nr);
 208
 209         if (@parts) { # the usual path if we got this far:
 210                 undef $bdy; # release memory ASAP if $nr > 0
 211
 212                 # compatibility with Email::MIME
 213                 $parts[-1] =~ s/\n\r?\n\z/\n/s if $epilogue_missing;
 214
 215                 # ignore empty parts
 216                 @parts = map { new_sub(undef, \$_) } grep /[^ \t\r\n]/s, @parts;
 217
 218                 # Keep "From: someone..." from preamble in old,
 219                 # buggy versions of git-send-email, otherwise drop it
 220                 # There's also a case where quoted text showed up in the
 221                 # preamble
 222                 # <20060515162817.65F0F1BBAE@citi.umich.edu>
 223                 unshift(@parts, new_sub(undef, \$pre)) if index($pre, ':') >= 0;
 224                 return \@parts;
 225         }
 226         # "multipart", but no boundary found, treat as single part
 227         $self->{bdy} //= $bdy;
 228         undef;
 229 }
 230
 231 # $p = [ \@parts, $depth, $idx ]
 232 # $idx[0] grows as $depth grows, $idx[1] == $p->[-1] == current part
 233 # (callers need to be updated)
 234 # \@parts is a queue which empties when we're done with a parent part
 235
 236 # same usage as PublicInbox::MsgIter::msg_iter
 237 # $cb - user-supplied callback sub
 238 # $arg - user-supplied arg (think pthread_create)
 239 # $once - unref body scalar during iteration
 240 # $all - used by IMAP server, only
 241 sub each_part {
 242         my ($self, $cb, $arg, $once, $all) = @_;
 243         my $p = mp_descend($self, $once // 0) or
 244                                         return $cb->([$self, 0, 1], $arg);
 245
 246         $cb->([$self, 0, 0], $arg) if ($all || $self->{-call_cb}); # rare
 247
 248         $p = [ $p, 0 ];
 249         my @s; # our virtual stack
 250         my $nr = 0;
 251         while ((scalar(@{$p->[0]}) || ($p = pop @s)) &&
 252                         ++$nr <= $mime_parts_limit) {
 253                 ++$p->[-1]; # bump index
 254                 my (undef, @idx) = @$p;
 255                 @idx = (join('.', @idx));
 256                 my $depth = ($idx[0] =~ tr/././) + 1;
 257                 my $sub = shift @{$p->[0]};
 258                 if ($depth < $mime_nesting_limit &&
 259                                 (my $nxt = mp_descend($sub, $nr))) {
 260                         push(@s, $p) if scalar @{$p->[0]};
 261                         $p = [ $nxt, @idx, 0 ];
 262                         ($all || $sub->{-call_cb}) and
 263                                 $cb->([$sub, $depth, @idx], $arg);
 264                 } else { # a leaf node
 265                         $cb->([$sub, $depth, @idx], $arg);
 266                 }
 267         }
 268 }
 269
 270 sub enc_qp {
 271         # prevent MIME::QuotedPrint from encoding CR as =0D since it's
 272         # against RFCs and breaks MUAs
 273         $_[0] =~ s/\r\n/\n/sg;
 274         encode_qp($_[0], "\r\n");
 275 }
 276
 277 sub dec_qp {
 278         # RFC 2822 requires all lines to end in CRLF, though... :<
 279         $_[0] = decode_qp($_[0]);
 280         $_[0] =~ s/\n/\r\n/sg;
 281         $_[0]
 282 }
 283
 284 sub identity_codec { $_[0] }
 285
 286 ########### compatibility section for existing Email::MIME uses #########
 287
 288 sub header_obj {
 289         bless { hdr => $_[0]->{hdr}, crlf => $_[0]->{crlf} }, __PACKAGE__;
 290 }
 291
 292 sub subparts {
 293         my ($self) = @_;
 294         my $parts = mp_descend($self, 0) or return ();
 295         my $bnd = ct($self)->{attributes}->{boundary} // die 'BUG: no boundary';
 296         my $bdy = $self->{bdy};
 297         if ($$bdy =~ /\A(.*?)(?:\r?\n)?^--\Q$bnd\E[ \t]*\r?$/sm) {
 298                 $self->{preamble} = $1;
 299         }
 300         if ($$bdy =~ /^--\Q$bnd\E--[ \t]*\r?\n(.+)\z/sm) {
 301                 $self->{epilogue} = $1;
 302         }
 303         @$parts;
 304 }
 305
 306 sub parts_set {
 307         my ($self, $parts) = @_;
 308
 309         # we can't fully support what Email::MIME does,
 310         # just what our filter code needs:
 311         my $bnd = ct($self)->{attributes}->{boundary} // die <<EOF;
 312 ->parts_set not supported for single-part messages
 313 EOF
 314         my $crlf = $self->{crlf};
 315         my $fin_bnd = "$crlf--$bnd--$crlf";
 316         $bnd = "$crlf--$bnd$crlf";
 317         ${$self->{bdy}} = join($bnd,
 318                                 delete($self->{preamble}) // '',
 319                                 map { $_->as_string } @$parts
 320                                 ) .
 321                                 $fin_bnd .
 322                                 (delete($self->{epilogue}) // '');
 323         undef;
 324 }
 325
 326 sub body_set {
 327         my ($self, $body) = @_;
 328         my $bdy = $self->{bdy} = ref($body) ? $body : \$body;
 329         if (my $cte = header_raw($self, 'Content-Transfer-Encoding')) {
 330                 my $enc = $MIME_ENC{lc($cte)} or croak("can't encode `$cte'");
 331                 $$bdy = $enc->($$bdy); # in-place
 332         }
 333         undef;
 334 }
 335
 336 sub body_str_set {
 337         my ($self, $str) = @_;
 338         my $cs = ct($self)->{attributes}->{charset} //
 339                 croak('body_str was given, but no charset is defined');
 340         my $enc = find_encoding($cs) // croak "unknown encoding `$cs'";
 341         my $tmp;
 342         {
 343                 my @w;
 344                 local $SIG{__WARN__} = sub { push @w, @_ };
 345                 $tmp = $enc->encode($str, Encode::FB_WARN);
 346                 croak(@w) if @w;
 347         };
 348         body_set($self, \$tmp);
 349 }
 350
 351 sub content_type { scalar header($_[0], 'Content-Type') }
 352
 353 # we only support raw header_set
 354 sub header_set {
 355         my ($self, $pfx, @vals) = @_;
 356         my $re = re_memo($pfx);
 357         my $hdr = $self->{hdr};
 358         return $$hdr =~ s!$re!!g if !@vals;
 359         $pfx .= ': ';
 360         my $len = 78 - length($pfx);
 361         @vals = map {;
 362                 # folding differs from Email::Simple::Header,
 363                 # we favor tabs for visibility (and space savings :P)
 364                 if (length($_) >= $len && (/\n[^ \t]/s || !/\n/s)) {
 365                         local $Text::Wrap::columns = $len;
 366                         local $Text::Wrap::huge = 'overflow';
 367                         $pfx . wrap('', "\t", $_) . $self->{crlf};
 368                 } else {
 369                         $pfx . $_ . $self->{crlf};
 370                 }
 371         } @vals;
 372         $$hdr =~ s!$re!shift(@vals) // ''!ge; # replace current headers, first
 373         $$hdr .= join('', @vals); # append any leftovers not replaced
 374         # wantarray ? @_[2..$#_] : $_[2]; # Email::Simple::Header compat
 375         undef; # we don't care for the return value
 376 }
 377
 378 # note: we only call this method on Subject
 379 sub header_str_set {
 380         my ($self, $name, @vals) = @_;
 381         for (@vals) {
 382                 next unless /[^\x20-\x7e]/;
 383                 # 39: int((75 - length("Subject: =?UTF-8?B?".'?=') ) / 4) * 3;
 384                 s/(.{1,39})/
 385                         my $x = $1;
 386                         utf8::encode($x); # to octets
 387                         '=?UTF-8?B?'.encode_base64($x, '').'?='
 388                 /xges;
 389         }
 390         header_set($self, $name, @vals);
 391 }
 392
 393 sub mhdr_decode ($) {
 394         eval { $MIME_Header->decode($_[0], Encode::FB_DEFAULT) } // $_[0];
 395 }
 396
 397 sub filename {
 398         my $dis = header_raw($_[0], 'Content-Disposition');
 399         my $attrs = parse_content_disposition($dis)->{attributes};
 400         my $fn = $attrs->{filename};
 401         $fn = ct($_[0])->{attributes}->{name} if !defined($fn) || $fn eq '';
 402         (defined($fn) && $fn =~ /=\?/) ? mhdr_decode($fn) : $fn;
 403 }
 404
 405 sub xs_addr_str { # helper for ->header / ->header_str
 406         for (@_) { # array from header_raw()
 407                 next unless /=\?/;
 408                 my @g = parse_email_groups($_); # [ foo => [ E::A::X, ... ]
 409                 for (my $i = 0; $i < @g; $i += 2) {
 410                         if (defined($g[$i]) && $g[$i] =~ /=\?/) {
 411                                 $g[$i] = mhdr_decode($g[$i]);
 412                         }
 413                         my $addrs = $g[$i + 1];
 414                         for my $eax (@$addrs) {
 415                                 for my $m (qw(phrase comment)) {
 416                                         my $v = $eax->$m;
 417                                         $eax->$m(mhdr_decode($v)) if
 418                                                         $v && $v =~ /=\?/;
 419                                 }
 420                         }
 421                 }
 422                 $_ = format_email_groups(@g);
 423         }
 424 }
 425
 426 eval {
 427         require Email::Address::XS;
 428         Email::Address::XS->import(qw(parse_email_groups format_email_groups));
 429         1;
 430 } or do {
 431         # fallback to just decoding everything, because parsing
 432         # email addresses correctly w/o C/XS is slow
 433         %DECODE_FULL = (%DECODE_FULL, %DECODE_ADDRESS);
 434         %DECODE_ADDRESS = ();
 435 };
 436
 437 *header = \&header_str;
 438 sub header_str {
 439         my ($self, $name) = @_;
 440         my @v = header_raw($self, $name);
 441         if ($DECODE_ADDRESS{$name}) {
 442                 xs_addr_str(@v);
 443         } elsif ($DECODE_FULL{$name}) {
 444                 for (@v) {
 445                         $_ = mhdr_decode($_) if /=\?/;
 446                 }
 447         }
 448         wantarray ? @v : $v[0];
 449 }
 450
 451 sub body_raw { ${$_[0]->{bdy} // \''}; }
 452
 453 sub body {
 454         my $raw = body_raw($_[0]);
 455         my $cte = header_raw($_[0], 'Content-Transfer-Encoding') or return $raw;
 456         ($cte) = ($cte =~ /([a-zA-Z0-9\-]+)/) or return $raw; # For S/MIME, etc
 457         my $dec = $MIME_DEC{lc($cte)} or return $raw;
 458         $dec->($raw);
 459 }
 460
 461 sub body_str {
 462         my ($self) = @_;
 463         my $ct = ct($self);
 464         my $cs = $ct->{attributes}->{charset} // do {
 465                 ($STR_TYPE{$ct->{type}} && $STR_SUBTYPE{$ct->{subtype}}) and
 466                         return body($self);
 467                 croak("can't get body as a string for ",
 468                         join("\n\t", header_raw($self, 'Content-Type')));
 469         };
 470         my $enc = find_encoding($cs) or croak "unknown encoding `$cs'";
 471         my $tmp = body($self);
 472         # workaround https://rt.cpan.org/Public/Bug/Display.html?id=139622
 473         my @w;
 474         local $SIG{__WARN__} = sub { push @w, @_ };
 475         my $ret = $enc->decode($tmp, Encode::FB_WARN);
 476         croak(@w) if @w;
 477         $ret;
 478 }
 479
 480 sub as_string {
 481         my ($self) = @_;
 482         my $ret = ${ $self->{hdr} };
 483         return $ret unless defined($self->{bdy});
 484         $ret .= $self->{crlf};
 485         $ret .= ${$self->{bdy}};
 486 }
 487
 488 # Unlike Email::MIME::charset_set, this only changes the parsed
 489 # representation of charset used for search indexing and HTML display.
 490 # This does NOT affect what ->as_string returns.
 491 sub charset_set {
 492         ct($_[0])->{attributes}->{charset} = $_[1];
 493 }
 494
 495 sub crlf { $_[0]->{crlf} // "\n" }
 496
 497 sub raw_size {
 498         my ($self) = @_;
 499         my $len = length(${$self->{hdr}});
 500         defined($self->{bdy}) and
 501                 $len += length(${$self->{bdy}}) + length($self->{crlf});
 502         $len;
 503 }
 504
 505 # warnings to ignore when handling spam mailboxes and maybe other places
 506 sub warn_ignore {
 507         my $s = "@_";
 508         # Email::Address::XS warnings
 509         $s =~ /^Argument contains empty /
 510         || $s =~ /^Element at index [0-9]+.*? contains /
 511         # PublicInbox::MsgTime
 512         || $s =~ /^bogus TZ offset: .+?, ignoring and assuming \+0000/
 513         || $s =~ /^bad Date: .+? in /
 514         # Encode::Unicode::UTF7
 515         || $s =~ /^Bad UTF7 data escape at /
 516 }
 517
 518 # this expects to be RHS in this assignment: "local $SIG{__WARN__} = ..."
 519 sub warn_ignore_cb {
 520         my $cb = $SIG{__WARN__} // \&CORE::warn;
 521         sub { $cb->(@_) unless warn_ignore(@_) }
 522 }
 523
 524 sub willneed { re_memo($_) for @_ }
 525
 526 willneed(qw(From To Cc Date Subject Content-Type In-Reply-To References
 527                 Message-ID X-Alt-Message-ID));
 528
 529 1;