lib/PublicInbox/ExtMsg.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used by the web interface to link to messages outside of the our
   5 # public-inboxes.  Mail threads may cross projects/threads; so
   6 # we should ensure users can find more easily find them on other
   7 # sites.
   8 package PublicInbox::ExtMsg;
   9 use strict;
  10 use warnings;
  11 use PublicInbox::Hval qw(ascii_html prurl mid_href);
  12 use PublicInbox::WwwStream qw(html_oneshot);
  13 use PublicInbox::Smsg;
  14 our $MIN_PARTIAL_LEN = 16;
  15
  16 # TODO: user-configurable
  17 our @EXT_URL = map { ascii_html($_) } (
  18         # leading "//" denotes protocol-relative (http:// or https://)
  19         '//marc.info/?i=%s',
  20         '//www.mail-archive.com/search?l=mid&q=%s',
  21         'nntp://news.gmane.io/%s',
  22         'https://lists.debian.org/msgid-search/%s',
  23         '//docs.FreeBSD.org/cgi/mid.cgi?db=mid&id=%s',
  24         'https://www.w3.org/mid/%s',
  25         'http://www.postgresql.org/message-id/%s',
  26         'https://lists.debconf.org/cgi-lurker/keyword.cgi?'.
  27                 'doc-url=/lurker&format=en.html&query=id:%s'
  28 );
  29
  30 sub PARTIAL_MAX () { 100 }
  31
  32 sub search_partial ($$) {
  33         my ($ibx, $mid) = @_;
  34         return if length($mid) < $MIN_PARTIAL_LEN;
  35         my $srch = $ibx->search or return;
  36         my $opt = { limit => PARTIAL_MAX, mset => 2 };
  37         my @try = ("m:$mid*");
  38         my $chop = $mid;
  39         if ($chop =~ s/(\W+)(\w*)\z//) {
  40                 my ($delim, $word) = ($1, $2);
  41                 if (length($word)) {
  42                         push @try, "m:$chop$delim";
  43                         push @try, "m:$chop$delim*";
  44                 }
  45                 push @try, "m:$chop";
  46                 push @try, "m:$chop*";
  47         }
  48
  49         # break out long words individually to search for, because
  50         # too many messages begin with "Pine.LNX." (or "alpine" or "nycvar")
  51         if ($mid =~ /\w{9,}/) {
  52                 my @long = ($mid =~ m!(\w{3,})!g);
  53                 push(@try, join(' ', map { "m:$_" } @long));
  54
  55                 # is the last element long enough to not trigger excessive
  56                 # wildcard matches?
  57                 if (length($long[-1]) > 8) {
  58                         $long[-1] .= '*';
  59                         push(@try, join(' ', map { "m:$_" } @long));
  60                 }
  61         }
  62
  63         foreach my $m (@try) {
  64                 # If Xapian can't handle the wildcard since it
  65                 # has too many results.  $@ can be
  66                 # Search::Xapian::QueryParserError or even:
  67                 # "something terrible happened at ../Search/Xapian/Enquire.pm"
  68                 my $mset = eval { $srch->mset($m, $opt) } or next;
  69                 my @mids = map {
  70                         $_->{mid}
  71                 } @{$srch->mset_to_smsg($ibx, $mset)};
  72                 return \@mids if scalar(@mids);
  73         }
  74 }
  75
  76 sub ext_msg_i {
  77         my ($other, $cur, $mid, $ibxs, $found) = @_;
  78
  79         return if $other->{name} eq $cur->{name} || !$other->base_url;
  80
  81         my $mm = $other->mm or return;
  82
  83         # try to find the URL with Msgmap to avoid forking
  84         my $num = $mm->num_for($mid);
  85         if (defined $num) {
  86                 push @$found, $other;
  87         } else {
  88                 # no point in trying the fork fallback if we
  89                 # know Xapian is up-to-date but missing the
  90                 # message in the current repo
  91                 push @$ibxs, $other;
  92         }
  93 }
  94
  95 sub ext_msg {
  96         my ($ctx) = @_;
  97         my $cur = $ctx->{-inbox};
  98         my $mid = $ctx->{mid};
  99
 100         eval { require PublicInbox::Msgmap };
 101         my $ibxs = [];
 102         my $found = [];
 103
 104         $ctx->{www}->{pi_config}->each_inbox(\&ext_msg_i,
 105                                                 $cur, $mid, $ibxs, $found);
 106
 107         return exact($ctx, $found, $mid) if @$found;
 108
 109         # fall back to partial MID matching
 110         my @partial;
 111         my $n_partial = 0;
 112         my $mids = search_partial($cur, $mid);
 113         if ($mids) {
 114                 $n_partial = scalar(@$mids);
 115                 push @partial, [ $cur, $mids ];
 116         }
 117
 118         # can't find a partial match in current inbox, try the others:
 119         if (!$n_partial && length($mid) >= $MIN_PARTIAL_LEN) {
 120                 foreach my $ibx (@$ibxs) {
 121                         $mids = search_partial($ibx, $mid) or next;
 122                         $n_partial += scalar(@$mids);
 123                         push @partial, [ $ibx, $mids];
 124                         last if $n_partial >= PARTIAL_MAX;
 125                 }
 126         }
 127
 128         my $code = 404;
 129         my $href = mid_href($mid);
 130         my $html = ascii_html($mid);
 131         my $title = "&lt;$html&gt; not found";
 132         my $s = "<pre>Message-ID &lt;$html&gt;\nnot found\n";
 133         if ($n_partial) {
 134                 $code = 300;
 135                 my $es = $n_partial == 1 ? '' : 'es';
 136                 $n_partial .= '+' if ($n_partial == PARTIAL_MAX);
 137                 $s .= "\n$n_partial partial match$es found:\n\n";
 138                 my $cur_name = $cur->{name};
 139                 foreach my $pair (@partial) {
 140                         my ($ibx, $res) = @$pair;
 141                         my $env = $ctx->{env} if $ibx->{name} eq $cur_name;
 142                         my $u = $ibx->base_url($env) or next;
 143                         foreach my $m (@$res) {
 144                                 my $href = mid_href($m);
 145                                 my $html = ascii_html($m);
 146                                 $s .= qq{<a\nhref="$u$href/">$u$html/</a>\n};
 147                         }
 148                 }
 149         }
 150         my $ext = ext_urls($ctx, $mid, $href, $html);
 151         if ($ext ne '') {
 152                 $s .= $ext;
 153                 $code = 300;
 154         }
 155         $ctx->{-html_tip} = $s .= '</pre>';
 156         $ctx->{-title_html} = $title;
 157         $ctx->{-upfx} = '../';
 158         html_oneshot($ctx, $code);
 159 }
 160
 161 sub ext_urls {
 162         my ($ctx, $mid, $href, $html) = @_;
 163
 164         # Fall back to external repos if configured
 165         if (@EXT_URL && index($mid, '@') >= 0) {
 166                 my $env = $ctx->{env};
 167                 my $e = "\nPerhaps try an external site:\n\n";
 168                 foreach my $url (@EXT_URL) {
 169                         my $u = prurl($env, $url);
 170                         my $r = sprintf($u, $href);
 171                         my $t = sprintf($u, $html);
 172                         $e .= qq{<a\nhref="$r">$t</a>\n};
 173                 }
 174                 return $e;
 175         }
 176         ''
 177 }
 178
 179 sub exact {
 180         my ($ctx, $found, $mid) = @_;
 181         my $href = mid_href($mid);
 182         my $html = ascii_html($mid);
 183         my $title = "&lt;$html&gt; found in ";
 184         my $end = @$found == 1 ? 'another inbox' : 'other inboxes';
 185         $ctx->{-title_html} = $title . $end;
 186         $ctx->{-upfx} = '../';
 187         my $ext_urls = ext_urls($ctx, $mid, $href, $html);
 188         my $code = (@$found == 1 && $ext_urls eq '') ? 200 : 300;
 189         $ctx->{-html_tip} = join('',
 190                         "<pre>Message-ID: &lt;$html&gt;\nfound in $end:\n\n",
 191                                 (map {
 192                                         my $u = $_->base_url;
 193                                         qq(<a\nhref="$u$href/">$u$html/</a>\n)
 194                                 } @$found),
 195                         $ext_urls, '</pre>');
 196         html_oneshot($ctx, $code);
 197 }
 198
 199 1;