lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use Email::Address;
   7 use URI::Escape qw/uri_escape/;
   8 use Encode qw/find_encoding/;
   9 use Encode::MIME::Header;
  10 use CGI qw(escapeHTML);
  11 use Date::Parse qw(strptime str2time);
  12 eval { require Git }; # this is GPLv2+, so we are OK to use it
  13 use constant {
  14         DATEFMT => '%Y-%m-%dT%H:%M:%SZ',
  15         MAX_PER_PAGE => 25,
  16 };
  17 my $enc_utf8 = find_encoding('utf8');
  18 my $enc_ascii = find_encoding('us-ascii');
  19 my $enc_mime = find_encoding('MIME-Header');
  20
  21 # FIXME: workaround https://rt.cpan.org/Public/Bug/Display.html?id=22817
  22
  23 # main function
  24 sub generate {
  25         my ($class, $args) = @_;
  26         require XML::Atom::SimpleFeed;
  27         require PublicInbox::View;
  28         require Email::MIME;
  29         require POSIX;
  30         my $max = $args->{max} || MAX_PER_PAGE;
  31         my $top = $args->{top}; # bool
  32
  33         local $ENV{GIT_DIR} = $args->{git_dir};
  34         my $feed_opts = get_feedopts($args);
  35
  36         my $feed = XML::Atom::SimpleFeed->new(
  37                 title => $feed_opts->{description} || "unnamed feed",
  38                 link => $feed_opts->{url} || "http://example.com/",
  39                 link => {
  40                         rel => 'self',
  41                         href => $feed_opts->{atomurl} ||
  42                                 "http://example.com/atom.xml",
  43                 },
  44                 id => $feed_opts->{address} || 'public-inbox@example.com',
  45                 updated => POSIX::strftime(DATEFMT, gmtime),
  46         );
  47
  48         my $git = try_git_pm($args->{git_dir});
  49         each_recent_blob($args, sub {
  50                 my ($add) = @_;
  51                 add_to_feed($feed_opts, $feed, $add, $top, $git);
  52         });
  53         $feed->as_string;
  54 }
  55
  56 sub generate_html_index {
  57         my ($class, $args) = @_;
  58         require Mail::Thread;
  59
  60         my $max = $args->{max} || MAX_PER_PAGE;
  61         my $top = $args->{top}; # bool
  62         local $ENV{GIT_DIR} = $args->{git_dir};
  63         my $feed_opts = get_feedopts($args);
  64         my $title = xs_html($feed_opts->{description} || "");
  65         my @messages;
  66         my $git = try_git_pm($args->{git_dir});
  67         my ($first, $last) = each_recent_blob($args, sub {
  68                 my $simple = do_cat_mail($git, 'Email::Simple', $_[0])
  69                         or return 0;
  70                 if ($top && ($simple->header("In-Reply-To") ||
  71                              $simple->header("References"))) {
  72                         return 0;
  73                 }
  74                 $simple->body_set(""); # save some memory
  75
  76                 my $t = eval { str2time($simple->header('Date')) };
  77                 defined($t) or $t = 0;
  78                 $simple->header_set('X-PI-Date', $t);
  79                 push @messages, $simple;
  80                 1;
  81         });
  82
  83         my $th = Mail::Thread->new(@messages);
  84         $th->thread;
  85         my @out = (
  86                 "<html><head><title>$title</title>" .
  87                 '<link rel=alternate title=Atom.feed href="' .
  88                 $feed_opts->{atomurl} . '" type="application/atom+xml"/>' .
  89                 '</head><body><pre>');
  90         push @out, $feed_opts->{midurl};
  91
  92         # sort by date, most recent at top
  93         $th->order(sub {
  94                 sort {
  95                         $b->topmost->message->header('X-PI-Date') <=>
  96                         $a->topmost->message->header('X-PI-Date')
  97                 } @_;
  98         });
  99         dump_html_line($_, 0, \@out) for $th->rootset;
 100
 101         my $footer = nav_footer($args->{cgi}, $first, $last);
 102         $footer = "<hr /><pre>$footer</pre>" if $footer;
 103         $out[0] . "</pre>$footer</html>";
 104 }
 105
 106 # private subs
 107
 108 sub nav_footer {
 109         my ($cgi, $first, $last) = @_;
 110         $cgi or return '';
 111         my $old_r = $cgi->param('r');
 112         my $prev = '    ';
 113         my $next = '    ';
 114         my %opts = (-path => 1, -query => 1, -relative => 1);
 115
 116         if ($last) {
 117                 $cgi->param('r', $last);
 118                 $next = $cgi->url(%opts);
 119                 $next = qq!<a href="$next">next</a>!;
 120         }
 121         if ($first && $old_r) {
 122                 $cgi->param('r', "$first..");
 123                 $prev = $cgi->url(%opts);
 124                 $prev = qq!<a href="$prev">prev</a>!;
 125         }
 126         "$prev $next";
 127 }
 128
 129 sub each_recent_blob {
 130         my ($args, $cb) = @_;
 131         my $max = $args->{max} || MAX_PER_PAGE;
 132         my $refhex = qr/[a-f0-9]{4,40}(?:~\d+)?/;
 133         my $cgi = $args->{cgi};
 134
 135         # revision ranges may be specified
 136         my $reverse;
 137         my $range = 'HEAD';
 138         my $r = $cgi->param('r') if $cgi;
 139         if ($r) {
 140                 if ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o) {
 141                         $range = $r;
 142                 } elsif ($r =~ /\A(?:$refhex\.\.)\z/o) {
 143                         $reverse = 1;
 144                         $range = $r;
 145                 }
 146         }
 147
 148         # get recent messages
 149         # we could use git log -z, but, we already know ssoma will not
 150         # leave us with filenames with spaces in them..
 151         my @cmd = qw/git log --no-notes --no-color --raw -r --no-abbrev/;
 152         push @cmd, '--reverse' if $reverse;
 153         push @cmd, $range;
 154         my $first;
 155
 156         my $pid = open(my $log, '-|', @cmd) or
 157                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 158         my %deleted;
 159         my $last;
 160         my $nr = 0;
 161         my @commits = ();
 162         while (my $line = <$log>) {
 163                 if ($line =~ /^:000000 100644 0{40} ([a-f0-9]{40})/) {
 164                         my $add = $1;
 165                         next if $deleted{$add};
 166                         $nr += $cb->($add);
 167                         if ($nr >= $max) {
 168                                 $last = 1;
 169                                 last;
 170                         }
 171                 } elsif ($line =~ /^:100644 000000 ([a-f0-9]{40}) 0{40}/) {
 172                         $deleted{$1} = 1;
 173                 } elsif ($line =~ /^commit ([a-f0-9]{40})/) {
 174                         push @commits, $1;
 175                 }
 176         }
 177
 178         if ($last) {
 179                 while (my $line = <$log>) {
 180                         if ($line =~ /^commit ([a-f0-9]{40})/) {
 181                                 push @commits, $1;
 182                                 last;
 183                         }
 184                 }
 185         } elsif ($reverse) {
 186                 unshift @commits, undef
 187         } else {
 188                 push @commits, undef;
 189         }
 190
 191         close $log; # we may EPIPE here
 192         # for pagination
 193         $reverse ? ($commits[-1],$commits[0]) : ($commits[0],$commits[-1]);
 194 }
 195
 196 # private functions below
 197 sub get_feedopts {
 198         my ($args) = @_;
 199         my $pi_config = $args->{pi_config};
 200         my $listname = $args->{listname};
 201         my $cgi = $args->{cgi};
 202         my %rv;
 203
 204         if ($pi_config && defined $listname && length $listname) {
 205                 foreach my $key (qw(description address)) {
 206                         $rv{$key} = $pi_config->get($listname, $key) || "";
 207                 }
 208         }
 209         my $url_base;
 210         if ($cgi) {
 211                 my $cgi_url = $cgi->url(-path=>1, -relative=>1);
 212                 my $base = $cgi->url(-base);
 213                 $url_base = $cgi_url;
 214                 if ($url_base =~ s!/(?:|index\.html)?\z!!) {
 215                         $rv{atomurl} = "$base$url_base/atom.xml";
 216                 } else {
 217                         $url_base =~ s!/atom\.xml\z!!;
 218                         $rv{atomurl} = $base . $cgi_url;
 219                         $url_base = $base . $url_base; # XXX is this needed?
 220                 }
 221         } else {
 222                 $url_base = "http://example.com";
 223                 $rv{atomurl} = "$url_base/atom.xml";
 224         }
 225         $rv{url} ||= "$url_base/";
 226         $rv{midurl} = "$url_base/m/";
 227         $rv{fullurl} = "$url_base/f/";
 228
 229         \%rv;
 230 }
 231
 232 sub utf8_header {
 233         my ($simple, $name) = @_;
 234         my $val = $simple->header($name);
 235         return "" unless defined $val;
 236         $val =~ tr/\t\n / /s;
 237         $val =~ tr/\r//d;
 238         $enc_utf8->encode($enc_mime->decode($val));
 239 }
 240
 241 sub feed_date {
 242         my ($date) = @_;
 243         my @t = eval { strptime($date) };
 244
 245         scalar(@t) ? POSIX::strftime(DATEFMT, @t) : 0;
 246 }
 247
 248 # returns 0 (skipped) or 1 (added)
 249 sub add_to_feed {
 250         my ($feed_opts, $feed, $add, $top, $git) = @_;
 251
 252         my $mime = do_cat_mail($git, 'Email::MIME', $add) or return 0;
 253         if ($top && $mime->header("In-Reply-To")) {
 254                 return 0;
 255         }
 256
 257         my $midurl = $feed_opts->{midurl} || 'http://example.com/m/';
 258         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/f/';
 259
 260         my $content = PublicInbox::View->as_feed_entry($mime, $fullurl);
 261         defined($content) or return 0;
 262
 263         my $mid = utf8_header($mime, "Message-ID") or return 0;
 264         $mid =~ s/\A<//; $mid =~ s/>\z//;
 265
 266         my $subject = utf8_header($mime, "Subject") || "";
 267         length($subject) or return 0;
 268
 269         my $from = utf8_header($mime, "From") or return 0;
 270
 271         my @from = Email::Address->parse($from);
 272         my $name = $from[0]->name;
 273         defined $name or $name = "";
 274         my $email = $from[0]->address;
 275         defined $email or $email = "";
 276
 277         my $url = $midurl . uri_escape($mid);
 278         my $date = utf8_header($mime, "Date");
 279         $date or return 0;
 280         $date = feed_date($date) or return 0;
 281         $feed->add_entry(
 282                 author => { name => $name, email => $email },
 283                 title => $subject,
 284                 updated => $date,
 285                 content => { type => "html", content => $content },
 286                 link => $url,
 287                 id => $add,
 288         );
 289         1;
 290 }
 291
 292 sub dump_html_line {
 293         my ($self, $level, $args) = @_; # args => [ $html, $midurl ]
 294         if ($self->message) {
 295                 $args->[0] .= (' ' x $level);
 296                 my $simple = $self->message;
 297                 my $subj = utf8_header($simple, "Subject");
 298                 my $mid = utf8_header($simple, "Message-ID");
 299                 $mid =~ s/\A<//;
 300                 $mid =~ s/>\z//;
 301                 my $url = $args->[1] . uri_escape($mid);
 302                 my $from = utf8_header($simple, "From");
 303                 my @from = Email::Address->parse($from);
 304                 $from = $from[0]->name;
 305                 (defined($from) && length($from)) or $from = $from[0]->address;
 306                 $from = xs_html($from);
 307                 $subj = xs_html($subj);
 308                 $args->[0] .= "<a href=\"$url.html\">$subj</a> $from\n";
 309         }
 310         dump_html_line($self->child, $level+1, $args) if $self->child;
 311         dump_html_line($self->next, $level, $args) if $self->next;
 312 }
 313
 314 sub xs_html {
 315         $enc_ascii->encode(escapeHTML($enc_utf8->decode($_[0])),
 316                         Encode::HTMLCREF);
 317 }
 318
 319 sub try_git_pm {
 320         my ($dir) = @_;
 321         eval { Git->repository(Directory => $dir) };
 322 };
 323
 324 sub do_cat_mail {
 325         my ($git, $class, $sha1) = @_;
 326         my $str;
 327         if ($git) {
 328                 open my $fh, '>', \$str or
 329                                 die "failed to setup string handle: $!\n";
 330                 binmode $fh;
 331                 my $bytes = $git->cat_blob($sha1, $fh);
 332                 close $fh or die "failed to close string handle: $!\n";
 333                 return if $bytes <= 0;
 334         } else {
 335                 $str = `git cat-file blob $sha1`;
 336                 return if $? != 0 || length($str) == 0;
 337         }
 338         $class->new($str);
 339 }
 340
 341 1;