lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use Email::Address;
   7 use Email::MIME;
   8 use Date::Parse qw(strptime str2time);
   9 use PublicInbox::Hval;
  10 eval { require Git }; # this is GPLv2+, so we are OK to use it
  11 use constant {
  12         DATEFMT => '%Y-%m-%dT%H:%M:%SZ',
  13         MAX_PER_PAGE => 25,
  14 };
  15
  16 # FIXME: workaround https://rt.cpan.org/Public/Bug/Display.html?id=22817
  17
  18 # main function
  19 sub generate {
  20         my ($class, $args) = @_;
  21         require XML::Atom::SimpleFeed;
  22         require PublicInbox::View;
  23         require POSIX;
  24         my $max = $args->{max} || MAX_PER_PAGE;
  25         my $top = $args->{top}; # bool
  26
  27         local $ENV{GIT_DIR} = $args->{git_dir};
  28         my $feed_opts = get_feedopts($args);
  29         my $addr = $feed_opts->{address};
  30         $addr = $addr->[0] if ref($addr);
  31         my $feed = XML::Atom::SimpleFeed->new(
  32                 title => $feed_opts->{description} || "unnamed feed",
  33                 link => $feed_opts->{url} || "http://example.com/",
  34                 link => {
  35                         rel => 'self',
  36                         href => $feed_opts->{atomurl} ||
  37                                 "http://example.com/atom.xml",
  38                 },
  39                 id => $addr || 'public-inbox@example.com',
  40                 updated => POSIX::strftime(DATEFMT, gmtime),
  41         );
  42
  43         my $git = try_git_pm($args->{git_dir});
  44         each_recent_blob($args, sub {
  45                 my ($add) = @_;
  46                 add_to_feed($feed_opts, $feed, $add, $top, $git);
  47         });
  48         $feed->as_string;
  49 }
  50
  51 sub generate_html_index {
  52         my ($class, $args) = @_;
  53         require Mail::Thread;
  54
  55         my $max = $args->{max} || MAX_PER_PAGE;
  56         my $top = $args->{top}; # bool
  57         local $ENV{GIT_DIR} = $args->{git_dir};
  58         my $feed_opts = get_feedopts($args);
  59
  60         my $title = $feed_opts->{description} || '';
  61         $title = PublicInbox::Hval->new_oneline($title)->as_html;
  62
  63         my @messages;
  64         my $git = try_git_pm($args->{git_dir});
  65         my ($first, $last) = each_recent_blob($args, sub {
  66                 my $mime = do_cat_mail($git, $_[0])
  67                         or return 0;
  68                 if ($top && ($mime->header('In-Reply-To') ||
  69                              $mime->header('References'))) {
  70                         return 0;
  71                 }
  72                 $mime->body_set(''); # save some memory
  73
  74                 my $t = eval { str2time($mime->header('Date')) };
  75                 defined($t) or $t = 0;
  76                 $mime->header_set('X-PI-Date', $t);
  77                 push @messages, $mime;
  78                 1;
  79         });
  80
  81         my $th = Mail::Thread->new(@messages);
  82         $th->thread;
  83         my @out = (
  84                 "<html><head><title>$title</title>" .
  85                 '<link rel=alternate title=Atom.feed href="' .
  86                 $feed_opts->{atomurl} . '" type="application/atom+xml"/>' .
  87                 '</head><body><pre>');
  88         push @out, $feed_opts->{midurl};
  89
  90         # sort by date, most recent at top
  91         $th->order(sub {
  92                 sort {
  93                         $b->topmost->message->header('X-PI-Date') <=>
  94                         $a->topmost->message->header('X-PI-Date')
  95                 } @_;
  96         });
  97         dump_html_line($_, 0, \@out) for $th->rootset;
  98
  99         my $footer = nav_footer($args->{cgi}, $first, $last);
 100         $footer = "<hr /><pre>$footer</pre>" if $footer;
 101         $out[0] . "</pre>$footer</html>";
 102 }
 103
 104 # private subs
 105
 106 sub nav_footer {
 107         my ($cgi, $first, $last) = @_;
 108         $cgi or return '';
 109         my $old_r = $cgi->param('r');
 110         my $prev = '    ';
 111         my $next = '    ';
 112         my %opts = (-path => 1, -query => 1, -relative => 1);
 113
 114         if ($last) {
 115                 $cgi->param('r', $last);
 116                 $next = $cgi->url(%opts);
 117                 $next = qq!<a href="$next">next</a>!;
 118         }
 119         if ($first && $old_r) {
 120                 $cgi->param('r', "$first..");
 121                 $prev = $cgi->url(%opts);
 122                 $prev = qq!<a href="$prev">prev</a>!;
 123         }
 124         "$prev $next";
 125 }
 126
 127 sub each_recent_blob {
 128         my ($args, $cb) = @_;
 129         my $max = $args->{max} || MAX_PER_PAGE;
 130         my $refhex = qr/[a-f0-9]{4,40}(?:~\d+)?/;
 131         my $cgi = $args->{cgi};
 132
 133         # revision ranges may be specified
 134         my $reverse;
 135         my $range = 'HEAD';
 136         my $r = $cgi->param('r') if $cgi;
 137         if ($r) {
 138                 if ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o) {
 139                         $range = $r;
 140                 } elsif ($r =~ /\A(?:$refhex\.\.)\z/o) {
 141                         $reverse = 1;
 142                         $range = $r;
 143                 }
 144         }
 145
 146         # get recent messages
 147         # we could use git log -z, but, we already know ssoma will not
 148         # leave us with filenames with spaces in them..
 149         my @cmd = qw/git log --no-notes --no-color --raw -r --no-abbrev/;
 150         push @cmd, '--reverse' if $reverse;
 151         push @cmd, $range;
 152         my $first;
 153
 154         my $pid = open(my $log, '-|', @cmd) or
 155                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 156         my %deleted;
 157         my $last;
 158         my $nr = 0;
 159         my @commits = ();
 160         while (my $line = <$log>) {
 161                 if ($line =~ /^:000000 100644 0{40} ([a-f0-9]{40})/) {
 162                         my $add = $1;
 163                         next if $deleted{$add};
 164                         $nr += $cb->($add);
 165                         if ($nr >= $max) {
 166                                 $last = 1;
 167                                 last;
 168                         }
 169                 } elsif ($line =~ /^:100644 000000 ([a-f0-9]{40}) 0{40}/) {
 170                         $deleted{$1} = 1;
 171                 } elsif ($line =~ /^commit ([a-f0-9]{40})/) {
 172                         push @commits, $1;
 173                 }
 174         }
 175
 176         if ($last) {
 177                 while (my $line = <$log>) {
 178                         if ($line =~ /^commit ([a-f0-9]{40})/) {
 179                                 push @commits, $1;
 180                                 last;
 181                         }
 182                 }
 183         } elsif ($reverse) {
 184                 unshift @commits, undef
 185         } else {
 186                 push @commits, undef;
 187         }
 188
 189         close $log; # we may EPIPE here
 190         # for pagination
 191         $reverse ? ($commits[-1],$commits[0]) : ($commits[0],$commits[-1]);
 192 }
 193
 194 # private functions below
 195 sub get_feedopts {
 196         my ($args) = @_;
 197         my $pi_config = $args->{pi_config};
 198         my $listname = $args->{listname};
 199         my $cgi = $args->{cgi};
 200         my %rv;
 201         if (open my $fh, '<', "$args->{git_dir}/description") {
 202                 chomp($rv{description} = <$fh>);
 203                 close $fh;
 204         }
 205
 206         if ($pi_config && defined $listname && length $listname) {
 207                 foreach my $key (qw(address)) {
 208                         $rv{$key} = $pi_config->get($listname, $key) || "";
 209                 }
 210         }
 211         my $url_base;
 212         if ($cgi) {
 213                 my $cgi_url = $cgi->url(-path=>1, -relative=>1);
 214                 my $base = $cgi->url(-base);
 215                 $url_base = $cgi_url;
 216                 if ($url_base =~ s!/(?:|index\.html)?\z!!) {
 217                         $rv{atomurl} = "$base$url_base/atom.xml";
 218                 } else {
 219                         $url_base =~ s!/atom\.xml\z!!;
 220                         $rv{atomurl} = $base . $cgi_url;
 221                         $url_base = $base . $url_base; # XXX is this needed?
 222                 }
 223         } else {
 224                 $url_base = "http://example.com";
 225                 $rv{atomurl} = "$url_base/atom.xml";
 226         }
 227         $rv{url} ||= "$url_base/";
 228         $rv{midurl} = "$url_base/m/";
 229         $rv{fullurl} = "$url_base/f/";
 230
 231         \%rv;
 232 }
 233
 234 sub mime_header {
 235         my ($mime, $name) = @_;
 236         PublicInbox::Hval->new_oneline($mime->header($name))->raw;
 237 }
 238
 239 sub feed_date {
 240         my ($date) = @_;
 241         my @t = eval { strptime($date) };
 242
 243         scalar(@t) ? POSIX::strftime(DATEFMT, @t) : 0;
 244 }
 245
 246 # returns 0 (skipped) or 1 (added)
 247 sub add_to_feed {
 248         my ($feed_opts, $feed, $add, $top, $git) = @_;
 249
 250         my $mime = do_cat_mail($git, $add) or return 0;
 251         if ($top && $mime->header('In-Reply-To')) {
 252                 return 0;
 253         }
 254
 255         my $midurl = $feed_opts->{midurl} || 'http://example.com/m/';
 256         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/f/';
 257
 258         my $mid = $mime->header_obj->header_raw('Message-ID');
 259         defined $mid or return 0;
 260         $mid = PublicInbox::Hval->new_msgid($mid);
 261         my $href = $mid->as_href;
 262         my $content = PublicInbox::View->as_feed_entry($mime,
 263                                                         "$fullurl$href.html");
 264         defined($content) or return 0;
 265
 266         my $subject = mime_header($mime, 'Subject') or return 0;
 267
 268         my $from = mime_header($mime, 'From') or return 0;
 269         my @from = Email::Address->parse($from);
 270         my $name = $from[0]->name;
 271         defined $name or $name = "";
 272         my $email = $from[0]->address;
 273         defined $email or $email = "";
 274
 275         my $date = $mime->header('Date');
 276         $date = PublicInbox::Hval->new_oneline($date);
 277         $date = feed_date($date->raw) or return 0;
 278         $feed->add_entry(
 279                 author => { name => $name, email => $email },
 280                 title => $subject,
 281                 updated => $date,
 282                 content => { type => "html", content => $content },
 283                 link => $midurl . $href,
 284                 id => $add,
 285         );
 286         1;
 287 }
 288
 289 sub dump_html_line {
 290         my ($self, $level, $args) = @_; # args => [ $html, $midurl ]
 291         if ($self->message) {
 292                 $args->[0] .= (' ' x $level);
 293                 my $mime = $self->message;
 294                 my $subj = $mime->header('Subject');
 295                 my $mid = $mime->header_obj->header_raw('Message-ID');
 296                 $mid = PublicInbox::Hval->new_msgid($mid);
 297                 my $url = $args->[1] . $mid->as_href;
 298                 my $from = mime_header($mime, 'From');
 299
 300                 my @from = Email::Address->parse($from);
 301                 $from = $from[0]->name;
 302                 (defined($from) && length($from)) or $from = $from[0]->address;
 303
 304                 $from = PublicInbox::Hval->new_oneline($from)->as_html;
 305                 $subj = PublicInbox::Hval->new_oneline($subj)->as_html;
 306                 $args->[0] .= "<a href=\"$url.html\">$subj</a> $from\n";
 307         }
 308         dump_html_line($self->child, $level+1, $args) if $self->child;
 309         dump_html_line($self->next, $level, $args) if $self->next;
 310 }
 311
 312 sub try_git_pm {
 313         my ($dir) = @_;
 314         eval { Git->repository(Directory => $dir) };
 315 };
 316
 317 sub do_cat_mail {
 318         my ($git, $sha1) = @_;
 319         my $str;
 320         if ($git) {
 321                 open my $fh, '>', \$str or
 322                                 die "failed to setup string handle: $!\n";
 323                 binmode $fh;
 324                 my $bytes = $git->cat_blob($sha1, $fh);
 325                 close $fh or die "failed to close string handle: $!\n";
 326                 return if $bytes <= 0;
 327         } else {
 328                 $str = `git cat-file blob $sha1`;
 329                 return if $? != 0 || length($str) == 0;
 330         }
 331         Email::MIME->new($str);
 332 }
 333
 334 1;