lib/PublicInbox/ExtSearchIdx.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Detached/external index cross inbox search indexing support
   5 # read-write counterpart to PublicInbox::ExtSearch
   6 #
   7 # It's based on the same ideas as public-inbox-v2-format(5) using
   8 # over.sqlite3 for dedupe and sharded Xapian.  msgmap.sqlite3 is
   9 # missing, so there is no Message-ID conflict resolution, meaning
  10 # no NNTP support for now.
  11 #
  12 # v2 has a 1:1 mapping of index:inbox or msgmap for NNTP support.
  13 # This is intended to be an M:N index:inbox mapping, but it'll likely
  14 # be 1:N in common practice (M==1)
  15
  16 package PublicInbox::ExtSearchIdx;
  17 use strict;
  18 use v5.10.1;
  19 use parent qw(PublicInbox::ExtSearch PublicInbox::Lock);
  20 use Carp qw(croak carp);
  21 use Scalar::Util qw(blessed);
  22 use Sys::Hostname qw(hostname);
  23 use POSIX qw(strftime);
  24 use File::Glob qw(bsd_glob GLOB_NOSORT);
  25 use PublicInbox::MultiGit;
  26 use PublicInbox::Search;
  27 use PublicInbox::SearchIdx qw(prepare_stack is_ancestor is_bad_blob);
  28 use PublicInbox::OverIdx;
  29 use PublicInbox::MiscIdx;
  30 use PublicInbox::MID qw(mids);
  31 use PublicInbox::V2Writable;
  32 use PublicInbox::InboxWritable;
  33 use PublicInbox::ContentHash qw(content_hash);
  34 use PublicInbox::Eml;
  35 use PublicInbox::DS qw(now add_timer);
  36 use DBI qw(:sql_types); # SQL_BLOB
  37
  38 sub new {
  39         my (undef, $dir, $opt) = @_;
  40         my $l = $opt->{indexlevel} // 'full';
  41         $l !~ $PublicInbox::SearchIdx::INDEXLEVELS and
  42                 die "invalid indexlevel=$l\n";
  43         $l eq 'basic' and die "E: indexlevel=basic not yet supported\n";
  44         my $self = bless {
  45                 xpfx => "$dir/ei".PublicInbox::Search::SCHEMA_VERSION,
  46                 topdir => $dir,
  47                 creat => $opt->{creat},
  48                 ibx_map => {}, # (newsgroup//inboxdir) => $ibx
  49                 ibx_active => [], # by config section order
  50                 ibx_known => [], # by config section order
  51                 indexlevel => $l,
  52                 transact_bytes => 0,
  53                 total_bytes => 0,
  54                 current_info => '',
  55                 parallel => 1,
  56                 lock_path => "$dir/ei.lock",
  57         }, __PACKAGE__;
  58         $self->{shards} = $self->count_shards ||
  59                 nproc_shards({ nproc => $opt->{jobs} });
  60         my $oidx = PublicInbox::OverIdx->new("$self->{xpfx}/over.sqlite3");
  61         $self->{-no_fsync} = $oidx->{-no_fsync} = 1 if !$opt->{fsync};
  62         $self->{oidx} = $oidx;
  63         $self
  64 }
  65
  66 sub attach_inbox {
  67         my ($self, $ibx, $types) = @_;
  68         $self->{ibx_map}->{$ibx->eidx_key} //= do {
  69                 delete $self->{-ibx_ary_known}; # invalidate cache
  70                 delete $self->{-ibx_ary_active}; # invalidate cache
  71                 $types //= [ qw(active known) ];
  72                 for my $t (@$types) {
  73                         push @{$self->{"ibx_$t"}}, $ibx;
  74                 }
  75                 $ibx;
  76         }
  77 }
  78
  79 sub _ibx_attach { # each_inbox callback
  80         my ($ibx, $self, $types) = @_;
  81         attach_inbox($self, $ibx, $types);
  82 }
  83
  84 sub attach_config {
  85         my ($self, $cfg, $ibxs) = @_;
  86         $self->{cfg} = $cfg;
  87         my $types;
  88         if ($ibxs) {
  89                 for my $ibx (@$ibxs) {
  90                         $self->{ibx_map}->{$ibx->eidx_key} //= do {
  91                                 push @{$self->{ibx_active}}, $ibx;
  92                                 push @{$self->{ibx_known}}, $ibx;
  93                                 $ibx;
  94                         }
  95                 }
  96                 # invalidate cache
  97                 delete $self->{-ibx_ary_known};
  98                 delete $self->{-ibx_ary_active};
  99                 $types = [ 'known' ];
 100         }
 101         $types //= [ qw(known active) ];
 102         $cfg->each_inbox(\&_ibx_attach, $self, $types);
 103 }
 104
 105 sub check_batch_limit ($) {
 106         my ($req) = @_;
 107         my $self = $req->{self};
 108         my $new_smsg = $req->{new_smsg};
 109         my $n = $self->{transact_bytes} += $new_smsg->{bytes};
 110
 111         # set flag for PublicInbox::V2Writable::index_todo:
 112         ${$req->{need_checkpoint}} = 1 if $n >= $self->{batch_bytes};
 113 }
 114
 115 sub apply_boost ($$) {
 116         my ($req, $smsg) = @_;
 117         my $id2pos = $req->{id2pos}; # index in ibx_sorted
 118         my $xr3 = $req->{self}->{oidx}->get_xref3($smsg->{num}, 1);
 119         @$xr3 = sort {
 120                 $id2pos->{$a->[0]} <=> $id2pos->{$b->[0]}
 121                                 ||
 122                 $a->[1] <=> $b->[1] # break ties with {xnum}
 123         } @$xr3;
 124         my $new_smsg = $req->{new_smsg};
 125         return if $xr3->[0]->[2] ne $new_smsg->oidbin; # loser
 126
 127         # replace the old smsg with the more boosted one
 128         $new_smsg->{num} = $smsg->{num};
 129         $new_smsg->populate($req->{eml}, $req);
 130         $req->{self}->{oidx}->add_overview($req->{eml}, $new_smsg);
 131 }
 132
 133 sub remove_doc ($$) {
 134         my ($self, $docid) = @_;
 135         $self->{oidx}->delete_by_num($docid);
 136         $self->{oidx}->eidxq_del($docid);
 137         $self->idx_shard($docid)->ipc_do('xdb_remove', $docid);
 138 }
 139
 140 sub _unref_doc ($$$$$;$) {
 141         my ($sync, $docid, $ibx, $xnum, $oidbin, $eml) = @_;
 142         my $smsg;
 143         if (ref($docid)) {
 144                 $smsg = $docid;
 145                 $docid = $smsg->{num};
 146         }
 147         if (defined($oidbin) && defined($xnum) && blessed($ibx) && $ibx->over) {
 148                 my $smsg = $ibx->over->get_art($xnum);
 149                 if ($smsg && $smsg->oidbin eq $oidbin) {
 150                         carp("BUG: (non-fatal) ".$ibx->eidx_key.
 151                                 " #$xnum $smsg->{blob} still valid");
 152                         return;
 153                 }
 154         }
 155         my $s = 'DELETE FROM xref3 WHERE oidbin = ?';
 156         $s .= ' AND ibx_id = ?' if defined($ibx);
 157         $s .= ' AND xnum = ?' if defined($xnum);
 158         my $del = $sync->{self}->{oidx}->dbh->prepare_cached($s);
 159         my $col = 0;
 160         $del->bind_param(++$col, $oidbin, SQL_BLOB);
 161         $del->bind_param(++$col, $ibx->{-ibx_id}) if $ibx;
 162         $del->bind_param(++$col, $xnum) if defined($xnum);
 163         $del->execute;
 164         my $xr3 = $sync->{self}->{oidx}->get_xref3($docid);
 165         if (scalar(@$xr3) == 0) { # all gone
 166                 remove_doc($sync->{self}, $docid);
 167         } else { # enqueue for reindex of remaining messages
 168                 if ($ibx) {
 169                         my $ekey = $ibx->{-gc_eidx_key} // $ibx->eidx_key;
 170                         my $idx = $sync->{self}->idx_shard($docid);
 171                         $idx->ipc_do('remove_eidx_info', $docid, $ekey, $eml);
 172                 } # else: we can't remove_eidx_info in reindex-only path
 173
 174                 # replace invalidated blob ASAP with something which should be
 175                 # readable since we may commit the transaction on checkpoint.
 176                 # eidxq processing will re-apply boost
 177                 $smsg //= $sync->{self}->{oidx}->get_art($docid);
 178                 my $hex = unpack('H*', $oidbin);
 179                 if ($smsg && $smsg->{blob} eq $hex) {
 180                         $xr3->[0] =~ /:([a-f0-9]{40,}+)\z/ or
 181                                 die "BUG: xref $xr3->[0] has no OID";
 182                         $sync->{self}->{oidx}->update_blob($smsg, $1);
 183                 }
 184                 # yes, add, we'll need to re-apply boost
 185                 $sync->{self}->{oidx}->eidxq_add($docid);
 186         }
 187         @$xr3
 188 }
 189
 190 sub do_xpost ($$) {
 191         my ($req, $smsg) = @_;
 192         my $self = $req->{self};
 193         my $docid = $smsg->{num};
 194         my $oid = $req->{oid};
 195         my $xibx = $req->{ibx};
 196         my $eml = $req->{eml};
 197         if (my $new_smsg = $req->{new_smsg}) { # 'm' on cross-posted message
 198                 my $eidx_key = $xibx->eidx_key;
 199                 my $xnum = $req->{xnum};
 200                 $self->{oidx}->add_xref3($docid, $xnum, $oid, $eidx_key);
 201                 my $idx = $self->idx_shard($docid);
 202                 $idx->ipc_do('add_eidx_info', $docid, $eidx_key, $eml);
 203                 apply_boost($req, $smsg) if $req->{boost_in_use};
 204         } else { # 'd' no {xnum}
 205                 $self->git->async_wait_all;
 206                 $oid = pack('H*', $oid);
 207                 _unref_doc($req, $docid, $xibx, undef, $oid, $eml);
 208         }
 209 }
 210
 211 # called by V2Writable::sync_prepare
 212 sub artnum_max { $_[0]->{oidx}->eidx_max }
 213
 214 sub index_unseen ($) {
 215         my ($req) = @_;
 216         my $new_smsg = $req->{new_smsg} or die 'BUG: {new_smsg} unset';
 217         my $eml = delete $req->{eml};
 218         $new_smsg->populate($eml, $req);
 219         my $self = $req->{self};
 220         my $docid = $self->{oidx}->adj_counter('eidx_docid', '+');
 221         $new_smsg->{num} = $docid;
 222         my $idx = $self->idx_shard($docid);
 223         $self->{oidx}->add_overview($eml, $new_smsg);
 224         my $oid = $new_smsg->{blob};
 225         my $ibx = delete $req->{ibx} or die 'BUG: {ibx} unset';
 226         $self->{oidx}->add_xref3($docid, $req->{xnum}, $oid, $ibx->eidx_key);
 227         $idx->index_eml($eml, $new_smsg, $ibx->eidx_key);
 228         check_batch_limit($req);
 229 }
 230
 231 sub do_finalize ($) {
 232         my ($req) = @_;
 233         if (my $indexed = $req->{indexed}) { # duplicated messages
 234                 do_xpost($req, $_) for @$indexed;
 235         } elsif (exists $req->{new_smsg}) { # totally unseen messsage
 236                 index_unseen($req);
 237         } else {
 238                 # `d' message was already unindexed in the v1/v2 inboxes,
 239                 # so it's too noisy to warn, here.
 240         }
 241         # cur_cmt may be undef for unindex_oid, set by V2Writable::index_todo
 242         if (defined(my $cur_cmt = $req->{cur_cmt})) {
 243                 ${$req->{latest_cmt}} = $cur_cmt;
 244         }
 245 }
 246
 247 sub do_step ($) { # main iterator for adding messages to the index
 248         my ($req) = @_;
 249         my $self = $req->{self} // die 'BUG: {self} missing';
 250         while (1) {
 251                 if (my $next_arg = $req->{next_arg}) {
 252                         if (my $smsg = $self->{oidx}->next_by_mid(@$next_arg)) {
 253                                 $req->{cur_smsg} = $smsg;
 254                                 $self->git->cat_async($smsg->{blob},
 255                                                         \&ck_existing, $req);
 256                                 return; # ck_existing calls do_step
 257                         }
 258                         delete $req->{next_arg};
 259                 }
 260                 die "BUG: {cur_smsg} still set" if $req->{cur_smsg};
 261                 my $mid = shift(@{$req->{mids}}) // last;
 262                 my ($id, $prev);
 263                 $req->{next_arg} = [ $mid, \$id, \$prev ];
 264                 # loop again
 265         }
 266         do_finalize($req);
 267 }
 268
 269 sub _blob_missing ($$) { # called when a known $smsg->{blob} is gone
 270         my ($req, $smsg) = @_;
 271         # xnum and ibx are unknown, we only call this when an entry from
 272         # /ei*/over.sqlite3 is bad, not on entries from xap*/over.sqlite3
 273         $req->{self}->git->async_wait_all;
 274         _unref_doc($req, $smsg, undef, undef, $smsg->oidbin);
 275 }
 276
 277 sub ck_existing { # git->cat_async callback
 278         my ($bref, $oid, $type, $size, $req) = @_;
 279         my $smsg = delete $req->{cur_smsg} or die 'BUG: {cur_smsg} missing';
 280         if ($type eq 'missing') {
 281                 _blob_missing($req, $smsg);
 282         } elsif (!is_bad_blob($oid, $type, $size, $smsg->{blob})) {
 283                 my $self = $req->{self} // die 'BUG: {self} missing';
 284                 local $self->{current_info} = "$self->{current_info} $oid";
 285                 my $cur = PublicInbox::Eml->new($bref);
 286                 if (content_hash($cur) eq $req->{chash}) {
 287                         push @{$req->{indexed}}, $smsg; # for do_xpost
 288                 } # else { index_unseen later }
 289         }
 290         do_step($req);
 291 }
 292
 293 # is the messages visible in the inbox currently being indexed?
 294 # return the number if so
 295 sub cur_ibx_xnum ($$) {
 296         my ($req, $bref) = @_;
 297         my $ibx = $req->{ibx} or die 'BUG: current {ibx} missing';
 298
 299         $req->{eml} = PublicInbox::Eml->new($bref);
 300         $req->{chash} = content_hash($req->{eml});
 301         $req->{mids} = mids($req->{eml});
 302         for my $mid (@{$req->{mids}}) {
 303                 my ($id, $prev);
 304                 while (my $x = $ibx->over->next_by_mid($mid, \$id, \$prev)) {
 305                         return $x->{num} if $x->{blob} eq $req->{oid};
 306                 }
 307         }
 308         undef;
 309 }
 310
 311 sub index_oid { # git->cat_async callback for 'm'
 312         my ($bref, $oid, $type, $size, $req) = @_;
 313         my $self = $req->{self};
 314         local $self->{current_info} = "$self->{current_info} $oid";
 315         return if is_bad_blob($oid, $type, $size, $req->{oid});
 316         my $new_smsg = $req->{new_smsg} = bless {
 317                 blob => $oid,
 318         }, 'PublicInbox::Smsg';
 319         $new_smsg->set_bytes($$bref, $size);
 320         defined($req->{xnum} = cur_ibx_xnum($req, $bref)) or return;
 321         ++${$req->{nr}};
 322         do_step($req);
 323 }
 324
 325 sub unindex_oid { # git->cat_async callback for 'd'
 326         my ($bref, $oid, $type, $size, $req) = @_;
 327         my $self = $req->{self};
 328         local $self->{current_info} = "$self->{current_info} $oid";
 329         return if is_bad_blob($oid, $type, $size, $req->{oid});
 330         return if defined(cur_ibx_xnum($req, $bref)); # was re-added
 331         do_step($req);
 332 }
 333
 334 # overrides V2Writable::last_commits, called by sync_ranges via sync_prepare
 335 sub last_commits {
 336         my ($self, $sync) = @_;
 337         my $heads = [];
 338         my $ekey = $sync->{ibx}->eidx_key;
 339         my $uv = $sync->{ibx}->uidvalidity;
 340         for my $i (0..$sync->{epoch_max}) {
 341                 $heads->[$i] = $self->{oidx}->eidx_meta("lc-v2:$ekey//$uv;$i");
 342         }
 343         $heads;
 344 }
 345
 346 sub _ibx_index_reject ($) {
 347         my ($ibx) = @_;
 348         $ibx->mm // return 'unindexed, no msgmap.sqlite3';
 349         $ibx->uidvalidity // return 'no UIDVALIDITY';
 350         $ibx->over // return 'unindexed, no over.sqlite3';
 351         undef;
 352 }
 353
 354 sub _sync_inbox ($$$) {
 355         my ($self, $sync, $ibx) = @_;
 356         my $ekey = $ibx->eidx_key;
 357         if (defined(my $err = _ibx_index_reject($ibx))) {
 358                 return "W: skipping $ekey ($err)";
 359         }
 360         $sync->{ibx} = $ibx;
 361         $sync->{nr} = \(my $nr = 0);
 362         my $v = $ibx->version;
 363         if ($v == 2) {
 364                 $sync->{epoch_max} = $ibx->max_git_epoch // return;
 365                 sync_prepare($self, $sync); # or return # TODO: once MiscIdx is stable
 366         } elsif ($v == 1) {
 367                 my $uv = $ibx->uidvalidity;
 368                 my $lc = $self->{oidx}->eidx_meta("lc-v1:$ekey//$uv");
 369                 my $head = $ibx->mm->last_commit //
 370                         return "E: $ibx->{inboxdir} is not indexed";
 371                 my $stk = prepare_stack($sync, $lc ? "$lc..$head" : $head);
 372                 my $unit = { stack => $stk, git => $ibx->git };
 373                 push @{$sync->{todo}}, $unit;
 374         } else {
 375                 return "E: $ekey unsupported inbox version (v$v)";
 376         }
 377         for my $unit (@{delete($sync->{todo}) // []}) {
 378                 last if $sync->{quit};
 379                 index_todo($self, $sync, $unit);
 380         }
 381         $self->{midx}->index_ibx($ibx) unless $sync->{quit};
 382         $ibx->git->cleanup; # done with this inbox, now
 383         undef;
 384 }
 385
 386 sub eidx_gc_scan_inboxes ($$) {
 387         my ($self, $sync) = @_;
 388         my ($x3_doc, $ibx_ck);
 389 restart:
 390         $x3_doc = $self->{oidx}->dbh->prepare(<<EOM);
 391 SELECT docid,xnum,oidbin FROM xref3 WHERE ibx_id = ?
 392 EOM
 393         $ibx_ck = $self->{oidx}->dbh->prepare(<<EOM);
 394 SELECT ibx_id,eidx_key FROM inboxes
 395 EOM
 396         $ibx_ck->execute;
 397         while (my ($ibx_id, $eidx_key) = $ibx_ck->fetchrow_array) {
 398                 next if $self->{ibx_map}->{$eidx_key};
 399                 $self->{midx}->remove_eidx_key($eidx_key);
 400                 warn "I: deleting messages for $eidx_key...\n";
 401                 $x3_doc->execute($ibx_id);
 402                 my $ibx = { -ibx_id => $ibx_id, -gc_eidx_key => $eidx_key };
 403                 while (my ($docid, $xnum, $oid) = $x3_doc->fetchrow_array) {
 404                         my $r = _unref_doc($sync, $docid, $ibx, $xnum, $oid);
 405                         $oid = unpack('H*', $oid);
 406                         $r = $r ? 'unref' : 'remove';
 407                         warn "I: $r #$docid $eidx_key $oid\n";
 408                         if (checkpoint_due($sync)) {
 409                                 $x3_doc = $ibx_ck = undef;
 410                                 reindex_checkpoint($self, $sync);
 411                                 goto restart;
 412                         }
 413                 }
 414                 $self->{oidx}->dbh->do(<<'', undef, $ibx_id);
 415 DELETE FROM inboxes WHERE ibx_id = ?
 416
 417                 # drop last_commit info
 418                 my $pat = $eidx_key;
 419                 $pat =~ s/([_%\\])/\\$1/g;
 420                 $self->{oidx}->dbh->do('PRAGMA case_sensitive_like = ON');
 421                 my $lc_i = $self->{oidx}->dbh->prepare(<<'');
 422 SELECT key FROM eidx_meta WHERE key LIKE ? ESCAPE ?
 423
 424                 $lc_i->execute("lc-%:$pat//%", '\\');
 425                 while (my ($key) = $lc_i->fetchrow_array) {
 426                         next if $key !~ m!\Alc-v[1-9]+:\Q$eidx_key\E//!;
 427                         warn "I: removing $key\n";
 428                         $self->{oidx}->dbh->do(<<'', undef, $key);
 429 DELETE FROM eidx_meta WHERE key = ?
 430
 431                 }
 432                 warn "I: $eidx_key removed\n";
 433         }
 434 }
 435
 436 sub eidx_gc_scan_shards ($$) { # TODO: use for lei/store
 437         my ($self, $sync) = @_;
 438         my $nr = $self->{oidx}->dbh->do(<<'');
 439 DELETE FROM xref3 WHERE docid NOT IN (SELECT num FROM over)
 440
 441         warn "I: eliminated $nr stale xref3 entries\n" if $nr != 0;
 442         reindex_checkpoint($self, $sync) if checkpoint_due($sync);
 443
 444         # fixup from old bugs:
 445         $nr = $self->{oidx}->dbh->do(<<'');
 446 DELETE FROM over WHERE num > 0 AND num NOT IN (SELECT docid FROM xref3)
 447
 448         warn "I: eliminated $nr stale over entries\n" if $nr != 0;
 449         reindex_checkpoint($self, $sync) if checkpoint_due($sync);
 450
 451         $nr = $self->{oidx}->dbh->do(<<'');
 452 DELETE FROM eidxq WHERE docid NOT IN (SELECT num FROM over)
 453
 454         warn "I: eliminated $nr stale reindex queue entries\n" if $nr != 0;
 455         reindex_checkpoint($self, $sync) if checkpoint_due($sync);
 456
 457         my ($cur) = $self->{oidx}->dbh->selectrow_array(<<EOM);
 458 SELECT MIN(num) FROM over WHERE num > 0
 459 EOM
 460         $cur // return; # empty
 461         my ($r, $n, %active_shards);
 462         $nr = 0;
 463         while (1) {
 464                 $r = $self->{oidx}->dbh->selectcol_arrayref(<<"", undef, $cur);
 465 SELECT num FROM over WHERE num >= ? ORDER BY num ASC LIMIT 10000
 466
 467                 last unless scalar(@$r);
 468                 while (defined($n = shift @$r)) {
 469                         for my $i ($cur..($n - 1)) {
 470                                 my $idx = idx_shard($self, $i);
 471                                 $idx->ipc_do('xdb_remove_quiet', $i);
 472                                 $active_shards{$idx} = $idx;
 473                         }
 474                         $cur = $n + 1;
 475                 }
 476                 if (checkpoint_due($sync)) {
 477                         for my $idx (values %active_shards) {
 478                                 $nr += $idx->ipc_do('nr_quiet_rm')
 479                         }
 480                         %active_shards = ();
 481                         reindex_checkpoint($self, $sync);
 482                 }
 483         }
 484         warn "I: eliminated $nr stale Xapian documents\n" if $nr != 0;
 485 }
 486
 487 sub eidx_gc {
 488         my ($self, $opt) = @_;
 489         $self->{cfg} or die "E: GC requires ->attach_config\n";
 490         $opt->{-idx_gc} = 1;
 491         my $sync = {
 492                 need_checkpoint => \(my $need_checkpoint = 0),
 493                 check_intvl => 10,
 494                 next_check => now() + 10,
 495                 checkpoint_unlocks => 1,
 496                 -opt => $opt,
 497                 self => $self,
 498         };
 499         $self->idx_init($opt); # acquire lock via V2Writable::_idx_init
 500         eidx_gc_scan_inboxes($self, $sync);
 501         eidx_gc_scan_shards($self, $sync);
 502         done($self);
 503 }
 504
 505 sub _ibx_for ($$$) {
 506         my ($self, $sync, $smsg) = @_;
 507         my $ibx_id = delete($smsg->{ibx_id}) // die '{ibx_id} unset';
 508         my $pos = $sync->{id2pos}->{$ibx_id} // die "$ibx_id no pos";
 509         $self->{-ibx_ary_known}->[$pos] //
 510                 die "BUG: ibx for $smsg->{blob} not mapped"
 511 }
 512
 513 sub _fd_constrained ($) {
 514         my ($self) = @_;
 515         $self->{-fd_constrained} //= do {
 516                 my $soft;
 517                 if (eval { require BSD::Resource; 1 }) {
 518                         my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 519                         ($soft, undef) = BSD::Resource::getrlimit($NOFILE);
 520                 } else {
 521                         chomp($soft = `sh -c 'ulimit -n'`);
 522                 }
 523                 if (defined($soft)) {
 524                         # $want is an estimate
 525                         my $want = scalar(@{$self->{ibx_active}}) + 64;
 526                         my $ret = $want > $soft;
 527                         if ($ret) {
 528                                 warn <<EOF;
 529 RLIMIT_NOFILE=$soft insufficient (want: $want), will close DB handles early
 530 EOF
 531                         }
 532                         $ret;
 533                 } else {
 534                         warn "Unable to determine RLIMIT_NOFILE: $@\n";
 535                         1;
 536                 }
 537         };
 538 }
 539
 540 sub _reindex_finalize ($$$) {
 541         my ($req, $smsg, $eml) = @_;
 542         my $sync = $req->{sync};
 543         my $self = $sync->{self};
 544         my $by_chash = delete $req->{by_chash} or die 'BUG: no {by_chash}';
 545         my $nr = scalar(keys(%$by_chash)) or die 'BUG: no content hashes';
 546         my $orig_smsg = $req->{orig_smsg} // die 'BUG: no {orig_smsg}';
 547         my $docid = $smsg->{num} = $orig_smsg->{num};
 548         $self->{oidx}->add_overview($eml, $smsg); # may rethread
 549         check_batch_limit({ %$sync, new_smsg => $smsg });
 550         my $chash0 = $smsg->{chash} // die "BUG: $smsg->{blob} no {chash}";
 551         my $stable = delete($by_chash->{$chash0}) //
 552                                 die "BUG: $smsg->{blob} chash missing";
 553         my $idx = $self->idx_shard($docid);
 554         my $top_smsg = pop @$stable;
 555         $top_smsg == $smsg or die 'BUG: top_smsg != smsg';
 556         my $ibx = _ibx_for($self, $sync, $smsg);
 557         $idx->index_eml($eml, $smsg, $ibx->eidx_key);
 558         for my $x (reverse @$stable) {
 559                 $ibx = _ibx_for($self, $sync, $x);
 560                 my $hdr = delete $x->{hdr} // die 'BUG: no {hdr}';
 561                 $idx->ipc_do('add_eidx_info', $docid, $ibx->eidx_key, $hdr);
 562         }
 563         return if $nr == 1; # likely, all good
 564
 565         $self->git->async_wait_all;
 566         warn "W: #$docid split into $nr due to deduplication change\n";
 567         my @todo;
 568         for my $ary (values %$by_chash) {
 569                 for my $x (reverse @$ary) {
 570                         warn "removing #$docid xref3 $x->{blob}\n";
 571                         my $bin = $x->oidbin;
 572                         my $n = _unref_doc($sync, $docid, undef, undef, $bin);
 573                         die "BUG: $x->{blob} invalidated #$docid" if $n == 0;
 574                 }
 575                 my $x = pop(@$ary) // die "BUG: #$docid {by_chash} empty";
 576                 $x->{num} = delete($x->{xnum}) // die '{xnum} unset';
 577                 $ibx = _ibx_for($self, $sync, $x);
 578                 if (my $over = $ibx->over) {
 579                         my $e = $over->get_art($x->{num});
 580                         $e->{blob} eq $x->{blob} or die <<EOF;
 581 $x->{blob} != $e->{blob} (${\$ibx->eidx_key}:$e->{num});
 582 EOF
 583                         push @todo, $ibx, $e;
 584                         $over->dbh_close if _fd_constrained($self);
 585                 } else {
 586                         die "$ibx->{inboxdir}: over.sqlite3 unusable: $!\n";
 587                 }
 588         }
 589         undef $by_chash;
 590         while (my ($ibx, $e) = splice(@todo, 0, 2)) {
 591                 reindex_unseen($self, $sync, $ibx, $e);
 592         }
 593 }
 594
 595 sub _reindex_oid { # git->cat_async callback
 596         my ($bref, $oid, $type, $size, $req) = @_;
 597         my $sync = $req->{sync};
 598         my $self = $sync->{self};
 599         my $orig_smsg = $req->{orig_smsg} // die 'BUG: no {orig_smsg}';
 600         my $expect_oid = $req->{xr3r}->[$req->{ix}]->[2];
 601         my $docid = $orig_smsg->{num};
 602         if (is_bad_blob($oid, $type, $size, $expect_oid)) {
 603                 my $oidbin = pack('H*', $expect_oid);
 604                 my $remain = _unref_doc($sync, $docid, undef, undef, $oidbin);
 605                 if ($remain == 0) {
 606                         warn "W: #$docid ($oid) gone or corrupt\n";
 607                 } elsif (my $next_oid = $req->{xr3r}->[++$req->{ix}]->[2]) {
 608                         $self->git->cat_async($next_oid, \&_reindex_oid, $req);
 609                 } else {
 610                         warn "BUG: #$docid ($oid) gone (UNEXPECTED)\n";
 611                 }
 612                 return;
 613         }
 614         my $ci = $self->{current_info};
 615         local $self->{current_info} = "$ci #$docid $oid";
 616         my $re_smsg = bless { blob => $oid }, 'PublicInbox::Smsg';
 617         $re_smsg->set_bytes($$bref, $size);
 618         my $eml = PublicInbox::Eml->new($bref);
 619         $re_smsg->populate($eml, { autime => $orig_smsg->{ds},
 620                                 cotime => $orig_smsg->{ts} });
 621         my $chash = content_hash($eml);
 622         $re_smsg->{chash} = $chash;
 623         $re_smsg->{xnum} = $req->{xr3r}->[$req->{ix}]->[1];
 624         $re_smsg->{ibx_id} = $req->{xr3r}->[$req->{ix}]->[0];
 625         $re_smsg->{hdr} = $eml->header_obj;
 626         push @{$req->{by_chash}->{$chash}}, $re_smsg;
 627         if (my $next_oid = $req->{xr3r}->[++$req->{ix}]->[2]) {
 628                 $self->git->cat_async($next_oid, \&_reindex_oid, $req);
 629         } else { # last $re_smsg is the highest priority xref3
 630                 local $self->{current_info} = "$ci #$docid";
 631                 _reindex_finalize($req, $re_smsg, $eml);
 632         }
 633 }
 634
 635 sub _reindex_smsg ($$$) {
 636         my ($self, $sync, $smsg) = @_;
 637         my $docid = $smsg->{num};
 638         my $xr3 = $self->{oidx}->get_xref3($docid, 1);
 639         if (scalar(@$xr3) == 0) { # _reindex_check_stale should've covered this
 640                 warn <<"";
 641 BUG? #$docid $smsg->{blob} is not referenced by inboxes during reindex
 642
 643                 remove_doc($self, $docid);
 644                 return;
 645         }
 646
 647         # we sort {xr3r} in the reverse order of ibx_sorted so we can
 648         # hit the common case in _reindex_finalize without rereading
 649         # from git (or holding multiple messages in memory).
 650         my $id2pos = $sync->{id2pos}; # index in ibx_sorted
 651         @$xr3 = sort {
 652                 $id2pos->{$b->[0]} <=> $id2pos->{$a->[0]}
 653                                 ||
 654                 $b->[1] <=> $a->[1] # break ties with {xnum}
 655         } @$xr3;
 656         @$xr3 = map { [ $_->[0], $_->[1], unpack('H*', $_->[2]) ] } @$xr3;
 657         my $req = { orig_smsg => $smsg, sync => $sync, xr3r => $xr3, ix => 0 };
 658         $self->git->cat_async($xr3->[$req->{ix}]->[2], \&_reindex_oid, $req);
 659 }
 660
 661 sub checkpoint_due ($) {
 662         my ($sync) = @_;
 663         ${$sync->{need_checkpoint}} || (now() > $sync->{next_check});
 664 }
 665
 666 sub host_ident () {
 667         # I've copied FS images and only changed the hostname before,
 668         # so prepend hostname.  Use `state' since these a BOFH can change
 669         # these while this process is running and we always want to be
 670         # able to release locks taken by this process.
 671         state $retval = hostname . '-' . do {
 672                 my $m; # machine-id(5) is systemd
 673                 if (open(my $fh, '<', '/etc/machine-id')) { $m = <$fh> }
 674                 # (g)hostid(1) is in GNU coreutils, kern.hostid is most BSDs
 675                 chomp($m ||= `{ sysctl -n kern.hostid ||
 676                                 hostid || ghostid; } 2>/dev/null`
 677                         || "no-machine-id-or-hostid-on-$^O");
 678                 $m;
 679         };
 680 }
 681
 682 sub eidxq_release {
 683         my ($self) = @_;
 684         my $expect = delete($self->{-eidxq_locked}) or return;
 685         my ($owner_pid, undef) = split(/-/, $expect);
 686         return if $owner_pid != $$; # shards may fork
 687         my $oidx = $self->{oidx};
 688         $oidx->begin_lazy;
 689         my $cur = $oidx->eidx_meta('eidxq_lock') // '';
 690         if ($cur eq $expect) {
 691                 $oidx->eidx_meta('eidxq_lock', '');
 692                 return 1;
 693         } elsif ($cur ne '') {
 694                 warn "E: eidxq_lock($expect) stolen by $cur\n";
 695         } else {
 696                 warn "E: eidxq_lock($expect) released by another process\n";
 697         }
 698         undef;
 699 }
 700
 701 sub DESTROY {
 702         my ($self) = @_;
 703         eidxq_release($self) and $self->{oidx}->commit_lazy;
 704 }
 705
 706 sub _eidxq_take ($) {
 707         my ($self) = @_;
 708         my $val = "$$-${\time}-$>-".host_ident;
 709         $self->{oidx}->eidx_meta('eidxq_lock', $val);
 710         $self->{-eidxq_locked} = $val;
 711 }
 712
 713 sub eidxq_lock_acquire ($) {
 714         my ($self) = @_;
 715         my $oidx = $self->{oidx};
 716         $oidx->begin_lazy;
 717         my $cur = $oidx->eidx_meta('eidxq_lock') || return _eidxq_take($self);
 718         if (my $locked = $self->{-eidxq_locked}) { # be lazy
 719                 return $locked if $locked eq $cur;
 720         }
 721         my ($pid, $time, $euid, $ident) = split(/-/, $cur, 4);
 722         my $t = strftime('%Y-%m-%d %k:%M:%S', gmtime($time));
 723         if ($euid == $> && $ident eq host_ident) {
 724                 if (kill(0, $pid)) {
 725                         warn <<EOM; return;
 726 I: PID:$pid (re)indexing Xapian since $t, it will continue our work
 727 EOM
 728                 }
 729                 if ($!{ESRCH}) {
 730                         warn "I: eidxq_lock is stale ($cur), clobbering\n";
 731                         return _eidxq_take($self);
 732                 }
 733                 warn "E: kill(0, $pid) failed: $!\n"; # fall-through:
 734         }
 735         my $fn = $oidx->dbh->sqlite_db_filename;
 736         warn <<EOF;
 737 W: PID:$pid, UID:$euid on $ident is indexing Xapian since $t
 738 W: If this is unexpected, delete `eidxq_lock' from the `eidx_meta' table:
 739 W:      sqlite3 $fn 'DELETE FROM eidx_meta WHERE key = "eidxq_lock"'
 740 EOF
 741         undef;
 742 }
 743
 744 sub ibx_sorted ($$) {
 745         my ($self, $type) = @_;
 746         $self->{"-ibx_ary_$type"} //= do {
 747                 # highest boost first, stable for config-ordering tiebreaker
 748                 use sort 'stable';
 749                 [ sort {
 750                         ($b->{boost} // 0) <=> ($a->{boost} // 0)
 751                   } @{$self->{'ibx_'.$type} // die "BUG: $type unknown"} ];
 752         }
 753 }
 754
 755 sub prep_id2pos ($) {
 756         my ($self) = @_;
 757         my %id2pos;
 758         my $pos = 0;
 759         $id2pos{$_->{-ibx_id}} = $pos++ for (@{ibx_sorted($self, 'known')});
 760         \%id2pos;
 761 }
 762
 763 sub eidxq_process ($$) { # for reindexing
 764         my ($self, $sync) = @_;
 765         local $self->{current_info} = 'eidxq process';
 766         return unless ($self->{cfg} && eidxq_lock_acquire($self));
 767         my $dbh = $self->{oidx}->dbh;
 768         my $tot = $dbh->selectrow_array('SELECT COUNT(*) FROM eidxq') or return;
 769         ${$sync->{nr}} = 0;
 770         local $sync->{-regen_fmt} = "%u/$tot\n";
 771         my $pr = $sync->{-opt}->{-progress};
 772         if ($pr) {
 773                 my $min = $dbh->selectrow_array('SELECT MIN(docid) FROM eidxq');
 774                 my $max = $dbh->selectrow_array('SELECT MAX(docid) FROM eidxq');
 775                 $pr->("Xapian indexing $min..$max (total=$tot)\n");
 776         }
 777         $sync->{id2pos} //= prep_id2pos($self);
 778         my ($del, $iter);
 779 restart:
 780         $del = $dbh->prepare('DELETE FROM eidxq WHERE docid = ?');
 781         $iter = $dbh->prepare('SELECT docid FROM eidxq ORDER BY docid ASC');
 782         $iter->execute;
 783         while (defined(my $docid = $iter->fetchrow_array)) {
 784                 last if $sync->{quit};
 785                 if (my $smsg = $self->{oidx}->get_art($docid)) {
 786                         _reindex_smsg($self, $sync, $smsg);
 787                 } else {
 788                         warn "E: #$docid does not exist in over\n";
 789                 }
 790                 $del->execute($docid);
 791                 ++${$sync->{nr}};
 792
 793                 if (checkpoint_due($sync)) {
 794                         $dbh = $del = $iter = undef;
 795                         reindex_checkpoint($self, $sync); # release lock
 796                         $dbh = $self->{oidx}->dbh;
 797                         goto restart;
 798                 }
 799         }
 800         $self->git->async_wait_all;
 801         $pr->("reindexed ${$sync->{nr}}/$tot\n") if $pr;
 802 }
 803
 804 sub _reindex_unseen { # git->cat_async callback
 805         my ($bref, $oid, $type, $size, $req) = @_;
 806         return if is_bad_blob($oid, $type, $size, $req->{oid});
 807         my $self = $req->{self} // die 'BUG: {self} unset';
 808         local $self->{current_info} = "$self->{current_info} $oid";
 809         my $new_smsg = bless { blob => $oid, }, 'PublicInbox::Smsg';
 810         $new_smsg->set_bytes($$bref, $size);
 811         my $eml = $req->{eml} = PublicInbox::Eml->new($bref);
 812         $req->{new_smsg} = $new_smsg;
 813         $req->{chash} = content_hash($eml);
 814         $req->{mids} = mids($eml); # do_step iterates through this
 815         do_step($req); # enter the normal indexing flow
 816 }
 817
 818 # --reindex may catch totally unseen messages, this handles them
 819 sub reindex_unseen ($$$$) {
 820         my ($self, $sync, $ibx, $xsmsg) = @_;
 821         my $req = {
 822                 %$sync, # has {self}
 823                 autime => $xsmsg->{ds},
 824                 cotime => $xsmsg->{ts},
 825                 oid => $xsmsg->{blob},
 826                 ibx => $ibx,
 827                 xnum => $xsmsg->{num},
 828                 # {mids} and {chash} will be filled in at _reindex_unseen
 829         };
 830         warn "I: reindex_unseen ${\$ibx->eidx_key}:$req->{xnum}:$req->{oid}\n";
 831         $self->git->cat_async($xsmsg->{blob}, \&_reindex_unseen, $req);
 832 }
 833
 834 sub _unref_stale_range ($$$) {
 835         my ($sync, $ibx, $lt_or_gt) = @_;
 836         my $r;
 837         my $lim = 10000;
 838         do {
 839                 $r = $sync->{self}->{oidx}->dbh->selectall_arrayref(
 840                         <<EOS, undef, $ibx->{-ibx_id});
 841 SELECT docid,xnum,oidbin FROM xref3
 842 WHERE ibx_id = ? AND xnum $lt_or_gt LIMIT $lim
 843 EOS
 844                 return if $sync->{quit};
 845                 for (@$r) { # hopefully rare, not worth optimizing:
 846                         my ($docid, $xnum, $oidbin) = @$_;
 847                         my $hex = unpack('H*', $oidbin);
 848                         warn("# $xnum:$hex (#$docid): stale\n");
 849                         _unref_doc($sync, $docid, $ibx, $xnum, $oidbin);
 850                 }
 851         } while (scalar(@$r) == $lim);
 852         1;
 853 }
 854
 855 sub _reindex_check_ibx ($$$) {
 856         my ($self, $sync, $ibx) = @_;
 857         my $ibx_id = $ibx->{-ibx_id};
 858         my $slice = 10000;
 859         my $opt = { limit => $slice };
 860         my ($beg, $end) = (1, $slice);
 861         my $err = sync_inbox($self, $sync, $ibx) and return;
 862         my $max = $ibx->over->max;
 863         $end = $max if $end > $max;
 864
 865         # first, check if we missed any messages in target $ibx
 866         my $msgs;
 867         my $pr = $sync->{-opt}->{-progress};
 868         my $ekey = $ibx->eidx_key;
 869         local $sync->{-regen_fmt} = "$ekey checking %u/$max\n";
 870         ${$sync->{nr}} = 0;
 871         my $fast = $sync->{-opt}->{fast};
 872         my $dsu; # _unref_stale_range (< $lo) called
 873         my ($lo, $hi);
 874         while (scalar(@{$msgs = $ibx->over->query_xover($beg, $end, $opt)})) {
 875                 ${$sync->{nr}} = $beg;
 876                 $beg = $msgs->[-1]->{num} + 1;
 877                 $end = $beg + $slice;
 878                 $end = $max if $end > $max;
 879                 if (checkpoint_due($sync)) {
 880                         reindex_checkpoint($self, $sync); # release lock
 881                 }
 882                 ($lo, $hi) = ($msgs->[0]->{num}, $msgs->[-1]->{num});
 883                 $dsu //= _unref_stale_range($sync, $ibx, "< $lo");
 884                 my $x3a = $self->{oidx}->dbh->selectall_arrayref(
 885                         <<"", undef, $ibx_id, $lo, $hi);
 886 SELECT xnum,oidbin,docid FROM xref3 WHERE
 887 ibx_id = ? AND xnum >= ? AND xnum <= ?
 888
 889                 my %x3m;
 890                 for (@$x3a) {
 891                         my $k = pack('J', $_->[0]) . $_->[1];
 892                         push @{$x3m{$k}}, $_->[2];
 893                 }
 894                 undef $x3a;
 895                 for my $xsmsg (@$msgs) {
 896                         my $k = pack('JH*', $xsmsg->{num}, $xsmsg->{blob});
 897                         my $docids = delete($x3m{$k});
 898                         if (!defined($docids)) {
 899                                 reindex_unseen($self, $sync, $ibx, $xsmsg);
 900                         } elsif (!$fast) {
 901                                 for my $num (@$docids) {
 902                                         $self->{oidx}->eidxq_add($num);
 903                                 }
 904                                 return if $sync->{quit};
 905                         }
 906                 }
 907                 return if $sync->{quit};
 908                 next unless scalar keys %x3m;
 909                 $self->git->async_wait_all; # wait for reindex_unseen
 910
 911                 # eliminate stale/mismatched entries
 912                 my %mismatch = map { $_->{num} => $_->{blob} } @$msgs;
 913                 while (my ($k, $docids) = each %x3m) {
 914                         my ($xnum, $hex) = unpack('JH*', $k);
 915                         my $bin = pack('H*', $hex);
 916                         my $exp = $mismatch{$xnum};
 917                         my $m = defined($exp) ? "mismatch (!= $exp)" : 'stale';
 918                         warn("# $xnum:$hex (#@$docids): $m\n");
 919                         for my $i (@$docids) {
 920                                 _unref_doc($sync, $i, $ibx, $xnum, $bin);
 921                         }
 922                 }
 923         }
 924         _unref_stale_range($sync, $ibx, "> $hi") if defined($hi);
 925 }
 926
 927 sub _reindex_inbox ($$$) {
 928         my ($self, $sync, $ibx) = @_;
 929         my $ekey = $ibx->eidx_key;
 930         local $self->{current_info} = $ekey;
 931         if (defined(my $err = _ibx_index_reject($ibx))) {
 932                 warn "W: cannot reindex $ekey ($err)\n";
 933         } else {
 934                 _reindex_check_ibx($self, $sync, $ibx);
 935         }
 936         delete @$ibx{qw(over mm search git)}; # won't need these for a bit
 937 }
 938
 939 sub eidx_reindex {
 940         my ($self, $sync) = @_;
 941         return unless $self->{cfg};
 942
 943         # acquire eidxq_lock early because full reindex takes forever
 944         # and incremental -extindex processes can run during our checkpoints
 945         if (!eidxq_lock_acquire($self)) {
 946                 warn "E: aborting --reindex\n";
 947                 return;
 948         }
 949         for my $ibx (@{ibx_sorted($self, 'active')}) {
 950                 _reindex_inbox($self, $sync, $ibx);
 951                 last if $sync->{quit};
 952         }
 953         $self->git->async_wait_all; # ensure eidxq gets filled completely
 954         eidxq_process($self, $sync) unless $sync->{quit};
 955 }
 956
 957 sub sync_inbox {
 958         my ($self, $sync, $ibx) = @_;
 959         my $err = _sync_inbox($self, $sync, $ibx);
 960         delete @$ibx{qw(mm over)};
 961         warn $err, "\n" if defined($err);
 962         $err;
 963 }
 964
 965 sub dd_smsg { # git->cat_async callback
 966         my ($bref, $oid, $type, $size, $dd) = @_;
 967         my $smsg = $dd->{smsg} // die 'BUG: dd->{smsg} missing';
 968         my $self = $dd->{self} // die 'BUG: {self} missing';
 969         my $per_mid = $dd->{per_mid} // die 'BUG: {per_mid} missing';
 970         if ($type eq 'missing') {
 971                 _blob_missing($dd, $smsg);
 972         } elsif (!is_bad_blob($oid, $type, $size, $smsg->{blob})) {
 973                 local $self->{current_info} = "$self->{current_info} $oid";
 974                 my $chash = content_hash(PublicInbox::Eml->new($bref));
 975                 push(@{$per_mid->{dd_chash}->{$chash}}, $smsg);
 976         }
 977         return if $per_mid->{last_smsg} != $smsg;
 978         while (my ($chash, $ary) = each %{$per_mid->{dd_chash}}) {
 979                 my $keep = shift @$ary;
 980                 next if !scalar(@$ary);
 981                 $per_mid->{sync}->{dedupe_cull} += scalar(@$ary);
 982                 print STDERR
 983                         "# <$keep->{mid}> keeping #$keep->{num}, dropping ",
 984                         join(', ', map { "#$_->{num}" } @$ary),"\n";
 985                 next if $per_mid->{sync}->{-opt}->{'dry-run'};
 986                 my $oidx = $self->{oidx};
 987                 for my $smsg (@$ary) {
 988                         my $gone = $smsg->{num};
 989                         $oidx->merge_xref3($keep->{num}, $gone, $smsg->oidbin);
 990                         remove_doc($self, $gone);
 991                 }
 992         }
 993 }
 994
 995 sub eidx_dedupe ($$$) {
 996         my ($self, $sync, $msgids) = @_;
 997         $sync->{dedupe_cull} = 0;
 998         my $candidates = 0;
 999         my $nr_mid = 0;
1000         return unless eidxq_lock_acquire($self);
1001         my ($iter, $cur_mid);
1002         my $min_id = 0;
1003         my $idx = 0;
1004         my ($max_id) = $self->{oidx}->dbh->selectrow_array(<<EOS);
1005 SELECT MAX(id) FROM msgid
1006 EOS
1007         local $sync->{-regen_fmt} = "dedupe %u/$max_id\n";
1008
1009         # note: we could write this query more intelligently,
1010         # but that causes lock contention with read-only processes
1011 dedupe_restart:
1012         $cur_mid = $msgids->[$idx];
1013         if ($cur_mid eq '') { # all Message-IDs
1014                 $iter = $self->{oidx}->dbh->prepare(<<EOS);
1015 SELECT mid,id FROM msgid WHERE id > ? ORDER BY id ASC
1016 EOS
1017                 $iter->execute($min_id);
1018         } else {
1019                 $iter = $self->{oidx}->dbh->prepare(<<EOS);
1020 SELECT mid,id FROM msgid WHERE mid = ? AND id > ? ORDER BY id ASC
1021 EOS
1022                 $iter->execute($cur_mid, $min_id);
1023         }
1024         while (my ($mid, $id) = $iter->fetchrow_array) {
1025                 last if $sync->{quit};
1026                 $self->{current_info} = "dedupe $mid";
1027                 ${$sync->{nr}} = $min_id = $id;
1028                 my ($prv, @smsg);
1029                 while (my $x = $self->{oidx}->next_by_mid($mid, \$id, \$prv)) {
1030                         push @smsg, $x;
1031                 }
1032                 next if scalar(@smsg) < 2;
1033                 my $per_mid = {
1034                         dd_chash => {}, # chash => [ary of smsgs]
1035                         last_smsg => $smsg[-1],
1036                         sync => $sync
1037                 };
1038                 $nr_mid++;
1039                 $candidates += scalar(@smsg) - 1;
1040                 for my $smsg (@smsg) {
1041                         my $dd = {
1042                                 per_mid => $per_mid,
1043                                 smsg => $smsg,
1044                                 self => $self,
1045                         };
1046                         $self->git->cat_async($smsg->{blob}, \&dd_smsg, $dd);
1047                 }
1048                 # need to wait on every single one @smsg contents can get
1049                 # invalidated inside dd_smsg for messages with multiple
1050                 # Message-IDs.
1051                 $self->git->async_wait_all;
1052
1053                 if (checkpoint_due($sync)) {
1054                         undef $iter;
1055                         reindex_checkpoint($self, $sync);
1056                         goto dedupe_restart;
1057                 }
1058         }
1059         goto dedupe_restart if defined($msgids->[++$idx]);
1060
1061         my $n = delete $sync->{dedupe_cull};
1062         if (my $pr = $sync->{-opt}->{-progress}) {
1063                 $pr->("culled $n/$candidates candidates ($nr_mid msgids)\n");
1064         }
1065         ${$sync->{nr}} = 0;
1066 }
1067
1068 sub eidx_sync { # main entry point
1069         my ($self, $opt) = @_;
1070
1071         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
1072         local $self->{current_info} = '';
1073         local $SIG{__WARN__} = sub {
1074                 return if PublicInbox::Eml::warn_ignore(@_);
1075                 $warn_cb->($self->{current_info}, ': ', @_);
1076         };
1077         $self->idx_init($opt); # acquire lock via V2Writable::_idx_init
1078         $self->{oidx}->rethread_prepare($opt);
1079         my $sync = {
1080                 need_checkpoint => \(my $need_checkpoint = 0),
1081                 check_intvl => 10,
1082                 next_check => now() + 10,
1083                 -opt => $opt,
1084                 # DO NOT SET {reindex} here, it's incompatible with reused
1085                 # V2Writable code, reindex is totally different here
1086                 # compared to v1/v2 inboxes because we have multiple histories
1087                 self => $self,
1088                 -regen_fmt => "%u/?\n",
1089         };
1090         local $SIG{USR1} = sub { $need_checkpoint = 1 };
1091         my $quit = PublicInbox::SearchIdx::quit_cb($sync);
1092         local $SIG{QUIT} = $quit;
1093         local $SIG{INT} = $quit;
1094         local $SIG{TERM} = $quit;
1095         for my $ibx (@{ibx_sorted($self, 'known')}) {
1096                 $ibx->{-ibx_id} //= $self->{oidx}->ibx_id($ibx->eidx_key);
1097         }
1098
1099         if (scalar(grep { defined($_->{boost}) } @{$self->{ibx_known}})) {
1100                 $sync->{id2pos} //= prep_id2pos($self);
1101                 $sync->{boost_in_use} = 1;
1102         }
1103
1104         if (my $msgids = delete($opt->{dedupe})) {
1105                 local $sync->{checkpoint_unlocks} = 1;
1106                 eidx_dedupe($self, $sync, $msgids);
1107         }
1108         if (delete($opt->{reindex})) {
1109                 local $sync->{checkpoint_unlocks} = 1;
1110                 eidx_reindex($self, $sync);
1111         }
1112
1113         # don't use $_ here, it'll get clobbered by reindex_checkpoint
1114         if ($opt->{scan} // 1) {
1115                 for my $ibx (@{ibx_sorted($self, 'active')}) {
1116                         last if $sync->{quit};
1117                         sync_inbox($self, $sync, $ibx);
1118                 }
1119         }
1120         $self->{oidx}->rethread_done($opt) unless $sync->{quit};
1121         eidxq_process($self, $sync) unless $sync->{quit};
1122
1123         eidxq_release($self);
1124         done($self);
1125         $sync; # for eidx_watch
1126 }
1127
1128 sub update_last_commit { # overrides V2Writable
1129         my ($self, $sync, $stk) = @_;
1130         my $unit = $sync->{unit} // return;
1131         my $latest_cmt = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
1132         defined($latest_cmt) or return;
1133         my $ibx = $sync->{ibx} or die 'BUG: {ibx} missing';
1134         my $ekey = $ibx->eidx_key;
1135         my $uv = $ibx->uidvalidity;
1136         my $epoch = $unit->{epoch};
1137         my $meta_key;
1138         my $v = $ibx->version;
1139         if ($v == 2) {
1140                 die 'No {epoch} for v2 unit' unless defined $epoch;
1141                 $meta_key = "lc-v2:$ekey//$uv;$epoch";
1142         } elsif ($v == 1) {
1143                 die 'Unexpected {epoch} for v1 unit' if defined $epoch;
1144                 $meta_key = "lc-v1:$ekey//$uv";
1145         } else {
1146                 die "Unsupported inbox version: $v";
1147         }
1148         my $last = $self->{oidx}->eidx_meta($meta_key);
1149         if (defined $last && is_ancestor($self->git, $last, $latest_cmt)) {
1150                 my @cmd = (qw(rev-list --count), "$last..$latest_cmt");
1151                 chomp(my $n = $unit->{git}->qx(@cmd));
1152                 return if $n ne '' && $n == 0;
1153         }
1154         $self->{oidx}->eidx_meta($meta_key, $latest_cmt);
1155 }
1156
1157 sub _idx_init { # with_umask callback
1158         my ($self, $opt) = @_;
1159         PublicInbox::V2Writable::_idx_init($self, $opt); # acquires ei.lock
1160         $self->{midx} = PublicInbox::MiscIdx->new($self);
1161 }
1162
1163 sub symlink_packs ($$) {
1164         my ($ibx, $pd) = @_;
1165         my $ret = 0;
1166         my $glob = "$ibx->{inboxdir}/git/*.git/objects/pack/*.idx";
1167         for my $idx (bsd_glob($glob, GLOB_NOSORT)) {
1168                 my $src = substr($idx, 0, -length('.idx'));
1169                 my $dst = $pd . substr($src, rindex($src, '/'));
1170                 if (-f "$src.pack" and
1171                                 symlink("$src.pack", "$dst.pack") and
1172                                 symlink($idx, "$dst.idx") and
1173                                 -f $idx) {
1174                         ++$ret;
1175                         # .promisor, .bitmap, .rev and .keep are optional
1176                         # XXX should we symlink .keep here?
1177                         for my $s (qw(promisor bitmap rev)) {
1178                                 symlink("$src.$s", "$dst.$s") if -f "$src.$s";
1179                         }
1180                 } elsif (!$!{EEXIST}) {
1181                         warn "W: ln -s $src.{pack,idx} => $dst.*: $!\n";
1182                         unlink "$dst.pack", "$dst.idx";
1183                 }
1184         }
1185         $ret;
1186 }
1187
1188 sub idx_init { # similar to V2Writable
1189         my ($self, $opt) = @_;
1190         return if $self->{idx_shards};
1191
1192         $self->git->cleanup;
1193         my $mode = 0644;
1194         my $ALL = $self->git->{git_dir}; # topdir/ALL.git
1195         my ($has_new, $alt, $seen, $prune, $prune_nr);
1196         if ($opt->{-private}) { # LeiStore
1197                 my $local = "$self->{topdir}/local"; # lei/store
1198                 $self->{mg} //= PublicInbox::MultiGit->new($self->{topdir},
1199                                                         'ALL.git', 'local');
1200                 $mode = 0600;
1201                 unless (-d $ALL) {
1202                         umask 077; # don't bother restoring for lei
1203                         PublicInbox::Import::init_bare($ALL);
1204                         $self->git->qx(qw(config core.sharedRepository 0600));
1205                 }
1206                 ($alt, $seen) = $self->{mg}->read_alternates(\$mode);
1207                 $has_new = $self->{mg}->merge_epochs($alt, $seen);
1208         } else { # extindex has no epochs
1209                 $self->{mg} //= PublicInbox::MultiGit->new($self->{topdir},
1210                                                         'ALL.git');
1211                 $prune = $opt->{-idx_gc} ? \$prune_nr : undef;
1212                 ($alt, $seen) = $self->{mg}->read_alternates(\$mode, $prune);
1213                 PublicInbox::Import::init_bare($ALL);
1214         }
1215
1216         # git-multi-pack-index(1) can speed up "git cat-file" startup slightly
1217         my $git_midx = 0;
1218         my $pd = "$ALL/objects/pack";
1219         if (opendir(my $dh, $pd)) { # drop stale symlinks
1220                 while (defined(my $dn = readdir($dh))) {
1221                         if ($dn =~ /\.(?:idx|pack|promisor|bitmap|rev)\z/) {
1222                                 my $f = "$pd/$dn";
1223                                 unlink($f) if -l $f && !-e $f;
1224                         }
1225                 }
1226         } elsif ($!{ENOENT}) {
1227                 mkdir($pd) or die "mkdir($pd): $!";
1228         } else {
1229                 die "opendir($pd): $!";
1230         }
1231         my $new = '';
1232         for my $ibx (@{ibx_sorted($self, 'active')}) {
1233                 # create symlinks for multi-pack-index
1234                 $git_midx += symlink_packs($ibx, $pd);
1235                 # add new lines to our alternates file
1236                 my $d = $ibx->git->{git_dir} . '/objects';
1237                 next if exists $alt->{$d};
1238                 if (my @st = stat($d)) {
1239                         next if $seen->{"$st[0]\0$st[1]"}++;
1240                 } else {
1241                         warn "W: stat($d) failed (from $ibx->{inboxdir}): $!\n";
1242                         next if $opt->{-idx_gc};
1243                 }
1244                 $new .= "$d\n";
1245         }
1246         ($has_new || $prune_nr || $new ne '') and
1247                 $self->{mg}->write_alternates($mode, $alt, $new);
1248         $git_midx and $self->with_umask(sub {
1249                 my @cmd = ('multi-pack-index');
1250                 push @cmd, '--no-progress' if ($opt->{quiet}//0) > 1;
1251                 my $lk = $self->lock_for_scope;
1252                 system('git', "--git-dir=$ALL", @cmd, 'write');
1253                 # ignore errors, fairly new command, may not exist
1254         });
1255         $self->parallel_init($self->{indexlevel});
1256         $self->with_umask(\&_idx_init, $self, $opt);
1257         $self->{oidx}->begin_lazy;
1258         $self->{oidx}->eidx_prep;
1259         $self->{midx}->create_xdb if $new ne '';
1260 }
1261
1262 sub _watch_commit { # PublicInbox::DS::add_timer callback
1263         my ($self) = @_;
1264         delete $self->{-commit_timer};
1265         eidxq_process($self, $self->{-watch_sync});
1266         eidxq_release($self);
1267         my $fmt = delete $self->{-watch_sync}->{-regen_fmt};
1268         reindex_checkpoint($self, $self->{-watch_sync});
1269         $self->{-watch_sync}->{-regen_fmt} = $fmt;
1270
1271         # call event_step => done unless commit_timer is armed
1272         PublicInbox::DS::requeue($self);
1273 }
1274
1275 sub on_inbox_unlock { # called by PublicInbox::InboxIdle
1276         my ($self, $ibx) = @_;
1277         my $opt = $self->{-watch_sync}->{-opt};
1278         my $pr = $opt->{-progress};
1279         my $ekey = $ibx->eidx_key;
1280         local $0 = "sync $ekey";
1281         $pr->("indexing $ekey\n") if $pr;
1282         $self->idx_init($opt);
1283         sync_inbox($self, $self->{-watch_sync}, $ibx);
1284         $self->{-commit_timer} //= add_timer($opt->{'commit-interval'} // 10,
1285                                         \&_watch_commit, $self);
1286 }
1287
1288 sub eidx_reload { # -extindex --watch SIGHUP handler
1289         my ($self, $idler) = @_;
1290         if ($self->{cfg}) {
1291                 my $pr = $self->{-watch_sync}->{-opt}->{-progress};
1292                 $pr->('reloading ...') if $pr;
1293                 delete $self->{-resync_queue};
1294                 delete $self->{-ibx_ary_known};
1295                 delete $self->{-ibx_ary_active};
1296                 $self->{ibx_known} = [];
1297                 $self->{ibx_active} = [];
1298                 %{$self->{ibx_map}} = ();
1299                 delete $self->{-watch_sync}->{id2pos};
1300                 my $cfg = PublicInbox::Config->new;
1301                 attach_config($self, $cfg);
1302                 $idler->refresh($cfg);
1303                 $pr->(" done\n") if $pr;
1304         } else {
1305                 warn "reload not supported without --all\n";
1306         }
1307 }
1308
1309 sub eidx_resync_start ($) { # -extindex --watch SIGUSR1 handler
1310         my ($self) = @_;
1311         $self->{-resync_queue} //= [ @{ibx_sorted($self, 'active')} ];
1312         PublicInbox::DS::requeue($self); # trigger our ->event_step
1313 }
1314
1315 sub event_step { # PublicInbox::DS::requeue callback
1316         my ($self) = @_;
1317         if (my $resync_queue = $self->{-resync_queue}) {
1318                 if (my $ibx = shift(@$resync_queue)) {
1319                         on_inbox_unlock($self, $ibx);
1320                         PublicInbox::DS::requeue($self);
1321                 } else {
1322                         delete $self->{-resync_queue};
1323                         _watch_commit($self);
1324                 }
1325         } else {
1326                 done($self) unless $self->{-commit_timer};
1327         }
1328 }
1329
1330 sub eidx_watch { # public-inbox-extindex --watch main loop
1331         my ($self, $opt) = @_;
1332         local @SIG{keys %SIG} = values %SIG;
1333         for my $sig (qw(HUP USR1 TSTP QUIT INT TERM)) {
1334                 $SIG{$sig} = sub { warn "SIG$sig ignored while scanning\n" };
1335         }
1336         require PublicInbox::InboxIdle;
1337         require PublicInbox::DS;
1338         require PublicInbox::Syscall;
1339         require PublicInbox::Sigfd;
1340         my $idler = PublicInbox::InboxIdle->new($self->{cfg});
1341         if (!$self->{cfg}) {
1342                 $idler->watch_inbox($_) for (@{ibx_sorted($self, 'active')});
1343         }
1344         for my $ibx (@{ibx_sorted($self, 'active')}) {
1345                 $ibx->subscribe_unlock(__PACKAGE__, $self)
1346         }
1347         my $pr = $opt->{-progress};
1348         $pr->("performing initial scan ...\n") if $pr;
1349         my $sync = eidx_sync($self, $opt); # initial sync
1350         return if $sync->{quit};
1351         my $oldset = PublicInbox::DS::block_signals();
1352         local $self->{current_info} = '';
1353         my $cb = $SIG{__WARN__} || \&CORE::warn;
1354         local $SIG{__WARN__} = sub {
1355                 return if PublicInbox::Eml::warn_ignore(@_);
1356                 $cb->($self->{current_info}, ': ', @_);
1357         };
1358         my $sig = {
1359                 HUP => sub { eidx_reload($self, $idler) },
1360                 USR1 => sub { eidx_resync_start($self) },
1361                 TSTP => sub { kill('STOP', $$) },
1362         };
1363         my $quit = PublicInbox::SearchIdx::quit_cb($sync);
1364         $sig->{QUIT} = $sig->{INT} = $sig->{TERM} = $quit;
1365         local $self->{-watch_sync} = $sync; # for ->on_inbox_unlock
1366         PublicInbox::DS->SetPostLoopCallback(sub { !$sync->{quit} });
1367         $pr->("initial scan complete, entering event loop\n") if $pr;
1368         # calls InboxIdle->event_step:
1369         PublicInbox::DS::event_loop($sig, $oldset);
1370         done($self);
1371 }
1372
1373 no warnings 'once';
1374 *done = \&PublicInbox::V2Writable::done;
1375 *with_umask = \&PublicInbox::InboxWritable::with_umask;
1376 *parallel_init = \&PublicInbox::V2Writable::parallel_init;
1377 *nproc_shards = \&PublicInbox::V2Writable::nproc_shards;
1378 *sync_prepare = \&PublicInbox::V2Writable::sync_prepare;
1379 *index_todo = \&PublicInbox::V2Writable::index_todo;
1380 *count_shards = \&PublicInbox::V2Writable::count_shards;
1381 *atfork_child = \&PublicInbox::V2Writable::atfork_child;
1382 *idx_shard = \&PublicInbox::V2Writable::idx_shard;
1383 *reindex_checkpoint = \&PublicInbox::V2Writable::reindex_checkpoint;
1384 *checkpoint = \&PublicInbox::V2Writable::checkpoint;
1385
1386 1;