lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use XML::Atom::SimpleFeed;
   7 use Email::MIME;
   8 use Email::Address;
   9 use URI::Escape qw/uri_escape/;
  10 use Encode qw/find_encoding/;
  11 use Encode::MIME::Header;
  12 use CGI qw(escapeHTML);
  13 use POSIX qw(strftime);
  14 use Date::Parse qw(strptime str2time);
  15 use constant DATEFMT => '%Y-%m-%dT%H:%M:%SZ';
  16 use PublicInbox::View;
  17 use Mail::Thread;
  18 my $enc_utf8 = find_encoding('utf8');
  19 my $enc_ascii = find_encoding('us-ascii');
  20 my $enc_mime = find_encoding('MIME-Header');
  21
  22 # FIXME: workaround https://rt.cpan.org/Public/Bug/Display.html?id=22817
  23
  24 # main function
  25 sub generate {
  26         my ($class, $args) = @_;
  27         my $max = $args->{max} || 25;
  28         my $top = $args->{top}; # bool
  29
  30         local $ENV{GIT_DIR} = $args->{git_dir};
  31         my $feed_opts = get_feedopts($args);
  32
  33         my $feed = XML::Atom::SimpleFeed->new(
  34                 title => $feed_opts->{description} || "unnamed feed",
  35                 link => $feed_opts->{url} || "http://example.com/",
  36                 link => {
  37                         rel => 'self',
  38                         href => $feed_opts->{atomurl} ||
  39                                 "http://example.com/atom",
  40                 },
  41                 id => $feed_opts->{address} || 'public-inbox@example.com',
  42                 updated => strftime(DATEFMT, gmtime),
  43         );
  44
  45         each_recent_blob($max, sub {
  46                 my ($add) = @_;
  47                 add_to_feed($feed_opts, $feed, $add, $top);
  48         });
  49         $feed->as_string;
  50 }
  51
  52 sub generate_html_index {
  53         my ($class, $args) = @_;
  54         my $max = $args->{max} || 50;
  55         my $top = $args->{top}; # bool
  56         local $ENV{GIT_DIR} = $args->{git_dir};
  57         my $feed_opts = get_feedopts($args);
  58         my $title = xs_html($feed_opts->{description} || "");
  59         my @messages;
  60         each_recent_blob($max, sub {
  61                 my $str = `git cat-file blob $_[0]`;
  62                 return 0 if $? != 0;
  63                 my $simple = Email::Simple->new($str);
  64                 if ($top && ($simple->header("In-Reply-To") ||
  65                              $simple->header("References"))) {
  66                         return 0;
  67                 }
  68                 $simple->body_set(""); # save some memory
  69
  70                 my $t = eval { str2time($simple->header('Date')) };
  71                 defined($t) or $t = 0;
  72                 $simple->header_set('X-PI-Date', $t);
  73                 push @messages, $simple;
  74                 1;
  75         });
  76
  77         my $th = Mail::Thread->new(@messages);
  78         $th->thread;
  79         my @args = (
  80                 "<html><head><title>$title</title>" .
  81                 '<link rel=alternate title=Atom.feed href="' .
  82                 $feed_opts->{atomurl} . '" type="application/atom+xml"/>' .
  83                 '</head><body><pre>');
  84         push @args, $feed_opts->{midurl};
  85
  86         # sort by date, most recent at top
  87         $th->order(sub {
  88                 sort {
  89                         $b->topmost->message->header('X-PI-Date') <=>
  90                         $a->topmost->message->header('X-PI-Date')
  91                 } @_;
  92         });
  93         dump_html_line($_, 0, \@args) for $th->rootset;
  94         $args[0] . '</pre></html>';
  95 }
  96
  97 # private subs
  98
  99 sub each_recent_blob {
 100         my ($max, $cb) = @_;
 101
 102         # get recent messages
 103         # we could use git log -z, but, we already know ssoma will not
 104         # leave us with filenames with spaces in them..
 105         my $cmd = "git log --no-notes --no-color --raw -r --no-abbrev HEAD |";
 106         my $pid = open my $log, $cmd or die "open `$cmd' pipe failed: $!\n";
 107         my %deleted;
 108         my $nr = 0;
 109         foreach my $line (<$log>) {
 110                 if ($line =~ /^:000000 100644 0{40} ([a-f0-9]{40})/) {
 111                         my $add = $1;
 112                         next if $deleted{$add};
 113                         $nr += $cb->($add);
 114                         last if $nr >= $max;
 115                 } elsif ($line =~ /^:100644 000000 ([a-f0-9]{40}) 0{40}/) {
 116                         $deleted{$1} = 1;
 117                 }
 118         }
 119
 120         close $log;
 121 }
 122
 123 # private functions below
 124 sub get_feedopts {
 125         my ($args) = @_;
 126         my $pi_config = $args->{pi_config};
 127         my $listname = $args->{listname};
 128         my $cgi = $args->{cgi};
 129         my %rv;
 130
 131         if ($pi_config && defined $listname && length $listname) {
 132                 foreach my $key (qw(description address)) {
 133                         $rv{$key} = $pi_config->get($listname, $key) || "";
 134                 }
 135         }
 136         my $url_base;
 137         if ($cgi) {
 138                 my $cgi_url = $cgi->url(-path=>1, -query=>1, -relative=>1);
 139                 my $base = $cgi->url(-base);
 140                 $url_base = $cgi_url;
 141                 if ($url_base =~ s!/(?:|(index|all)\.html)?\z!!) {
 142                         my $ia = $1 || 'index';
 143                         $rv{atomurl} = "$base$url_base/$ia.atom.xml";
 144                 } else {
 145                         $url_base =~ s!/?(?:index|all)\.atom\.xml\z!!;
 146                         $rv{atomurl} = $base . $cgi_url;
 147                         $url_base = $base . $url_base; # XXX is this needed?
 148                 }
 149         } else {
 150                 $url_base = "http://example.com";
 151                 $rv{atomurl} = "$url_base/index.atom.xml";
 152         }
 153         $rv{url} ||= "$url_base/";
 154         $rv{midurl} = "$url_base/m/";
 155         $rv{fullurl} = "$url_base/f/";
 156
 157         \%rv;
 158 }
 159
 160 sub utf8_header {
 161         my ($simple, $name) = @_;
 162         my $val = $simple->header($name);
 163         return "" unless defined $val;
 164         $val =~ tr/\t\n / /s;
 165         $val =~ tr/\r//d;
 166         $enc_utf8->encode($enc_mime->decode($val));
 167 }
 168
 169 sub feed_date {
 170         my ($date) = @_;
 171         my @t = eval { strptime($date) };
 172
 173         scalar(@t) ? strftime(DATEFMT, @t) : 0;
 174 }
 175
 176 # returns 0 (skipped) or 1 (added)
 177 sub add_to_feed {
 178         my ($feed_opts, $feed, $add, $top) = @_;
 179
 180         # we can use git cat-file --batch if performance becomes a
 181         # problem, but I doubt it...
 182         my $str = `git cat-file blob $add`;
 183         return 0 if $? != 0;
 184         my $mime = Email::MIME->new($str);
 185
 186         if ($top && $mime->header("In-Reply-To")) {
 187                 return 0;
 188         }
 189
 190         my $midurl = $feed_opts->{midurl} || 'http://example.com/m/';
 191         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/f/';
 192
 193         my $content = PublicInbox::View->as_feed_entry($mime, $fullurl);
 194         defined($content) or return 0;
 195
 196         my $mid = utf8_header($mime, "Message-ID") or return 0;
 197         $mid =~ s/\A<//; $mid =~ s/>\z//;
 198
 199         my $subject = utf8_header($mime, "Subject") || "";
 200         length($subject) or return 0;
 201
 202         my $from = utf8_header($mime, "From") or return 0;
 203
 204         my @from = Email::Address->parse($from);
 205         my $name = $from[0]->name;
 206         defined $name or $name = "";
 207         my $email = $from[0]->address;
 208         defined $email or $email = "";
 209
 210         my $url = $midurl . uri_escape($mid);
 211         my $date = utf8_header($mime, "Date");
 212         $date or return 0;
 213         $date = feed_date($date) or return 0;
 214         $feed->add_entry(
 215                 author => { name => $name, email => $email },
 216                 title => $subject,
 217                 updated => $date,
 218                 content => { type => "html", content => $content },
 219                 link => $url,
 220                 id => $add,
 221         );
 222         1;
 223 }
 224
 225 sub dump_html_line {
 226         my ($self, $level, $args) = @_; # args => [ $html, $midurl ]
 227         $args->[0] .= (' ' x $level);
 228         if ($self->message) {
 229                 my $simple = $self->message;
 230                 my $subj = utf8_header($simple, "Subject");
 231                 my $mid = utf8_header($simple, "Message-ID");
 232                 $mid =~ s/\A<//;
 233                 $mid =~ s/>\z//;
 234                 my $url = $args->[1] . uri_escape($mid);
 235                 my $from = utf8_header($simple, "From");
 236                 my @from = Email::Address->parse($from);
 237                 $from = $from[0]->name;
 238                 (defined($from) && length($from)) or $from = $from[0]->address;
 239                 $from = xs_html($from);
 240                 $subj = xs_html($subj);
 241                 $args->[0] .= "<a href=\"$url.html\">$subj</a> $from\n";
 242         } else {
 243                 $args->[0] .= "[ Message not available ]\n";
 244         }
 245         dump_html_line($self->child, $level+1, $args) if $self->child;
 246         dump_html_line($self->next, $level, $args) if $self->next;
 247 }
 248
 249 sub xs_html {
 250         $enc_ascii->encode(escapeHTML($enc_utf8->decode($_[0])),
 251                         Encode::HTMLCREF);
 252 }
 253
 254 1;