lib/PublicInbox/EvCleanup.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # event cleanups (currently for PublicInbox::DS)
   5 package PublicInbox::EvCleanup;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use PublicInbox::Syscall qw(EPOLLOUT EPOLLONESHOT);
  10
  11 my $ENABLED;
  12 sub enabled { $ENABLED }
  13 sub enable { $ENABLED = 1 }
  14 my $singleton;
  15 my $asapq = [ [], undef ];
  16 my $nextq = [ [], undef ];
  17 my $laterq = [ [], undef ];
  18
  19 sub once_init () {
  20         my $self = fields::new('PublicInbox::EvCleanup');
  21         my ($r, $w);
  22
  23         # This is a dummy pipe which is always writable so it can always
  24         # fires in the next event loop iteration.
  25         pipe($r, $w) or die "pipe: $!";
  26         fcntl($w, 1031, 4096) if $^O eq 'linux'; # 1031: F_SETPIPE_SZ
  27         $self->SUPER::new($w, 0);
  28
  29         # always writable, since PublicInbox::EvCleanup::event_step
  30         # never drains wbuf.  We can avoid wasting a hash slot by
  31         # stuffing the read-end of the pipe into the never-to-be-touched
  32         # wbuf
  33         $self->{wbuf} = $r;
  34         $self;
  35 }
  36
  37 sub _run_all ($) {
  38         my ($q) = @_;
  39
  40         my $run = $q->[0];
  41         $q->[0] = [];
  42         $q->[1] = undef;
  43         $_->() foreach @$run;
  44 }
  45
  46 # ensure PublicInbox::DS::ToClose processing after timers fire
  47 sub _asap_close () { $asapq->[1] ||= _asap_timer() }
  48
  49 # Called by PublicInbox::DS
  50 sub event_step { _run_all($asapq) }
  51
  52 sub _run_next () {
  53         _run_all($nextq);
  54         _asap_close();
  55 }
  56
  57 sub _run_later () {
  58         _run_all($laterq);
  59         _asap_close();
  60 }
  61
  62 sub _asap_timer () {
  63         $singleton ||= once_init();
  64         $singleton->watch(EPOLLOUT|EPOLLONESHOT);
  65         1;
  66 }
  67
  68 sub asap ($) {
  69         my ($cb) = @_;
  70         push @{$asapq->[0]}, $cb;
  71         $asapq->[1] ||= _asap_timer();
  72 }
  73
  74 sub next_tick ($) {
  75         my ($cb) = @_;
  76         push @{$nextq->[0]}, $cb;
  77         $nextq->[1] ||= PublicInbox::DS->AddTimer(0, *_run_next);
  78 }
  79
  80 sub later ($) {
  81         my ($cb) = @_;
  82         push @{$laterq->[0]}, $cb;
  83         $laterq->[1] ||= PublicInbox::DS->AddTimer(60, *_run_later);
  84 }
  85
  86 END {
  87         event_step();
  88         _run_all($nextq);
  89         _run_all($laterq);
  90 }
  91
  92 1;