lib/PublicInbox/ExtSearchIdx.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Detached/external index cross inbox search indexing support
   5 # read-write counterpart to PublicInbox::ExtSearch
   6 #
   7 # It's based on the same ideas as public-inbox-v2-format(5) using
   8 # over.sqlite3 for dedupe and sharded Xapian.  msgmap.sqlite3 is
   9 # missing, so there is no Message-ID conflict resolution, meaning
  10 # no NNTP support for now.
  11 #
  12 # v2 has a 1:1 mapping of index:inbox or msgmap for NNTP support.
  13 # This is intended to be an M:N index:inbox mapping, but it'll likely
  14 # be 1:N in common practice (M==1)
  15
  16 package PublicInbox::ExtSearchIdx;
  17 use strict;
  18 use v5.10.1;
  19 use parent qw(PublicInbox::ExtSearch PublicInbox::Lock);
  20 use Carp qw(croak carp);
  21 use Sys::Hostname qw(hostname);
  22 use POSIX qw(strftime);
  23 use PublicInbox::Search;
  24 use PublicInbox::SearchIdx qw(crlf_adjust prepare_stack is_ancestor
  25         is_bad_blob);
  26 use PublicInbox::OverIdx;
  27 use PublicInbox::MiscIdx;
  28 use PublicInbox::MID qw(mids);
  29 use PublicInbox::V2Writable;
  30 use PublicInbox::InboxWritable;
  31 use PublicInbox::ContentHash qw(content_hash);
  32 use PublicInbox::Eml;
  33 use PublicInbox::DS qw(now);
  34 use DBI qw(:sql_types); # SQL_BLOB
  35
  36 sub new {
  37         my (undef, $dir, $opt) = @_;
  38         my $l = $opt->{indexlevel} // 'full';
  39         $l !~ $PublicInbox::SearchIdx::INDEXLEVELS and
  40                 die "invalid indexlevel=$l\n";
  41         $l eq 'basic' and die "E: indexlevel=basic not yet supported\n";
  42         my $self = bless {
  43                 xpfx => "$dir/ei".PublicInbox::Search::SCHEMA_VERSION,
  44                 topdir => $dir,
  45                 creat => $opt->{creat},
  46                 ibx_map => {}, # (newsgroup//inboxdir) => $ibx
  47                 ibx_list => [],
  48                 indexlevel => $l,
  49                 transact_bytes => 0,
  50                 total_bytes => 0,
  51                 current_info => '',
  52                 parallel => 1,
  53                 lock_path => "$dir/ei.lock",
  54         }, __PACKAGE__;
  55         $self->{shards} = $self->count_shards || nproc_shards($opt->{creat});
  56         my $oidx = PublicInbox::OverIdx->new("$self->{xpfx}/over.sqlite3");
  57         $oidx->{-no_fsync} = 1 if $opt->{-no_fsync};
  58         $self->{oidx} = $oidx;
  59         $self
  60 }
  61
  62 sub attach_inbox {
  63         my ($self, $ibx) = @_;
  64         my $ekey = $ibx->eidx_key;
  65         my $misc = $self->{misc};
  66         if ($misc && $misc->inbox_data($ibx)) { # all good if already indexed
  67         } else {
  68                 my @sqlite = ($ibx->over, $ibx->mm);
  69                 my $uidvalidity = $ibx->uidvalidity;
  70                 $ibx->{mm} = $ibx->{over} = undef;
  71                 if (scalar(@sqlite) != 2) {
  72                         warn "W: skipping $ekey (unindexed)\n";
  73                         return;
  74                 }
  75                 if (!defined($uidvalidity)) {
  76                         warn "W: skipping $ekey (no UIDVALIDITY)\n";
  77                         return;
  78                 }
  79         }
  80         $self->{ibx_map}->{$ekey} //= do {
  81                 push @{$self->{ibx_list}}, $ibx;
  82                 $ibx;
  83         }
  84 }
  85
  86 sub _ibx_attach { # each_inbox callback
  87         my ($ibx, $self) = @_;
  88         attach_inbox($self, $ibx);
  89 }
  90
  91 sub attach_config {
  92         my ($self, $cfg) = @_;
  93         $self->{cfg} = $cfg;
  94         $cfg->each_inbox(\&_ibx_attach, $self);
  95 }
  96
  97 sub check_batch_limit ($) {
  98         my ($req) = @_;
  99         my $self = $req->{self};
 100         my $new_smsg = $req->{new_smsg};
 101
 102         # {raw_bytes} may be unset, so just use {bytes}
 103         my $n = $self->{transact_bytes} += $new_smsg->{bytes};
 104
 105         # set flag for PublicInbox::V2Writable::index_todo:
 106         ${$req->{need_checkpoint}} = 1 if $n >= $self->{batch_bytes};
 107 }
 108
 109 sub do_xpost ($$) {
 110         my ($req, $smsg) = @_;
 111         my $self = $req->{self};
 112         my $docid = $smsg->{num};
 113         my $idx = $self->idx_shard($docid);
 114         my $oid = $req->{oid};
 115         my $xibx = $req->{ibx};
 116         my $eml = $req->{eml};
 117         my $eidx_key = $xibx->eidx_key;
 118         if (my $new_smsg = $req->{new_smsg}) { # 'm' on cross-posted message
 119                 my $xnum = $req->{xnum};
 120                 $self->{oidx}->add_xref3($docid, $xnum, $oid, $eidx_key);
 121                 $idx->shard_add_eidx_info($docid, $eidx_key, $eml);
 122                 check_batch_limit($req);
 123         } else { # 'd'
 124                 my $rm_eidx_info;
 125                 my $nr = $self->{oidx}->remove_xref3($docid, $oid, $eidx_key,
 126                                                         \$rm_eidx_info);
 127                 if ($nr == 0) {
 128                         $self->{oidx}->eidxq_del($docid);
 129                         $idx->shard_remove($docid);
 130                 } elsif ($rm_eidx_info) {
 131                         $idx->shard_remove_eidx_info($docid, $eidx_key, $eml);
 132                         $self->{oidx}->eidxq_add($docid); # yes, add
 133                 }
 134         }
 135 }
 136
 137 # called by V2Writable::sync_prepare
 138 sub artnum_max { $_[0]->{oidx}->eidx_max }
 139
 140 sub index_unseen ($) {
 141         my ($req) = @_;
 142         my $new_smsg = $req->{new_smsg} or die 'BUG: {new_smsg} unset';
 143         my $eml = delete $req->{eml};
 144         $new_smsg->populate($eml, $req);
 145         my $self = $req->{self};
 146         my $docid = $self->{oidx}->adj_counter('eidx_docid', '+');
 147         $new_smsg->{num} = $docid;
 148         my $idx = $self->idx_shard($docid);
 149         $self->{oidx}->add_overview($eml, $new_smsg);
 150         my $oid = $new_smsg->{blob};
 151         my $ibx = delete $req->{ibx} or die 'BUG: {ibx} unset';
 152         $self->{oidx}->add_xref3($docid, $req->{xnum}, $oid, $ibx->eidx_key);
 153         $idx->index_raw(undef, $eml, $new_smsg, $ibx->eidx_key);
 154         check_batch_limit($req);
 155 }
 156
 157 sub do_finalize ($) {
 158         my ($req) = @_;
 159         if (my $indexed = $req->{indexed}) {
 160                 do_xpost($req, $_) for @$indexed;
 161         } elsif (exists $req->{new_smsg}) { # totally unseen messsage
 162                 index_unseen($req);
 163         } else {
 164                 # `d' message was already unindexed in the v1/v2 inboxes,
 165                 # so it's too noisy to warn, here.
 166         }
 167         # cur_cmt may be undef for unindex_oid, set by V2Writable::index_todo
 168         if (defined(my $cur_cmt = $req->{cur_cmt})) {
 169                 ${$req->{latest_cmt}} = $cur_cmt;
 170         }
 171 }
 172
 173 sub do_step ($) { # main iterator for adding messages to the index
 174         my ($req) = @_;
 175         my $self = $req->{self} // die 'BUG: {self} missing';
 176         while (1) {
 177                 if (my $next_arg = $req->{next_arg}) {
 178                         if (my $smsg = $self->{oidx}->next_by_mid(@$next_arg)) {
 179                                 $req->{cur_smsg} = $smsg;
 180                                 $self->git->cat_async($smsg->{blob},
 181                                                         \&ck_existing, $req);
 182                                 return; # ck_existing calls do_step
 183                         }
 184                         delete $req->{cur_smsg};
 185                         delete $req->{next_arg};
 186                 }
 187                 my $mid = shift(@{$req->{mids}});
 188                 last unless defined $mid;
 189                 my ($id, $prev);
 190                 $req->{next_arg} = [ $mid, \$id, \$prev ];
 191                 # loop again
 192         }
 193         do_finalize($req);
 194 }
 195
 196 sub _blob_missing ($) { # called when req->{cur_smsg}->{blob} is bad
 197         my ($req) = @_;
 198         my $smsg = $req->{cur_smsg} or die 'BUG: {cur_smsg} missing';
 199         my $self = $req->{self};
 200         my $xref3 = $self->{oidx}->get_xref3($smsg->{num});
 201         my @keep = grep(!/:$smsg->{blob}\z/, @$xref3);
 202         if (@keep) {
 203                 $keep[0] =~ /:([a-f0-9]{40,}+)\z/ or
 204                         die "BUG: xref $keep[0] has no OID";
 205                 my $oidhex = $1;
 206                 $self->{oidx}->remove_xref3($smsg->{num}, $smsg->{blob});
 207                 my $upd = $self->{oidx}->update_blob($smsg, $oidhex);
 208                 my $saved = $self->{oidx}->get_art($smsg->{num});
 209         } else {
 210                 $self->{oidx}->delete_by_num($smsg->{num});
 211         }
 212 }
 213
 214 sub ck_existing { # git->cat_async callback
 215         my ($bref, $oid, $type, $size, $req) = @_;
 216         my $smsg = $req->{cur_smsg} or die 'BUG: {cur_smsg} missing';
 217         if ($type eq 'missing') {
 218                 _blob_missing($req);
 219         } elsif (!is_bad_blob($oid, $type, $size, $smsg->{blob})) {
 220                 my $self = $req->{self} // die 'BUG: {self} missing';
 221                 local $self->{current_info} = "$self->{current_info} $oid";
 222                 my $cur = PublicInbox::Eml->new($bref);
 223                 if (content_hash($cur) eq $req->{chash}) {
 224                         push @{$req->{indexed}}, $smsg; # for do_xpost
 225                 } # else { index_unseen later }
 226         }
 227         do_step($req);
 228 }
 229
 230 # is the messages visible in the inbox currently being indexed?
 231 # return the number if so
 232 sub cur_ibx_xnum ($$) {
 233         my ($req, $bref) = @_;
 234         my $ibx = $req->{ibx} or die 'BUG: current {ibx} missing';
 235
 236         $req->{eml} = PublicInbox::Eml->new($bref);
 237         $req->{chash} = content_hash($req->{eml});
 238         $req->{mids} = mids($req->{eml});
 239         my @q = @{$req->{mids}}; # copy
 240         while (defined(my $mid = shift @q)) {
 241                 my ($id, $prev);
 242                 while (my $x = $ibx->over->next_by_mid($mid, \$id, \$prev)) {
 243                         return $x->{num} if $x->{blob} eq $req->{oid};
 244                 }
 245         }
 246         undef;
 247 }
 248
 249 sub index_oid { # git->cat_async callback for 'm'
 250         my ($bref, $oid, $type, $size, $req) = @_;
 251         my $self = $req->{self};
 252         local $self->{current_info} = "$self->{current_info} $oid";
 253         return if is_bad_blob($oid, $type, $size, $req->{oid});
 254         my $new_smsg = $req->{new_smsg} = bless {
 255                 blob => $oid,
 256         }, 'PublicInbox::Smsg';
 257         $new_smsg->{bytes} = $size + crlf_adjust($$bref);
 258         defined($req->{xnum} = cur_ibx_xnum($req, $bref)) or return;
 259         ++${$req->{nr}};
 260         do_step($req);
 261 }
 262
 263 sub unindex_oid { # git->cat_async callback for 'd'
 264         my ($bref, $oid, $type, $size, $req) = @_;
 265         my $self = $req->{self};
 266         local $self->{current_info} = "$self->{current_info} $oid";
 267         return if is_bad_blob($oid, $type, $size, $req->{oid});
 268         return if defined(cur_ibx_xnum($req, $bref)); # was re-added
 269         do_step($req);
 270 }
 271
 272 # overrides V2Writable::last_commits, called by sync_ranges via sync_prepare
 273 sub last_commits {
 274         my ($self, $sync) = @_;
 275         my $heads = [];
 276         my $ekey = $sync->{ibx}->eidx_key;
 277         my $uv = $sync->{ibx}->uidvalidity;
 278         for my $i (0..$sync->{epoch_max}) {
 279                 $heads->[$i] = $self->{oidx}->eidx_meta("lc-v2:$ekey//$uv;$i");
 280         }
 281         $heads;
 282 }
 283
 284 sub _sync_inbox ($$$) {
 285         my ($self, $sync, $ibx) = @_;
 286         $sync->{ibx} = $ibx;
 287         $sync->{nr} = \(my $nr = 0);
 288         my $v = $ibx->version;
 289         my $ekey = $ibx->eidx_key;
 290         if ($v == 2) {
 291                 $sync->{epoch_max} = $ibx->max_git_epoch // return;
 292                 sync_prepare($self, $sync); # or return # TODO: once MiscIdx is stable
 293         } elsif ($v == 1) {
 294                 my $uv = $ibx->uidvalidity;
 295                 my $lc = $self->{oidx}->eidx_meta("lc-v1:$ekey//$uv");
 296                 my $head = $ibx->mm->last_commit;
 297                 unless (defined $head) {
 298                         warn "E: $ibx->{inboxdir} is not indexed\n";
 299                         return;
 300                 }
 301                 my $stk = prepare_stack($sync, $lc ? "$lc..$head" : $head);
 302                 my $unit = { stack => $stk, git => $ibx->git };
 303                 push @{$sync->{todo}}, $unit;
 304         } else {
 305                 warn "E: $ekey unsupported inbox version (v$v)\n";
 306                 return;
 307         }
 308         for my $unit (@{delete($sync->{todo}) // []}) {
 309                 last if $sync->{quit};
 310                 index_todo($self, $sync, $unit);
 311         }
 312         $self->{midx}->index_ibx($ibx) unless $sync->{quit};
 313         $ibx->git->cleanup; # done with this inbox, now
 314 }
 315
 316 sub gc_unref_doc ($$$$) {
 317         my ($self, $ibx_id, $eidx_key, $docid) = @_;
 318         my $dbh = $self->{oidx}->dbh;
 319
 320         # for debug/info purposes, oids may no longer be accessible
 321         my $sth = $dbh->prepare_cached(<<'', undef, 1);
 322 SELECT oidbin FROM xref3 WHERE docid = ? AND ibx_id = ?
 323
 324         $sth->execute($docid, $ibx_id);
 325         my @oid = map { unpack('H*', $_->[0]) } @{$sth->fetchall_arrayref};
 326
 327         $dbh->prepare_cached(<<'')->execute($docid, $ibx_id);
 328 DELETE FROM xref3 WHERE docid = ? AND ibx_id = ?
 329
 330         my $remain = $self->{oidx}->get_xref3($docid);
 331         if (scalar(@$remain)) {
 332                 $self->{oidx}->eidxq_add($docid); # enqueue for reindex
 333                 for my $oid (@oid) {
 334                         warn "I: unref #$docid $eidx_key $oid\n";
 335                 }
 336         } else {
 337                 warn "I: remove #$docid $eidx_key @oid\n";
 338                 $self->idx_shard($docid)->shard_remove($docid);
 339         }
 340 }
 341
 342 sub eidx_gc {
 343         my ($self, $opt) = @_;
 344         $self->{cfg} or die "E: GC requires ->attach_config\n";
 345         $opt->{-idx_gc} = 1;
 346         $self->idx_init($opt); # acquire lock via V2Writable::_idx_init
 347
 348         my $dbh = $self->{oidx}->dbh;
 349         my $x3_doc = $dbh->prepare('SELECT docid FROM xref3 WHERE ibx_id = ?');
 350         my $ibx_ck = $dbh->prepare('SELECT ibx_id,eidx_key FROM inboxes');
 351         my $lc_i = $dbh->prepare('SELECT key FROM eidx_meta WHERE key LIKE ?');
 352
 353         $ibx_ck->execute;
 354         while (my ($ibx_id, $eidx_key) = $ibx_ck->fetchrow_array) {
 355                 next if $self->{ibx_map}->{$eidx_key};
 356                 $self->{midx}->remove_eidx_key($eidx_key);
 357                 warn "I: deleting messages for $eidx_key...\n";
 358                 $x3_doc->execute($ibx_id);
 359                 while (defined(my $docid = $x3_doc->fetchrow_array)) {
 360                         gc_unref_doc($self, $ibx_id, $eidx_key, $docid);
 361                 }
 362                 $dbh->prepare_cached(<<'')->execute($ibx_id);
 363 DELETE FROM inboxes WHERE ibx_id = ?
 364
 365                 # drop last_commit info
 366                 my $pat = $eidx_key;
 367                 $pat =~ s/([_%])/\\$1/g;
 368                 $lc_i->execute("lc-%:$pat//%");
 369                 while (my ($key) = $lc_i->fetchrow_array) {
 370                         next if $key !~ m!\Alc-v[1-9]+:\Q$eidx_key\E//!;
 371                         warn "I: removing $key\n";
 372                         $dbh->prepare_cached(<<'')->execute($key);
 373 DELETE FROM eidx_meta WHERE key = ?
 374
 375                 }
 376
 377                 warn "I: $eidx_key removed\n";
 378         }
 379
 380         # it's not real unless it's in `over', we use parallelism here,
 381         # shards will be reading directly from over, so commit
 382         $self->{oidx}->commit_lazy;
 383         $self->{oidx}->begin_lazy;
 384
 385         for my $idx (@{$self->{idx_shards}}) {
 386                 warn "I: cleaning up shard #$idx->{shard}\n";
 387                 $idx->shard_over_check($self->{oidx});
 388         }
 389         my $nr = $dbh->do(<<'');
 390 DELETE FROM xref3 WHERE docid NOT IN (SELECT num FROM over)
 391
 392         warn "I: eliminated $nr stale xref3 entries\n" if $nr != 0;
 393
 394         done($self);
 395 }
 396
 397 sub _ibx_for ($$$) {
 398         my ($self, $sync, $smsg) = @_;
 399         my $ibx_id = delete($smsg->{ibx_id}) // die '{ibx_id} unset';
 400         my $pos = $sync->{id2pos}->{$ibx_id} // die "$ibx_id no pos";
 401         $self->{ibx_list}->[$pos] // die "BUG: ibx for $smsg->{blob} not mapped"
 402 }
 403
 404 sub _reindex_finalize ($$$) {
 405         my ($req, $smsg, $eml) = @_;
 406         my $sync = $req->{sync};
 407         my $self = $sync->{self};
 408         my $by_chash = delete $req->{by_chash} or die 'BUG: no {by_chash}';
 409         my $nr = scalar(keys(%$by_chash)) or die 'BUG: no content hashes';
 410         my $orig_smsg = $req->{orig_smsg} // die 'BUG: no {orig_smsg}';
 411         my $docid = $smsg->{num} = $orig_smsg->{num};
 412         $self->{oidx}->add_overview($eml, $smsg); # may rethread
 413         check_batch_limit({ %$sync, new_smsg => $smsg });
 414         my $chash0 = $smsg->{chash} // die "BUG: $smsg->{blob} no {chash}";
 415         my $stable = delete($by_chash->{$chash0}) //
 416                                 die "BUG: $smsg->{blob} chash missing";
 417         my $idx = $self->idx_shard($docid);
 418         my $top_smsg = pop @$stable;
 419         $top_smsg == $smsg or die 'BUG: top_smsg != smsg';
 420         my $ibx = _ibx_for($self, $sync, $smsg);
 421         $idx->index_raw(undef, $eml, $smsg, $ibx->eidx_key);
 422         for my $x (reverse @$stable) {
 423                 $ibx = _ibx_for($self, $sync, $x);
 424                 my $hdr = delete $x->{hdr} // die 'BUG: no {hdr}';
 425                 $idx->shard_add_eidx_info($docid, $ibx->eidx_key, $hdr);
 426         }
 427         return if $nr == 1; # likely, all good
 428
 429         warn "W: #$docid split into $nr due to deduplication change\n";
 430         my @todo;
 431         for my $ary (values %$by_chash) {
 432                 for my $x (reverse @$ary) {
 433                         warn "removing #$docid xref3 $x->{blob}\n";
 434                         my $n = $self->{oidx}->remove_xref3($docid, $x->{blob});
 435                         die "BUG: $x->{blob} invalidated #$docid" if $n == 0;
 436                 }
 437                 my $x = pop(@$ary) // die "BUG: #$docid {by_chash} empty";
 438                 $x->{num} = delete($x->{xnum}) // die '{xnum} unset';
 439                 $ibx = _ibx_for($self, $sync, $x);
 440                 my $e = $ibx->over->get_art($x->{num});
 441                 $e->{blob} eq $x->{blob} or die <<EOF;
 442 $x->{blob} != $e->{blob} (${\$ibx->eidx_key}:$e->{num});
 443 EOF
 444                 push @todo, $ibx, $e;
 445         }
 446         undef $by_chash;
 447         while (my ($ibx, $e) = splice(@todo, 0, 2)) {
 448                 reindex_unseen($self, $sync, $ibx, $e);
 449         }
 450 }
 451
 452 sub _reindex_oid { # git->cat_async callback
 453         my ($bref, $oid, $type, $size, $req) = @_;
 454         my $sync = $req->{sync};
 455         my $self = $sync->{self};
 456         my $orig_smsg = $req->{orig_smsg} // die 'BUG: no {orig_smsg}';
 457         my $expect_oid = $req->{xr3r}->[$req->{ix}]->[2];
 458         my $docid = $orig_smsg->{num};
 459         if (is_bad_blob($oid, $type, $size, $expect_oid)) {
 460                 my $remain = $self->{oidx}->remove_xref3($docid, $expect_oid);
 461                 if ($remain == 0) {
 462                         warn "W: #$docid gone or corrupted\n";
 463                         $self->idx_shard($docid)->shard_remove($docid);
 464                 } elsif (my $next_oid = $req->{xr3r}->[++$req->{ix}]->[2]) {
 465                         $self->git->cat_async($next_oid, \&_reindex_oid, $req);
 466                 } else {
 467                         warn "BUG: #$docid gone (UNEXPECTED)\n";
 468                         $self->idx_shard($docid)->shard_remove($docid);
 469                 }
 470                 return;
 471         }
 472         my $ci = $self->{current_info};
 473         local $self->{current_info} = "$ci #$docid $oid";
 474         my $re_smsg = bless { blob => $oid }, 'PublicInbox::Smsg';
 475         $re_smsg->{bytes} = $size + crlf_adjust($$bref);
 476         my $eml = PublicInbox::Eml->new($bref);
 477         $re_smsg->populate($eml, { autime => $orig_smsg->{ds},
 478                                 cotime => $orig_smsg->{ts} });
 479         my $chash = content_hash($eml);
 480         $re_smsg->{chash} = $chash;
 481         $re_smsg->{xnum} = $req->{xr3r}->[$req->{ix}]->[1];
 482         $re_smsg->{ibx_id} = $req->{xr3r}->[$req->{ix}]->[0];
 483         $re_smsg->{hdr} = $eml->header_obj;
 484         push @{$req->{by_chash}->{$chash}}, $re_smsg;
 485         if (my $next_oid = $req->{xr3r}->[++$req->{ix}]->[2]) {
 486                 $self->git->cat_async($next_oid, \&_reindex_oid, $req);
 487         } else { # last $re_smsg is the highest priority xref3
 488                 local $self->{current_info} = "$ci #$docid";
 489                 _reindex_finalize($req, $re_smsg, $eml);
 490         }
 491 }
 492
 493 sub _reindex_smsg ($$$) {
 494         my ($self, $sync, $smsg) = @_;
 495         my $docid = $smsg->{num};
 496         my $xr3 = $self->{oidx}->get_xref3($docid, 1);
 497         if (scalar(@$xr3) == 0) { # _reindex_check_stale should've covered this
 498                 warn <<"";
 499 BUG? #$docid $smsg->{blob} is not referenced by inboxes during reindex
 500
 501                 $self->{oidx}->delete_by_num($docid);
 502                 $self->idx_shard($docid)->shard_remove($docid);
 503                 return;
 504         }
 505
 506         # we sort {xr3r} in the reverse order of {ibx_list} so we can
 507         # hit the common case in _reindex_finalize without rereading
 508         # from git (or holding multiple messages in memory).
 509         my $id2pos = $sync->{id2pos}; # index in {ibx_list}
 510         @$xr3 = sort {
 511                 $id2pos->{$b->[0]} <=> $id2pos->{$a->[0]}
 512                                 ||
 513                 $b->[1] <=> $a->[1] # break ties with {xnum}
 514         } @$xr3;
 515         @$xr3 = map { [ $_->[0], $_->[1], unpack('H*', $_->[2]) ] } @$xr3;
 516         my $req = { orig_smsg => $smsg, sync => $sync, xr3r => $xr3, ix => 0 };
 517         $self->git->cat_async($xr3->[$req->{ix}]->[2], \&_reindex_oid, $req);
 518 }
 519
 520 sub checkpoint_due ($) {
 521         my ($sync) = @_;
 522         ${$sync->{need_checkpoint}} || (now() > $sync->{next_check});
 523 }
 524
 525 sub host_ident () {
 526         # I've copied FS images and only changed the hostname before,
 527         # so prepend hostname.  Use `state' since these a BOFH can change
 528         # these while this process is running and we always want to be
 529         # able to release locks taken by this process.
 530         state $retval = hostname . '-' . do {
 531                 my $m; # machine-id(5) is systemd
 532                 if (open(my $fh, '<', '/etc/machine-id')) { $m = <$fh> }
 533                 # (g)hostid(1) is in GNU coreutils, kern.hostid is most BSDs
 534                 chomp($m ||= `{ sysctl -n kern.hostid ||
 535                                 hostid || ghostid; } 2>/dev/null`
 536                         || "no-machine-id-or-hostid-on-$^O");
 537                 $m;
 538         };
 539 }
 540
 541 sub eidxq_release {
 542         my ($self) = @_;
 543         my $expect = delete($self->{-eidxq_locked}) or return;
 544         my ($owner_pid, undef) = split(/-/, $expect);
 545         return if $owner_pid != $$; # shards may fork
 546         my $oidx = $self->{oidx};
 547         $oidx->begin_lazy;
 548         my $cur = $oidx->eidx_meta('eidxq_lock') // '';
 549         if ($cur eq $expect) {
 550                 $oidx->eidx_meta('eidxq_lock', '');
 551                 return 1;
 552         } elsif ($cur ne '') {
 553                 warn "E: eidxq_lock($expect) stolen by $cur\n";
 554         } else {
 555                 warn "E: eidxq_lock($expect) released by another process\n";
 556         }
 557         undef;
 558 }
 559
 560 sub DESTROY {
 561         my ($self) = @_;
 562         eidxq_release($self) and $self->{oidx}->commit_lazy;
 563 }
 564
 565 sub _eidxq_take ($) {
 566         my ($self) = @_;
 567         my $val = "$$-${\time}-$>-".host_ident;
 568         $self->{oidx}->eidx_meta('eidxq_lock', $val);
 569         $self->{-eidxq_locked} = $val;
 570 }
 571
 572 sub eidxq_lock_acquire ($) {
 573         my ($self) = @_;
 574         my $oidx = $self->{oidx};
 575         $oidx->begin_lazy;
 576         my $cur = $oidx->eidx_meta('eidxq_lock') || return _eidxq_take($self);
 577         if (my $locked = $self->{-eidxq_locked}) { # be lazy
 578                 return $locked if $locked eq $cur;
 579         }
 580         my ($pid, $time, $euid, $ident) = split(/-/, $cur, 4);
 581         my $t = strftime('%Y-%m-%d %k:%M:%S', gmtime($time));
 582         if ($euid == $> && $ident eq host_ident) {
 583                 if (kill(0, $pid)) {
 584                         warn <<EOM; return;
 585 I: PID:$pid (re)indexing Xapian since $t, it will continue our work
 586 EOM
 587                 }
 588                 if ($!{ESRCH}) {
 589                         warn "I: eidxq_lock is stale ($cur), clobbering\n";
 590                         return _eidxq_take($self);
 591                 }
 592                 warn "E: kill(0, $pid) failed: $!\n"; # fall-through:
 593         }
 594         my $fn = $oidx->dbh->sqlite_db_filename;
 595         warn <<EOF;
 596 W: PID:$pid, UID:$euid on $ident is indexing Xapian since $t
 597 W: If this is unexpected, delete `eidxq_lock' from the `eidx_meta' table:
 598 W:      sqlite3 $fn 'DELETE FROM eidx_meta WHERE key = "eidxq_lock"'
 599 EOF
 600         undef;
 601 }
 602
 603 sub eidxq_process ($$) { # for reindexing
 604         my ($self, $sync) = @_;
 605
 606         return unless eidxq_lock_acquire($self);
 607         my $dbh = $self->{oidx}->dbh;
 608         my $tot = $dbh->selectrow_array('SELECT COUNT(*) FROM eidxq') or return;
 609         ${$sync->{nr}} = 0;
 610         $sync->{-regen_fmt} = "%u/$tot\n";
 611         my $pr = $sync->{-opt}->{-progress};
 612         if ($pr) {
 613                 my $min = $dbh->selectrow_array('SELECT MIN(docid) FROM eidxq');
 614                 my $max = $dbh->selectrow_array('SELECT MAX(docid) FROM eidxq');
 615                 $pr->("Xapian indexing $min..$max (total=$tot)\n");
 616         }
 617         $sync->{id2pos} //= do {
 618                 my %id2pos;
 619                 my $pos = 0;
 620                 $id2pos{$_->{-ibx_id}} = $pos++ for @{$self->{ibx_list}};
 621                 \%id2pos;
 622         };
 623         my ($del, $iter);
 624 restart:
 625         $del = $dbh->prepare('DELETE FROM eidxq WHERE docid = ?');
 626         $iter = $dbh->prepare('SELECT docid FROM eidxq ORDER BY docid ASC');
 627         $iter->execute;
 628         while (defined(my $docid = $iter->fetchrow_array)) {
 629                 last if $sync->{quit};
 630                 if (my $smsg = $self->{oidx}->get_art($docid)) {
 631                         _reindex_smsg($self, $sync, $smsg);
 632                 } else {
 633                         warn "E: #$docid does not exist in over\n";
 634                 }
 635                 $del->execute($docid);
 636                 ++${$sync->{nr}};
 637
 638                 if (checkpoint_due($sync)) {
 639                         $dbh = $del = $iter = undef;
 640                         reindex_checkpoint($self, $sync); # release lock
 641                         $dbh = $self->{oidx}->dbh;
 642                         goto restart;
 643                 }
 644         }
 645         $self->git->async_wait_all;
 646         $pr->("reindexed ${$sync->{nr}}/$tot\n") if $pr;
 647 }
 648
 649 sub _reindex_unseen { # git->cat_async callback
 650         my ($bref, $oid, $type, $size, $req) = @_;
 651         return if is_bad_blob($oid, $type, $size, $req->{oid});
 652         my $self = $req->{self} // die 'BUG: {self} unset';
 653         local $self->{current_info} = "$self->{current_info} $oid";
 654         my $new_smsg = bless { blob => $oid, }, 'PublicInbox::Smsg';
 655         $new_smsg->{bytes} = $size + crlf_adjust($$bref);
 656         my $eml = $req->{eml} = PublicInbox::Eml->new($bref);
 657         $req->{new_smsg} = $new_smsg;
 658         $req->{chash} = content_hash($eml);
 659         $req->{mids} = mids($eml); # do_step iterates through this
 660         do_step($req); # enter the normal indexing flow
 661 }
 662
 663 # --reindex may catch totally unseen messages, this handles them
 664 sub reindex_unseen ($$$$) {
 665         my ($self, $sync, $ibx, $xsmsg) = @_;
 666         my $req = {
 667                 %$sync, # has {self}
 668                 autime => $xsmsg->{ds},
 669                 cotime => $xsmsg->{ts},
 670                 oid => $xsmsg->{blob},
 671                 ibx => $ibx,
 672                 xnum => $xsmsg->{num},
 673                 # {mids} and {chash} will be filled in at _reindex_unseen
 674         };
 675         warn "I: reindex_unseen ${\$ibx->eidx_key}:$req->{xnum}:$req->{oid}\n";
 676         $self->git->cat_async($xsmsg->{blob}, \&_reindex_unseen, $req);
 677 }
 678
 679 sub _reindex_check_unseen ($$$) {
 680         my ($self, $sync, $ibx) = @_;
 681         my $ibx_id = $ibx->{-ibx_id};
 682         my $slice = 1000;
 683         my ($beg, $end) = (1, $slice);
 684
 685         # first, check if we missed any messages in target $ibx
 686         my $msgs;
 687         my $pr = $sync->{-opt}->{-progress};
 688         my $ekey = $ibx->eidx_key;
 689         $sync->{-regen_fmt} = "$ekey checking unseen %u/".$ibx->over->max."\n";
 690         ${$sync->{nr}} = 0;
 691
 692         while (scalar(@{$msgs = $ibx->over->query_xover($beg, $end)})) {
 693                 ${$sync->{nr}} = $beg;
 694                 $beg = $msgs->[-1]->{num} + 1;
 695                 $end = $beg + $slice;
 696                 if (checkpoint_due($sync)) {
 697                         reindex_checkpoint($self, $sync); # release lock
 698                 }
 699
 700                 my $inx3 = $self->{oidx}->dbh->prepare_cached(<<'', undef, 1);
 701 SELECT DISTINCT(docid) FROM xref3 WHERE
 702 ibx_id = ? AND xnum = ? AND oidbin = ?
 703
 704                 for my $xsmsg (@$msgs) {
 705                         my $oidbin = pack('H*', $xsmsg->{blob});
 706                         $inx3->bind_param(1, $ibx_id);
 707                         $inx3->bind_param(2, $xsmsg->{num});
 708                         $inx3->bind_param(3, $oidbin, SQL_BLOB);
 709                         $inx3->execute;
 710                         my $docids = $inx3->fetchall_arrayref;
 711                         # index messages which were totally missed
 712                         # the first time around ASAP:
 713                         if (scalar(@$docids) == 0) {
 714                                 reindex_unseen($self, $sync, $ibx, $xsmsg);
 715                         } else { # already seen, reindex later
 716                                 for my $r (@$docids) {
 717                                         $self->{oidx}->eidxq_add($r->[0]);
 718                                 }
 719                         }
 720                         last if $sync->{quit};
 721                 }
 722                 last if $sync->{quit};
 723         }
 724 }
 725
 726 sub _reindex_check_stale ($$$) {
 727         my ($self, $sync, $ibx) = @_;
 728         my $min = 0;
 729         my $pr = $sync->{-opt}->{-progress};
 730         my $fetching;
 731         my $ekey = $ibx->eidx_key;
 732         $sync->{-regen_fmt} =
 733                         "$ekey check stale/missing %u/".$ibx->over->max."\n";
 734         ${$sync->{nr}} = 0;
 735         do {
 736                 if (checkpoint_due($sync)) {
 737                         reindex_checkpoint($self, $sync); # release lock
 738                 }
 739                 # now, check if there's stale xrefs
 740                 my $iter = $self->{oidx}->dbh->prepare_cached(<<'', undef, 1);
 741 SELECT docid,xnum,oidbin FROM xref3 WHERE ibx_id = ? AND docid > ?
 742 ORDER BY docid,xnum ASC LIMIT 10000
 743
 744                 $iter->execute($ibx->{-ibx_id}, $min);
 745                 $fetching = undef;
 746
 747                 while (my ($docid, $xnum, $oidbin) = $iter->fetchrow_array) {
 748                         return if $sync->{quit};
 749                         ${$sync->{nr}} = $xnum;
 750
 751                         $fetching = $min = $docid;
 752                         my $smsg = $ibx->over->get_art($xnum);
 753                         my $oidhex = unpack('H*', $oidbin);
 754                         my $err;
 755                         if (!$smsg) {
 756                                 $err = 'stale';
 757                         } elsif ($smsg->{blob} ne $oidhex) {
 758                                 $err = "mismatch (!= $smsg->{blob})";
 759                         } else {
 760                                 next; # likely, all good
 761                         }
 762                         # current_info already has eidx_key
 763                         warn "$xnum:$oidhex (#$docid): $err\n";
 764                         my $del = $self->{oidx}->dbh->prepare_cached(<<'');
 765 DELETE FROM xref3 WHERE ibx_id = ? AND xnum = ? AND oidbin = ?
 766
 767                         $del->bind_param(1, $ibx->{-ibx_id});
 768                         $del->bind_param(2, $xnum);
 769                         $del->bind_param(3, $oidbin, SQL_BLOB);
 770                         $del->execute;
 771
 772                         # get_xref3 over-fetches, but this is a rare path:
 773                         my $xr3 = $self->{oidx}->get_xref3($docid);
 774                         my $idx = $self->idx_shard($docid);
 775                         if (scalar(@$xr3) == 0) { # all gone
 776                                 $self->{oidx}->delete_by_num($docid);
 777                                 $self->{oidx}->eidxq_del($docid);
 778                                 $idx->shard_remove($docid);
 779                         } else { # enqueue for reindex of remaining messages
 780                                 $idx->shard_remove_eidx_info($docid,
 781                                                         $ibx->eidx_key);
 782                                 $self->{oidx}->eidxq_add($docid); # yes, add
 783                         }
 784                 }
 785         } while (defined $fetching);
 786 }
 787
 788 sub _reindex_inbox ($$$) {
 789         my ($self, $sync, $ibx) = @_;
 790         local $self->{current_info} = $ibx->eidx_key;
 791         _reindex_check_unseen($self, $sync, $ibx);
 792         _reindex_check_stale($self, $sync, $ibx) unless $sync->{quit};
 793         delete @$ibx{qw(over mm search git)}; # won't need these for a bit
 794 }
 795
 796 sub eidx_reindex {
 797         my ($self, $sync) = @_;
 798
 799         # acquire eidxq_lock early because full reindex takes forever
 800         # and incremental -extindex processes can run during our checkpoints
 801         if (!eidxq_lock_acquire($self)) {
 802                 warn "E: aborting --reindex\n";
 803                 return;
 804         }
 805         for my $ibx (@{$self->{ibx_list}}) {
 806                 _reindex_inbox($self, $sync, $ibx);
 807                 last if $sync->{quit};
 808         }
 809         $self->git->async_wait_all; # ensure eidxq gets filled completely
 810         eidxq_process($self, $sync) unless $sync->{quit};
 811 }
 812
 813 sub eidx_sync { # main entry point
 814         my ($self, $opt) = @_;
 815
 816         my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
 817         local $self->{current_info} = '';
 818         local $SIG{__WARN__} = sub {
 819                 $warn_cb->($self->{current_info}, ': ', @_);
 820         };
 821         $self->idx_init($opt); # acquire lock via V2Writable::_idx_init
 822         $self->{oidx}->rethread_prepare($opt);
 823         my $sync = {
 824                 need_checkpoint => \(my $need_checkpoint = 0),
 825                 check_intvl => 10,
 826                 next_check => now() + 10,
 827                 -opt => $opt,
 828                 # DO NOT SET {reindex} here, it's incompatible with reused
 829                 # V2Writable code, reindex is totally different here
 830                 # compared to v1/v2 inboxes because we have multiple histories
 831                 self => $self,
 832                 -regen_fmt => "%u/?\n",
 833         };
 834         local $SIG{USR1} = sub { $need_checkpoint = 1 };
 835         my $quit = PublicInbox::SearchIdx::quit_cb($sync);
 836         local $SIG{QUIT} = $quit;
 837         local $SIG{INT} = $quit;
 838         local $SIG{TERM} = $quit;
 839         for my $ibx (@{$self->{ibx_list}}) {
 840                 $ibx->{-ibx_id} //= $self->{oidx}->ibx_id($ibx->eidx_key);
 841         }
 842         if (delete($opt->{reindex})) {
 843                 $sync->{checkpoint_unlocks} = 1;
 844                 eidx_reindex($self, $sync);
 845         }
 846
 847         # don't use $_ here, it'll get clobbered by reindex_checkpoint
 848         for my $ibx (@{$self->{ibx_list}}) {
 849                 last if $sync->{quit};
 850                 _sync_inbox($self, $sync, $ibx);
 851         }
 852         $self->{oidx}->rethread_done($opt) unless $sync->{quit};
 853         eidxq_process($self, $sync) unless $sync->{quit};
 854
 855         eidxq_release($self);
 856         PublicInbox::V2Writable::done($self);
 857 }
 858
 859 sub update_last_commit { # overrides V2Writable
 860         my ($self, $sync, $stk) = @_;
 861         my $unit = $sync->{unit} // return;
 862         my $latest_cmt = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 863         defined($latest_cmt) or return;
 864         my $ibx = $sync->{ibx} or die 'BUG: {ibx} missing';
 865         my $ekey = $ibx->eidx_key;
 866         my $uv = $ibx->uidvalidity;
 867         my $epoch = $unit->{epoch};
 868         my $meta_key;
 869         my $v = $ibx->version;
 870         if ($v == 2) {
 871                 die 'No {epoch} for v2 unit' unless defined $epoch;
 872                 $meta_key = "lc-v2:$ekey//$uv;$epoch";
 873         } elsif ($v == 1) {
 874                 die 'Unexpected {epoch} for v1 unit' if defined $epoch;
 875                 $meta_key = "lc-v1:$ekey//$uv";
 876         } else {
 877                 die "Unsupported inbox version: $v";
 878         }
 879         my $last = $self->{oidx}->eidx_meta($meta_key);
 880         if (defined $last && is_ancestor($self->git, $last, $latest_cmt)) {
 881                 my @cmd = (qw(rev-list --count), "$last..$latest_cmt");
 882                 chomp(my $n = $unit->{git}->qx(@cmd));
 883                 return if $n ne '' && $n == 0;
 884         }
 885         $self->{oidx}->eidx_meta($meta_key, $latest_cmt);
 886 }
 887
 888 sub _idx_init { # with_umask callback
 889         my ($self, $opt) = @_;
 890         PublicInbox::V2Writable::_idx_init($self, $opt);
 891         $self->{midx} = PublicInbox::MiscIdx->new($self);
 892 }
 893
 894 sub idx_init { # similar to V2Writable
 895         my ($self, $opt) = @_;
 896         return if $self->{idx_shards};
 897
 898         $self->git->cleanup;
 899
 900         my $ALL = $self->git->{git_dir}; # ALL.git
 901         PublicInbox::Import::init_bare($ALL) unless -d $ALL;
 902         my $info_dir = "$ALL/objects/info";
 903         my $alt = "$info_dir/alternates";
 904         my $mode = 0644;
 905         my (@old, @new, %seen); # seen: st_dev + st_ino
 906         if (-e $alt) {
 907                 open(my $fh, '<', $alt) or die "open $alt: $!";
 908                 $mode = (stat($fh))[2] & 07777;
 909                 while (my $line = <$fh>) {
 910                         chomp(my $d = $line);
 911                         if (my @st = stat($d)) {
 912                                 next if $seen{"$st[0]\0$st[1]"}++;
 913                         } else {
 914                                 warn "W: stat($d) failed (from $alt): $!\n";
 915                                 next if $opt->{-idx_gc};
 916                         }
 917                         push @old, $line;
 918                 }
 919         }
 920         for my $ibx (@{$self->{ibx_list}}) {
 921                 my $line = $ibx->git->{git_dir} . "/objects\n";
 922                 chomp(my $d = $line);
 923                 if (my @st = stat($d)) {
 924                         next if $seen{"$st[0]\0$st[1]"}++;
 925                 } else {
 926                         warn "W: stat($d) failed (from $ibx->{inboxdir}): $!\n";
 927                         next if $opt->{-idx_gc};
 928                 }
 929                 push @new, $line;
 930         }
 931         if (scalar @new) {
 932                 push @old, @new;
 933                 my $o = \@old;
 934                 PublicInbox::V2Writable::write_alternates($info_dir, $mode, $o);
 935         }
 936         $self->parallel_init($self->{indexlevel});
 937         $self->with_umask(\&_idx_init, $self, $opt);
 938         $self->{oidx}->begin_lazy;
 939         $self->{oidx}->eidx_prep;
 940         $self->{midx}->begin_txn;
 941 }
 942
 943 no warnings 'once';
 944 *done = \&PublicInbox::V2Writable::done;
 945 *with_umask = \&PublicInbox::InboxWritable::with_umask;
 946 *parallel_init = \&PublicInbox::V2Writable::parallel_init;
 947 *nproc_shards = \&PublicInbox::V2Writable::nproc_shards;
 948 *sync_prepare = \&PublicInbox::V2Writable::sync_prepare;
 949 *index_todo = \&PublicInbox::V2Writable::index_todo;
 950 *count_shards = \&PublicInbox::V2Writable::count_shards;
 951 *atfork_child = \&PublicInbox::V2Writable::atfork_child;
 952 *idx_shard = \&PublicInbox::V2Writable::idx_shard;
 953 *reindex_checkpoint = \&PublicInbox::V2Writable::reindex_checkpoint;
 954
 955 1;