lib/PublicInbox/Eml.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Lazy MIME parser, it still slurps the full message but keeps short
   5 # lifetimes.  Unlike Email::MIME, it doesn't pre-split multipart
   6 # messages or do any up-front parsing of headers besides splitting
   7 # the header string from the body.
   8 #
   9 # Contains ideas and code from Email::Simple and Email::MIME
  10 # (Perl Artistic License, GPL-1+)
  11 #
  12 # This aims to replace Email::MIME for our purposes, similar API
  13 # but internal field names are differ if they're not 100%-compatible.
  14 #
  15 # Includes some proposed fixes for Email::MIME:
  16 # - header-less sub parts - https://github.com/rjbs/Email-MIME/issues/14
  17 # - "0" as boundary - https://github.com/rjbs/Email-MIME/issues/63
  18 #
  19 # $self = {
  20 #       bdy => scalar ref for body (may be undef),
  21 #       hdr => scalar ref for header,
  22 #       crlf => "\n" or "\r\n" (scalar, not a ref),
  23 #
  24 #       # filled in during ->each_part
  25 #       ct => hash ref returned by parse_content_type
  26 # }
  27 package PublicInbox::Eml;
  28 use strict;
  29 use v5.10.1;
  30 use Carp qw(croak);
  31 use Encode qw(find_encoding decode encode); # stdlib
  32 use Text::Wrap qw(wrap); # stdlib, we need Perl 5.6+ for $huge
  33 use MIME::Base64 3.05; # Perl 5.10.0 / 5.9.2
  34 use MIME::QuotedPrint 3.05; # ditto
  35
  36 my $MIME_Header = find_encoding('MIME-Header');
  37
  38 use PublicInbox::EmlContentFoo qw(parse_content_type parse_content_disposition);
  39 $PublicInbox::EmlContentFoo::STRICT_PARAMS = 0;
  40
  41 our $MAXPARTS = 1000; # same as SpamAssassin
  42 our $MAXDEPTH = 20; # seems enough, Perl sucks, here
  43 our $MAXBOUNDLEN = 2048; # same as postfix
  44
  45 my %MIME_ENC = (qp => \&enc_qp, base64 => \&encode_base64);
  46 my %MIME_DEC = (qp => \&dec_qp, base64 => \&decode_base64);
  47 $MIME_ENC{quotedprint} = $MIME_ENC{'quoted-printable'} = $MIME_ENC{qp};
  48 $MIME_DEC{quotedprint} = $MIME_DEC{'quoted-printable'} = $MIME_DEC{qp};
  49 $MIME_ENC{$_} = \&identity_codec for qw(7bit 8bit binary);
  50
  51 my %DECODE_ADDRESS = map { $_ => 1 } qw(From To Cc Sender Reply-To);
  52 my %DECODE_FULL = (
  53         Subject => 1,
  54         'Content-Description' => 1,
  55         'Content-Type' => 1, # not correct, but needed, oh well
  56 );
  57 our %STR_TYPE = (text => 1);
  58 our %STR_SUBTYPE = (plain => 1, html => 1);
  59
  60 my %re_memo;
  61 sub re_memo ($) {
  62         my ($k) = @_;
  63         # Do not normalize $k with lc/uc; instead strive to keep
  64         # capitalization in our codebase consistent.
  65         $re_memo{$k} ||= qr/^\Q$k\E:[ \t]*([^\n]*\r?\n # 1st line
  66                                         # continuation lines:
  67                                         (?:[^:\n]*?[ \t]+[^\n]*\r?\n)*)
  68                                         /ismx
  69 }
  70
  71 # compatible with our uses of Email::MIME
  72 sub new {
  73         my $ref = ref($_[1]) ? $_[1] : \(my $cpy = $_[1]);
  74         if ($$ref =~ /\r?\n(\r?\n)/s) { # likely
  75                 # This can modify $$ref in-place and to avoid memcpy/memmove
  76                 # on a potentially large $$ref.  It does need to make a
  77                 # copy for $hdr, though.  Idea stolen from Email::Simple
  78                 my $hdr = substr($$ref, 0, $+[0], ''); # sv_chop on $$ref
  79                 substr($hdr, -(length($1))) = ''; # lower SvCUR
  80                 bless { hdr => \$hdr, crlf => $1, bdy => $ref }, __PACKAGE__;
  81         } elsif ($$ref =~ /^[a-z0-9-]+[ \t]*:/ims && $$ref =~ /(\r?\n)\z/s) {
  82                 # body is optional :P
  83                 bless { hdr => \($$ref), crlf => $1 }, __PACKAGE__;
  84         } else { # nothing useful
  85                 my $hdr = $$ref = '';
  86                 bless { hdr => \$hdr, crlf => "\n" }, __PACKAGE__;
  87         }
  88 }
  89
  90 sub new_sub {
  91         my (undef, $ref) = @_;
  92         # special case for messages like <85k5su9k59.fsf_-_@lola.goethe.zz>
  93         $$ref =~ /\A(\r?\n)/s or goto &new;
  94         my $hdr = substr($$ref, 0, $+[0], ''); # sv_chop on $$ref
  95         bless { hdr => \$hdr, crlf => $1, bdy => $ref }, __PACKAGE__;
  96 }
  97
  98 # same output as Email::Simple::Header::header_raw, but we extract
  99 # headers on-demand instead of parsing them into a list which
 100 # requires O(n) lookups anyways
 101 sub header_raw {
 102         my $re = re_memo($_[1]);
 103         my @v = (${ $_[0]->{hdr} } =~ /$re/g);
 104         for (@v) {
 105                 # for compatibility w/ Email::Simple::Header,
 106                 s/\s+\z//s;
 107                 s/\A\s+//s;
 108                 s/\r?\n[ \t]*/ /gs;
 109         }
 110         wantarray ? @v : $v[0];
 111 }
 112
 113 # pick the first Content-Type header to match Email::MIME behavior.
 114 # It's usually the right one based on historical archives.
 115 sub ct ($) {
 116         # PublicInbox::EmlContentFoo::content_type:
 117         $_[0]->{ct} //= parse_content_type(header($_[0], 'Content-Type'));
 118 }
 119
 120 # returns a queue of sub-parts iff it's worth descending into
 121 # TODO: descend into message/rfc822 parts (Email::MIME didn't)
 122 sub mp_descend ($$) {
 123         my ($self, $nr) = @_; # or $once for top-level
 124         my $bnd = ct($self)->{attributes}->{boundary} // return; # single-part
 125         return if $bnd eq '' || length($bnd) >= $MAXBOUNDLEN;
 126         $bnd = quotemeta($bnd);
 127
 128         # "multipart" messages can exist w/o a body
 129         my $bdy = ($nr ? delete($self->{bdy}) : \(body_raw($self))) or return;
 130
 131         # Cut at the the first epilogue, not subsequent ones.
 132         # *sigh* just the regexp match alone seems to bump RSS by
 133         # length($$bdy) on a ~30M string:
 134         my $epilogue_missing;
 135         if ($$bdy =~ /(?:\r?\n)?^--$bnd--[ \t]*\r?$/sm) {
 136                 substr($$bdy, $-[0]) = '';
 137         } else {
 138                 $epilogue_missing = 1;
 139         }
 140
 141         # *Sigh* split() doesn't work in-place and return CoW strings
 142         # because Perl wants to "\0"-terminate strings.  So split()
 143         # again bumps RSS by length($$bdy)
 144
 145         # Quiet warning for "Complex regular subexpression recursion limit"
 146         # in case we get many empty parts, it's harmless in this case
 147         no warnings 'regexp';
 148         my ($pre, @parts) = split(/(?:\r?\n)?(?:^--$bnd[ \t]*\r?\n)+/ms,
 149                                 $$bdy,
 150                                 # + 3 since we don't want the last part
 151                                 # processed to include any other excluded
 152                                 # parts ($nr starts at 1, and I suck at math)
 153                                 $MAXPARTS + 3 - $nr);
 154
 155         if (@parts) { # the usual path if we got this far:
 156                 undef $bdy; # release memory ASAP if $nr > 0
 157
 158                 # compatibility with Email::MIME
 159                 $parts[-1] =~ s/\n\r?\n\z/\n/s if $epilogue_missing;
 160
 161                 @parts = grep /[^ \t\r\n]/s, @parts; # ignore empty parts
 162
 163                 # Keep "From: someone..." from preamble in old,
 164                 # buggy versions of git-send-email, otherwise drop it
 165                 # There's also a case where quoted text showed up in the
 166                 # preamble
 167                 # <20060515162817.65F0F1BBAE@citi.umich.edu>
 168                 unshift(@parts, $pre) if $pre =~ /:/s;
 169                 return \@parts;
 170         }
 171         # "multipart", but no boundary found, treat as single part
 172         $self->{bdy} //= $bdy;
 173         undef;
 174 }
 175
 176 # $p = [ \@parts, $depth, $idx ]
 177 # $idx[0] grows as $depth grows, $idx[1] == $p->[-1] == current part
 178 # (callers need to be updated)
 179 # \@parts is a queue which empties when we're done with a parent part
 180
 181 # same usage as PublicInbox::MsgIter::msg_iter
 182 # $cb - user-supplied callback sub
 183 # $arg - user-supplied arg (think pthread_create)
 184 # $once - unref body scalar during iteration
 185 sub each_part {
 186         my ($self, $cb, $arg, $once) = @_;
 187         my $p = mp_descend($self, $once // 0) or
 188                                         return $cb->([$self, 0, 0], $arg);
 189         $p = [ $p, 0 ];
 190         my @s; # our virtual stack
 191         my $nr = 0;
 192         while ((scalar(@{$p->[0]}) || ($p = pop @s)) && ++$nr <= $MAXPARTS) {
 193                 ++$p->[-1]; # bump index
 194                 my (undef, @idx) = @$p;
 195                 @idx = (join('.', @idx));
 196                 my $depth = ($idx[0] =~ tr/././) + 1;
 197                 my $sub = new_sub(undef, \(shift @{$p->[0]}));
 198                 if ($depth < $MAXDEPTH && (my $nxt = mp_descend($sub, $nr))) {
 199                         push(@s, $p) if scalar @{$p->[0]};
 200                         $p = [ $nxt, @idx, 0 ];
 201                 } else { # a leaf node
 202                         $cb->([$sub, $depth, @idx], $arg);
 203                 }
 204         }
 205 }
 206
 207 sub enc_qp {
 208         # prevent MIME::QuotedPrint from encoding CR as =0D since it's
 209         # against RFCs and breaks MUAs
 210         $_[0] =~ s/\r\n/\n/sg;
 211         encode_qp($_[0], "\r\n");
 212 }
 213
 214 sub dec_qp {
 215         # RFC 2822 requires all lines to end in CRLF, though... :<
 216         $_[0] = decode_qp($_[0]);
 217         $_[0] =~ s/\n/\r\n/sg;
 218         $_[0]
 219 }
 220
 221 sub identity_codec { $_[0] }
 222
 223 ########### compatibility section for existing Email::MIME uses #########
 224
 225 sub header_obj {
 226         bless { hdr => $_[0]->{hdr}, crlf => $_[0]->{crlf} }, __PACKAGE__;
 227 }
 228
 229 sub subparts {
 230         my ($self) = @_;
 231         my $parts = mp_descend($self, 0) or return ();
 232         my $bnd = ct($self)->{attributes}->{boundary} // die 'BUG: no boundary';
 233         my $bdy = $self->{bdy};
 234         if ($$bdy =~ /\A(.*?)(?:\r?\n)?^--\Q$bnd\E[ \t]*\r?$/sm) {
 235                 $self->{preamble} = $1;
 236         }
 237         if ($$bdy =~ /^--\Q$bnd\E--[ \t]*\r?\n(.+)\z/sm) {
 238                 $self->{epilogue} = $1;
 239         }
 240         map { new_sub(undef, \$_) } @$parts;
 241 }
 242
 243 sub parts_set {
 244         my ($self, $parts) = @_;
 245
 246         # we can't fully support what Email::MIME does,
 247         # just what our filter code needs:
 248         my $bnd = ct($self)->{attributes}->{boundary} // die <<EOF;
 249 ->parts_set not supported for single-part messages
 250 EOF
 251         my $crlf = $self->{crlf};
 252         my $fin_bnd = "$crlf--$bnd--$crlf";
 253         $bnd = "$crlf--$bnd$crlf";
 254         ${$self->{bdy}} = join($bnd,
 255                                 delete($self->{preamble}) // '',
 256                                 map { $_->as_string } @$parts
 257                                 ) .
 258                                 $fin_bnd .
 259                                 (delete($self->{epilogue}) // '');
 260         undef;
 261 }
 262
 263 sub body_set {
 264         my ($self, $body) = @_;
 265         my $bdy = $self->{bdy} = ref($body) ? $body : \$body;
 266         if (my $cte = header_raw($self, 'Content-Transfer-Encoding')) {
 267                 my $enc = $MIME_ENC{lc($cte)} or croak("can't encode `$cte'");
 268                 $$bdy = $enc->($$bdy); # in-place
 269         }
 270         undef;
 271 }
 272
 273 sub body_str_set {
 274         my ($self, $body_str) = @_;
 275         my $charset = ct($self)->{attributes}->{charset} or
 276                 Carp::confess('body_str was given, but no charset is defined');
 277         body_set($self, \(encode($charset, $body_str, Encode::FB_CROAK)));
 278 }
 279
 280 sub content_type { scalar header($_[0], 'Content-Type') }
 281
 282 # we only support raw header_set
 283 sub header_set {
 284         my ($self, $pfx, @vals) = @_;
 285         my $re = re_memo($pfx);
 286         my $hdr = $self->{hdr};
 287         return $$hdr =~ s!$re!!g if !@vals;
 288         $pfx .= ': ';
 289         my $len = 78 - length($pfx);
 290         @vals = map {;
 291                 # folding differs from Email::Simple::Header,
 292                 # we favor tabs for visibility (and space savings :P)
 293                 if (length($_) >= $len && (/\n[^ \t]/s || !/\n/s)) {
 294                         local $Text::Wrap::columns = $len;
 295                         local $Text::Wrap::huge = 'overflow';
 296                         $pfx . wrap('', "\t", $_) . $self->{crlf};
 297                 } else {
 298                         $pfx . $_ . $self->{crlf};
 299                 }
 300         } @vals;
 301         $$hdr =~ s!$re!shift(@vals) // ''!ge; # replace current headers, first
 302         $$hdr .= join('', @vals); # append any leftovers not replaced
 303         # wantarray ? @_[2..$#_] : $_[2]; # Email::Simple::Header compat
 304         undef; # we don't care for the return value
 305 }
 306
 307 # note: we only call this method on Subject
 308 sub header_str_set {
 309         my ($self, $name, @vals) = @_;
 310         for (@vals) {
 311                 next unless /[^\x20-\x7e]/;
 312                 utf8::encode($_); # to octets
 313                 # 39: int((75 - length("Subject: =?UTF-8?B?".'?=') ) / 4) * 3;
 314                 s/(.{1,39})/'=?UTF-8?B?'.encode_base64($1, '').'?='/ges;
 315         }
 316         header_set($self, $name, @vals);
 317 }
 318
 319 sub mhdr_decode ($) { eval { $MIME_Header->decode($_[0]) } // $_[0] }
 320
 321 sub filename {
 322         my $dis = header_raw($_[0], 'Content-Disposition');
 323         my $attrs = parse_content_disposition($dis)->{attributes};
 324         my $fn = $attrs->{filename};
 325         $fn = ct($_[0])->{attributes}->{name} if !defined($fn) || $fn eq '';
 326         (defined($fn) && $fn =~ /=\?/) ? mhdr_decode($fn) : $fn;
 327 }
 328
 329 sub xs_addr_str { # helper for ->header / ->header_str
 330         for (@_) { # array from header_raw()
 331                 next unless /=\?/;
 332                 my @g = parse_email_groups($_); # [ foo => [ E::A::X, ... ]
 333                 for (my $i = 0; $i < @g; $i += 2) {
 334                         if (defined($g[$i]) && $g[$i] =~ /=\?/) {
 335                                 $g[$i] = mhdr_decode($g[$i]);
 336                         }
 337                         my $addrs = $g[$i + 1];
 338                         for my $eax (@$addrs) {
 339                                 for my $m (qw(phrase comment)) {
 340                                         my $v = $eax->$m;
 341                                         $eax->$m(mhdr_decode($v)) if
 342                                                         $v && $v =~ /=\?/;
 343                                 }
 344                         }
 345                 }
 346                 $_ = format_email_groups(@g);
 347         }
 348 }
 349
 350 eval {
 351         require Email::Address::XS;
 352         Email::Address::XS->import(qw(parse_email_groups format_email_groups));
 353         1;
 354 } or do {
 355         # fallback to just decoding everything, because parsing
 356         # email addresses correctly w/o C/XS is slow
 357         %DECODE_FULL = (%DECODE_FULL, %DECODE_ADDRESS);
 358         %DECODE_ADDRESS = ();
 359 };
 360
 361 *header = \&header_str;
 362 sub header_str {
 363         my ($self, $name) = @_;
 364         my @v = header_raw($self, $name);
 365         if ($DECODE_ADDRESS{$name}) {
 366                 xs_addr_str(@v);
 367         } elsif ($DECODE_FULL{$name}) {
 368                 for (@v) {
 369                         $_ = mhdr_decode($_) if /=\?/;
 370                 }
 371         }
 372         wantarray ? @v : $v[0];
 373 }
 374
 375 sub body_raw { ${$_[0]->{bdy} // \''}; }
 376
 377 sub body {
 378         my $raw = body_raw($_[0]);
 379         my $cte = header_raw($_[0], 'Content-Transfer-Encoding') or return $raw;
 380         ($cte) = ($cte =~ /([a-zA-Z0-9\-]+)/) or return $raw; # For S/MIME, etc
 381         my $dec = $MIME_DEC{lc($cte)} or return $raw;
 382         $dec->($raw);
 383 }
 384
 385 sub body_str {
 386         my ($self) = @_;
 387         my $ct = ct($self);
 388         my $charset = $ct->{attributes}->{charset};
 389         if (!$charset) {
 390                 if ($STR_TYPE{$ct->{type}} && $STR_SUBTYPE{$ct->{subtype}}) {
 391                         return body($self);
 392                 }
 393                 Carp::confess("can't get body as a string for ",
 394                         join("\n\t", header_raw($self, 'Content-Type')));
 395         }
 396         decode($charset, body($self), Encode::FB_CROAK);
 397 }
 398
 399 sub as_string {
 400         my ($self) = @_;
 401         my $ret = ${ $self->{hdr} };
 402         return $ret unless defined($self->{bdy});
 403         $ret .= $self->{crlf};
 404         $ret .= ${$self->{bdy}};
 405 }
 406
 407 # Unlike Email::MIME::charset_set, this only changes the parsed
 408 # representation of charset used for search indexing and HTML display.
 409 # This does NOT affect what ->as_string returns.
 410 sub charset_set {
 411         ct($_[0])->{attributes}->{charset} = $_[1];
 412 }
 413
 414 sub crlf { $_[0]->{crlf} // "\n" }
 415
 416 sub willneed { re_memo($_) for @_ }
 417
 418 willneed(qw(From To Cc Date Subject Content-Type In-Reply-To References
 419                 Message-ID X-Alt-Message-ID));
 420
 421 1;