lib/PublicInbox/ExtSearchIdx.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Detached/external index cross inbox search indexing support
   5 # read-write counterpart to PublicInbox::ExtSearch
   6 #
   7 # It's based on the same ideas as public-inbox-v2-format(5) using
   8 # over.sqlite3 for dedupe and sharded Xapian.  msgmap.sqlite3 is
   9 # missing, so there is no Message-ID conflict resolution, meaning
  10 # no NNTP support for now.
  11 #
  12 # v2 has a 1:1 mapping of index:inbox or msgmap for NNTP support.
  13 # This is intended to be an M:N index:inbox mapping, but it'll likely
  14 # be 1:N in common practice (M==1)
  15
  16 package PublicInbox::ExtSearchIdx;
  17 use strict;
  18 use v5.10.1;
  19 use parent qw(PublicInbox::ExtSearch PublicInbox::Lock);
  20 use Carp qw(croak carp);
  21 use PublicInbox::Search;
  22 use PublicInbox::SearchIdx qw(crlf_adjust prepare_stack);
  23 use PublicInbox::OverIdx;
  24 use PublicInbox::MID qw(mids);
  25 use PublicInbox::V2Writable;
  26 use PublicInbox::InboxWritable;
  27 use PublicInbox::ContentHash qw(content_hash);
  28 use PublicInbox::Eml;
  29 use File::Spec;
  30
  31 sub new {
  32         my (undef, $dir, $opt) = @_;
  33         my $l = $opt->{indexlevel} // 'full';
  34         $l !~ $PublicInbox::SearchIdx::INDEXLEVELS and
  35                 die "invalid indexlevel=$l\n";
  36         $l eq 'basic' and die "E: indexlevel=basic not yet supported\n";
  37         my $self = bless {
  38                 xpfx => "$dir/ei".PublicInbox::Search::SCHEMA_VERSION,
  39                 topdir => $dir,
  40                 creat => $opt->{creat},
  41                 ibx_map => {}, # (newsgroup//inboxdir) => $ibx
  42                 ibx_list => [],
  43                 indexlevel => $l,
  44                 transact_bytes => 0,
  45                 total_bytes => 0,
  46                 current_info => '',
  47                 parallel => 1,
  48                 lock_path => "$dir/ei.lock",
  49         }, __PACKAGE__;
  50         $self->{shards} = $self->count_shards || nproc_shards($opt->{creat});
  51         my $oidx = PublicInbox::OverIdx->new("$self->{xpfx}/over.sqlite3");
  52         $oidx->{-no_fsync} = 1 if $opt->{-no_fsync};
  53         $self->{oidx} = $oidx;
  54         $self
  55 }
  56
  57 sub attach_inbox {
  58         my ($self, $ibx) = @_;
  59         $ibx = PublicInbox::InboxWritable->new($ibx);
  60         my $key = $ibx->eidx_key;
  61         if (!$ibx->over || !$ibx->mm) {
  62                 warn "W: skipping $key (unindexed)\n";
  63                 return;
  64         }
  65         if (!defined($ibx->uidvalidity)) {
  66                 warn "W: skipping $key (no UIDVALIDITY)\n";
  67                 return;
  68         }
  69         my $ibxdir = File::Spec->canonpath($ibx->{inboxdir});
  70         if ($ibxdir ne $ibx->{inboxdir}) {
  71                 warn "W: `$ibx->{inboxdir}' canonicalized to `$ibxdir'\n";
  72                 $ibx->{inboxdir} = $ibxdir;
  73         }
  74         $ibx = PublicInbox::InboxWritable->new($ibx);
  75         $self->{ibx_map}->{$key} //= do {
  76                 push @{$self->{ibx_list}}, $ibx;
  77                 $ibx;
  78         }
  79 }
  80
  81 sub _ibx_attach { # each_inbox callback
  82         my ($ibx, $self) = @_;
  83         attach_inbox($self, $ibx);
  84 }
  85
  86 sub attach_config {
  87         my ($self, $cfg) = @_;
  88         $cfg->each_inbox(\&_ibx_attach, $self);
  89 }
  90
  91 sub git_blob_digest ($) {
  92         my ($bref) = @_;
  93         my $dig = Digest::SHA->new(1); # XXX SHA256 later
  94         $dig->add('blob '.length($$bref)."\0");
  95         $dig->add($$bref);
  96         $dig;
  97 }
  98
  99 sub is_bad_blob ($$$$) {
 100         my ($oid, $type, $size, $expect_oid) = @_;
 101         if ($type ne 'blob') {
 102                 carp "W: $expect_oid is not a blob (type=$type)";
 103                 return 1;
 104         }
 105         croak "BUG: $oid != $expect_oid" if $oid ne $expect_oid;
 106         $size == 0 ? 1 : 0; # size == 0 means purged
 107 }
 108
 109 sub do_xpost ($$) {
 110         my ($req, $smsg) = @_;
 111         my $self = $req->{self};
 112         my $docid = $smsg->{num};
 113         my $idx = $self->idx_shard($docid);
 114         my $oid = $req->{oid};
 115         my $xibx = $req->{ibx};
 116         my $eml = $req->{eml};
 117         if (my $new_smsg = $req->{new_smsg}) { # 'm' on cross-posted message
 118                 my $xnum = $req->{xnum};
 119                 $idx->shard_add_xref3($docid, $xnum, $oid, $xibx, $eml);
 120         } else { # 'd'
 121                 $idx->shard_remove_xref3($docid, $oid, $xibx, $eml);
 122         }
 123 }
 124
 125 # called by V2Writable::sync_prepare
 126 sub artnum_max { $_[0]->{oidx}->eidx_max }
 127
 128 sub index_unseen ($) {
 129         my ($req) = @_;
 130         my $new_smsg = $req->{new_smsg} or die 'BUG: {new_smsg} unset';
 131         my $eml = delete $req->{eml};
 132         $new_smsg->populate($eml, $req);
 133         my $self = $req->{self};
 134         my $docid = $self->{oidx}->adj_counter('eidx_docid', '+');
 135         $new_smsg->{num} = $docid;
 136         my $idx = $self->idx_shard($docid);
 137         $self->{oidx}->add_overview($eml, $new_smsg);
 138         $idx->index_raw(undef, $eml, $new_smsg, $req->{ibx});
 139 }
 140
 141 sub do_finalize ($) {
 142         my ($req) = @_;
 143         if (my $indexed = $req->{indexed}) {
 144                 do_xpost($req, $_) for @$indexed;
 145         } elsif (exists $req->{new_smsg}) { # totally unseen messsage
 146                 index_unseen($req);
 147         } else {
 148                 warn "W: ignoring delete $req->{oid} (not found)\n";
 149         }
 150 }
 151
 152 sub do_step ($) { # main iterator for adding messages to the index
 153         my ($req) = @_;
 154         my $self = $req->{self};
 155         while (1) {
 156                 if (my $next_arg = $req->{next_arg}) {
 157                         if (my $smsg = $self->{oidx}->next_by_mid(@$next_arg)) {
 158                                 $req->{cur_smsg} = $smsg;
 159                                 $self->git->cat_async($smsg->{blob},
 160                                                         \&ck_existing, $req);
 161                                 return; # ck_existing calls do_step
 162                         }
 163                         delete $req->{cur_smsg};
 164                         delete $req->{next_arg};
 165                 }
 166                 my $mid = shift(@{$req->{mids}});
 167                 last unless defined $mid;
 168                 my ($id, $prev);
 169                 $req->{next_arg} = [ $mid, \$id, \$prev ];
 170                 # loop again
 171         }
 172         do_finalize($req);
 173 }
 174
 175 sub ck_existing { # git->cat_async callback
 176         my ($bref, $oid, $type, $size, $req) = @_;
 177         my $smsg = $req->{cur_smsg} or die 'BUG: {cur_smsg} missing';
 178         return if is_bad_blob($oid, $type, $size, $smsg->{blob});
 179         my $cur = PublicInbox::Eml->new($bref);
 180         if (content_hash($cur) eq $req->{chash}) {
 181                 push @{$req->{indexed}}, $smsg; # for do_xpost
 182         } # else { index_unseen later }
 183         do_step($req);
 184 }
 185
 186 # is the messages visible in the inbox currently being indexed?
 187 # return the number if so
 188 sub cur_ibx_xnum ($$) {
 189         my ($req, $bref) = @_;
 190         my $ibx = $req->{ibx} or die 'BUG: current {ibx} missing';
 191
 192         # XXX overkill?
 193         git_blob_digest($bref)->hexdigest eq $req->{oid} or die
 194                 "BUG: blob mismatch $req->{oid}";
 195
 196         $req->{eml} = PublicInbox::Eml->new($bref);
 197         $req->{chash} = content_hash($req->{eml});
 198         $req->{mids} = mids($req->{eml});
 199         my @q = @{$req->{mids}}; # copy
 200         while (defined(my $mid = shift @q)) {
 201                 my ($id, $prev);
 202                 while (my $x = $ibx->over->next_by_mid($mid, \$id, \$prev)) {
 203                         return $x->{num} if $x->{blob} eq $req->{oid};
 204                 }
 205         }
 206         undef;
 207 }
 208
 209 sub index_oid { # git->cat_async callback for 'm'
 210         my ($bref, $oid, $type, $size, $req) = @_;
 211         return if is_bad_blob($oid, $type, $size, $req->{oid});
 212         my $new_smsg = $req->{new_smsg} = bless {
 213                 blob => $oid,
 214         }, 'PublicInbox::Smsg';
 215         $new_smsg->{bytes} = $size + crlf_adjust($$bref);
 216         defined($req->{xnum} = cur_ibx_xnum($req, $bref)) or return;
 217         do_step($req);
 218 }
 219
 220 sub unindex_oid { # git->cat_async callback for 'd'
 221         my ($bref, $oid, $type, $size, $req) = @_;
 222         return if is_bad_blob($oid, $type, $size, $req->{oid});
 223         return if defined(cur_ibx_xnum($req, $bref)); # was re-added
 224         do_step($req);
 225 }
 226
 227 # overrides V2Writable::last_commits, called by sync_ranges via sync_prepare
 228 sub last_commits {
 229         my ($self, $sync) = @_;
 230         my $heads = [];
 231         my $ekey = $sync->{ibx}->eidx_key;
 232         my $uv = $sync->{ibx}->uidvalidity;
 233         for my $i (0..$sync->{epoch_max}) {
 234                 $heads->[$i] = $self->{oidx}->eidx_meta("lc-v2:$ekey//$uv;$i");
 235         }
 236         $heads;
 237 }
 238
 239 sub _sync_inbox ($$$) {
 240         my ($self, $opt, $ibx) = @_;
 241         my $sync = {
 242                 need_checkpoint => \(my $bool = 0),
 243                 reindex => $opt->{reindex},
 244                 -opt => $opt,
 245                 self => $self,
 246                 ibx => $ibx,
 247         };
 248         my $v = $ibx->version;
 249         my $ekey = $ibx->eidx_key;
 250         if ($v == 2) {
 251                 my $epoch_max;
 252                 defined($ibx->git_dir_latest(\$epoch_max)) or return;
 253                 $sync->{epoch_max} = $epoch_max;
 254                 sync_prepare($self, $sync) or return; # fills $sync->{todo}
 255         } elsif ($v == 1) {
 256                 my $uv = $ibx->uidvalidity;
 257                 my $lc = $self->{oidx}->eidx_meta("lc-v1:$ekey//$uv");
 258                 my $stk = prepare_stack($sync, $lc ? "$lc..HEAD" : 'HEAD');
 259                 my $unit = { stack => $stk, git => $ibx->git };
 260                 push @{$sync->{todo}}, $unit;
 261         } else {
 262                 warn "E: $ekey unsupported inbox version (v$v)\n";
 263                 return;
 264         }
 265         index_todo($self, $sync, $_) for @{$sync->{todo}};
 266 }
 267
 268 sub eidx_sync { # main entry point
 269         my ($self, $opt) = @_;
 270         $self->idx_init($opt); # acquire lock via V2Writable::_idx_init
 271         $self->{oidx}->rethread_prepare($opt);
 272
 273         _sync_inbox($self, $opt, $_) for (@{$self->{ibx_list}});
 274
 275         $self->{oidx}->rethread_done($opt);
 276
 277         PublicInbox::V2Writable::done($self);
 278 }
 279
 280 sub update_last_commit {
 281         my ($self, $sync, $unit, $latest_cmt) = @_;
 282
 283         my $ALL = $self->git;
 284         # while (scalar(@{$ALL->{inflight_c}}) || scalar(@{$ALL->{inflight}})) {
 285                 # $ALL->check_async_wait;
 286                 # $ALL->cat_async_wait;
 287         # }
 288         # TODO
 289 }
 290
 291 sub idx_init { # similar to V2Writable
 292         my ($self, $opt) = @_;
 293         return if $self->{idx_shards};
 294
 295         $self->git->cleanup;
 296
 297         my $ALL = $self->git->{git_dir}; # ALL.git
 298         PublicInbox::Import::init_bare($ALL) unless -d $ALL;
 299         my $info_dir = "$ALL/objects/info";
 300         my $alt = "$info_dir/alternates";
 301         my $mode = 0644;
 302         my (%old, @old, %new, @new);
 303         if (-e $alt) {
 304                 open(my $fh, '<', $alt) or die "open $alt: $!";
 305                 $mode = (stat($fh))[2] & 07777;
 306                 while (<$fh>) {
 307                         push @old, $_ if !$old{$_}++;
 308                 }
 309         }
 310         for my $ibx (@{$self->{ibx_list}}) {
 311                 my $line = $ibx->git->{git_dir} . "/objects\n";
 312                 next if $old{$line};
 313                 $new{$line} = 1;
 314                 push @new, $line;
 315         }
 316         push @old, @new;
 317         PublicInbox::V2Writable::write_alternates($info_dir, $mode, \@old);
 318         $self->parallel_init($self->{indexlevel});
 319         $self->umask_prepare;
 320         $self->with_umask(\&PublicInbox::V2Writable::_idx_init, $self, $opt);
 321         $self->{oidx}->begin_lazy;
 322         $self->{oidx}->eidx_prep;
 323 }
 324
 325 no warnings 'once';
 326 *done = \&PublicInbox::V2Writable::done;
 327 *umask_prepare = \&PublicInbox::InboxWritable::umask_prepare;
 328 *with_umask = \&PublicInbox::InboxWritable::with_umask;
 329 *parallel_init = \&PublicInbox::V2Writable::parallel_init;
 330 *nproc_shards = \&PublicInbox::V2Writable::nproc_shards;
 331 *sync_prepare = \&PublicInbox::V2Writable::sync_prepare;
 332 *index_todo = \&PublicInbox::V2Writable::index_todo;
 333 *count_shards = \&PublicInbox::V2Writable::count_shards;
 334 *atfork_child = \&PublicInbox::V2Writable::atfork_child;
 335 *idx_shard = \&PublicInbox::V2Writable::idx_shard;
 336
 337 1;