lib/PublicInbox/ExtSearch.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Read-only external (detached) index for cross inbox search.
   5 # This is a read-only counterpart to PublicInbox::ExtSearchIdx
   6 # and behaves like PublicInbox::Inbox AND PublicInbox::Search
   7 package PublicInbox::ExtSearch;
   8 use strict;
   9 use v5.10.1;
  10 use PublicInbox::Over;
  11 use PublicInbox::Inbox;
  12 use PublicInbox::MiscSearch;
  13 use DBI qw(:sql_types); # SQL_BLOB
  14
  15 # for ->reopen, ->mset, ->mset_to_artnums
  16 use parent qw(PublicInbox::Search);
  17
  18 sub new {
  19         my (undef, $topdir) = @_;
  20         bless {
  21                 topdir => $topdir,
  22                 # xpfx => 'ei15'
  23                 xpfx => "$topdir/ei".PublicInbox::Search::SCHEMA_VERSION
  24         }, __PACKAGE__;
  25 }
  26
  27 sub misc {
  28         my ($self) = @_;
  29         $self->{misc} //= PublicInbox::MiscSearch->new("$self->{xpfx}/misc");
  30 }
  31
  32 # overrides PublicInbox::Search::_xdb
  33 sub _xdb {
  34         my ($self) = @_;
  35         $self->xdb_sharded;
  36 }
  37
  38 # same as per-inbox ->over, for now...
  39 sub over {
  40         my ($self) = @_;
  41         $self->{over} //= PublicInbox::Over->new("$self->{xpfx}/over.sqlite3");
  42 }
  43
  44 sub git {
  45         my ($self) = @_;
  46         $self->{git} //= PublicInbox::Git->new("$self->{topdir}/ALL.git");
  47 }
  48
  49 # returns a hashref of { $NEWSGROUP_NAME => $ART_NO } using the `xref3' table
  50 sub nntp_xref_for { # NNTP only
  51         my ($self, $xibx, $xsmsg) = @_;
  52         my $dbh = over($self)->dbh;
  53
  54         my $sth = $dbh->prepare_cached(<<'', undef, 1);
  55 SELECT ibx_id FROM inboxes WHERE eidx_key = ? LIMIT 1
  56
  57         $sth->execute($xibx->{newsgroup});
  58         my $xibx_id = $sth->fetchrow_array // do {
  59                 warn "W: `$xibx->{newsgroup}' not found in $self->{topdir}\n";
  60                 return;
  61         };
  62
  63         $sth = $dbh->prepare_cached(<<'', undef, 1);
  64 SELECT docid FROM xref3 WHERE oidbin = ? AND xnum = ? AND ibx_id = ? LIMIT 1
  65
  66         $sth->bind_param(1, pack('H*', $xsmsg->{blob}), SQL_BLOB);
  67
  68         # NNTP::cmd_over can set {num} to zero according to RFC 3977 8.3.2
  69         $sth->bind_param(2, $xsmsg->{num} || $xsmsg->{-orig_num});
  70         $sth->bind_param(3, $xibx_id);
  71         $sth->execute;
  72         my $docid = $sth->fetchrow_array // do {
  73                 warn <<EOF;
  74 W: `$xibx->{newsgroup}:$xsmsg->{num}' not found in $self->{topdir}"
  75 EOF
  76                 return;
  77         };
  78
  79         # LIMIT is number of newsgroups on server:
  80         $sth = $dbh->prepare_cached(<<'', undef, 1);
  81 SELECT ibx_id,xnum FROM xref3 WHERE docid = ? AND ibx_id != ?
  82
  83         $sth->execute($docid, $xibx_id);
  84         my $rows = $sth->fetchall_arrayref;
  85
  86         my $eidx_key_sth = $dbh->prepare_cached(<<'', undef, 1);
  87 SELECT eidx_key FROM inboxes WHERE ibx_id = ? LIMIT 1
  88
  89         my %xref = map {
  90                 my ($ibx_id, $xnum) = @$_;
  91
  92                 $eidx_key_sth->execute($ibx_id);
  93                 my $eidx_key = $eidx_key_sth->fetchrow_array;
  94
  95                 # only include if there's a newsgroup name
  96                 $eidx_key && index($eidx_key, '/') >= 0 ?
  97                         () : ($eidx_key => $xnum)
  98         } @$rows;
  99         $xref{$xibx->{newsgroup}} = $xsmsg->{num};
 100         \%xref;
 101 }
 102
 103 sub mm { undef }
 104
 105 sub altid_map { {} }
 106
 107 sub description {
 108         my ($self) = @_;
 109         ($self->{description} //=
 110                 PublicInbox::Inbox::cat_desc("$self->{topdir}/description")) //
 111                 '$EXTINDEX_DIR/description missing';
 112 }
 113
 114 sub cloneurl { [] } # TODO
 115
 116 sub base_url { 'https://example.com/TODO/' }
 117 sub nntp_url { [] }
 118
 119 no warnings 'once';
 120 *smsg_eml = \&PublicInbox::Inbox::smsg_eml;
 121 *smsg_by_mid = \&PublicInbox::Inbox::smsg_by_mid;
 122 *msg_by_mid = \&PublicInbox::Inbox::msg_by_mid;
 123 *modified = \&PublicInbox::Inbox::modified;
 124 *recent = \&PublicInbox::Inbox::recent;
 125
 126 *max_git_epoch = *nntp_usable = *msg_by_path = \&mm; # undef
 127 *isrch = *search = \&PublicInbox::Search::reopen;
 128
 129 1;