lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use XML::Atom::SimpleFeed;
   7 use Email::MIME;
   8 use Email::Address;
   9 use URI::Escape qw/uri_escape/;
  10 use Encode qw/find_encoding/;
  11 use Encode::MIME::Header;
  12 use CGI qw(escapeHTML);
  13 use POSIX qw(strftime);
  14 use Date::Parse qw(strptime str2time);
  15 use constant {
  16         DATEFMT => '%Y-%m-%dT%H:%M:%SZ',
  17         MAX_PER_PAGE => 25,
  18 };
  19 use PublicInbox::View;
  20 use Mail::Thread;
  21 my $enc_utf8 = find_encoding('utf8');
  22 my $enc_ascii = find_encoding('us-ascii');
  23 my $enc_mime = find_encoding('MIME-Header');
  24
  25 # FIXME: workaround https://rt.cpan.org/Public/Bug/Display.html?id=22817
  26
  27 # main function
  28 sub generate {
  29         my ($class, $args) = @_;
  30         my $max = $args->{max} || MAX_PER_PAGE;
  31         my $top = $args->{top}; # bool
  32
  33         local $ENV{GIT_DIR} = $args->{git_dir};
  34         my $feed_opts = get_feedopts($args);
  35
  36         my $feed = XML::Atom::SimpleFeed->new(
  37                 title => $feed_opts->{description} || "unnamed feed",
  38                 link => $feed_opts->{url} || "http://example.com/",
  39                 link => {
  40                         rel => 'self',
  41                         href => $feed_opts->{atomurl} ||
  42                                 "http://example.com/atom",
  43                 },
  44                 id => $feed_opts->{address} || 'public-inbox@example.com',
  45                 updated => strftime(DATEFMT, gmtime),
  46         );
  47
  48         each_recent_blob($args, sub {
  49                 my ($add) = @_;
  50                 add_to_feed($feed_opts, $feed, $add, $top);
  51         });
  52         $feed->as_string;
  53 }
  54
  55 sub generate_html_index {
  56         my ($class, $args) = @_;
  57         my $max = $args->{max} || MAX_PER_PAGE;
  58         my $top = $args->{top}; # bool
  59         local $ENV{GIT_DIR} = $args->{git_dir};
  60         my $feed_opts = get_feedopts($args);
  61         my $title = xs_html($feed_opts->{description} || "");
  62         my @messages;
  63         my ($first, $last) = each_recent_blob($args, sub {
  64                 my $str = `git cat-file blob $_[0]`;
  65                 return 0 if $? != 0;
  66                 my $simple = Email::Simple->new($str);
  67                 if ($top && ($simple->header("In-Reply-To") ||
  68                              $simple->header("References"))) {
  69                         return 0;
  70                 }
  71                 $simple->body_set(""); # save some memory
  72
  73                 my $t = eval { str2time($simple->header('Date')) };
  74                 defined($t) or $t = 0;
  75                 $simple->header_set('X-PI-Date', $t);
  76                 push @messages, $simple;
  77                 1;
  78         });
  79
  80         my $th = Mail::Thread->new(@messages);
  81         $th->thread;
  82         my @out = (
  83                 "<html><head><title>$title</title>" .
  84                 '<link rel=alternate title=Atom.feed href="' .
  85                 $feed_opts->{atomurl} . '" type="application/atom+xml"/>' .
  86                 '</head><body><pre>');
  87         push @out, $feed_opts->{midurl};
  88
  89         # sort by date, most recent at top
  90         $th->order(sub {
  91                 sort {
  92                         $b->topmost->message->header('X-PI-Date') <=>
  93                         $a->topmost->message->header('X-PI-Date')
  94                 } @_;
  95         });
  96         dump_html_line($_, 0, \@out) for $th->rootset;
  97
  98         my $footer = nav_footer($args->{cgi}, $first, $last);
  99         $footer = "<hr /><pre>$footer</pre>" if $footer;
 100         $out[0] . "</pre>$footer</html>";
 101 }
 102
 103 # private subs
 104
 105 sub nav_footer {
 106         my ($cgi, $first, $last) = @_;
 107         $cgi or return '';
 108         my $old_r = $cgi->param('r');
 109         my $prev = '    ';
 110         my $next = '    ';
 111         my %opts = (-path => 1, -query => 1, -relative => 1);
 112
 113         if ($last) {
 114                 $cgi->param('r', $last);
 115                 $next = $cgi->url(%opts);
 116                 $next = qq!<a href="$next">next</a>!;
 117         }
 118         if ($first && $old_r) {
 119                 $cgi->param('r', "$first..");
 120                 $prev = $cgi->url(%opts);
 121                 $prev = qq!<a href="$prev">prev</a>!;
 122         }
 123         "$prev $next";
 124 }
 125
 126 sub each_recent_blob {
 127         my ($args, $cb) = @_;
 128         my $max = $args->{max} || MAX_PER_PAGE;
 129         my $refhex = qr/[a-f0-9]{4,40}(?:~\d+)?/;
 130         my $cgi = $args->{cgi};
 131
 132         # revision ranges may be specified
 133         my $reverse;
 134         my $range = 'HEAD';
 135         my $r = $cgi->param('r') if $cgi;
 136         if ($r) {
 137                 if ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o) {
 138                         $range = $r;
 139                 } elsif ($r =~ /\A(?:$refhex\.\.)\z/o) {
 140                         $reverse = 1;
 141                         $range = $r;
 142                 }
 143         }
 144
 145         # get recent messages
 146         # we could use git log -z, but, we already know ssoma will not
 147         # leave us with filenames with spaces in them..
 148         my @cmd = qw/git log --no-notes --no-color --raw -r --no-abbrev/;
 149         push @cmd, '--reverse' if $reverse;
 150         push @cmd, $range;
 151         my $first;
 152
 153         my $pid = open(my $log, '-|', @cmd) or
 154                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 155         my %deleted;
 156         my $last;
 157         my $nr = 0;
 158         my @commits = ();
 159         while (my $line = <$log>) {
 160                 if ($line =~ /^:000000 100644 0{40} ([a-f0-9]{40})/) {
 161                         my $add = $1;
 162                         next if $deleted{$add};
 163                         $nr += $cb->($add);
 164                         if ($nr >= $max) {
 165                                 $last = 1;
 166                                 last;
 167                         }
 168                 } elsif ($line =~ /^:100644 000000 ([a-f0-9]{40}) 0{40}/) {
 169                         $deleted{$1} = 1;
 170                 } elsif ($line =~ /^commit ([a-f0-9]{40})/) {
 171                         push @commits, $1;
 172                 }
 173         }
 174
 175         if ($last) {
 176                 while (my $line = <$log>) {
 177                         if ($line =~ /^commit ([a-f0-9]{40})/) {
 178                                 push @commits, $1;
 179                                 last;
 180                         }
 181                 }
 182         }
 183
 184         close $log; # we may EPIPE here
 185         # for pagination
 186         $reverse ? ($commits[-1],$commits[0]) : ($commits[0],$commits[-1]);
 187 }
 188
 189 # private functions below
 190 sub get_feedopts {
 191         my ($args) = @_;
 192         my $pi_config = $args->{pi_config};
 193         my $listname = $args->{listname};
 194         my $cgi = $args->{cgi};
 195         my %rv;
 196
 197         if ($pi_config && defined $listname && length $listname) {
 198                 foreach my $key (qw(description address)) {
 199                         $rv{$key} = $pi_config->get($listname, $key) || "";
 200                 }
 201         }
 202         my $url_base;
 203         if ($cgi) {
 204                 my $cgi_url = $cgi->url(-path=>1, -relative=>1);
 205                 my $base = $cgi->url(-base);
 206                 $url_base = $cgi_url;
 207                 if ($url_base =~ s!/(?:|index\.html)?\z!!) {
 208                         $rv{atomurl} = "$base$url_base/index.atom.xml";
 209                 } else {
 210                         $url_base =~ s!/?(?:index|all)\.atom\.xml\z!!;
 211                         $rv{atomurl} = $base . $cgi_url;
 212                         $url_base = $base . $url_base; # XXX is this needed?
 213                 }
 214         } else {
 215                 $url_base = "http://example.com";
 216                 $rv{atomurl} = "$url_base/index.atom.xml";
 217         }
 218         $rv{url} ||= "$url_base/";
 219         $rv{midurl} = "$url_base/m/";
 220         $rv{fullurl} = "$url_base/f/";
 221
 222         \%rv;
 223 }
 224
 225 sub utf8_header {
 226         my ($simple, $name) = @_;
 227         my $val = $simple->header($name);
 228         return "" unless defined $val;
 229         $val =~ tr/\t\n / /s;
 230         $val =~ tr/\r//d;
 231         $enc_utf8->encode($enc_mime->decode($val));
 232 }
 233
 234 sub feed_date {
 235         my ($date) = @_;
 236         my @t = eval { strptime($date) };
 237
 238         scalar(@t) ? strftime(DATEFMT, @t) : 0;
 239 }
 240
 241 # returns 0 (skipped) or 1 (added)
 242 sub add_to_feed {
 243         my ($feed_opts, $feed, $add, $top) = @_;
 244
 245         # we can use git cat-file --batch if performance becomes a
 246         # problem, but I doubt it...
 247         my $str = `git cat-file blob $add`;
 248         return 0 if $? != 0;
 249         my $mime = Email::MIME->new($str);
 250
 251         if ($top && $mime->header("In-Reply-To")) {
 252                 return 0;
 253         }
 254
 255         my $midurl = $feed_opts->{midurl} || 'http://example.com/m/';
 256         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/f/';
 257
 258         my $content = PublicInbox::View->as_feed_entry($mime, $fullurl);
 259         defined($content) or return 0;
 260
 261         my $mid = utf8_header($mime, "Message-ID") or return 0;
 262         $mid =~ s/\A<//; $mid =~ s/>\z//;
 263
 264         my $subject = utf8_header($mime, "Subject") || "";
 265         length($subject) or return 0;
 266
 267         my $from = utf8_header($mime, "From") or return 0;
 268
 269         my @from = Email::Address->parse($from);
 270         my $name = $from[0]->name;
 271         defined $name or $name = "";
 272         my $email = $from[0]->address;
 273         defined $email or $email = "";
 274
 275         my $url = $midurl . uri_escape($mid);
 276         my $date = utf8_header($mime, "Date");
 277         $date or return 0;
 278         $date = feed_date($date) or return 0;
 279         $feed->add_entry(
 280                 author => { name => $name, email => $email },
 281                 title => $subject,
 282                 updated => $date,
 283                 content => { type => "html", content => $content },
 284                 link => $url,
 285                 id => $add,
 286         );
 287         1;
 288 }
 289
 290 sub dump_html_line {
 291         my ($self, $level, $args) = @_; # args => [ $html, $midurl ]
 292         $args->[0] .= (' ' x $level);
 293         if ($self->message) {
 294                 my $simple = $self->message;
 295                 my $subj = utf8_header($simple, "Subject");
 296                 my $mid = utf8_header($simple, "Message-ID");
 297                 $mid =~ s/\A<//;
 298                 $mid =~ s/>\z//;
 299                 my $url = $args->[1] . uri_escape($mid);
 300                 my $from = utf8_header($simple, "From");
 301                 my @from = Email::Address->parse($from);
 302                 $from = $from[0]->name;
 303                 (defined($from) && length($from)) or $from = $from[0]->address;
 304                 $from = xs_html($from);
 305                 $subj = xs_html($subj);
 306                 $args->[0] .= "<a href=\"$url.html\">$subj</a> $from\n";
 307         } else {
 308                 $args->[0] .= "[ Message not available ]\n";
 309         }
 310         dump_html_line($self->child, $level+1, $args) if $self->child;
 311         dump_html_line($self->next, $level, $args) if $self->next;
 312 }
 313
 314 sub xs_html {
 315         $enc_ascii->encode(escapeHTML($enc_utf8->decode($_[0])),
 316                         Encode::HTMLCREF);
 317 }
 318
 319 1;