lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use Email::Address;
   7 use Email::MIME;
   8 use Date::Parse qw(strptime str2time);
   9 use PublicInbox::Hval;
  10 eval { require Git }; # this is GPLv2+, so we are OK to use it
  11 use constant {
  12         DATEFMT => '%Y-%m-%dT%H:%M:%SZ',
  13         MAX_PER_PAGE => 25,
  14 };
  15
  16 # FIXME: workaround https://rt.cpan.org/Public/Bug/Display.html?id=22817
  17
  18 # main function
  19 sub generate {
  20         my ($class, $args) = @_;
  21         require XML::Atom::SimpleFeed;
  22         require PublicInbox::View;
  23         require POSIX;
  24         my $max = $args->{max} || MAX_PER_PAGE;
  25
  26         local $ENV{GIT_DIR} = $args->{git_dir};
  27         my $feed_opts = get_feedopts($args);
  28         my $addr = $feed_opts->{address};
  29         $addr = $addr->[0] if ref($addr);
  30         my $feed = XML::Atom::SimpleFeed->new(
  31                 title => $feed_opts->{description} || "unnamed feed",
  32                 link => $feed_opts->{url} || "http://example.com/",
  33                 link => {
  34                         rel => 'self',
  35                         href => $feed_opts->{atomurl} ||
  36                                 "http://example.com/atom.xml",
  37                 },
  38                 id => 'mailto:' . ($addr || 'public-inbox@example.com'),
  39                 updated => POSIX::strftime(DATEFMT, gmtime),
  40         );
  41
  42         my $git = try_git_pm($args->{git_dir});
  43         each_recent_blob($args, sub {
  44                 my ($add) = @_;
  45                 add_to_feed($feed_opts, $feed, $add, $git);
  46         });
  47         $feed->as_string;
  48 }
  49
  50 sub generate_html_index {
  51         my ($class, $args) = @_;
  52         require Mail::Thread;
  53
  54         my $max = $args->{max} || MAX_PER_PAGE;
  55         local $ENV{GIT_DIR} = $args->{git_dir};
  56         my $feed_opts = get_feedopts($args);
  57
  58         my $title = $feed_opts->{description} || '';
  59         $title = PublicInbox::Hval->new_oneline($title)->as_html;
  60
  61         my @messages;
  62         my $git = try_git_pm($args->{git_dir});
  63         my $last = each_recent_blob($args, sub {
  64                 my $mime = do_cat_mail($git, $_[0]) or return 0;
  65                 $mime->body_set(''); # save some memory
  66
  67                 my $t = eval { str2time($mime->header('Date')) };
  68                 defined($t) or $t = 0;
  69                 $mime->header_set('X-PI-Date', $t);
  70                 push @messages, $mime;
  71                 1;
  72         });
  73
  74         my $th = Mail::Thread->new(@messages);
  75         $th->thread;
  76         my @out = (
  77                 "<html><head><title>$title</title>" .
  78                 '<link rel="alternate" title="Atom feed" href="' .
  79                 $feed_opts->{atomurl} . '" type="application/atom+xml"/>' .
  80                 '</head><body><pre>');
  81         push @out, $feed_opts->{midurl};
  82
  83         # sort by date, most recent at top
  84         $th->order(sub {
  85                 sort {
  86                         $b->topmost->message->header('X-PI-Date') <=>
  87                         $a->topmost->message->header('X-PI-Date')
  88                 } @_;
  89         });
  90         dump_html_line($_, 0, \@out) for $th->rootset;
  91
  92         my $footer = nav_footer($args->{cgi}, $last);
  93         $footer = "<hr /><pre>$footer</pre>" if $footer;
  94         $out[0] . "</pre>$footer</html>";
  95 }
  96
  97 # private subs
  98
  99 sub nav_footer {
 100         my ($cgi, $last) = @_;
 101         $cgi or return '';
 102         my $old_r = $cgi->param('r');
 103         my $head = '    ';
 104         my $next = '    ';
 105
 106         if ($last) {
 107                 $next = $cgi->path_info . "?r=$last";
 108                 $next = qq!<a href="$next">next</a>!;
 109         }
 110         if ($old_r) {
 111                 $head = $cgi->path_info;
 112                 $head = qq!<a href="$head">head</a>!;
 113         }
 114         "$head $next";
 115 }
 116
 117 sub each_recent_blob {
 118         my ($args, $cb) = @_;
 119         my $max = $args->{max} || MAX_PER_PAGE;
 120         my $hex = '[a-f0-9]';
 121         my $addmsg = qr!^:000000 100644 \S+ \S+ A\t(${hex}{2}/${hex}{38})$!;
 122         my $delmsg = qr!^:100644 000000 \S+ \S+ D\t(${hex}{2}/${hex}{38})$!;
 123         my $refhex = qr/${hex}{4,40}(?:~\d+)?/;
 124         my $cgi = $args->{cgi};
 125
 126         # revision ranges may be specified
 127         my $range = 'HEAD';
 128         my $r = $cgi->param('r') if $cgi;
 129         if ($r && ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o)) {
 130                 $range = $r;
 131         }
 132
 133         # get recent messages
 134         # we could use git log -z, but, we already know ssoma will not
 135         # leave us with filenames with spaces in them..
 136         my @cmd = qw/git log --no-notes --no-color --raw -r/;
 137         push @cmd, $range;
 138
 139         my $pid = open(my $log, '-|', @cmd) or
 140                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 141         my %deleted; # only an optimization at this point
 142         my $last;
 143         my $nr = 0;
 144         my @commits = ();
 145         while (my $line = <$log>) {
 146                 if ($line =~ /$addmsg/o) {
 147                         my $add = $1;
 148                         next if $deleted{$add};
 149                         $nr += $cb->($add);
 150                         if ($nr >= $max) {
 151                                 $last = 1;
 152                                 last;
 153                         }
 154                 } elsif ($line =~ /$delmsg/o) {
 155                         $deleted{$1} = 1;
 156                 } elsif ($line =~ /^commit (${hex}{40})/) {
 157                         push @commits, $1;
 158                 }
 159         }
 160
 161         if ($last) {
 162                 while (my $line = <$log>) {
 163                         if ($line =~ /^commit (${hex}{40})/) {
 164                                 push @commits, $1;
 165                                 last;
 166                         }
 167                 }
 168         } else {
 169                 push @commits, undef;
 170         }
 171
 172         close $log; # we may EPIPE here
 173         # for pagination
 174         $commits[-1];
 175 }
 176
 177 # private functions below
 178 sub get_feedopts {
 179         my ($args) = @_;
 180         my $pi_config = $args->{pi_config};
 181         my $listname = $args->{listname};
 182         my $cgi = $args->{cgi};
 183         my %rv;
 184         if (open my $fh, '<', "$args->{git_dir}/description") {
 185                 chomp($rv{description} = <$fh>);
 186                 close $fh;
 187         }
 188
 189         if ($pi_config && defined $listname && length $listname) {
 190                 foreach my $key (qw(address)) {
 191                         $rv{$key} = $pi_config->get($listname, $key) || "";
 192                 }
 193         }
 194         my $url_base;
 195         if ($cgi) {
 196                 my $path_info = $cgi->path_info;
 197                 my $base;
 198                 if (ref($cgi) eq 'CGI') {
 199                         $base = $cgi->url(-base);
 200                 } else {
 201                         $base = "${$cgi->base}";
 202                         $base =~ s!/\z!!;
 203                 }
 204                 $url_base = $path_info;
 205                 if ($url_base =~ s!/(?:|index\.html)?\z!!) {
 206                         $rv{atomurl} = "$base$url_base/atom.xml";
 207                 } else {
 208                         $url_base =~ s!/atom\.xml\z!!;
 209                         $rv{atomurl} = $base . $path_info;
 210                         $url_base = $base . $url_base; # XXX is this needed?
 211                 }
 212         } else {
 213                 $url_base = "http://example.com";
 214                 $rv{atomurl} = "$url_base/atom.xml";
 215         }
 216         $rv{url} ||= "$url_base/";
 217         $rv{midurl} = "$url_base/m/";
 218         $rv{fullurl} = "$url_base/f/";
 219
 220         \%rv;
 221 }
 222
 223 sub mime_header {
 224         my ($mime, $name) = @_;
 225         PublicInbox::Hval->new_oneline($mime->header($name))->raw;
 226 }
 227
 228 sub feed_date {
 229         my ($date) = @_;
 230         my @t = eval { strptime($date) };
 231
 232         scalar(@t) ? POSIX::strftime(DATEFMT, @t) : 0;
 233 }
 234
 235 # returns 0 (skipped) or 1 (added)
 236 sub add_to_feed {
 237         my ($feed_opts, $feed, $add, $git) = @_;
 238
 239         my $mime = do_cat_mail($git, $add) or return 0;
 240         my $midurl = $feed_opts->{midurl} || 'http://example.com/m/';
 241         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/f/';
 242
 243         my $mid = $mime->header_obj->header_raw('Message-ID');
 244         defined $mid or return 0;
 245         $mid = PublicInbox::Hval->new_msgid($mid);
 246         my $href = $mid->as_href . '.html';
 247         my $content = PublicInbox::View->as_feed_entry($mime, $fullurl . $href);
 248         defined($content) or return 0;
 249
 250         my $subject = mime_header($mime, 'Subject') or return 0;
 251
 252         my $from = mime_header($mime, 'From') or return 0;
 253         my @from = Email::Address->parse($from);
 254         my $name = $from[0]->name;
 255         defined $name or $name = "";
 256         my $email = $from[0]->address;
 257         defined $email or $email = "";
 258
 259         my $date = $mime->header('Date');
 260         $date = PublicInbox::Hval->new_oneline($date);
 261         $date = feed_date($date->raw) or return 0;
 262         $add =~ tr!/!!d;
 263         my $h = '[a-f0-9]';
 264         my (@uuid5) = ($add =~ m!\A($h{8})($h{4})($h{4})($h{4})($h{12})!o);
 265
 266         $feed->add_entry(
 267                 author => { name => $name, email => $email },
 268                 title => $subject,
 269                 updated => $date,
 270                 content => { type => 'xhtml', content => $content },
 271                 link => $midurl . $href,
 272                 id => 'urn:uuid:' . join('-', @uuid5),
 273         );
 274         1;
 275 }
 276
 277 sub dump_html_line {
 278         my ($self, $level, $args) = @_; # args => [ $html, $midurl ]
 279         if ($self->message) {
 280                 $args->[0] .= (' ' x $level);
 281                 my $mime = $self->message;
 282                 my $subj = $mime->header('Subject');
 283                 my $mid = $mime->header_obj->header_raw('Message-ID');
 284                 $mid = PublicInbox::Hval->new_msgid($mid);
 285                 my $url = $args->[1] . $mid->as_href;
 286                 my $from = mime_header($mime, 'From');
 287
 288                 my @from = Email::Address->parse($from);
 289                 $from = $from[0]->name;
 290                 (defined($from) && length($from)) or $from = $from[0]->address;
 291
 292                 $from = PublicInbox::Hval->new_oneline($from)->as_html;
 293                 $subj = PublicInbox::Hval->new_oneline($subj)->as_html;
 294                 $args->[0] .= "<a href=\"$url.html\">$subj</a> $from\n";
 295         }
 296         dump_html_line($self->child, $level+1, $args) if $self->child;
 297         dump_html_line($self->next, $level, $args) if $self->next;
 298 }
 299
 300 sub try_git_pm {
 301         my ($dir) = @_;
 302         eval { Git->repository(Directory => $dir) };
 303 };
 304
 305 sub do_cat_mail {
 306         my ($git, $path) = @_;
 307         my $str;
 308         if ($git) {
 309                 open my $fh, '>', \$str or
 310                                 die "failed to setup string handle: $!\n";
 311                 binmode $fh;
 312                 my $err = '';
 313                 my $bytes;
 314                 {
 315                         local $SIG{__WARN__} = sub { $err .= $_[0] };
 316                         $bytes = $git->cat_blob("HEAD:$path", $fh);
 317                 }
 318                 close $fh or die "failed to close string handle: $!\n";
 319
 320                 if ($bytes < 0 && $err &&
 321                                 $err !~ /doesn't exist in the repository/) {
 322                         warn $err;
 323                 }
 324                 return if $bytes <= 0;
 325         } else {
 326                 $str = `git cat-file blob HEAD:$path`;
 327                 return if $? != 0 || length($str) == 0;
 328         }
 329         Email::MIME->new($str);
 330 }
 331
 332 1;