lib/PublicInbox/ExtSearchIdx.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Detached/external index cross inbox search indexing support
   5 # read-write counterpart to PublicInbox::ExtSearch
   6 #
   7 # It's based on the same ideas as public-inbox-v2-format(5) using
   8 # over.sqlite3 for dedupe and sharded Xapian.  msgmap.sqlite3 is
   9 # missing, so there is no Message-ID conflict resolution, meaning
  10 # no NNTP support for now.
  11 #
  12 # v2 has a 1:1 mapping of index:inbox or msgmap for NNTP support.
  13 # This is intended to be an M:N index:inbox mapping, but it'll likely
  14 # be 1:N in common practice (M==1)
  15
  16 package PublicInbox::ExtSearchIdx;
  17 use strict;
  18 use v5.10.1;
  19 use parent qw(PublicInbox::ExtSearch PublicInbox::Lock);
  20 use Carp qw(croak carp);
  21 use Scalar::Util qw(blessed);
  22 use Sys::Hostname qw(hostname);
  23 use POSIX qw(strftime);
  24 use File::Glob qw(bsd_glob GLOB_NOSORT);
  25 use PublicInbox::MultiGit;
  26 use PublicInbox::Search;
  27 use PublicInbox::SearchIdx qw(prepare_stack is_ancestor is_bad_blob);
  28 use PublicInbox::OverIdx;
  29 use PublicInbox::MiscIdx;
  30 use PublicInbox::MID qw(mids);
  31 use PublicInbox::V2Writable;
  32 use PublicInbox::InboxWritable;
  33 use PublicInbox::ContentHash qw(content_hash);
  34 use PublicInbox::Eml;
  35 use PublicInbox::DS qw(now add_timer);
  36 use DBI qw(:sql_types); # SQL_BLOB
  37
  38 sub new {
  39         my (undef, $dir, $opt) = @_;
  40         my $l = $opt->{indexlevel} // 'full';
  41         $l !~ $PublicInbox::SearchIdx::INDEXLEVELS and
  42                 die "invalid indexlevel=$l\n";
  43         $l eq 'basic' and die "E: indexlevel=basic not yet supported\n";
  44         my $self = bless {
  45                 xpfx => "$dir/ei".PublicInbox::Search::SCHEMA_VERSION,
  46                 topdir => $dir,
  47                 creat => $opt->{creat},
  48                 ibx_map => {}, # (newsgroup//inboxdir) => $ibx
  49                 ibx_active => [], # by config section order
  50                 ibx_known => [], # by config section order
  51                 indexlevel => $l,
  52                 transact_bytes => 0,
  53                 total_bytes => 0,
  54                 current_info => '',
  55                 parallel => 1,
  56                 lock_path => "$dir/ei.lock",
  57         }, __PACKAGE__;
  58         $self->{shards} = $self->count_shards ||
  59                 nproc_shards({ nproc => $opt->{jobs} });
  60         my $oidx = PublicInbox::OverIdx->new("$self->{xpfx}/over.sqlite3");
  61         $self->{-no_fsync} = $oidx->{-no_fsync} = 1 if !$opt->{fsync};
  62         $self->{-dangerous} = 1 if $opt->{dangerous};
  63         $self->{oidx} = $oidx;
  64         $self
  65 }
  66
  67 sub attach_inbox {
  68         my ($self, $ibx, $types) = @_;
  69         $self->{ibx_map}->{$ibx->eidx_key} //= do {
  70                 delete $self->{-ibx_ary_known}; # invalidate cache
  71                 delete $self->{-ibx_ary_active}; # invalidate cache
  72                 $types //= [ qw(active known) ];
  73                 for my $t (@$types) {
  74                         push @{$self->{"ibx_$t"}}, $ibx;
  75                 }
  76                 $ibx;
  77         }
  78 }
  79
  80 sub _ibx_attach { # each_inbox callback
  81         my ($ibx, $self, $types) = @_;
  82         attach_inbox($self, $ibx, $types);
  83 }
  84
  85 sub attach_config {
  86         my ($self, $cfg, $ibxs) = @_;
  87         $self->{cfg} = $cfg;
  88         my $types;
  89         if ($ibxs) {
  90                 for my $ibx (@$ibxs) {
  91                         $self->{ibx_map}->{$ibx->eidx_key} //= do {
  92                                 push @{$self->{ibx_active}}, $ibx;
  93                                 push @{$self->{ibx_known}}, $ibx;
  94                                 $ibx;
  95                         }
  96                 }
  97                 # invalidate cache
  98                 delete $self->{-ibx_ary_known};
  99                 delete $self->{-ibx_ary_active};
 100                 $types = [ 'known' ];
 101         }
 102         $types //= [ qw(known active) ];
 103         $cfg->each_inbox(\&_ibx_attach, $self, $types);
 104 }
 105
 106 sub check_batch_limit ($) {
 107         my ($req) = @_;
 108         my $self = $req->{self};
 109         my $new_smsg = $req->{new_smsg};
 110         my $n = $self->{transact_bytes} += $new_smsg->{bytes};
 111
 112         # set flag for PublicInbox::V2Writable::index_todo:
 113         ${$req->{need_checkpoint}} = 1 if $n >= $self->{batch_bytes};
 114 }
 115
 116 sub apply_boost ($$) {
 117         my ($req, $smsg) = @_;
 118         my $id2pos = $req->{id2pos}; # index in ibx_sorted
 119         my $xr3 = $req->{self}->{oidx}->get_xref3($smsg->{num}, 1);
 120         @$xr3 = sort {
 121                 $id2pos->{$a->[0]} <=> $id2pos->{$b->[0]}
 122                                 ||
 123                 $a->[1] <=> $b->[1] # break ties with {xnum}
 124         } @$xr3;
 125         my $new_smsg = $req->{new_smsg};
 126         return if $xr3->[0]->[2] ne $new_smsg->oidbin; # loser
 127
 128         # replace the old smsg with the more boosted one
 129         $new_smsg->{num} = $smsg->{num};
 130         $new_smsg->populate($req->{eml}, $req);
 131         $req->{self}->{oidx}->add_overview($req->{eml}, $new_smsg);
 132 }
 133
 134 sub remove_doc ($$) {
 135         my ($self, $docid) = @_;
 136         $self->{oidx}->delete_by_num($docid);
 137         $self->{oidx}->eidxq_del($docid);
 138         $self->idx_shard($docid)->ipc_do('xdb_remove', $docid);
 139 }
 140
 141 sub _unref_doc ($$$$$;$) {
 142         my ($sync, $docid, $ibx, $xnum, $oidbin, $eml) = @_;
 143         my $smsg;
 144         if (ref($docid)) {
 145                 $smsg = $docid;
 146                 $docid = $smsg->{num};
 147         }
 148         if (defined($oidbin) && defined($xnum) && blessed($ibx) && $ibx->over) {
 149                 my $smsg = $ibx->over->get_art($xnum);
 150                 if ($smsg && $smsg->oidbin eq $oidbin) {
 151                         carp("BUG: (non-fatal) ".$ibx->eidx_key.
 152                                 " #$xnum $smsg->{blob} still valid");
 153                         return;
 154                 }
 155         }
 156         my $s = 'DELETE FROM xref3 WHERE oidbin = ?';
 157         $s .= ' AND ibx_id = ?' if defined($ibx);
 158         $s .= ' AND xnum = ?' if defined($xnum);
 159         my $del = $sync->{self}->{oidx}->dbh->prepare_cached($s);
 160         my $col = 0;
 161         $del->bind_param(++$col, $oidbin, SQL_BLOB);
 162         $del->bind_param(++$col, $ibx->{-ibx_id}) if $ibx;
 163         $del->bind_param(++$col, $xnum) if defined($xnum);
 164         $del->execute;
 165         my $xr3 = $sync->{self}->{oidx}->get_xref3($docid);
 166         if (scalar(@$xr3) == 0) { # all gone
 167                 remove_doc($sync->{self}, $docid);
 168         } else { # enqueue for reindex of remaining messages
 169                 if ($ibx) {
 170                         my $ekey = $ibx->{-gc_eidx_key} // $ibx->eidx_key;
 171                         my $idx = $sync->{self}->idx_shard($docid);
 172                         $idx->ipc_do('remove_eidx_info', $docid, $ekey, $eml);
 173                 } # else: we can't remove_eidx_info in reindex-only path
 174
 175                 # replace invalidated blob ASAP with something which should be
 176                 # readable since we may commit the transaction on checkpoint.
 177                 # eidxq processing will re-apply boost
 178                 $smsg //= $sync->{self}->{oidx}->get_art($docid);
 179                 my $hex = unpack('H*', $oidbin);
 180                 if ($smsg && $smsg->{blob} eq $hex) {
 181                         $xr3->[0] =~ /:([a-f0-9]{40,}+)\z/ or
 182                                 die "BUG: xref $xr3->[0] has no OID";
 183                         $sync->{self}->{oidx}->update_blob($smsg, $1);
 184                 }
 185                 # yes, add, we'll need to re-apply boost
 186                 $sync->{self}->{oidx}->eidxq_add($docid);
 187         }
 188         @$xr3
 189 }
 190
 191 sub do_xpost ($$) {
 192         my ($req, $smsg) = @_;
 193         my $self = $req->{self};
 194         my $docid = $smsg->{num};
 195         my $oid = $req->{oid};
 196         my $xibx = $req->{ibx};
 197         my $eml = $req->{eml};
 198         if (my $new_smsg = $req->{new_smsg}) { # 'm' on cross-posted message
 199                 my $eidx_key = $xibx->eidx_key;
 200                 my $xnum = $req->{xnum};
 201                 $self->{oidx}->add_xref3($docid, $xnum, $oid, $eidx_key);
 202                 my $idx = $self->idx_shard($docid);
 203                 $idx->ipc_do('add_eidx_info', $docid, $eidx_key, $eml);
 204                 apply_boost($req, $smsg) if $req->{boost_in_use};
 205         } else { # 'd' no {xnum}
 206                 $self->git->async_wait_all;
 207                 $oid = pack('H*', $oid);
 208                 _unref_doc($req, $docid, $xibx, undef, $oid, $eml);
 209         }
 210 }
 211
 212 # called by V2Writable::sync_prepare
 213 sub artnum_max { $_[0]->{oidx}->eidx_max }
 214
 215 sub index_unseen ($) {
 216         my ($req) = @_;
 217         my $new_smsg = $req->{new_smsg} or die 'BUG: {new_smsg} unset';
 218         my $eml = delete $req->{eml};
 219         $new_smsg->populate($eml, $req);
 220         my $self = $req->{self};
 221         my $docid = $self->{oidx}->adj_counter('eidx_docid', '+');
 222         $new_smsg->{num} = $docid;
 223         my $idx = $self->idx_shard($docid);
 224         $self->{oidx}->add_overview($eml, $new_smsg);
 225         my $oid = $new_smsg->{blob};
 226         my $ibx = delete $req->{ibx} or die 'BUG: {ibx} unset';
 227         $self->{oidx}->add_xref3($docid, $req->{xnum}, $oid, $ibx->eidx_key);
 228         $idx->index_eml($eml, $new_smsg, $ibx->eidx_key);
 229         check_batch_limit($req);
 230 }
 231
 232 sub do_finalize ($) {
 233         my ($req) = @_;
 234         if (my $indexed = $req->{indexed}) { # duplicated messages
 235                 do_xpost($req, $_) for @$indexed;
 236         } elsif (exists $req->{new_smsg}) { # totally unseen messsage
 237                 index_unseen($req);
 238         } else {
 239                 # `d' message was already unindexed in the v1/v2 inboxes,
 240                 # so it's too noisy to warn, here.
 241         }
 242         # cur_cmt may be undef for unindex_oid, set by V2Writable::index_todo
 243         if (defined(my $cur_cmt = $req->{cur_cmt})) {
 244                 ${$req->{latest_cmt}} = $cur_cmt;
 245         }
 246 }
 247
 248 sub do_step ($) { # main iterator for adding messages to the index
 249         my ($req) = @_;
 250         my $self = $req->{self} // die 'BUG: {self} missing';
 251         while (1) {
 252                 if (my $next_arg = $req->{next_arg}) {
 253                         if (my $smsg = $self->{oidx}->next_by_mid(@$next_arg)) {
 254                                 $req->{cur_smsg} = $smsg;
 255                                 $self->git->cat_async($smsg->{blob},
 256                                                         \&ck_existing, $req);
 257                                 return; # ck_existing calls do_step
 258                         }
 259                         delete $req->{next_arg};
 260                 }
 261                 die "BUG: {cur_smsg} still set" if $req->{cur_smsg};
 262                 my $mid = shift(@{$req->{mids}}) // last;
 263                 my ($id, $prev);
 264                 $req->{next_arg} = [ $mid, \$id, \$prev ];
 265                 # loop again
 266         }
 267         do_finalize($req);
 268 }
 269
 270 sub _blob_missing ($$) { # called when a known $smsg->{blob} is gone
 271         my ($req, $smsg) = @_;
 272         # xnum and ibx are unknown, we only call this when an entry from
 273         # /ei*/over.sqlite3 is bad, not on entries from xap*/over.sqlite3
 274         $req->{self}->git->async_wait_all;
 275         _unref_doc($req, $smsg, undef, undef, $smsg->oidbin);
 276 }
 277
 278 sub ck_existing { # git->cat_async callback
 279         my ($bref, $oid, $type, $size, $req) = @_;
 280         my $smsg = delete $req->{cur_smsg} or die 'BUG: {cur_smsg} missing';
 281         if ($type eq 'missing') {
 282                 _blob_missing($req, $smsg);
 283         } elsif (!is_bad_blob($oid, $type, $size, $smsg->{blob})) {
 284                 my $self = $req->{self} // die 'BUG: {self} missing';
 285                 local $self->{current_info} = "$self->{current_info} $oid";
 286                 my $cur = PublicInbox::Eml->new($bref);
 287                 if (content_hash($cur) eq $req->{chash}) {
 288                         push @{$req->{indexed}}, $smsg; # for do_xpost
 289                 } # else { index_unseen later }
 290         }
 291         do_step($req);
 292 }
 293
 294 # is the messages visible in the inbox currently being indexed?
 295 # return the number if so
 296 sub cur_ibx_xnum ($$;$) {
 297         my ($req, $bref, $mismatch) = @_;
 298         my $ibx = $req->{ibx} or die 'BUG: current {ibx} missing';
 299
 300         $req->{eml} = PublicInbox::Eml->new($bref);
 301         $req->{chash} = content_hash($req->{eml});
 302         $req->{mids} = mids($req->{eml});
 303         for my $mid (@{$req->{mids}}) {
 304                 my ($id, $prev);
 305                 while (my $x = $ibx->over->next_by_mid($mid, \$id, \$prev)) {
 306                         return $x->{num} if $x->{blob} eq $req->{oid};
 307                         push @$mismatch, $x if $mismatch;
 308                 }
 309         }
 310         undef;
 311 }
 312
 313 sub index_oid { # git->cat_async callback for 'm'
 314         my ($bref, $oid, $type, $size, $req) = @_;
 315         my $self = $req->{self};
 316         local $self->{current_info} = "$self->{current_info} $oid";
 317         return if is_bad_blob($oid, $type, $size, $req->{oid});
 318         my $new_smsg = $req->{new_smsg} = bless {
 319                 blob => $oid,
 320         }, 'PublicInbox::Smsg';
 321         $new_smsg->set_bytes($$bref, $size);
 322         ++${$req->{nr}};
 323         my $mismatch = [];
 324         $req->{xnum} = cur_ibx_xnum($req, $bref, $mismatch) // do {
 325                 warn "# deleted\n";
 326                 warn "# mismatch $_->{blob}\n" for @$mismatch;
 327                 ${$req->{latest_cmt}} = $req->{cur_cmt} //
 328                         die "BUG: {cur_cmt} unset ($oid)\n";
 329                 return;
 330         };
 331         do_step($req);
 332 }
 333
 334 sub unindex_oid { # git->cat_async callback for 'd'
 335         my ($bref, $oid, $type, $size, $req) = @_;
 336         my $self = $req->{self};
 337         local $self->{current_info} = "$self->{current_info} $oid";
 338         return if is_bad_blob($oid, $type, $size, $req->{oid});
 339         return if defined(cur_ibx_xnum($req, $bref)); # was re-added
 340         do_step($req);
 341 }
 342
 343 # overrides V2Writable::last_commits, called by sync_ranges via sync_prepare
 344 sub last_commits {
 345         my ($self, $sync) = @_;
 346         my $heads = [];
 347         my $ekey = $sync->{ibx}->eidx_key;
 348         my $uv = $sync->{ibx}->uidvalidity;
 349         for my $i (0..$sync->{epoch_max}) {
 350                 $heads->[$i] = $self->{oidx}->eidx_meta("lc-v2:$ekey//$uv;$i");
 351         }
 352         $heads;
 353 }
 354
 355 sub _ibx_index_reject ($) {
 356         my ($ibx) = @_;
 357         $ibx->mm // return 'unindexed, no msgmap.sqlite3';
 358         $ibx->uidvalidity // return 'no UIDVALIDITY';
 359         $ibx->over // return 'unindexed, no over.sqlite3';
 360         undef;
 361 }
 362
 363 sub _sync_inbox ($$$) {
 364         my ($self, $sync, $ibx) = @_;
 365         my $ekey = $ibx->eidx_key;
 366         if (defined(my $err = _ibx_index_reject($ibx))) {
 367                 return "W: skipping $ekey ($err)";
 368         }
 369         $sync->{ibx} = $ibx;
 370         $sync->{nr} = \(my $nr = 0);
 371         my $v = $ibx->version;
 372         if ($v == 2) {
 373                 $sync->{epoch_max} = $ibx->max_git_epoch // return;
 374                 sync_prepare($self, $sync); # or return # TODO: once MiscIdx is stable
 375         } elsif ($v == 1) {
 376                 my $uv = $ibx->uidvalidity;
 377                 my $lc = $self->{oidx}->eidx_meta("lc-v1:$ekey//$uv");
 378                 my $head = $ibx->mm->last_commit //
 379                         return "E: $ibx->{inboxdir} is not indexed";
 380                 my $stk = prepare_stack($sync, $lc ? "$lc..$head" : $head);
 381                 my $unit = { stack => $stk, git => $ibx->git };
 382                 push @{$sync->{todo}}, $unit;
 383         } else {
 384                 return "E: $ekey unsupported inbox version (v$v)";
 385         }
 386         for my $unit (@{delete($sync->{todo}) // []}) {
 387                 last if $sync->{quit};
 388                 index_todo($self, $sync, $unit);
 389         }
 390         $self->{midx}->index_ibx($ibx) unless $sync->{quit};
 391         $ibx->git->cleanup; # done with this inbox, now
 392         undef;
 393 }
 394
 395 sub eidx_gc_scan_inboxes ($$) {
 396         my ($self, $sync) = @_;
 397         my ($x3_doc, $ibx_ck);
 398 restart:
 399         $x3_doc = $self->{oidx}->dbh->prepare(<<EOM);
 400 SELECT docid,xnum,oidbin FROM xref3 WHERE ibx_id = ?
 401 EOM
 402         $ibx_ck = $self->{oidx}->dbh->prepare(<<EOM);
 403 SELECT ibx_id,eidx_key FROM inboxes
 404 EOM
 405         $ibx_ck->execute;
 406         while (my ($ibx_id, $eidx_key) = $ibx_ck->fetchrow_array) {
 407                 next if $self->{ibx_map}->{$eidx_key};
 408                 $self->{midx}->remove_eidx_key($eidx_key);
 409                 warn "I: deleting messages for $eidx_key...\n";
 410                 $x3_doc->execute($ibx_id);
 411                 my $ibx = { -ibx_id => $ibx_id, -gc_eidx_key => $eidx_key };
 412                 while (my ($docid, $xnum, $oid) = $x3_doc->fetchrow_array) {
 413                         my $r = _unref_doc($sync, $docid, $ibx, $xnum, $oid);
 414                         $oid = unpack('H*', $oid);
 415                         $r = $r ? 'unref' : 'remove';
 416                         warn "I: $r #$docid $eidx_key $oid\n";
 417                         if (checkpoint_due($sync)) {
 418                                 $x3_doc = $ibx_ck = undef;
 419                                 reindex_checkpoint($self, $sync);
 420                                 goto restart;
 421                         }
 422                 }
 423                 $self->{oidx}->dbh->do(<<'', undef, $ibx_id);
 424 DELETE FROM inboxes WHERE ibx_id = ?
 425
 426                 # drop last_commit info
 427                 my $pat = $eidx_key;
 428                 $pat =~ s/([_%\\])/\\$1/g;
 429                 $self->{oidx}->dbh->do('PRAGMA case_sensitive_like = ON');
 430                 my $lc_i = $self->{oidx}->dbh->prepare(<<'');
 431 SELECT key FROM eidx_meta WHERE key LIKE ? ESCAPE ?
 432
 433                 $lc_i->execute("lc-%:$pat//%", '\\');
 434                 while (my ($key) = $lc_i->fetchrow_array) {
 435                         next if $key !~ m!\Alc-v[1-9]+:\Q$eidx_key\E//!;
 436                         warn "I: removing $key\n";
 437                         $self->{oidx}->dbh->do(<<'', undef, $key);
 438 DELETE FROM eidx_meta WHERE key = ?
 439
 440                 }
 441                 warn "I: $eidx_key removed\n";
 442         }
 443 }
 444
 445 sub eidx_gc_scan_shards ($$) { # TODO: use for lei/store
 446         my ($self, $sync) = @_;
 447         my $nr = $self->{oidx}->dbh->do(<<'');
 448 DELETE FROM xref3 WHERE docid NOT IN (SELECT num FROM over)
 449
 450         warn "I: eliminated $nr stale xref3 entries\n" if $nr != 0;
 451         reindex_checkpoint($self, $sync) if checkpoint_due($sync);
 452
 453         # fixup from old bugs:
 454         $nr = $self->{oidx}->dbh->do(<<'');
 455 DELETE FROM over WHERE num > 0 AND num NOT IN (SELECT docid FROM xref3)
 456
 457         warn "I: eliminated $nr stale over entries\n" if $nr != 0;
 458         reindex_checkpoint($self, $sync) if checkpoint_due($sync);
 459
 460         $nr = $self->{oidx}->dbh->do(<<'');
 461 DELETE FROM eidxq WHERE docid NOT IN (SELECT num FROM over)
 462
 463         warn "I: eliminated $nr stale reindex queue entries\n" if $nr != 0;
 464         reindex_checkpoint($self, $sync) if checkpoint_due($sync);
 465
 466         my ($cur) = $self->{oidx}->dbh->selectrow_array(<<EOM);
 467 SELECT MIN(num) FROM over WHERE num > 0
 468 EOM
 469         $cur // return; # empty
 470         my ($r, $n, %active_shards);
 471         $nr = 0;
 472         while (1) {
 473                 $r = $self->{oidx}->dbh->selectcol_arrayref(<<"", undef, $cur);
 474 SELECT num FROM over WHERE num >= ? ORDER BY num ASC LIMIT 10000
 475
 476                 last unless scalar(@$r);
 477                 while (defined($n = shift @$r)) {
 478                         for my $i ($cur..($n - 1)) {
 479                                 my $idx = idx_shard($self, $i);
 480                                 $idx->ipc_do('xdb_remove_quiet', $i);
 481                                 $active_shards{$idx} = $idx;
 482                         }
 483                         $cur = $n + 1;
 484                 }
 485                 if (checkpoint_due($sync)) {
 486                         for my $idx (values %active_shards) {
 487                                 $nr += $idx->ipc_do('nr_quiet_rm')
 488                         }
 489                         %active_shards = ();
 490                         reindex_checkpoint($self, $sync);
 491                 }
 492         }
 493         warn "I: eliminated $nr stale Xapian documents\n" if $nr != 0;
 494 }
 495
 496 sub eidx_gc {
 497         my ($self, $opt) = @_;
 498         $self->{cfg} or die "E: GC requires ->attach_config\n";
 499         $opt->{-idx_gc} = 1;
 500         my $sync = {
 501                 need_checkpoint => \(my $need_checkpoint = 0),
 502                 check_intvl => 10,
 503                 next_check => now() + 10,
 504                 checkpoint_unlocks => 1,
 505                 -opt => $opt,
 506                 self => $self,
 507         };
 508         $self->idx_init($opt); # acquire lock via V2Writable::_idx_init
 509         eidx_gc_scan_inboxes($self, $sync);
 510         eidx_gc_scan_shards($self, $sync);
 511         done($self);
 512 }
 513
 514 sub _ibx_for ($$$) {
 515         my ($self, $sync, $smsg) = @_;
 516         my $ibx_id = delete($smsg->{ibx_id}) // die '{ibx_id} unset';
 517         my $pos = $sync->{id2pos}->{$ibx_id} // die "$ibx_id no pos";
 518         $self->{-ibx_ary_known}->[$pos] //
 519                 die "BUG: ibx for $smsg->{blob} not mapped"
 520 }
 521
 522 sub _fd_constrained ($) {
 523         my ($self) = @_;
 524         $self->{-fd_constrained} //= do {
 525                 my $soft;
 526                 if (eval { require BSD::Resource; 1 }) {
 527                         my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 528                         ($soft, undef) = BSD::Resource::getrlimit($NOFILE);
 529                 } else {
 530                         chomp($soft = `sh -c 'ulimit -n'`);
 531                 }
 532                 if (defined($soft)) {
 533                         # $want is an estimate
 534                         my $want = scalar(@{$self->{ibx_active}}) + 64;
 535                         my $ret = $want > $soft;
 536                         if ($ret) {
 537                                 warn <<EOF;
 538 RLIMIT_NOFILE=$soft insufficient (want: $want), will close DB handles early
 539 EOF
 540                         }
 541                         $ret;
 542                 } else {
 543                         warn "Unable to determine RLIMIT_NOFILE: $@\n";
 544                         1;
 545                 }
 546         };
 547 }
 548
 549 sub _reindex_finalize ($$$) {
 550         my ($req, $smsg, $eml) = @_;
 551         my $sync = $req->{sync};
 552         my $self = $sync->{self};
 553         my $by_chash = delete $req->{by_chash} or die 'BUG: no {by_chash}';
 554         my $nr = scalar(keys(%$by_chash)) or die 'BUG: no content hashes';
 555         my $orig_smsg = $req->{orig_smsg} // die 'BUG: no {orig_smsg}';
 556         my $docid = $smsg->{num} = $orig_smsg->{num};
 557         $self->{oidx}->add_overview($eml, $smsg); # may rethread
 558         check_batch_limit({ %$sync, new_smsg => $smsg });
 559         my $chash0 = $smsg->{chash} // die "BUG: $smsg->{blob} no {chash}";
 560         my $stable = delete($by_chash->{$chash0}) //
 561                                 die "BUG: $smsg->{blob} chash missing";
 562         my $idx = $self->idx_shard($docid);
 563         my $top_smsg = pop @$stable;
 564         $top_smsg == $smsg or die 'BUG: top_smsg != smsg';
 565         my $ibx = _ibx_for($self, $sync, $smsg);
 566         $idx->index_eml($eml, $smsg, $ibx->eidx_key);
 567         for my $x (reverse @$stable) {
 568                 $ibx = _ibx_for($self, $sync, $x);
 569                 my $hdr = delete $x->{hdr} // die 'BUG: no {hdr}';
 570                 $idx->ipc_do('add_eidx_info', $docid, $ibx->eidx_key, $hdr);
 571         }
 572         return if $nr == 1; # likely, all good
 573
 574         $self->git->async_wait_all;
 575         warn "W: #$docid split into $nr due to deduplication change\n";
 576         my @todo;
 577         for my $ary (values %$by_chash) {
 578                 for my $x (reverse @$ary) {
 579                         warn "removing #$docid xref3 $x->{blob}\n";
 580                         my $bin = $x->oidbin;
 581                         my $n = _unref_doc($sync, $docid, undef, undef, $bin);
 582                         die "BUG: $x->{blob} invalidated #$docid" if $n == 0;
 583                 }
 584                 my $x = pop(@$ary) // die "BUG: #$docid {by_chash} empty";
 585                 $x->{num} = delete($x->{xnum}) // die '{xnum} unset';
 586                 $ibx = _ibx_for($self, $sync, $x);
 587                 if (my $over = $ibx->over) {
 588                         my $e = $over->get_art($x->{num});
 589                         $e->{blob} eq $x->{blob} or die <<EOF;
 590 $x->{blob} != $e->{blob} (${\$ibx->eidx_key}:$e->{num});
 591 EOF
 592                         push @todo, $ibx, $e;
 593                         $over->dbh_close if _fd_constrained($self);
 594                 } else {
 595                         die "$ibx->{inboxdir}: over.sqlite3 unusable: $!\n";
 596                 }
 597         }
 598         undef $by_chash;
 599         while (my ($ibx, $e) = splice(@todo, 0, 2)) {
 600                 reindex_unseen($self, $sync, $ibx, $e);
 601         }
 602 }
 603
 604 sub _reindex_oid { # git->cat_async callback
 605         my ($bref, $oid, $type, $size, $req) = @_;
 606         my $sync = $req->{sync};
 607         my $self = $sync->{self};
 608         my $orig_smsg = $req->{orig_smsg} // die 'BUG: no {orig_smsg}';
 609         my $expect_oid = $req->{xr3r}->[$req->{ix}]->[2];
 610         my $docid = $orig_smsg->{num};
 611         if (is_bad_blob($oid, $type, $size, $expect_oid)) {
 612                 my $oidbin = pack('H*', $expect_oid);
 613                 my $remain = _unref_doc($sync, $docid, undef, undef, $oidbin);
 614                 if ($remain == 0) {
 615                         warn "W: #$docid ($oid) gone or corrupt\n";
 616                 } elsif (my $next_oid = $req->{xr3r}->[++$req->{ix}]->[2]) {
 617                         $self->git->cat_async($next_oid, \&_reindex_oid, $req);
 618                 } else {
 619                         warn "BUG: #$docid ($oid) gone (UNEXPECTED)\n";
 620                 }
 621                 return;
 622         }
 623         my $ci = $self->{current_info};
 624         local $self->{current_info} = "$ci #$docid $oid";
 625         my $re_smsg = bless { blob => $oid }, 'PublicInbox::Smsg';
 626         $re_smsg->set_bytes($$bref, $size);
 627         my $eml = PublicInbox::Eml->new($bref);
 628         $re_smsg->populate($eml, { autime => $orig_smsg->{ds},
 629                                 cotime => $orig_smsg->{ts} });
 630         my $chash = content_hash($eml);
 631         $re_smsg->{chash} = $chash;
 632         $re_smsg->{xnum} = $req->{xr3r}->[$req->{ix}]->[1];
 633         $re_smsg->{ibx_id} = $req->{xr3r}->[$req->{ix}]->[0];
 634         $re_smsg->{hdr} = $eml->header_obj;
 635         push @{$req->{by_chash}->{$chash}}, $re_smsg;
 636         if (my $next_oid = $req->{xr3r}->[++$req->{ix}]->[2]) {
 637                 $self->git->cat_async($next_oid, \&_reindex_oid, $req);
 638         } else { # last $re_smsg is the highest priority xref3
 639                 local $self->{current_info} = "$ci #$docid";
 640                 _reindex_finalize($req, $re_smsg, $eml);
 641         }
 642 }
 643
 644 sub _reindex_smsg ($$$) {
 645         my ($self, $sync, $smsg) = @_;
 646         my $docid = $smsg->{num};
 647         my $xr3 = $self->{oidx}->get_xref3($docid, 1);
 648         if (scalar(@$xr3) == 0) { # _reindex_check_stale should've covered this
 649                 warn <<"";
 650 BUG? #$docid $smsg->{blob} is not referenced by inboxes during reindex
 651
 652                 remove_doc($self, $docid);
 653                 return;
 654         }
 655
 656         # we sort {xr3r} in the reverse order of ibx_sorted so we can
 657         # hit the common case in _reindex_finalize without rereading
 658         # from git (or holding multiple messages in memory).
 659         my $id2pos = $sync->{id2pos}; # index in ibx_sorted
 660         @$xr3 = sort {
 661                 $id2pos->{$b->[0]} <=> $id2pos->{$a->[0]}
 662                                 ||
 663                 $b->[1] <=> $a->[1] # break ties with {xnum}
 664         } @$xr3;
 665         @$xr3 = map { [ $_->[0], $_->[1], unpack('H*', $_->[2]) ] } @$xr3;
 666         my $req = { orig_smsg => $smsg, sync => $sync, xr3r => $xr3, ix => 0 };
 667         $self->git->cat_async($xr3->[$req->{ix}]->[2], \&_reindex_oid, $req);
 668 }
 669
 670 sub checkpoint_due ($) {
 671         my ($sync) = @_;
 672         ${$sync->{need_checkpoint}} || (now() > $sync->{next_check});
 673 }
 674
 675 sub host_ident () {
 676         # I've copied FS images and only changed the hostname before,
 677         # so prepend hostname.  Use `state' since these a BOFH can change
 678         # these while this process is running and we always want to be
 679         # able to release locks taken by this process.
 680         state $retval = hostname . '-' . do {
 681                 my $m; # machine-id(5) is systemd
 682                 if (open(my $fh, '<', '/etc/machine-id')) { $m = <$fh> }
 683                 # (g)hostid(1) is in GNU coreutils, kern.hostid is most BSDs
 684                 chomp($m ||= `{ sysctl -n kern.hostid ||
 685                                 hostid || ghostid; } 2>/dev/null`
 686                         || "no-machine-id-or-hostid-on-$^O");
 687                 $m;
 688         };
 689 }
 690
 691 sub eidxq_release {
 692         my ($self) = @_;
 693         my $expect = delete($self->{-eidxq_locked}) or return;
 694         my ($owner_pid, undef) = split(/-/, $expect);
 695         return if $owner_pid != $$; # shards may fork
 696         my $oidx = $self->{oidx};
 697         $oidx->begin_lazy;
 698         my $cur = $oidx->eidx_meta('eidxq_lock') // '';
 699         if ($cur eq $expect) {
 700                 $oidx->eidx_meta('eidxq_lock', '');
 701                 return 1;
 702         } elsif ($cur ne '') {
 703                 warn "E: eidxq_lock($expect) stolen by $cur\n";
 704         } else {
 705                 warn "E: eidxq_lock($expect) released by another process\n";
 706         }
 707         undef;
 708 }
 709
 710 sub DESTROY {
 711         my ($self) = @_;
 712         eidxq_release($self) and $self->{oidx}->commit_lazy;
 713 }
 714
 715 sub _eidxq_take ($) {
 716         my ($self) = @_;
 717         my $val = "$$-${\time}-$>-".host_ident;
 718         $self->{oidx}->eidx_meta('eidxq_lock', $val);
 719         $self->{-eidxq_locked} = $val;
 720 }
 721
 722 sub eidxq_lock_acquire ($) {
 723         my ($self) = @_;
 724         my $oidx = $self->{oidx};
 725         $oidx->begin_lazy;
 726         my $cur = $oidx->eidx_meta('eidxq_lock') || return _eidxq_take($self);
 727         if (my $locked = $self->{-eidxq_locked}) { # be lazy
 728                 return $locked if $locked eq $cur;
 729         }
 730         my ($pid, $time, $euid, $ident) = split(/-/, $cur, 4);
 731         my $t = strftime('%Y-%m-%d %k:%M %z', localtime($time));
 732         local $self->{current_info} = 'eidxq';
 733         if ($euid == $> && $ident eq host_ident) {
 734                 if (kill(0, $pid)) {
 735                         warn <<EOM; return;
 736 I: PID:$pid (re)indexing since $t, it will continue our work
 737 EOM
 738                 }
 739                 if ($!{ESRCH}) {
 740                         warn "I: eidxq_lock is stale ($cur), clobbering\n";
 741                         return _eidxq_take($self);
 742                 }
 743                 warn "E: kill(0, $pid) failed: $!\n"; # fall-through:
 744         }
 745         my $fn = $oidx->dbh->sqlite_db_filename;
 746         warn <<EOF;
 747 W: PID:$pid, UID:$euid on $ident is indexing Xapian since $t
 748 W: If this is unexpected, delete `eidxq_lock' from the `eidx_meta' table:
 749 W:      sqlite3 $fn 'DELETE FROM eidx_meta WHERE key = "eidxq_lock"'
 750 EOF
 751         undef;
 752 }
 753
 754 sub ibx_sorted ($$) {
 755         my ($self, $type) = @_;
 756         $self->{"-ibx_ary_$type"} //= do {
 757                 # highest boost first, stable for config-ordering tiebreaker
 758                 use sort 'stable';
 759                 [ sort {
 760                         ($b->{boost} // 0) <=> ($a->{boost} // 0)
 761                   } @{$self->{'ibx_'.$type} // die "BUG: $type unknown"} ];
 762         }
 763 }
 764
 765 sub prep_id2pos ($) {
 766         my ($self) = @_;
 767         my %id2pos;
 768         my $pos = 0;
 769         $id2pos{$_->{-ibx_id}} = $pos++ for (@{ibx_sorted($self, 'known')});
 770         \%id2pos;
 771 }
 772
 773 sub eidxq_process ($$) { # for reindexing
 774         my ($self, $sync) = @_;
 775         local $self->{current_info} = 'eidxq process';
 776         return unless ($self->{cfg} && eidxq_lock_acquire($self));
 777         my $dbh = $self->{oidx}->dbh;
 778         my $tot = $dbh->selectrow_array('SELECT COUNT(*) FROM eidxq') or return;
 779         ${$sync->{nr}} = 0;
 780         local $sync->{-regen_fmt} = "%u/$tot\n";
 781         my $pr = $sync->{-opt}->{-progress};
 782         if ($pr) {
 783                 my $min = $dbh->selectrow_array('SELECT MIN(docid) FROM eidxq');
 784                 my $max = $dbh->selectrow_array('SELECT MAX(docid) FROM eidxq');
 785                 $pr->("Xapian indexing $min..$max (total=$tot)\n");
 786         }
 787         $sync->{id2pos} //= prep_id2pos($self);
 788         my ($del, $iter);
 789 restart:
 790         $del = $dbh->prepare('DELETE FROM eidxq WHERE docid = ?');
 791         $iter = $dbh->prepare('SELECT docid FROM eidxq ORDER BY docid ASC');
 792         $iter->execute;
 793         while (defined(my $docid = $iter->fetchrow_array)) {
 794                 last if $sync->{quit};
 795                 if (my $smsg = $self->{oidx}->get_art($docid)) {
 796                         _reindex_smsg($self, $sync, $smsg);
 797                 } else {
 798                         warn "E: #$docid does not exist in over\n";
 799                 }
 800                 $del->execute($docid);
 801                 ++${$sync->{nr}};
 802
 803                 if (checkpoint_due($sync)) {
 804                         $dbh = $del = $iter = undef;
 805                         reindex_checkpoint($self, $sync); # release lock
 806                         $dbh = $self->{oidx}->dbh;
 807                         goto restart;
 808                 }
 809         }
 810         $self->git->async_wait_all;
 811         $pr->("reindexed ${$sync->{nr}}/$tot\n") if $pr;
 812 }
 813
 814 sub _reindex_unseen { # git->cat_async callback
 815         my ($bref, $oid, $type, $size, $req) = @_;
 816         return if is_bad_blob($oid, $type, $size, $req->{oid});
 817         my $self = $req->{self} // die 'BUG: {self} unset';
 818         local $self->{current_info} = "$self->{current_info} $oid";
 819         my $new_smsg = bless { blob => $oid, }, 'PublicInbox::Smsg';
 820         $new_smsg->set_bytes($$bref, $size);
 821         my $eml = $req->{eml} = PublicInbox::Eml->new($bref);
 822         $req->{new_smsg} = $new_smsg;
 823         $req->{chash} = content_hash($eml);
 824         $req->{mids} = mids($eml); # do_step iterates through this
 825         do_step($req); # enter the normal indexing flow
 826 }
 827
 828 # --reindex may catch totally unseen messages, this handles them
 829 sub reindex_unseen ($$$$) {
 830         my ($self, $sync, $ibx, $xsmsg) = @_;
 831         my $req = {
 832                 %$sync, # has {self}
 833                 autime => $xsmsg->{ds},
 834                 cotime => $xsmsg->{ts},
 835                 oid => $xsmsg->{blob},
 836                 ibx => $ibx,
 837                 xnum => $xsmsg->{num},
 838                 # {mids} and {chash} will be filled in at _reindex_unseen
 839         };
 840         warn "I: reindex_unseen ${\$ibx->eidx_key}:$req->{xnum}:$req->{oid}\n";
 841         $self->git->cat_async($xsmsg->{blob}, \&_reindex_unseen, $req);
 842 }
 843
 844 sub _unref_stale_range ($$$) {
 845         my ($sync, $ibx, $lt_or_gt) = @_;
 846         my $r;
 847         my $lim = 10000;
 848         do {
 849                 $r = $sync->{self}->{oidx}->dbh->selectall_arrayref(
 850                         <<EOS, undef, $ibx->{-ibx_id});
 851 SELECT docid,xnum,oidbin FROM xref3
 852 WHERE ibx_id = ? AND $lt_or_gt LIMIT $lim
 853 EOS
 854                 return if $sync->{quit};
 855                 for (@$r) { # hopefully rare, not worth optimizing:
 856                         my ($docid, $xnum, $oidbin) = @$_;
 857                         my $hex = unpack('H*', $oidbin);
 858                         warn("# $xnum:$hex (#$docid): stale\n");
 859                         _unref_doc($sync, $docid, $ibx, $xnum, $oidbin);
 860                 }
 861         } while (scalar(@$r) == $lim);
 862         1;
 863 }
 864
 865 sub _reindex_check_ibx ($$$) {
 866         my ($self, $sync, $ibx) = @_;
 867         my $ibx_id = $ibx->{-ibx_id};
 868         my $slice = 10000;
 869         my $opt = { limit => $slice };
 870         my ($beg, $end) = (1, $slice);
 871         my $ekey = $ibx->eidx_key;
 872         my ($max, $max0);
 873         do {
 874                 $max0 = $ibx->mm->num_highwater;
 875                 sync_inbox($self, $sync, $ibx) and return; # warned
 876                 $max = $ibx->mm->num_highwater;
 877                 return if $sync->{quit};
 878         } while ($max > $max0 &&
 879                 warn("# $ekey moved $max0..$max, resyncing..\n"));
 880         $end = $max if $end > $max;
 881
 882         # first, check if we missed any messages in target $ibx
 883         my $msgs;
 884         my $pr = $sync->{-opt}->{-progress};
 885         local $sync->{-regen_fmt} = "$ekey checking %u/$max\n";
 886         ${$sync->{nr}} = 0;
 887         my $fast = $sync->{-opt}->{fast};
 888         my $usr; # _unref_stale_range (< $lo) called
 889         my ($lo, $hi);
 890         while (scalar(@{$msgs = $ibx->over->query_xover($beg, $end, $opt)})) {
 891                 ${$sync->{nr}} = $beg;
 892                 $beg = $msgs->[-1]->{num} + 1;
 893                 $end = $beg + $slice;
 894                 $end = $max if $end > $max;
 895                 if (checkpoint_due($sync)) {
 896                         reindex_checkpoint($self, $sync); # release lock
 897                 }
 898                 ($lo, $hi) = ($msgs->[0]->{num}, $msgs->[-1]->{num});
 899                 $usr //= _unref_stale_range($sync, $ibx, "xnum < $lo");
 900                 my $x3a = $self->{oidx}->dbh->selectall_arrayref(
 901                         <<"", undef, $ibx_id, $lo, $hi);
 902 SELECT xnum,oidbin,docid FROM xref3 WHERE
 903 ibx_id = ? AND xnum >= ? AND xnum <= ?
 904
 905                 my %x3m;
 906                 for (@$x3a) {
 907                         my $k = pack('J', $_->[0]) . $_->[1];
 908                         push @{$x3m{$k}}, $_->[2];
 909                 }
 910                 undef $x3a;
 911                 for my $xsmsg (@$msgs) {
 912                         my $k = pack('JH*', $xsmsg->{num}, $xsmsg->{blob});
 913                         my $docids = delete($x3m{$k});
 914                         if (!defined($docids)) {
 915                                 reindex_unseen($self, $sync, $ibx, $xsmsg);
 916                         } elsif (!$fast) {
 917                                 for my $num (@$docids) {
 918                                         $self->{oidx}->eidxq_add($num);
 919                                 }
 920                         }
 921                         return if $sync->{quit};
 922                 }
 923                 next unless scalar keys %x3m;
 924                 $self->git->async_wait_all; # wait for reindex_unseen
 925
 926                 # eliminate stale/mismatched entries
 927                 my %mismatch = map { $_->{num} => $_->{blob} } @$msgs;
 928                 while (my ($k, $docids) = each %x3m) {
 929                         my ($xnum, $hex) = unpack('JH*', $k);
 930                         my $bin = pack('H*', $hex);
 931                         my $exp = $mismatch{$xnum};
 932                         if (defined $exp) {
 933                                 my $smsg = $ibx->over->get_art($xnum) // next;
 934                                 # $xnum may be expired by another process
 935                                 if ($smsg->{blob} eq $hex) {
 936                                         warn <<"";
 937 BUG: (non-fatal) $ekey #$xnum $smsg->{blob} still matches (old exp: $exp)
 938
 939                                         next;
 940                                 } # else: continue to unref
 941                         }
 942                         my $m = defined($exp) ? "mismatch (!= $exp)" : 'stale';
 943                         warn("# $xnum:$hex (#@$docids): $m\n");
 944                         for my $i (@$docids) {
 945                                 _unref_doc($sync, $i, $ibx, $xnum, $bin);
 946                         }
 947                         return if $sync->{quit};
 948                 }
 949         }
 950         defined($hi) and ($hi < $max) and
 951                 _unref_stale_range($sync, $ibx, "xnum > $hi AND xnum <= $max");
 952 }
 953
 954 sub _reindex_inbox ($$$) {
 955         my ($self, $sync, $ibx) = @_;
 956         my $ekey = $ibx->eidx_key;
 957         local $self->{current_info} = $ekey;
 958         if (defined(my $err = _ibx_index_reject($ibx))) {
 959                 warn "W: cannot reindex $ekey ($err)\n";
 960         } else {
 961                 _reindex_check_ibx($self, $sync, $ibx);
 962         }
 963         delete @$ibx{qw(over mm search git)}; # won't need these for a bit
 964 }
 965
 966 sub eidx_reindex {
 967         my ($self, $sync) = @_;
 968         return unless $self->{cfg};
 969
 970         # acquire eidxq_lock early because full reindex takes forever
 971         # and incremental -extindex processes can run during our checkpoints
 972         if (!eidxq_lock_acquire($self)) {
 973                 warn "E: aborting --reindex\n";
 974                 return;
 975         }
 976         for my $ibx (@{ibx_sorted($self, 'active')}) {
 977                 _reindex_inbox($self, $sync, $ibx);
 978                 last if $sync->{quit};
 979         }
 980         $self->git->async_wait_all; # ensure eidxq gets filled completely
 981         eidxq_process($self, $sync) unless $sync->{quit};
 982 }
 983
 984 sub sync_inbox {
 985         my ($self, $sync, $ibx) = @_;
 986         my $err = _sync_inbox($self, $sync, $ibx);
 987         delete @$ibx{qw(mm over)};
 988         warn $err, "\n" if defined($err);
 989         $err;
 990 }
 991
 992 sub dd_smsg { # git->cat_async callback
 993         my ($bref, $oid, $type, $size, $dd) = @_;
 994         my $smsg = $dd->{smsg} // die 'BUG: dd->{smsg} missing';
 995         my $self = $dd->{self} // die 'BUG: {self} missing';
 996         my $per_mid = $dd->{per_mid} // die 'BUG: {per_mid} missing';
 997         if ($type eq 'missing') {
 998                 _blob_missing($dd, $smsg);
 999         } elsif (!is_bad_blob($oid, $type, $size, $smsg->{blob})) {
1000                 local $self->{current_info} = "$self->{current_info} $oid";
1001                 my $chash = content_hash(PublicInbox::Eml->new($bref));
1002                 push(@{$per_mid->{dd_chash}->{$chash}}, $smsg);
1003         }
1004         return if $per_mid->{last_smsg} != $smsg;
1005         while (my ($chash, $ary) = each %{$per_mid->{dd_chash}}) {
1006                 my $keep = shift @$ary;
1007                 next if !scalar(@$ary);
1008                 $per_mid->{sync}->{dedupe_cull} += scalar(@$ary);
1009                 print STDERR
1010                         "# <$keep->{mid}> keeping #$keep->{num}, dropping ",
1011                         join(', ', map { "#$_->{num}" } @$ary),"\n";
1012                 next if $per_mid->{sync}->{-opt}->{'dry-run'};
1013                 my $oidx = $self->{oidx};
1014                 for my $smsg (@$ary) {
1015                         my $gone = $smsg->{num};
1016                         $oidx->merge_xref3($keep->{num}, $gone, $smsg->oidbin);
1017                         remove_doc($self, $gone);
1018                 }
1019         }
1020 }
1021
1022 sub eidx_dedupe ($$$) {
1023         my ($self, $sync, $msgids) = @_;
1024         $sync->{dedupe_cull} = 0;
1025         my $candidates = 0;
1026         my $nr_mid = 0;
1027         return unless eidxq_lock_acquire($self);
1028         my ($iter, $cur_mid);
1029         my $min_id = 0;
1030         my $idx = 0;
1031         my ($max_id) = $self->{oidx}->dbh->selectrow_array(<<EOS);
1032 SELECT MAX(id) FROM msgid
1033 EOS
1034         local $sync->{-regen_fmt} = "dedupe %u/$max_id\n";
1035
1036         # note: we could write this query more intelligently,
1037         # but that causes lock contention with read-only processes
1038 dedupe_restart:
1039         $cur_mid = $msgids->[$idx];
1040         if ($cur_mid eq '') { # all Message-IDs
1041                 $iter = $self->{oidx}->dbh->prepare(<<EOS);
1042 SELECT mid,id FROM msgid WHERE id > ? ORDER BY id ASC
1043 EOS
1044                 $iter->execute($min_id);
1045         } else {
1046                 $iter = $self->{oidx}->dbh->prepare(<<EOS);
1047 SELECT mid,id FROM msgid WHERE mid = ? AND id > ? ORDER BY id ASC
1048 EOS
1049                 $iter->execute($cur_mid, $min_id);
1050         }
1051         while (my ($mid, $id) = $iter->fetchrow_array) {
1052                 last if $sync->{quit};
1053                 $self->{current_info} = "dedupe $mid";
1054                 ${$sync->{nr}} = $min_id = $id;
1055                 my ($prv, @smsg);
1056                 while (my $x = $self->{oidx}->next_by_mid($mid, \$id, \$prv)) {
1057                         push @smsg, $x;
1058                 }
1059                 next if scalar(@smsg) < 2;
1060                 my $per_mid = {
1061                         dd_chash => {}, # chash => [ary of smsgs]
1062                         last_smsg => $smsg[-1],
1063                         sync => $sync
1064                 };
1065                 $nr_mid++;
1066                 $candidates += scalar(@smsg) - 1;
1067                 for my $smsg (@smsg) {
1068                         my $dd = {
1069                                 per_mid => $per_mid,
1070                                 smsg => $smsg,
1071                                 self => $self,
1072                         };
1073                         $self->git->cat_async($smsg->{blob}, \&dd_smsg, $dd);
1074                 }
1075                 # need to wait on every single one @smsg contents can get
1076                 # invalidated inside dd_smsg for messages with multiple
1077                 # Message-IDs.
1078                 $self->git->async_wait_all;
1079
1080                 if (checkpoint_due($sync)) {
1081                         undef $iter;
1082                         reindex_checkpoint($self, $sync);
1083                         goto dedupe_restart;
1084                 }
1085         }
1086         goto dedupe_restart if defined($msgids->[++$idx]);
1087
1088         my $n = delete $sync->{dedupe_cull};
1089         if (my $pr = $sync->{-opt}->{-progress}) {
1090                 $pr->("culled $n/$candidates candidates ($nr_mid msgids)\n");
1091         }
1092         ${$sync->{nr}} = 0;
1093 }
1094
1095 sub eidx_sync { # main entry point
1096         my ($self, $opt) = @_;
1097
1098         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
1099         local $self->{current_info} = '';
1100         local $SIG{__WARN__} = sub {
1101                 return if PublicInbox::Eml::warn_ignore(@_);
1102                 $warn_cb->($self->{current_info}, ': ', @_);
1103         };
1104         $self->idx_init($opt); # acquire lock via V2Writable::_idx_init
1105         $self->{oidx}->rethread_prepare($opt);
1106         my $sync = {
1107                 need_checkpoint => \(my $need_checkpoint = 0),
1108                 check_intvl => 10,
1109                 next_check => now() + 10,
1110                 -opt => $opt,
1111                 # DO NOT SET {reindex} here, it's incompatible with reused
1112                 # V2Writable code, reindex is totally different here
1113                 # compared to v1/v2 inboxes because we have multiple histories
1114                 self => $self,
1115                 -regen_fmt => "%u/?\n",
1116         };
1117         local $SIG{USR1} = sub { $need_checkpoint = 1 };
1118         my $quit = PublicInbox::SearchIdx::quit_cb($sync);
1119         local $SIG{QUIT} = $quit;
1120         local $SIG{INT} = $quit;
1121         local $SIG{TERM} = $quit;
1122         for my $ibx (@{ibx_sorted($self, 'known')}) {
1123                 $ibx->{-ibx_id} //= $self->{oidx}->ibx_id($ibx->eidx_key);
1124         }
1125
1126         if (scalar(grep { defined($_->{boost}) } @{$self->{ibx_known}})) {
1127                 $sync->{id2pos} //= prep_id2pos($self);
1128                 $sync->{boost_in_use} = 1;
1129         }
1130
1131         if (my $msgids = delete($opt->{dedupe})) {
1132                 local $sync->{checkpoint_unlocks} = 1;
1133                 eidx_dedupe($self, $sync, $msgids);
1134         }
1135         if (delete($opt->{reindex})) {
1136                 local $sync->{checkpoint_unlocks} = 1;
1137                 eidx_reindex($self, $sync);
1138         }
1139
1140         # don't use $_ here, it'll get clobbered by reindex_checkpoint
1141         if ($opt->{scan} // 1) {
1142                 for my $ibx (@{ibx_sorted($self, 'active')}) {
1143                         last if $sync->{quit};
1144                         sync_inbox($self, $sync, $ibx);
1145                 }
1146         }
1147         $self->{oidx}->rethread_done($opt) unless $sync->{quit};
1148         eidxq_process($self, $sync) unless $sync->{quit};
1149
1150         eidxq_release($self);
1151         done($self);
1152         $sync; # for eidx_watch
1153 }
1154
1155 sub update_last_commit { # overrides V2Writable
1156         my ($self, $sync, $stk) = @_;
1157         my $unit = $sync->{unit} // return;
1158         my $latest_cmt = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
1159         defined($latest_cmt) or return;
1160         my $ibx = $sync->{ibx} or die 'BUG: {ibx} missing';
1161         my $ekey = $ibx->eidx_key;
1162         my $uv = $ibx->uidvalidity;
1163         my $epoch = $unit->{epoch};
1164         my $meta_key;
1165         my $v = $ibx->version;
1166         if ($v == 2) {
1167                 die 'No {epoch} for v2 unit' unless defined $epoch;
1168                 $meta_key = "lc-v2:$ekey//$uv;$epoch";
1169         } elsif ($v == 1) {
1170                 die 'Unexpected {epoch} for v1 unit' if defined $epoch;
1171                 $meta_key = "lc-v1:$ekey//$uv";
1172         } else {
1173                 die "Unsupported inbox version: $v";
1174         }
1175         my $last = $self->{oidx}->eidx_meta($meta_key);
1176         if (defined $last && is_ancestor($self->git, $last, $latest_cmt)) {
1177                 my @cmd = (qw(rev-list --count), "$last..$latest_cmt");
1178                 chomp(my $n = $unit->{git}->qx(@cmd));
1179                 return if $n ne '' && $n == 0;
1180         }
1181         $self->{oidx}->eidx_meta($meta_key, $latest_cmt);
1182 }
1183
1184 sub _idx_init { # with_umask callback
1185         my ($self, $opt) = @_;
1186         PublicInbox::V2Writable::_idx_init($self, $opt); # acquires ei.lock
1187         $self->{midx} = PublicInbox::MiscIdx->new($self);
1188 }
1189
1190 sub symlink_packs ($$) {
1191         my ($ibx, $pd) = @_;
1192         my $ret = 0;
1193         my $glob = "$ibx->{inboxdir}/git/*.git/objects/pack/*.idx";
1194         for my $idx (bsd_glob($glob, GLOB_NOSORT)) {
1195                 my $src = substr($idx, 0, -length('.idx'));
1196                 my $dst = $pd . substr($src, rindex($src, '/'));
1197                 if (-f "$src.pack" and
1198                                 symlink("$src.pack", "$dst.pack") and
1199                                 symlink($idx, "$dst.idx") and
1200                                 -f $idx) {
1201                         ++$ret;
1202                         # .promisor, .bitmap, .rev and .keep are optional
1203                         # XXX should we symlink .keep here?
1204                         for my $s (qw(promisor bitmap rev)) {
1205                                 symlink("$src.$s", "$dst.$s") if -f "$src.$s";
1206                         }
1207                 } elsif (!$!{EEXIST}) {
1208                         warn "W: ln -s $src.{pack,idx} => $dst.*: $!\n";
1209                         unlink "$dst.pack", "$dst.idx";
1210                 }
1211         }
1212         $ret;
1213 }
1214
1215 sub idx_init { # similar to V2Writable
1216         my ($self, $opt) = @_;
1217         return if $self->{idx_shards};
1218
1219         $self->git->cleanup;
1220         my $mode = 0644;
1221         my $ALL = $self->git->{git_dir}; # topdir/ALL.git
1222         my ($has_new, $alt, $seen, $prune, $prune_nr);
1223         if ($opt->{-private}) { # LeiStore
1224                 my $local = "$self->{topdir}/local"; # lei/store
1225                 $self->{mg} //= PublicInbox::MultiGit->new($self->{topdir},
1226                                                         'ALL.git', 'local');
1227                 $mode = 0600;
1228                 unless (-d $ALL) {
1229                         umask 077; # don't bother restoring for lei
1230                         PublicInbox::Import::init_bare($ALL);
1231                         $self->git->qx(qw(config core.sharedRepository 0600));
1232                 }
1233                 ($alt, $seen) = $self->{mg}->read_alternates(\$mode);
1234                 $has_new = $self->{mg}->merge_epochs($alt, $seen);
1235         } else { # extindex has no epochs
1236                 $self->{mg} //= PublicInbox::MultiGit->new($self->{topdir},
1237                                                         'ALL.git');
1238                 $prune = $opt->{-idx_gc} ? \$prune_nr : undef;
1239                 ($alt, $seen) = $self->{mg}->read_alternates(\$mode, $prune);
1240                 PublicInbox::Import::init_bare($ALL);
1241         }
1242
1243         # git-multi-pack-index(1) can speed up "git cat-file" startup slightly
1244         my $git_midx = 0;
1245         my $pd = "$ALL/objects/pack";
1246         if (opendir(my $dh, $pd)) { # drop stale symlinks
1247                 while (defined(my $dn = readdir($dh))) {
1248                         if ($dn =~ /\.(?:idx|pack|promisor|bitmap|rev)\z/) {
1249                                 my $f = "$pd/$dn";
1250                                 unlink($f) if -l $f && !-e $f;
1251                         }
1252                 }
1253         } elsif ($!{ENOENT}) {
1254                 mkdir($pd) or die "mkdir($pd): $!";
1255         } else {
1256                 die "opendir($pd): $!";
1257         }
1258         my $new = '';
1259         for my $ibx (@{ibx_sorted($self, 'active')}) {
1260                 # create symlinks for multi-pack-index
1261                 $git_midx += symlink_packs($ibx, $pd);
1262                 # add new lines to our alternates file
1263                 my $d = $ibx->git->{git_dir} . '/objects';
1264                 next if exists $alt->{$d};
1265                 if (my @st = stat($d)) {
1266                         next if $seen->{"$st[0]\0$st[1]"}++;
1267                 } else {
1268                         warn "W: stat($d) failed (from $ibx->{inboxdir}): $!\n";
1269                         next if $opt->{-idx_gc};
1270                 }
1271                 $new .= "$d\n";
1272         }
1273         ($has_new || $prune_nr || $new ne '') and
1274                 $self->{mg}->write_alternates($mode, $alt, $new);
1275         $git_midx and $self->with_umask(sub {
1276                 my @cmd = ('multi-pack-index');
1277                 push @cmd, '--no-progress' if ($opt->{quiet}//0) > 1;
1278                 my $lk = $self->lock_for_scope;
1279                 system('git', "--git-dir=$ALL", @cmd, 'write');
1280                 # ignore errors, fairly new command, may not exist
1281         });
1282         $self->parallel_init($self->{indexlevel});
1283         $self->with_umask(\&_idx_init, $self, $opt);
1284         $self->{oidx}->begin_lazy;
1285         $self->{oidx}->eidx_prep;
1286         $self->{midx}->create_xdb if $new ne '';
1287 }
1288
1289 sub _watch_commit { # PublicInbox::DS::add_timer callback
1290         my ($self) = @_;
1291         delete $self->{-commit_timer};
1292         eidxq_process($self, $self->{-watch_sync});
1293         eidxq_release($self);
1294         my $fmt = delete $self->{-watch_sync}->{-regen_fmt};
1295         reindex_checkpoint($self, $self->{-watch_sync});
1296         $self->{-watch_sync}->{-regen_fmt} = $fmt;
1297
1298         # call event_step => done unless commit_timer is armed
1299         PublicInbox::DS::requeue($self);
1300 }
1301
1302 sub on_inbox_unlock { # called by PublicInbox::InboxIdle
1303         my ($self, $ibx) = @_;
1304         my $opt = $self->{-watch_sync}->{-opt};
1305         my $pr = $opt->{-progress};
1306         my $ekey = $ibx->eidx_key;
1307         local $0 = "sync $ekey";
1308         $pr->("indexing $ekey\n") if $pr;
1309         $self->idx_init($opt);
1310         sync_inbox($self, $self->{-watch_sync}, $ibx);
1311         $self->{-commit_timer} //= add_timer($opt->{'commit-interval'} // 10,
1312                                         \&_watch_commit, $self);
1313 }
1314
1315 sub eidx_reload { # -extindex --watch SIGHUP handler
1316         my ($self, $idler) = @_;
1317         if ($self->{cfg}) {
1318                 my $pr = $self->{-watch_sync}->{-opt}->{-progress};
1319                 $pr->('reloading ...') if $pr;
1320                 delete $self->{-resync_queue};
1321                 delete $self->{-ibx_ary_known};
1322                 delete $self->{-ibx_ary_active};
1323                 $self->{ibx_known} = [];
1324                 $self->{ibx_active} = [];
1325                 %{$self->{ibx_map}} = ();
1326                 delete $self->{-watch_sync}->{id2pos};
1327                 my $cfg = PublicInbox::Config->new;
1328                 attach_config($self, $cfg);
1329                 $idler->refresh($cfg);
1330                 $pr->(" done\n") if $pr;
1331         } else {
1332                 warn "reload not supported without --all\n";
1333         }
1334 }
1335
1336 sub eidx_resync_start ($) { # -extindex --watch SIGUSR1 handler
1337         my ($self) = @_;
1338         $self->{-resync_queue} //= [ @{ibx_sorted($self, 'active')} ];
1339         PublicInbox::DS::requeue($self); # trigger our ->event_step
1340 }
1341
1342 sub event_step { # PublicInbox::DS::requeue callback
1343         my ($self) = @_;
1344         if (my $resync_queue = $self->{-resync_queue}) {
1345                 if (my $ibx = shift(@$resync_queue)) {
1346                         on_inbox_unlock($self, $ibx);
1347                         PublicInbox::DS::requeue($self);
1348                 } else {
1349                         delete $self->{-resync_queue};
1350                         _watch_commit($self);
1351                 }
1352         } else {
1353                 done($self) unless $self->{-commit_timer};
1354         }
1355 }
1356
1357 sub eidx_watch { # public-inbox-extindex --watch main loop
1358         my ($self, $opt) = @_;
1359         local @SIG{keys %SIG} = values %SIG;
1360         for my $sig (qw(HUP USR1 TSTP QUIT INT TERM)) {
1361                 $SIG{$sig} = sub { warn "SIG$sig ignored while scanning\n" };
1362         }
1363         require PublicInbox::InboxIdle;
1364         require PublicInbox::DS;
1365         require PublicInbox::Syscall;
1366         require PublicInbox::Sigfd;
1367         my $idler = PublicInbox::InboxIdle->new($self->{cfg});
1368         if (!$self->{cfg}) {
1369                 $idler->watch_inbox($_) for (@{ibx_sorted($self, 'active')});
1370         }
1371         for my $ibx (@{ibx_sorted($self, 'active')}) {
1372                 $ibx->subscribe_unlock(__PACKAGE__, $self)
1373         }
1374         my $pr = $opt->{-progress};
1375         $pr->("performing initial scan ...\n") if $pr;
1376         my $sync = eidx_sync($self, $opt); # initial sync
1377         return if $sync->{quit};
1378         my $oldset = PublicInbox::DS::block_signals();
1379         local $self->{current_info} = '';
1380         my $cb = $SIG{__WARN__} || \&CORE::warn;
1381         local $SIG{__WARN__} = sub {
1382                 return if PublicInbox::Eml::warn_ignore(@_);
1383                 $cb->($self->{current_info}, ': ', @_);
1384         };
1385         my $sig = {
1386                 HUP => sub { eidx_reload($self, $idler) },
1387                 USR1 => sub { eidx_resync_start($self) },
1388                 TSTP => sub { kill('STOP', $$) },
1389         };
1390         my $quit = PublicInbox::SearchIdx::quit_cb($sync);
1391         $sig->{QUIT} = $sig->{INT} = $sig->{TERM} = $quit;
1392         local $self->{-watch_sync} = $sync; # for ->on_inbox_unlock
1393         PublicInbox::DS->SetPostLoopCallback(sub { !$sync->{quit} });
1394         $pr->("initial scan complete, entering event loop\n") if $pr;
1395         # calls InboxIdle->event_step:
1396         PublicInbox::DS::event_loop($sig, $oldset);
1397         done($self);
1398 }
1399
1400 no warnings 'once';
1401 *done = \&PublicInbox::V2Writable::done;
1402 *with_umask = \&PublicInbox::InboxWritable::with_umask;
1403 *parallel_init = \&PublicInbox::V2Writable::parallel_init;
1404 *nproc_shards = \&PublicInbox::V2Writable::nproc_shards;
1405 *sync_prepare = \&PublicInbox::V2Writable::sync_prepare;
1406 *index_todo = \&PublicInbox::V2Writable::index_todo;
1407 *count_shards = \&PublicInbox::V2Writable::count_shards;
1408 *atfork_child = \&PublicInbox::V2Writable::atfork_child;
1409 *idx_shard = \&PublicInbox::V2Writable::idx_shard;
1410 *reindex_checkpoint = \&PublicInbox::V2Writable::reindex_checkpoint;
1411 *checkpoint = \&PublicInbox::V2Writable::checkpoint;
1412
1413 1;