]> Sergey Matveev's repositories - public-inbox.git/blob - lib/PublicInbox/Feed.pm
6ed0085630825fd985564d4c0cf0d202ddcf556d
[public-inbox.git] / lib / PublicInbox / Feed.pm
1 # Copyright (C) 2013-2015 all contributors <meta@public-inbox.org>
2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
3 #
4 # Used for generating Atom feeds for web-accessible mailing list archives.
5 package PublicInbox::Feed;
6 use strict;
7 use warnings;
8 use Email::Address;
9 use Email::MIME;
10 use Date::Parse qw(strptime);
11 use PublicInbox::Hval qw/ascii_html/;
12 use PublicInbox::Git;
13 use PublicInbox::View;
14 use PublicInbox::MID qw/mid_clean mid2path/;
15 use POSIX qw/strftime/;
16 use constant {
17         DATEFMT => '%Y-%m-%dT%H:%M:%SZ', # Atom standard
18         MAX_PER_PAGE => 25, # this needs to be tunable
19 };
20
21 # main function
22 sub generate {
23         my ($ctx) = @_;
24         sub { emit_atom($_[0], $ctx) };
25 }
26
27 sub generate_thread_atom {
28         my ($ctx) = @_;
29         sub { emit_atom_thread($_[0], $ctx) };
30 }
31
32 sub generate_html_index {
33         my ($ctx) = @_;
34         sub { emit_html_index($_[0], $ctx) };
35 }
36
37 # private subs
38
39 sub title_tag {
40         my ($title) = @_;
41         $title =~ tr/\t\n / /s; # squeeze spaces
42         # try to avoid the type attribute in title:
43         $title = ascii_html($title);
44         my $type = index($title, '&') >= 0 ? "\ntype=\"html\"" : '';
45         "<title$type>$title</title>";
46 }
47
48 sub atom_header {
49         my ($feed_opts, $title) = @_;
50
51         $title = title_tag($feed_opts->{description}) unless (defined $title);
52
53         qq(<?xml version="1.0" encoding="us-ascii"?>\n) .
54         qq{<feed\nxmlns="http://www.w3.org/2005/Atom">} .
55         qq{$title} .
56         qq(<link\nrel="alternate"\ntype="text/html") .
57                 qq(\nhref="$feed_opts->{url}"/>) .
58         qq(<link\nrel="self"\nhref="$feed_opts->{atomurl}"/>) .
59         qq(<id>mailto:$feed_opts->{id_addr}</id>);
60 }
61
62 sub emit_atom {
63         my ($cb, $ctx) = @_;
64         my $feed_opts = get_feedopts($ctx);
65         my $fh = $cb->([ 200, ['Content-Type' => 'application/atom+xml']]);
66         my $max = $ctx->{max} || MAX_PER_PAGE;
67         my $x = atom_header($feed_opts);
68         my $git = $ctx->{git} ||= PublicInbox::Git->new($ctx->{git_dir});
69         each_recent_blob($ctx, sub {
70                 my ($path, undef, $ts) = @_;
71                 if (defined $x) {
72                         $fh->write($x . feed_updated(undef, $ts));
73                         $x = undef;
74                 }
75                 add_to_feed($feed_opts, $fh, $path, $git);
76         });
77         end_feed($fh);
78 }
79
80 sub _no_thread {
81         my ($cb) = @_;
82         my $fh = $cb->([404, ['Content-Type' => 'text/plain']]);
83         $fh->write("No feed found for thread\n");
84         $fh->close;
85 }
86
87 sub end_feed {
88         my ($fh) = @_;
89         Email::Address->purge_cache;
90         $fh->write('</feed>');
91         $fh->close;
92 }
93
94 sub emit_atom_thread {
95         my ($cb, $ctx) = @_;
96         my $res = $ctx->{srch}->get_thread($ctx->{mid});
97         return _no_thread($cb) unless $res->{total};
98         my $feed_opts = get_feedopts($ctx);
99         my $fh = $cb->([200, ['Content-Type' => 'application/atom+xml']]);
100
101         my $html_url = $feed_opts->{atomurl} = $ctx->{self_url};
102         $html_url =~ s!/t\.atom\z!/!;
103         $feed_opts->{url} = $html_url;
104         $feed_opts->{emit_header} = 1;
105
106         my $git = $ctx->{git} ||= PublicInbox::Git->new($ctx->{git_dir});
107         foreach my $msg (@{$res->{msgs}}) {
108                 add_to_feed($feed_opts, $fh, mid2path($msg->mid), $git);
109         }
110         end_feed($fh);
111 }
112
113 sub emit_html_index {
114         my ($res, $ctx) = @_;
115         my $feed_opts = get_feedopts($ctx);
116         my $fh = $res->([200,['Content-Type'=>'text/html; charset=UTF-8']]);
117
118         my $max = $ctx->{max} || MAX_PER_PAGE;
119
120         my $title = ascii_html($feed_opts->{description} || '');
121         my ($footer, $param, $last);
122         my $state = { ctx => $ctx, seen => {}, anchor_idx => 0, fh => $fh };
123         my $srch = $ctx->{srch};
124
125         my $top = "<b>$title</b> (<a\nhref=\"new.atom\">Atom feed</a>)";
126
127         if ($srch) {
128                 $top = qq{<form\naction=""><pre>$top} .
129                           qq{ <input\nname=q\ntype=text />} .
130                           qq{<input\ntype=submit\nvalue=search />} .
131                           q{</pre></form><pre>}
132         } else {
133                 $top = '<pre>' . $top . "\n";
134         }
135
136         $fh->write("<html><head><title>$title</title>" .
137                    "<link\nrel=alternate\ntitle=\"Atom feed\"\n".
138                    "href=\"new.atom\"\ntype=\"application/atom+xml\"/>" .
139                    PublicInbox::Hval::STYLE .
140                    "</head><body>$top");
141
142         # if the 'r' query parameter is given, it is a legacy permalink
143         # which we must continue supporting:
144         my $cgi = $ctx->{cgi};
145         if ($cgi && !$cgi->param('r') && $srch) {
146                 $state->{srch} = $srch;
147                 $last = PublicInbox::View::emit_index_topics($state);
148                 $param = 'o';
149         } else {
150                 $last = emit_index_nosrch($ctx, $state);
151                 $param = 'r';
152         }
153         $footer = nav_footer($cgi, $last, $feed_opts, $state, $param);
154         if ($footer) {
155                 my $list_footer = $ctx->{footer};
156                 $footer .= "\n\n" . $list_footer if $list_footer;
157                 $footer = "<hr /><pre>$footer</pre>";
158         }
159         $fh->write("$footer</body></html>");
160         $fh->close;
161 }
162
163 sub emit_index_nosrch {
164         my ($ctx, $state) = @_;
165         my $git = $ctx->{git} ||= PublicInbox::Git->new($ctx->{git_dir});
166         my (undef, $last) = each_recent_blob($ctx, sub {
167                 my ($path, $commit, $ts, $u, $subj) = @_;
168                 $state->{first} ||= $commit;
169
170                 my $mime = do_cat_mail($git, $path) or return 0;
171                 PublicInbox::View::index_entry($mime, 0, $state);
172                 1;
173         });
174         Email::Address->purge_cache;
175         $last;
176 }
177
178 sub nav_footer {
179         my ($cgi, $last, $feed_opts, $state, $param) = @_;
180         $cgi or return '';
181         my $old_r = $cgi->param($param);
182         my $head = '    ';
183         my $next = '    ';
184         my $first = $state->{first};
185         my $anchor = $state->{anchor_idx};
186
187         if ($last) {
188                 $next = qq!<a\nhref="?$param=$last"\nrel=next>next</a>!;
189         }
190         if ($old_r) {
191                 $head = $cgi->path_info;
192                 $head = qq!<a\nhref="$head">head</a>!;
193         }
194         my $atom = "<a\nhref=\"$feed_opts->{atomurl}\">Atom feed</a>";
195         "<a\nname=\"s$anchor\">page:</a> $next $head $atom";
196 }
197
198 sub each_recent_blob {
199         my ($ctx, $cb) = @_;
200         my $max = $ctx->{max} || MAX_PER_PAGE;
201         my $hex = '[a-f0-9]';
202         my $addmsg = qr!^:000000 100644 \S+ \S+ A\t(${hex}{2}/${hex}{38})$!;
203         my $delmsg = qr!^:100644 000000 \S+ \S+ D\t(${hex}{2}/${hex}{38})$!;
204         my $refhex = qr/(?:HEAD|${hex}{4,40})(?:~\d+)?/;
205         my $cgi = $ctx->{cgi};
206
207         # revision ranges may be specified
208         my $range = 'HEAD';
209         my $r = $cgi->param('r') if $cgi;
210         if ($r && ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o)) {
211                 $range = $r;
212         }
213
214         # get recent messages
215         # we could use git log -z, but, we already know ssoma will not
216         # leave us with filenames with spaces in them..
217         my $git = $ctx->{git} ||= PublicInbox::Git->new($ctx->{git_dir});
218         my $log = $git->popen(qw/log --no-notes --no-color --raw -r
219                                 --abbrev=16 --abbrev-commit/,
220                                 "--format=%h%x00%ct%x00%an%x00%s%x00",
221                                 $range);
222         my %deleted; # only an optimization at this point
223         my $last;
224         my $nr = 0;
225         my ($cur_commit, $first_commit, $last_commit);
226         my ($ts, $subj, $u);
227         local $/ = "\n";
228         while (defined(my $line = <$log>)) {
229                 if ($line =~ /$addmsg/o) {
230                         my $add = $1;
231                         next if $deleted{$add}; # optimization-only
232                         $nr += $cb->($add, $cur_commit, $ts, $u, $subj);
233                         if ($nr >= $max) {
234                                 $last = 1;
235                                 last;
236                         }
237                 } elsif ($line =~ /$delmsg/o) {
238                         $deleted{$1} = 1;
239                 } elsif ($line =~ /^${hex}{7,40}/o) {
240                         ($cur_commit, $ts, $u, $subj) = split("\0", $line);
241                         unless (defined $first_commit) {
242                                 $first_commit = $cur_commit;
243                         }
244                 }
245         }
246
247         if ($last) {
248                 local $/ = "\n";
249                 while (my $line = <$log>) {
250                         if ($line =~ /^(${hex}{7,40})/o) {
251                                 $last_commit = $1;
252                                 last;
253                         }
254                 }
255         }
256
257         # for pagination
258         ($first_commit, $last_commit);
259 }
260
261 # private functions below
262 sub get_feedopts {
263         my ($ctx) = @_;
264         my $pi_config = $ctx->{pi_config};
265         my $inbox = $ctx->{inbox};
266         my $obj = $ctx->{-inbox};
267         my $cgi = $ctx->{cgi};
268         my %rv = ( description => $obj ? $obj->description : 'FIXME' );
269
270         if ($obj) {
271                 $rv{address} = $obj->{address};
272                 $rv{id_addr} = $obj->{-primary_address};
273         } elsif ($pi_config && defined $inbox && $inbox ne '') {
274                 # TODO: remove
275                 my $addr = $pi_config->get($inbox, 'address') || "";
276                 $rv{address} = $addr;
277                 $addr = $addr->[0] if ref($addr);
278                 $rv{id_addr} = $addr;
279         }
280         $rv{id_addr} ||= 'public-inbox@example.com';
281
282         my $url_base;
283         if ($obj) {
284                 $url_base = $obj->base_url($cgi); # CGI may be undef
285                 if (my $mid = $ctx->{mid}) { # per-thread feed:
286                         $rv{atomurl} = "$url_base$mid/t.atom";
287                 } else {
288                         $rv{atomurl} = $url_base."new.atom";
289                 }
290         } else {
291                 $url_base = 'http://example.com/';
292                 $rv{atomurl} = $url_base.'new.atom';
293         }
294         $rv{url} ||= $url_base;
295         $rv{midurl} = $url_base;
296
297         \%rv;
298 }
299
300 sub feed_updated {
301         my ($date, $ts) = @_;
302         my @t = eval { strptime($date) } if defined $date;
303         @t = gmtime($ts || time) unless scalar @t;
304
305         '<updated>' . strftime(DATEFMT, @t) . '</updated>';
306 }
307
308 # returns 0 (skipped) or 1 (added)
309 sub add_to_feed {
310         my ($feed_opts, $fh, $add, $git) = @_;
311
312         my $mime = do_cat_mail($git, $add) or return 0;
313         my $url = $feed_opts->{url};
314         my $midurl = $feed_opts->{midurl};
315
316         my $header_obj = $mime->header_obj;
317         my $mid = $header_obj->header_raw('Message-ID');
318         defined $mid or return 0;
319         $mid = PublicInbox::Hval->new_msgid($mid);
320         my $href = $midurl.$mid->as_href;
321
322         my $content = qq(<pre\nstyle="white-space:pre-wrap">) .
323                 PublicInbox::View::multipart_text_as_html($mime, $href) .
324                 '</pre>';
325         my $date = $header_obj->header('Date');
326         my $updated = feed_updated($date);
327
328         my $title = $header_obj->header('Subject');
329         defined $title or return 0;
330         $title = title_tag($title);
331
332         my $from = $header_obj->header('From') or return 0;
333         my @from = Email::Address->parse($from) or return 0;
334         my $name = ascii_html($from[0]->name);
335         my $email = $from[0]->address;
336         $email = ascii_html($email);
337
338         if (delete $feed_opts->{emit_header}) {
339                 $fh->write(atom_header($feed_opts, $title) . $updated);
340         }
341         $fh->write("<entry><author><name>$name</name><email>$email</email>" .
342                    "</author>$title$updated" .
343                    qq{<content\ntype="xhtml">} .
344                    qq{<div\nxmlns="http://www.w3.org/1999/xhtml">});
345         $fh->write($content);
346
347         $add =~ tr!/!!d;
348         my $h = '[a-f0-9]';
349         my (@uuid5) = ($add =~ m!\A($h{8})($h{4})($h{4})($h{4})($h{12})!o);
350         my $id = 'urn:uuid:' . join('-', @uuid5);
351         $fh->write(qq!</div></content><link\nhref="$href/"/>!.
352                    "<id>$id</id></entry>");
353         1;
354 }
355
356 sub do_cat_mail {
357         my ($git, $path) = @_;
358         my $mime = eval {
359                 my $str = $git->cat_file("HEAD:$path");
360                 Email::MIME->new($str);
361         };
362         $@ ? undef : $mime;
363 }
364
365 1;