lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use XML::Atom::SimpleFeed;
   7 use Email::MIME;
   8 use Email::Address;
   9 use URI::Escape qw/uri_escape/;
  10 use Encode qw/encode decode/;
  11 use Encode::MIME::Header;
  12 use CGI qw(escapeHTML);
  13 use POSIX qw(strftime);
  14 use Date::Parse qw(strptime);
  15 use constant DATEFMT => '%Y-%m-%dT%H:%M:%SZ';
  16 use PublicInbox::View;
  17 use Mail::Thread;
  18
  19 # main function
  20 sub generate {
  21         my ($class, $args) = @_;
  22         my $max = $args->{max} || 25;
  23         my $top = $args->{top}; # bool
  24
  25         local $ENV{GIT_DIR} = $args->{git_dir};
  26         my $feed_opts = get_feedopts($args);
  27
  28         my $feed = XML::Atom::SimpleFeed->new(
  29                 title => $feed_opts->{description} || "unnamed feed",
  30                 link => $feed_opts->{url} || "http://example.com/",
  31                 link => {
  32                         rel => 'self',
  33                         href => $feed_opts->{atomurl} ||
  34                                 "http://example.com/atom",
  35                 },
  36                 id => $feed_opts->{address} || 'public-inbox@example.com',
  37                 updated => strftime(DATEFMT, gmtime),
  38         );
  39
  40         each_recent_blob($max, sub {
  41                 my ($add) = @_;
  42                 add_to_feed($feed_opts, $feed, $add, $top);
  43         });
  44         $feed->as_string;
  45 }
  46
  47 sub generate_html_index {
  48         my ($class, $args) = @_;
  49         my $max = $args->{max} || 50;
  50         my $top = $args->{top}; # bool
  51         local $ENV{GIT_DIR} = $args->{git_dir};
  52         my $feed_opts = get_feedopts($args);
  53         my $title = escapeHTML($feed_opts->{description} || "");
  54         my @messages;
  55         each_recent_blob($max, sub {
  56                 my $str = `git cat-file blob $_[0]`;
  57                 return 0 if $? != 0;
  58                 my $simple = Email::Simple->new($str);
  59                 $simple->body_set(""); # save some memory
  60                 push @messages, $simple;
  61                 1;
  62         });
  63
  64         my $th = Mail::Thread->new(@messages);
  65         $th->thread;
  66         my @args = (
  67                 "<html><head><title>$title</title>" .
  68                 '<link rel=alternate title=Atom.feed href=' .
  69                 $feed_opts->{atomurl} . ' type="application/atom+xml"/>' .
  70                 '</head><body><pre>');
  71         push @args, $feed_opts->{midurl};
  72         dump_html_line($_, 0, \@args) for $th->rootset;
  73         $args[0] . '</pre></html>';
  74 }
  75
  76 # private subs
  77
  78 sub each_recent_blob {
  79         my ($max, $cb) = @_;
  80
  81         # get recent messages
  82         # we could use git log -z, but, we already know ssoma will not
  83         # leave us with filenames with spaces in them..
  84         my $cmd = "git log --no-notes --no-color --raw -r --no-abbrev HEAD |";
  85         my $pid = open my $log, $cmd or die "open `$cmd' pipe failed: $!\n";
  86         my %deleted;
  87         my $nr = 0;
  88         foreach my $line (<$log>) {
  89                 if ($line =~ /^:000000 100644 0{40} ([a-f0-9]{40})/) {
  90                         my $add = $1;
  91                         next if $deleted{$add};
  92                         $nr += $cb->($add);
  93                         last if $nr >= $max;
  94                 } elsif ($line =~ /^:100644 000000 ([a-f0-9]{40}) 0{40}/) {
  95                         $deleted{$1} = 1;
  96                 }
  97         }
  98
  99         close $log;
 100 }
 101
 102 # private functions below
 103 sub get_feedopts {
 104         my ($args) = @_;
 105         my $pi_config = $args->{pi_config};
 106         my $listname = $args->{listname};
 107         my $cgi = $args->{cgi};
 108         my %rv;
 109
 110         if ($pi_config && defined $listname && length $listname) {
 111                 foreach my $key (qw(description address)) {
 112                         $rv{$key} = $pi_config->get($listname, $key) || "";
 113                 }
 114         }
 115         my $url_base;
 116         if ($cgi) {
 117                 my $cgi_url = $cgi->self_url;
 118                 $url_base = $cgi_url;
 119                 $url_base =~ s!/?(?:index|all)\.atom\.xml\z!!;
 120                 $rv{atomurl} = $cgi_url;
 121         } else {
 122                 $url_base = "http://example.com";
 123                 $rv{atomurl} = "$url_base/index.atom.xml";
 124         }
 125         $rv{url} ||= "$url_base/";
 126         $rv{midurl} = "$url_base/mid/";
 127         $rv{fullurl} = "$url_base/full/";
 128
 129         \%rv;
 130 }
 131
 132 sub utf8_header {
 133         my ($simple, $name) = @_;
 134         my $val = $simple->header($name);
 135         return "" unless defined $val;
 136         $val =~ tr/\t\r\n / /s;
 137         encode('utf8', decode('MIME-Header', $val));
 138 }
 139
 140 sub feed_date {
 141         my ($date) = @_;
 142         my @t = eval { strptime($date) };
 143
 144         scalar(@t) ? strftime(DATEFMT, @t) : 0;
 145 }
 146
 147 # returns 0 (skipped) or 1 (added)
 148 sub add_to_feed {
 149         my ($feed_opts, $feed, $add, $top) = @_;
 150
 151         # we can use git cat-file --batch if performance becomes a
 152         # problem, but I doubt it...
 153         my $str = `git cat-file blob $add`;
 154         return 0 if $? != 0;
 155         my $mime = Email::MIME->new($str);
 156
 157         if ($top && $mime->header("In-Reply-To")) {
 158                 return 0;
 159         }
 160
 161         my $midurl = $feed_opts->{midurl} || 'http://example.com/mid/';
 162         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/full/';
 163
 164         my $content = PublicInbox::View->as_feed_entry($mime, $fullurl);
 165         defined($content) or return 0;
 166
 167         my $mid = utf8_header($mime, "Message-ID") or return 0;
 168         $mid =~ s/\A<//; $mid =~ s/>\z//;
 169
 170         my $subject = utf8_header($mime, "Subject") || "";
 171         length($subject) or return 0;
 172
 173         my $from = utf8_header($mime, "From") or return 0;
 174
 175         my @from = Email::Address->parse($from);
 176         my $name = $from[0]->name;
 177         defined $name or $name = "";
 178         my $email = $from[0]->address;
 179         defined $email or $email = "";
 180
 181         my $url = $midurl . uri_escape($mid);
 182         my $date = utf8_header($mime, "Date");
 183         $date or return 0;
 184         $date = feed_date($date) or return 0;
 185         $feed->add_entry(
 186                 author => { name => $name, email => $email },
 187                 title => $subject,
 188                 updated => $date,
 189                 content => { type => "html", content => $content },
 190                 link => $url,
 191                 id => $add,
 192         );
 193         1;
 194 }
 195
 196 sub dump_html_line {
 197         my ($self, $level, $args) = @_; # args => [ $html, $midurl ]
 198         $args->[0] .= (' ' x $level);
 199         if ($self->message) {
 200                 my $simple = $self->message;
 201                 my $subj = utf8_header($simple, "Subject");
 202                 my $mid = utf8_header($simple, "Message-ID");
 203                 $mid =~ s/\A<//;
 204                 $mid =~ s/>\z//;
 205                 my $url = $args->[1] . uri_escape($mid);
 206                 my $from = utf8_header($simple, "From");
 207                 my @from = Email::Address->parse($from);
 208                 $from = $from[0]->name;
 209                 (defined($from) && length($from)) or $from = $from[0]->address;
 210                 $from = escapeHTML($from);
 211                 $subj = escapeHTML($subj);
 212                 $args->[0] .= "<a href=$url>`-&gt; $subj</a> $from\n";
 213         } else {
 214                 $args->[0] .= "[ Message not available ]\n";
 215         }
 216         dump_html_line($self->child, $level+1, $args) if $self->child;
 217         dump_html_line($self->next, $level, $args) if $self->next;
 218 }
 219
 220 1;