lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use Email::Address;
   7 use URI::Escape qw/uri_escape/;
   8 use Encode qw/find_encoding/;
   9 use Encode::MIME::Header;
  10 use CGI qw(escapeHTML);
  11 use Date::Parse qw(strptime str2time);
  12 eval { require Git }; # this is GPLv2+, so we are OK to use it
  13 use constant {
  14         DATEFMT => '%Y-%m-%dT%H:%M:%SZ',
  15         MAX_PER_PAGE => 25,
  16 };
  17 my $enc_utf8 = find_encoding('utf8');
  18 my $enc_ascii = find_encoding('us-ascii');
  19 my $enc_mime = find_encoding('MIME-Header');
  20
  21 # FIXME: workaround https://rt.cpan.org/Public/Bug/Display.html?id=22817
  22
  23 # main function
  24 sub generate {
  25         my ($class, $args) = @_;
  26         require XML::Atom::SimpleFeed;
  27         require PublicInbox::View;
  28         require Email::MIME;
  29         require POSIX;
  30         my $max = $args->{max} || MAX_PER_PAGE;
  31         my $top = $args->{top}; # bool
  32
  33         local $ENV{GIT_DIR} = $args->{git_dir};
  34         my $feed_opts = get_feedopts($args);
  35         my $addr = $feed_opts->{address};
  36         $addr = $addr->[0] if ref($addr);
  37         my $feed = XML::Atom::SimpleFeed->new(
  38                 title => $feed_opts->{description} || "unnamed feed",
  39                 link => $feed_opts->{url} || "http://example.com/",
  40                 link => {
  41                         rel => 'self',
  42                         href => $feed_opts->{atomurl} ||
  43                                 "http://example.com/atom.xml",
  44                 },
  45                 id => $addr || 'public-inbox@example.com',
  46                 updated => POSIX::strftime(DATEFMT, gmtime),
  47         );
  48
  49         my $git = try_git_pm($args->{git_dir});
  50         each_recent_blob($args, sub {
  51                 my ($add) = @_;
  52                 add_to_feed($feed_opts, $feed, $add, $top, $git);
  53         });
  54         $feed->as_string;
  55 }
  56
  57 sub generate_html_index {
  58         my ($class, $args) = @_;
  59         require Mail::Thread;
  60
  61         my $max = $args->{max} || MAX_PER_PAGE;
  62         my $top = $args->{top}; # bool
  63         local $ENV{GIT_DIR} = $args->{git_dir};
  64         my $feed_opts = get_feedopts($args);
  65         my $title = xs_html($feed_opts->{description} || "");
  66         my @messages;
  67         my $git = try_git_pm($args->{git_dir});
  68         my ($first, $last) = each_recent_blob($args, sub {
  69                 my $simple = do_cat_mail($git, 'Email::Simple', $_[0])
  70                         or return 0;
  71                 if ($top && ($simple->header("In-Reply-To") ||
  72                              $simple->header("References"))) {
  73                         return 0;
  74                 }
  75                 $simple->body_set(""); # save some memory
  76
  77                 my $t = eval { str2time($simple->header('Date')) };
  78                 defined($t) or $t = 0;
  79                 $simple->header_set('X-PI-Date', $t);
  80                 push @messages, $simple;
  81                 1;
  82         });
  83
  84         my $th = Mail::Thread->new(@messages);
  85         $th->thread;
  86         my @out = (
  87                 "<html><head><title>$title</title>" .
  88                 '<link rel=alternate title=Atom.feed href="' .
  89                 $feed_opts->{atomurl} . '" type="application/atom+xml"/>' .
  90                 '</head><body><pre>');
  91         push @out, $feed_opts->{midurl};
  92
  93         # sort by date, most recent at top
  94         $th->order(sub {
  95                 sort {
  96                         $b->topmost->message->header('X-PI-Date') <=>
  97                         $a->topmost->message->header('X-PI-Date')
  98                 } @_;
  99         });
 100         dump_html_line($_, 0, \@out) for $th->rootset;
 101
 102         my $footer = nav_footer($args->{cgi}, $first, $last);
 103         $footer = "<hr /><pre>$footer</pre>" if $footer;
 104         $out[0] . "</pre>$footer</html>";
 105 }
 106
 107 # private subs
 108
 109 sub nav_footer {
 110         my ($cgi, $first, $last) = @_;
 111         $cgi or return '';
 112         my $old_r = $cgi->param('r');
 113         my $prev = '    ';
 114         my $next = '    ';
 115         my %opts = (-path => 1, -query => 1, -relative => 1);
 116
 117         if ($last) {
 118                 $cgi->param('r', $last);
 119                 $next = $cgi->url(%opts);
 120                 $next = qq!<a href="$next">next</a>!;
 121         }
 122         if ($first && $old_r) {
 123                 $cgi->param('r', "$first..");
 124                 $prev = $cgi->url(%opts);
 125                 $prev = qq!<a href="$prev">prev</a>!;
 126         }
 127         "$prev $next";
 128 }
 129
 130 sub each_recent_blob {
 131         my ($args, $cb) = @_;
 132         my $max = $args->{max} || MAX_PER_PAGE;
 133         my $refhex = qr/[a-f0-9]{4,40}(?:~\d+)?/;
 134         my $cgi = $args->{cgi};
 135
 136         # revision ranges may be specified
 137         my $reverse;
 138         my $range = 'HEAD';
 139         my $r = $cgi->param('r') if $cgi;
 140         if ($r) {
 141                 if ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o) {
 142                         $range = $r;
 143                 } elsif ($r =~ /\A(?:$refhex\.\.)\z/o) {
 144                         $reverse = 1;
 145                         $range = $r;
 146                 }
 147         }
 148
 149         # get recent messages
 150         # we could use git log -z, but, we already know ssoma will not
 151         # leave us with filenames with spaces in them..
 152         my @cmd = qw/git log --no-notes --no-color --raw -r --no-abbrev/;
 153         push @cmd, '--reverse' if $reverse;
 154         push @cmd, $range;
 155         my $first;
 156
 157         my $pid = open(my $log, '-|', @cmd) or
 158                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 159         my %deleted;
 160         my $last;
 161         my $nr = 0;
 162         my @commits = ();
 163         while (my $line = <$log>) {
 164                 if ($line =~ /^:000000 100644 0{40} ([a-f0-9]{40})/) {
 165                         my $add = $1;
 166                         next if $deleted{$add};
 167                         $nr += $cb->($add);
 168                         if ($nr >= $max) {
 169                                 $last = 1;
 170                                 last;
 171                         }
 172                 } elsif ($line =~ /^:100644 000000 ([a-f0-9]{40}) 0{40}/) {
 173                         $deleted{$1} = 1;
 174                 } elsif ($line =~ /^commit ([a-f0-9]{40})/) {
 175                         push @commits, $1;
 176                 }
 177         }
 178
 179         if ($last) {
 180                 while (my $line = <$log>) {
 181                         if ($line =~ /^commit ([a-f0-9]{40})/) {
 182                                 push @commits, $1;
 183                                 last;
 184                         }
 185                 }
 186         } elsif ($reverse) {
 187                 unshift @commits, undef
 188         } else {
 189                 push @commits, undef;
 190         }
 191
 192         close $log; # we may EPIPE here
 193         # for pagination
 194         $reverse ? ($commits[-1],$commits[0]) : ($commits[0],$commits[-1]);
 195 }
 196
 197 # private functions below
 198 sub get_feedopts {
 199         my ($args) = @_;
 200         my $pi_config = $args->{pi_config};
 201         my $listname = $args->{listname};
 202         my $cgi = $args->{cgi};
 203         my %rv;
 204         if (open my $fh, '<', "$args->{git_dir}/description") {
 205                 chomp($rv{description} = <$fh>);
 206                 close $fh;
 207         }
 208
 209         if ($pi_config && defined $listname && length $listname) {
 210                 foreach my $key (qw(address)) {
 211                         $rv{$key} = $pi_config->get($listname, $key) || "";
 212                 }
 213         }
 214         my $url_base;
 215         if ($cgi) {
 216                 my $cgi_url = $cgi->url(-path=>1, -relative=>1);
 217                 my $base = $cgi->url(-base);
 218                 $url_base = $cgi_url;
 219                 if ($url_base =~ s!/(?:|index\.html)?\z!!) {
 220                         $rv{atomurl} = "$base$url_base/atom.xml";
 221                 } else {
 222                         $url_base =~ s!/atom\.xml\z!!;
 223                         $rv{atomurl} = $base . $cgi_url;
 224                         $url_base = $base . $url_base; # XXX is this needed?
 225                 }
 226         } else {
 227                 $url_base = "http://example.com";
 228                 $rv{atomurl} = "$url_base/atom.xml";
 229         }
 230         $rv{url} ||= "$url_base/";
 231         $rv{midurl} = "$url_base/m/";
 232         $rv{fullurl} = "$url_base/f/";
 233
 234         \%rv;
 235 }
 236
 237 sub utf8_header {
 238         my ($simple, $name) = @_;
 239         my $val = $simple->header($name);
 240         return "" unless defined $val;
 241         $val =~ tr/\t\n / /s;
 242         $val =~ tr/\r//d;
 243         $enc_utf8->encode($enc_mime->decode($val));
 244 }
 245
 246 sub feed_date {
 247         my ($date) = @_;
 248         my @t = eval { strptime($date) };
 249
 250         scalar(@t) ? POSIX::strftime(DATEFMT, @t) : 0;
 251 }
 252
 253 # returns 0 (skipped) or 1 (added)
 254 sub add_to_feed {
 255         my ($feed_opts, $feed, $add, $top, $git) = @_;
 256
 257         my $mime = do_cat_mail($git, 'Email::MIME', $add) or return 0;
 258         if ($top && $mime->header("In-Reply-To")) {
 259                 return 0;
 260         }
 261
 262         my $midurl = $feed_opts->{midurl} || 'http://example.com/m/';
 263         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/f/';
 264
 265         my $mid = utf8_header($mime, "Message-ID") or return 0;
 266         # FIXME: refactor
 267         my (undef, $href) = PublicInbox::View::trim_message_id($mid);
 268
 269         my $content = PublicInbox::View->as_feed_entry($mime,
 270                                                         "$fullurl$href.html");
 271         defined($content) or return 0;
 272
 273         my $subject = utf8_header($mime, "Subject") || "";
 274         length($subject) or return 0;
 275
 276         my $from = utf8_header($mime, "From") or return 0;
 277
 278         my @from = Email::Address->parse($from);
 279         my $name = $from[0]->name;
 280         defined $name or $name = "";
 281         my $email = $from[0]->address;
 282         defined $email or $email = "";
 283
 284         my $date = utf8_header($mime, "Date");
 285         $date or return 0;
 286         $date = feed_date($date) or return 0;
 287         $feed->add_entry(
 288                 author => { name => $name, email => $email },
 289                 title => $subject,
 290                 updated => $date,
 291                 content => { type => "html", content => $content },
 292                 link => $midurl . $href,
 293                 id => $add,
 294         );
 295         1;
 296 }
 297
 298 sub dump_html_line {
 299         my ($self, $level, $args) = @_; # args => [ $html, $midurl ]
 300         if ($self->message) {
 301                 $args->[0] .= (' ' x $level);
 302                 my $simple = $self->message;
 303                 my $subj = utf8_header($simple, "Subject");
 304                 my $mid = utf8_header($simple, "Message-ID");
 305                 $mid =~ s/\A<//;
 306                 $mid =~ s/>\z//;
 307                 my $url = $args->[1] . xs_html(uri_escape($mid));
 308                 my $from = utf8_header($simple, "From");
 309                 my @from = Email::Address->parse($from);
 310                 $from = $from[0]->name;
 311                 (defined($from) && length($from)) or $from = $from[0]->address;
 312                 $from = xs_html($from);
 313                 $subj = xs_html($subj);
 314                 $args->[0] .= "<a href=\"$url.html\">$subj</a> $from\n";
 315         }
 316         dump_html_line($self->child, $level+1, $args) if $self->child;
 317         dump_html_line($self->next, $level, $args) if $self->next;
 318 }
 319
 320 sub xs_html {
 321         $enc_ascii->encode(escapeHTML($enc_utf8->decode($_[0])),
 322                         Encode::HTMLCREF);
 323 }
 324
 325 sub try_git_pm {
 326         my ($dir) = @_;
 327         eval { Git->repository(Directory => $dir) };
 328 };
 329
 330 sub do_cat_mail {
 331         my ($git, $class, $sha1) = @_;
 332         my $str;
 333         if ($git) {
 334                 open my $fh, '>', \$str or
 335                                 die "failed to setup string handle: $!\n";
 336                 binmode $fh;
 337                 my $bytes = $git->cat_blob($sha1, $fh);
 338                 close $fh or die "failed to close string handle: $!\n";
 339                 return if $bytes <= 0;
 340         } else {
 341                 $str = `git cat-file blob $sha1`;
 342                 return if $? != 0 || length($str) == 0;
 343         }
 344         $class->new($str);
 345 }
 346
 347 1;