lib/PublicInbox/ExtSearchIdx.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Detached/external index cross inbox search indexing support
   5 # read-write counterpart to PublicInbox::ExtSearch
   6 #
   7 # It's based on the same ideas as public-inbox-v2-format(5) using
   8 # over.sqlite3 for dedupe and sharded Xapian.  msgmap.sqlite3 is
   9 # missing, so there is no Message-ID conflict resolution, meaning
  10 # no NNTP support for now.
  11 #
  12 # v2 has a 1:1 mapping of index:inbox or msgmap for NNTP support.
  13 # This is intended to be an M:N index:inbox mapping, but it'll likely
  14 # be 1:N in common practice (M==1)
  15
  16 package PublicInbox::ExtSearchIdx;
  17 use strict;
  18 use v5.10.1;
  19 use parent qw(PublicInbox::ExtSearch PublicInbox::Lock);
  20 use Carp qw(croak carp);
  21 use PublicInbox::Search;
  22 use PublicInbox::SearchIdx qw(crlf_adjust prepare_stack is_ancestor
  23         is_bad_blob);
  24 use PublicInbox::OverIdx;
  25 use PublicInbox::MiscIdx;
  26 use PublicInbox::MID qw(mids);
  27 use PublicInbox::V2Writable;
  28 use PublicInbox::InboxWritable;
  29 use PublicInbox::ContentHash qw(content_hash);
  30 use PublicInbox::Eml;
  31 use File::Spec;
  32 use DBI qw(:sql_types); # SQL_BLOB
  33
  34 sub new {
  35         my (undef, $dir, $opt) = @_;
  36         $dir = File::Spec->canonpath($dir);
  37         my $l = $opt->{indexlevel} // 'full';
  38         $l !~ $PublicInbox::SearchIdx::INDEXLEVELS and
  39                 die "invalid indexlevel=$l\n";
  40         $l eq 'basic' and die "E: indexlevel=basic not yet supported\n";
  41         my $self = bless {
  42                 xpfx => "$dir/ei".PublicInbox::Search::SCHEMA_VERSION,
  43                 topdir => $dir,
  44                 creat => $opt->{creat},
  45                 ibx_map => {}, # (newsgroup//inboxdir) => $ibx
  46                 ibx_list => [],
  47                 indexlevel => $l,
  48                 transact_bytes => 0,
  49                 total_bytes => 0,
  50                 current_info => '',
  51                 parallel => 1,
  52                 lock_path => "$dir/ei.lock",
  53         }, __PACKAGE__;
  54         $self->{shards} = $self->count_shards || nproc_shards($opt->{creat});
  55         my $oidx = PublicInbox::OverIdx->new("$self->{xpfx}/over.sqlite3");
  56         $oidx->{-no_fsync} = 1 if $opt->{-no_fsync};
  57         $self->{oidx} = $oidx;
  58         $self
  59 }
  60
  61 sub attach_inbox {
  62         my ($self, $ibx) = @_;
  63         $ibx = PublicInbox::InboxWritable->new($ibx);
  64         my $key = $ibx->eidx_key;
  65         if (!$ibx->over || !$ibx->mm) {
  66                 warn "W: skipping $key (unindexed)\n";
  67                 return;
  68         }
  69         if (!defined($ibx->uidvalidity)) {
  70                 warn "W: skipping $key (no UIDVALIDITY)\n";
  71                 return;
  72         }
  73         my $ibxdir = File::Spec->canonpath($ibx->{inboxdir});
  74         if ($ibxdir ne $ibx->{inboxdir}) {
  75                 warn "W: `$ibx->{inboxdir}' canonicalized to `$ibxdir'\n";
  76                 $ibx->{inboxdir} = $ibxdir;
  77         }
  78         $ibx = PublicInbox::InboxWritable->new($ibx);
  79         $self->{ibx_map}->{$key} //= do {
  80                 push @{$self->{ibx_list}}, $ibx;
  81                 $ibx;
  82         }
  83 }
  84
  85 sub _ibx_attach { # each_inbox callback
  86         my ($ibx, $self) = @_;
  87         attach_inbox($self, $ibx);
  88 }
  89
  90 sub attach_config {
  91         my ($self, $cfg) = @_;
  92         $self->{cfg} = $cfg;
  93         $cfg->each_inbox(\&_ibx_attach, $self);
  94 }
  95
  96 sub check_batch_limit ($) {
  97         my ($req) = @_;
  98         my $self = $req->{self};
  99         my $new_smsg = $req->{new_smsg};
 100
 101         # {raw_bytes} may be unset, so just use {bytes}
 102         my $n = $self->{transact_bytes} += $new_smsg->{bytes};
 103
 104         # set flag for PublicInbox::V2Writable::index_todo:
 105         ${$req->{need_checkpoint}} = 1 if $n >= $self->{batch_bytes};
 106 }
 107
 108 sub do_xpost ($$) {
 109         my ($req, $smsg) = @_;
 110         my $self = $req->{self};
 111         my $docid = $smsg->{num};
 112         my $idx = $self->idx_shard($docid);
 113         my $oid = $req->{oid};
 114         my $xibx = $req->{ibx};
 115         my $eml = $req->{eml};
 116         my $eidx_key = $xibx->eidx_key;
 117         if (my $new_smsg = $req->{new_smsg}) { # 'm' on cross-posted message
 118                 my $xnum = $req->{xnum};
 119                 $self->{oidx}->add_xref3($docid, $xnum, $oid, $eidx_key);
 120                 $idx->shard_add_eidx_info($docid, $eidx_key, $eml);
 121                 check_batch_limit($req);
 122         } else { # 'd'
 123                 my $rm_eidx_info;
 124                 my $nr = $self->{oidx}->remove_xref3($docid, $oid, $eidx_key,
 125                                                         \$rm_eidx_info);
 126                 if ($nr == 0) {
 127                         $self->{oidx}->eidxq_del($docid);
 128                         $idx->shard_remove($docid);
 129                 } elsif ($rm_eidx_info) {
 130                         $idx->shard_remove_eidx_info($docid, $eidx_key, $eml);
 131                         $self->{oidx}->eidxq_add($docid); # yes, add
 132                 }
 133         }
 134 }
 135
 136 # called by V2Writable::sync_prepare
 137 sub artnum_max { $_[0]->{oidx}->eidx_max }
 138
 139 sub index_unseen ($) {
 140         my ($req) = @_;
 141         my $new_smsg = $req->{new_smsg} or die 'BUG: {new_smsg} unset';
 142         my $eml = delete $req->{eml};
 143         $new_smsg->populate($eml, $req);
 144         my $self = $req->{self};
 145         my $docid = $self->{oidx}->adj_counter('eidx_docid', '+');
 146         $new_smsg->{num} = $docid;
 147         my $idx = $self->idx_shard($docid);
 148         $self->{oidx}->add_overview($eml, $new_smsg);
 149         my $oid = $new_smsg->{blob};
 150         my $ibx = delete $req->{ibx} or die 'BUG: {ibx} unset';
 151         $self->{oidx}->add_xref3($docid, $req->{xnum}, $oid, $ibx->eidx_key);
 152         $idx->index_raw(undef, $eml, $new_smsg, $ibx);
 153         check_batch_limit($req);
 154 }
 155
 156 sub do_finalize ($) {
 157         my ($req) = @_;
 158         if (my $indexed = $req->{indexed}) {
 159                 do_xpost($req, $_) for @$indexed;
 160         } elsif (exists $req->{new_smsg}) { # totally unseen messsage
 161                 index_unseen($req);
 162         } else {
 163                 # `d' message was already unindexed in the v1/v2 inboxes,
 164                 # so it's too noisy to warn, here.
 165         }
 166         # cur_cmt may be undef for unindex_oid, set by V2Writable::index_todo
 167         if (defined(my $cur_cmt = $req->{cur_cmt})) {
 168                 ${$req->{latest_cmt}} = $cur_cmt;
 169         }
 170 }
 171
 172 sub do_step ($) { # main iterator for adding messages to the index
 173         my ($req) = @_;
 174         my $self = $req->{self} // die 'BUG: {self} missing';
 175         while (1) {
 176                 if (my $next_arg = $req->{next_arg}) {
 177                         if (my $smsg = $self->{oidx}->next_by_mid(@$next_arg)) {
 178                                 $req->{cur_smsg} = $smsg;
 179                                 $self->git->cat_async($smsg->{blob},
 180                                                         \&ck_existing, $req);
 181                                 return; # ck_existing calls do_step
 182                         }
 183                         delete $req->{cur_smsg};
 184                         delete $req->{next_arg};
 185                 }
 186                 my $mid = shift(@{$req->{mids}});
 187                 last unless defined $mid;
 188                 my ($id, $prev);
 189                 $req->{next_arg} = [ $mid, \$id, \$prev ];
 190                 # loop again
 191         }
 192         do_finalize($req);
 193 }
 194
 195 sub _blob_missing ($) { # called when req->{cur_smsg}->{blob} is bad
 196         my ($req) = @_;
 197         my $smsg = $req->{cur_smsg} or die 'BUG: {cur_smsg} missing';
 198         my $self = $req->{self};
 199         my $xref3 = $self->{oidx}->get_xref3($smsg->{num});
 200         my @keep = grep(!/:$smsg->{blob}\z/, @$xref3);
 201         if (@keep) {
 202                 $keep[0] =~ /:([a-f0-9]{40,}+)\z/ or
 203                         die "BUG: xref $keep[0] has no OID";
 204                 my $oidhex = $1;
 205                 $self->{oidx}->remove_xref3($smsg->{num}, $smsg->{blob});
 206                 my $upd = $self->{oidx}->update_blob($smsg, $oidhex);
 207                 my $saved = $self->{oidx}->get_art($smsg->{num});
 208         } else {
 209                 $self->{oidx}->delete_by_num($smsg->{num});
 210         }
 211 }
 212
 213 sub ck_existing { # git->cat_async callback
 214         my ($bref, $oid, $type, $size, $req) = @_;
 215         my $smsg = $req->{cur_smsg} or die 'BUG: {cur_smsg} missing';
 216         if ($type eq 'missing') {
 217                 _blob_missing($req);
 218         } elsif (!is_bad_blob($oid, $type, $size, $smsg->{blob})) {
 219                 my $self = $req->{self} // die 'BUG: {self} missing';
 220                 local $self->{current_info} = "$self->{current_info} $oid";
 221                 my $cur = PublicInbox::Eml->new($bref);
 222                 if (content_hash($cur) eq $req->{chash}) {
 223                         push @{$req->{indexed}}, $smsg; # for do_xpost
 224                 } # else { index_unseen later }
 225         }
 226         do_step($req);
 227 }
 228
 229 # is the messages visible in the inbox currently being indexed?
 230 # return the number if so
 231 sub cur_ibx_xnum ($$) {
 232         my ($req, $bref) = @_;
 233         my $ibx = $req->{ibx} or die 'BUG: current {ibx} missing';
 234
 235         $req->{eml} = PublicInbox::Eml->new($bref);
 236         $req->{chash} = content_hash($req->{eml});
 237         $req->{mids} = mids($req->{eml});
 238         my @q = @{$req->{mids}}; # copy
 239         while (defined(my $mid = shift @q)) {
 240                 my ($id, $prev);
 241                 while (my $x = $ibx->over->next_by_mid($mid, \$id, \$prev)) {
 242                         return $x->{num} if $x->{blob} eq $req->{oid};
 243                 }
 244         }
 245         undef;
 246 }
 247
 248 sub index_oid { # git->cat_async callback for 'm'
 249         my ($bref, $oid, $type, $size, $req) = @_;
 250         my $self = $req->{self};
 251         local $self->{current_info} = "$self->{current_info} $oid";
 252         return if is_bad_blob($oid, $type, $size, $req->{oid});
 253         my $new_smsg = $req->{new_smsg} = bless {
 254                 blob => $oid,
 255         }, 'PublicInbox::Smsg';
 256         $new_smsg->{bytes} = $size + crlf_adjust($$bref);
 257         defined($req->{xnum} = cur_ibx_xnum($req, $bref)) or return;
 258         ++${$req->{nr}};
 259         do_step($req);
 260 }
 261
 262 sub unindex_oid { # git->cat_async callback for 'd'
 263         my ($bref, $oid, $type, $size, $req) = @_;
 264         my $self = $req->{self};
 265         local $self->{current_info} = "$self->{current_info} $oid";
 266         return if is_bad_blob($oid, $type, $size, $req->{oid});
 267         return if defined(cur_ibx_xnum($req, $bref)); # was re-added
 268         do_step($req);
 269 }
 270
 271 # overrides V2Writable::last_commits, called by sync_ranges via sync_prepare
 272 sub last_commits {
 273         my ($self, $sync) = @_;
 274         my $heads = [];
 275         my $ekey = $sync->{ibx}->eidx_key;
 276         my $uv = $sync->{ibx}->uidvalidity;
 277         for my $i (0..$sync->{epoch_max}) {
 278                 $heads->[$i] = $self->{oidx}->eidx_meta("lc-v2:$ekey//$uv;$i");
 279         }
 280         $heads;
 281 }
 282
 283 sub _sync_inbox ($$$) {
 284         my ($self, $sync, $ibx) = @_;
 285         $sync->{ibx} = $ibx;
 286         $sync->{nr} = \(my $nr = 0);
 287         my $v = $ibx->version;
 288         my $ekey = $ibx->eidx_key;
 289         if ($v == 2) {
 290                 my $epoch_max;
 291                 defined($ibx->git_dir_latest(\$epoch_max)) or return;
 292                 $sync->{epoch_max} = $epoch_max;
 293                 sync_prepare($self, $sync); # or return # TODO: once MiscIdx is stable
 294         } elsif ($v == 1) {
 295                 my $uv = $ibx->uidvalidity;
 296                 my $lc = $self->{oidx}->eidx_meta("lc-v1:$ekey//$uv");
 297                 my $head = $ibx->mm->last_commit;
 298                 unless (defined $head) {
 299                         warn "E: $ibx->{inboxdir} is not indexed\n";
 300                         return;
 301                 }
 302                 my $stk = prepare_stack($sync, $lc ? "$lc..$head" : $head);
 303                 my $unit = { stack => $stk, git => $ibx->git };
 304                 push @{$sync->{todo}}, $unit;
 305         } else {
 306                 warn "E: $ekey unsupported inbox version (v$v)\n";
 307                 return;
 308         }
 309         for my $unit (@{delete($sync->{todo}) // []}) {
 310                 last if $sync->{quit};
 311                 index_todo($self, $sync, $unit);
 312         }
 313         $self->{midx}->index_ibx($ibx) unless $sync->{quit};
 314         $ibx->git->cleanup; # done with this inbox, now
 315 }
 316
 317 sub gc_unref_doc ($$$$) {
 318         my ($self, $ibx_id, $eidx_key, $docid) = @_;
 319         my $dbh = $self->{oidx}->dbh;
 320
 321         # for debug/info purposes, oids may no longer be accessible
 322         my $sth = $dbh->prepare_cached(<<'', undef, 1);
 323 SELECT oidbin FROM xref3 WHERE docid = ? AND ibx_id = ?
 324
 325         $sth->execute($docid, $ibx_id);
 326         my @oid = map { unpack('H*', $_->[0]) } @{$sth->fetchall_arrayref};
 327
 328         $dbh->prepare_cached(<<'')->execute($docid, $ibx_id);
 329 DELETE FROM xref3 WHERE docid = ? AND ibx_id = ?
 330
 331         my $remain = $self->{oidx}->get_xref3($docid);
 332         if (scalar(@$remain)) {
 333                 $self->{oidx}->eidxq_add($docid); # enqueue for reindex
 334                 for my $oid (@oid) {
 335                         warn "I: unref #$docid $eidx_key $oid\n";
 336                 }
 337         } else {
 338                 warn "I: remove #$docid $eidx_key @oid\n";
 339                 $self->idx_shard($docid)->shard_remove($docid);
 340         }
 341 }
 342
 343 sub eidx_gc {
 344         my ($self, $opt) = @_;
 345         $self->{cfg} or die "E: GC requires ->attach_config\n";
 346         $opt->{-idx_gc} = 1;
 347         $self->idx_init($opt); # acquire lock via V2Writable::_idx_init
 348
 349         my $dbh = $self->{oidx}->dbh;
 350         my $x3_doc = $dbh->prepare('SELECT docid FROM xref3 WHERE ibx_id = ?');
 351         my $ibx_ck = $dbh->prepare('SELECT ibx_id,eidx_key FROM inboxes');
 352         my $lc_i = $dbh->prepare('SELECT key FROM eidx_meta WHERE key LIKE ?');
 353
 354         $ibx_ck->execute;
 355         while (my ($ibx_id, $eidx_key) = $ibx_ck->fetchrow_array) {
 356                 next if $self->{ibx_map}->{$eidx_key};
 357                 $self->{midx}->remove_eidx_key($eidx_key);
 358                 warn "I: deleting messages for $eidx_key...\n";
 359                 $x3_doc->execute($ibx_id);
 360                 while (defined(my $docid = $x3_doc->fetchrow_array)) {
 361                         gc_unref_doc($self, $ibx_id, $eidx_key, $docid);
 362                 }
 363                 $dbh->prepare_cached(<<'')->execute($ibx_id);
 364 DELETE FROM inboxes WHERE ibx_id = ?
 365
 366                 # drop last_commit info
 367                 my $pat = $eidx_key;
 368                 $pat =~ s/([_%])/\\$1/g;
 369                 $lc_i->execute("lc-%:$pat//%");
 370                 while (my ($key) = $lc_i->fetchrow_array) {
 371                         next if $key !~ m!\Alc-v[1-9]+:\Q$eidx_key\E//!;
 372                         warn "I: removing $key\n";
 373                         $dbh->prepare_cached(<<'')->execute($key);
 374 DELETE FROM eidx_meta WHERE key = ?
 375
 376                 }
 377
 378                 warn "I: $eidx_key removed\n";
 379         }
 380
 381         # it's not real unless it's in `over', we use parallelism here,
 382         # shards will be reading directly from over, so commit
 383         $self->{oidx}->commit_lazy;
 384         $self->{oidx}->begin_lazy;
 385
 386         for my $idx (@{$self->{idx_shards}}) {
 387                 warn "I: cleaning up shard #$idx->{shard}\n";
 388                 $idx->shard_over_check($self->{oidx});
 389         }
 390         my $nr = $dbh->do(<<'');
 391 DELETE FROM xref3 WHERE docid NOT IN (SELECT num FROM over)
 392
 393         warn "I: eliminated $nr stale xref3 entries\n" if $nr != 0;
 394
 395         done($self);
 396 }
 397
 398 sub _reindex_finalize ($$$) {
 399         my ($req, $smsg, $eml) = @_;
 400         my $sync = $req->{sync};
 401         my $self = $sync->{self};
 402         my $by_chash = $req->{by_chash};
 403         my $nr = scalar(keys(%$by_chash)) or die 'BUG: no content hashes';
 404         my $orig_smsg = $req->{orig_smsg} // die 'BUG: no {orig_smsg}';
 405         my $docid = $smsg->{num} = $orig_smsg->{num};
 406         $self->{oidx}->add_overview($eml, $smsg); # may rethread
 407         return if $nr == 1; # likely, all good
 408
 409         warn "W: #$docid split into $nr due to deduplication change\n";
 410         my $chash0 = $smsg->{chash} // die "BUG: $smsg->{blob} no {chash}";
 411         delete($by_chash->{$chash0}) // die "BUG: $smsg->{blob} chash missing";
 412         for my $ary (values %$by_chash) {
 413                 for my $x (reverse @$ary) {
 414                         my $n = $self->{oidx}->remove_xref3($docid, $x->{blob});
 415                         die "BUG: $x->{blob} invalidated #$docid" if $n == 0;
 416                 }
 417                 my $x = $ary->[-1] // die "BUG: #$docid {by_chash} empty";
 418                 $x->{num} = delete($x->{xnum}) // die '{xnum} unset';
 419                 my $ibx_id = delete($x->{ibx_id}) // die '{ibx_id} unset';
 420                 my $pos = $sync->{id2pos}->{$ibx_id} // die "$ibx_id no pos";
 421                 my $ibx = $self->{ibx_list}->[$pos] //
 422                         die "BUG: ibx for $x->{blob} not mapped";
 423                 my $e = $ibx->over->get_art($x->{num});
 424                 $e->{blob} eq $x->{blob} or die <<EOF;
 425 $x->{blob} != $e->{blob} (${\$ibx->eidx_key}:$e->{num});
 426 EOF
 427                 reindex_unseen($self, $sync, $ibx, $e);
 428         }
 429 }
 430
 431 sub _reindex_oid { # git->cat_async callback
 432         my ($bref, $oid, $type, $size, $req) = @_;
 433         my $sync = $req->{sync};
 434         my $self = $sync->{self};
 435         my $orig_smsg = $req->{orig_smsg} // die 'BUG: no {orig_smsg}';
 436         my $expect_oid = $req->{xr3}->[$req->{ix}]->[2];
 437         my $docid = $orig_smsg->{num};
 438         if (is_bad_blob($oid, $type, $size, $expect_oid)) {
 439                 my $remain = $self->{oidx}->remove_xref3($docid, $expect_oid);
 440                 if ($remain == 0) {
 441                         warn "W: #$docid gone or corrupted\n";
 442                         $self->idx_shard($docid)->shard_remove($docid);
 443                 } elsif (my $next_oid = $req->{xr3}->[++$req->{ix}]->[2]) {
 444                         $self->git->cat_async($next_oid, \&_reindex_oid, $req);
 445                 } else {
 446                         warn "BUG: #$docid gone (UNEXPECTED)\n";
 447                         $self->idx_shard($docid)->shard_remove($docid);
 448                 }
 449                 return;
 450         }
 451         my $ci = $self->{current_info};
 452         local $self->{current_info} = "$ci #$docid $oid";
 453         my $re_smsg = bless { blob => $oid }, 'PublicInbox::Smsg';
 454         $re_smsg->{bytes} = $size + crlf_adjust($$bref);
 455         my $eml = PublicInbox::Eml->new($bref);
 456         $re_smsg->populate($eml, { autime => $orig_smsg->{ds},
 457                                 cotime => $orig_smsg->{ts} });
 458         my $chash = content_hash($eml);
 459         $re_smsg->{chash} = $chash;
 460         $re_smsg->{xnum} = $req->{xr3}->[$req->{ix}]->[1];
 461         $re_smsg->{ibx_id} = $req->{xr3}->[$req->{ix}]->[0];
 462         push @{$req->{by_chash}->{$chash}}, $re_smsg;
 463         if (my $next_oid = $req->{xr3}->[++$req->{ix}]->[2]) {
 464                 $self->git->cat_async($next_oid, \&_reindex_oid, $req);
 465         } else { # last $re_smsg is the highest priority xref3
 466                 local $self->{current_info} = "$ci #$docid";
 467                 _reindex_finalize($req, $re_smsg, $eml);
 468         }
 469 }
 470
 471 sub _reindex_smsg ($$$) {
 472         my ($self, $sync, $smsg) = @_;
 473         my $docid = $smsg->{num};
 474         my $xr3 = $self->{oidx}->get_xref3($docid, 1);
 475         if (scalar(@$xr3) == 0) { # _reindex_check_stale should've covered this
 476                 warn <<"";
 477 BUG? #$docid $smsg->{blob} is not referenced by inboxes during reindex
 478
 479                 $self->{oidx}->delete_by_num($docid);
 480                 $self->idx_shard($docid)->shard_remove($docid);
 481                 return;
 482         }
 483
 484         # we sort {xr3} in the reverse order of {ibx_list} so we can
 485         # hit the common case in _reindex_finalize without rereading
 486         # from git (or holding multiple messages in memory).
 487         my $id2pos = $sync->{id2pos}; # index in {ibx_list}
 488         @$xr3 = sort {
 489                 $id2pos->{$b->[0]} <=> $id2pos->{$a->[0]}
 490                                 ||
 491                 $b->[1] <=> $a->[1] # break ties with {xnum}
 492         } @$xr3;
 493         @$xr3 = map { [ $_->[0], $_->[1], unpack('H*', $_->[2]) ] } @$xr3;
 494         my $req = { orig_smsg => $smsg, sync => $sync, xr3 => $xr3, ix => 0 };
 495         $self->git->cat_async($xr3->[$req->{ix}]->[2], \&_reindex_oid, $req);
 496 }
 497
 498 sub eidxq_process ($$) { # for reindexing
 499         my ($self, $sync) = @_;
 500
 501         $self->{oidx}->commit_lazy; # ensure shard workers can see it
 502         $self->{oidx}->begin_lazy;
 503         my $dbh = $self->{oidx}->dbh;
 504         my $tot = $dbh->selectrow_array('SELECT COUNT(*) FROM eidxq') or return;
 505         ${$sync->{nr}} = 0;
 506         $sync->{-regen_fmt} = "%u/$tot\n";
 507         my $pr = $sync->{-opt}->{-progress};
 508         if ($pr) {
 509                 my $min = $dbh->selectrow_array('SELECT MIN(docid) FROM eidxq');
 510                 my $max = $dbh->selectrow_array('SELECT MAX(docid) FROM eidxq');
 511                 $pr->("Xapian indexing $min..$max (total=$tot)\n");
 512         }
 513         my %id2pos;
 514         my $pos = 0;
 515         $id2pos{$_->{-ibx_id}} = $pos++ for @{$self->{ibx_list}};
 516         $sync->{id2pos} = \%id2pos;
 517
 518         my $del = $dbh->prepare('DELETE FROM eidxq WHERE docid = ?');
 519         my $iter = $dbh->prepare('SELECT docid FROM eidxq ORDER BY docid ASC');
 520         $iter->execute;
 521         while (defined(my $docid = $iter->fetchrow_array)) {
 522                 last if $sync->{quit};
 523                 if (my $smsg = $self->{oidx}->get_art($docid)) {
 524                         _reindex_smsg($self, $sync, $smsg);
 525                 } else {
 526                         warn "E: #$docid does not exist in over\n";
 527                 }
 528                 $del->execute($docid);
 529
 530                 my $cur = ++${$sync->{nr}};
 531
 532                 # shards flush on their own, just don't queue up too many
 533                 # deletes
 534                 if (($cur % 1000) == 0) {
 535                         $self->git->async_wait_all;
 536                         $self->{oidx}->commit_lazy;
 537                         $self->{oidx}->begin_lazy;
 538                         $pr->("reindexed $cur/$tot\n") if $pr;
 539                 }
 540                 # this is only for SIGUSR1, shards do their own accounting:
 541                 reindex_checkpoint($self, $sync) if ${$sync->{need_checkpoint}};
 542         }
 543         $self->git->async_wait_all;
 544         $pr->("reindexed ${$sync->{nr}}/$tot\n") if $pr;
 545 }
 546
 547 sub _reindex_unseen { # git->cat_async callback
 548         my ($bref, $oid, $type, $size, $req) = @_;
 549         return if is_bad_blob($oid, $type, $size, $req->{oid});
 550         my $self = $req->{self} // die 'BUG: {self} unset';
 551         local $self->{current_info} = "$self->{current_info} $oid";
 552         my $new_smsg = bless { blob => $oid, }, 'PublicInbox::Smsg';
 553         $new_smsg->{bytes} = $size + crlf_adjust($$bref);
 554         my $eml = $req->{eml} = PublicInbox::Eml->new($bref);
 555         $req->{new_smsg} = $new_smsg;
 556         $req->{chash} = content_hash($eml);
 557         $req->{mids} = mids($eml); # do_step iterates through this
 558         do_step($req); # enter the normal indexing flow
 559 }
 560
 561 # --reindex may catch totally unseen messages, this handles them
 562 sub reindex_unseen ($$$$) {
 563         my ($self, $sync, $ibx, $xsmsg) = @_;
 564         my $req = {
 565                 %$sync, # has {self}
 566                 autime => $xsmsg->{ds},
 567                 cotime => $xsmsg->{ts},
 568                 oid => $xsmsg->{blob},
 569                 ibx => $ibx,
 570                 xnum => $xsmsg->{num},
 571                 # {mids} and {chash} will be filled in at _reindex_unseen
 572         };
 573         warn "I: reindex_unseen ${\$ibx->eidx_key}:$req->{xnum}:$req->{oid}\n";
 574         $self->git->cat_async($xsmsg->{blob}, \&_reindex_unseen, $req);
 575 }
 576
 577 sub _reindex_check_unseen ($$$) {
 578         my ($self, $sync, $ibx) = @_;
 579         my $ibx_id = $ibx->{-ibx_id};
 580         my ($beg, $end) = (1, 1000);
 581
 582         # first, check if we missed any messages in target $ibx
 583         my $inx3 = $self->{oidx}->dbh->prepare(<<'');
 584 SELECT DISTINCT(docid) FROM xref3 WHERE ibx_id = ? AND xnum = ? AND oidbin = ?
 585
 586         my $msgs;
 587         while (scalar(@{$msgs = $ibx->over->query_xover($beg, $end)})) {
 588                 $beg = $msgs->[-1]->{num} + 1;
 589                 $end = $beg + 1000;
 590                 for my $xsmsg (@$msgs) {
 591                         my $oidbin = pack('H*', $xsmsg->{blob});
 592                         $inx3->bind_param(1, $ibx_id);
 593                         $inx3->bind_param(2, $xsmsg->{num});
 594                         $inx3->bind_param(3, $oidbin, SQL_BLOB);
 595                         $inx3->execute;
 596                         my $docids = $inx3->fetchall_arrayref;
 597                         # index messages which were totally missed
 598                         # the first time around ASAP:
 599                         if (scalar(@$docids) == 0) {
 600                                 reindex_unseen($self, $sync, $ibx, $xsmsg);
 601                         } else { # already seen, reindex later
 602                                 for my $r (@$docids) {
 603                                         $self->{oidx}->eidxq_add($r->[0]);
 604                                 }
 605                         }
 606                         last if $sync->{quit};
 607                 }
 608                 last if $sync->{quit};
 609         }
 610 }
 611
 612 sub _reindex_check_stale ($$$) {
 613         my ($self, $sync, $ibx) = @_;
 614
 615         # now, check if there's stale xrefs
 616         my $get_xnum = $self->{oidx}->dbh->prepare(<<'');
 617 SELECT docid,xnum,oidbin FROM xref3 WHERE ibx_id = ? ORDER BY docid ASC
 618
 619         $get_xnum->execute($ibx->{-ibx_id});
 620         my $del_xref3 = $self->{oidx}->dbh->prepare(<<'');
 621 DELETE FROM xref3 WHERE ibx_id = ? AND xnum = ? AND oidbin = ?
 622
 623         while (my ($docid, $xnum, $oidbin) = $get_xnum->fetchrow_array) {
 624                 last if $sync->{quit};
 625                 my $smsg = $ibx->over->get_art($xnum);
 626                 my $oidhex = unpack('H*', $oidbin);
 627                 my $err;
 628                 if (!$smsg) {
 629                         $err = 'stale';
 630                 } elsif ($smsg->{blob} ne $oidhex) {
 631                         $err = "mismatch (!= $smsg->{blob})";
 632                 } else {
 633                         next; # likely, all good
 634                 }
 635                 warn $ibx->eidx_key . ":$xnum:$oidhex (#$docid): $err\n";
 636                 $del_xref3->bind_param(1, $ibx->{-ibx_id});
 637                 $del_xref3->bind_param(2, $xnum);
 638                 $del_xref3->bind_param(3, $oidbin, SQL_BLOB);
 639                 $del_xref3->execute;
 640
 641                 # get_xref3 over-fetches, but this is a rare path:
 642                 my $xr3 = $self->{oidx}->get_xref3($docid);
 643                 my $idx = $self->idx_shard($docid);
 644                 if (scalar(@$xr3) == 0) { # all gone
 645                         $self->{oidx}->delete_by_num($docid);
 646                         $self->{oidx}->eidxq_del($docid);
 647                         $idx->shard_remove($docid);
 648                 } else { # enqueue for reindex of remaining messages
 649                         $idx->shard_remove_eidx_info($docid, $ibx->eidx_key);
 650                         $self->{oidx}->eidxq_add($docid); # yes, add
 651                 }
 652         }
 653 }
 654
 655 sub _reindex_inbox ($$$) {
 656         my ($self, $sync, $ibx) = @_;
 657         _reindex_check_unseen($self, $sync, $ibx);
 658         _reindex_check_stale($self, $sync, $ibx) unless $sync->{quit};
 659         delete @$ibx{qw(over mm search git)}; # won't need these for a bit
 660 }
 661
 662 sub eidx_reindex {
 663         my ($self, $sync) = @_;
 664
 665         for my $ibx (@{$self->{ibx_list}}) {
 666                 _reindex_inbox($self, $sync, $ibx);
 667                 last if $sync->{quit};
 668         }
 669         $self->git->async_wait_all; # ensure eidxq gets filled completely
 670         eidxq_process($self, $sync) unless $sync->{quit};
 671 }
 672
 673 sub eidx_sync { # main entry point
 674         my ($self, $opt) = @_;
 675
 676         my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
 677         local $self->{current_info} = '';
 678         local $SIG{__WARN__} = sub {
 679                 $warn_cb->($self->{current_info}, ': ', @_);
 680         };
 681         $self->idx_init($opt); # acquire lock via V2Writable::_idx_init
 682         $self->{oidx}->rethread_prepare($opt);
 683         my $sync = {
 684                 need_checkpoint => \(my $need_checkpoint = 0),
 685                 -opt => $opt,
 686                 # DO NOT SET {reindex} here, it's incompatible with reused
 687                 # V2Writable code, reindex is totally different here
 688                 # compared to v1/v2 inboxes because we have multiple histories
 689                 self => $self,
 690                 -regen_fmt => "%u/?\n",
 691         };
 692         local $SIG{USR1} = sub { $need_checkpoint = 1 };
 693         my $quit = PublicInbox::SearchIdx::quit_cb($sync);
 694         local $SIG{QUIT} = $quit;
 695         local $SIG{INT} = $quit;
 696         local $SIG{TERM} = $quit;
 697         for my $ibx (@{$self->{ibx_list}}) {
 698                 $ibx->{-ibx_id} //= $self->{oidx}->ibx_id($ibx->eidx_key);
 699         }
 700         eidx_reindex($self, $sync) if delete($opt->{reindex});
 701
 702         # don't use $_ here, it'll get clobbered by reindex_checkpoint
 703         for my $ibx (@{$self->{ibx_list}}) {
 704                 last if $sync->{quit};
 705                 _sync_inbox($self, $sync, $ibx);
 706         }
 707         $self->{oidx}->rethread_done($opt) unless $sync->{quit};
 708         eidxq_process($self, $sync) unless $sync->{quit};
 709
 710         PublicInbox::V2Writable::done($self);
 711 }
 712
 713 sub update_last_commit { # overrides V2Writable
 714         my ($self, $sync, $stk) = @_;
 715         my $unit = $sync->{unit} // return;
 716         my $latest_cmt = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 717         defined($latest_cmt) or return;
 718         my $ibx = $sync->{ibx} or die 'BUG: {ibx} missing';
 719         my $ekey = $ibx->eidx_key;
 720         my $uv = $ibx->uidvalidity;
 721         my $epoch = $unit->{epoch};
 722         my $meta_key;
 723         my $v = $ibx->version;
 724         if ($v == 2) {
 725                 die 'No {epoch} for v2 unit' unless defined $epoch;
 726                 $meta_key = "lc-v2:$ekey//$uv;$epoch";
 727         } elsif ($v == 1) {
 728                 die 'Unexpected {epoch} for v1 unit' if defined $epoch;
 729                 $meta_key = "lc-v1:$ekey//$uv";
 730         } else {
 731                 die "Unsupported inbox version: $v";
 732         }
 733         my $last = $self->{oidx}->eidx_meta($meta_key);
 734         if (defined $last && is_ancestor($self->git, $last, $latest_cmt)) {
 735                 my @cmd = (qw(rev-list --count), "$last..$latest_cmt");
 736                 chomp(my $n = $unit->{git}->qx(@cmd));
 737                 return if $n ne '' && $n == 0;
 738         }
 739         $self->{oidx}->eidx_meta($meta_key, $latest_cmt);
 740 }
 741
 742 sub _idx_init { # with_umask callback
 743         my ($self, $opt) = @_;
 744         PublicInbox::V2Writable::_idx_init($self, $opt);
 745         $self->{midx} = PublicInbox::MiscIdx->new($self);
 746 }
 747
 748 sub idx_init { # similar to V2Writable
 749         my ($self, $opt) = @_;
 750         return if $self->{idx_shards};
 751
 752         $self->git->cleanup;
 753
 754         my $ALL = $self->git->{git_dir}; # ALL.git
 755         PublicInbox::Import::init_bare($ALL) unless -d $ALL;
 756         my $info_dir = "$ALL/objects/info";
 757         my $alt = "$info_dir/alternates";
 758         my $mode = 0644;
 759         my (@old, @new, %seen); # seen: st_dev + st_ino
 760         if (-e $alt) {
 761                 open(my $fh, '<', $alt) or die "open $alt: $!";
 762                 $mode = (stat($fh))[2] & 07777;
 763                 while (my $line = <$fh>) {
 764                         chomp(my $d = $line);
 765                         if (my @st = stat($d)) {
 766                                 next if $seen{"$st[0]\0$st[1]"}++;
 767                         } else {
 768                                 warn "W: stat($d) failed (from $alt): $!\n";
 769                                 next if $opt->{-idx_gc};
 770                         }
 771                         push @old, $line;
 772                 }
 773         }
 774         for my $ibx (@{$self->{ibx_list}}) {
 775                 my $line = $ibx->git->{git_dir} . "/objects\n";
 776                 chomp(my $d = $line);
 777                 if (my @st = stat($d)) {
 778                         next if $seen{"$st[0]\0$st[1]"}++;
 779                 } else {
 780                         warn "W: stat($d) failed (from $ibx->{inboxdir}): $!\n";
 781                         next if $opt->{-idx_gc};
 782                 }
 783                 push @new, $line;
 784         }
 785         if (scalar @new) {
 786                 push @old, @new;
 787                 my $o = \@old;
 788                 PublicInbox::V2Writable::write_alternates($info_dir, $mode, $o);
 789         }
 790         $self->parallel_init($self->{indexlevel});
 791         $self->umask_prepare;
 792         $self->with_umask(\&_idx_init, $self, $opt);
 793         $self->{oidx}->begin_lazy;
 794         $self->{oidx}->eidx_prep;
 795         $self->{midx}->begin_txn;
 796 }
 797
 798 no warnings 'once';
 799 *done = \&PublicInbox::V2Writable::done;
 800 *umask_prepare = \&PublicInbox::InboxWritable::umask_prepare;
 801 *with_umask = \&PublicInbox::InboxWritable::with_umask;
 802 *parallel_init = \&PublicInbox::V2Writable::parallel_init;
 803 *nproc_shards = \&PublicInbox::V2Writable::nproc_shards;
 804 *sync_prepare = \&PublicInbox::V2Writable::sync_prepare;
 805 *index_todo = \&PublicInbox::V2Writable::index_todo;
 806 *count_shards = \&PublicInbox::V2Writable::count_shards;
 807 *atfork_child = \&PublicInbox::V2Writable::atfork_child;
 808 *idx_shard = \&PublicInbox::V2Writable::idx_shard;
 809 *reindex_checkpoint = \&PublicInbox::V2Writable::reindex_checkpoint;
 810
 811 1;