lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use XML::Atom::SimpleFeed;
   7 use Email::MIME;
   8 use Email::Address;
   9 use URI::Escape qw/uri_escape/;
  10 use Encode qw/encode decode/;
  11 use Encode::MIME::Header;
  12 use CGI qw(escapeHTML);
  13 use POSIX qw(strftime);
  14 use Date::Parse qw(strptime);
  15 use constant DATEFMT => '%Y-%m-%dT%H:%M:%SZ';
  16 use PublicInbox::View;
  17
  18 # main function
  19 sub generate {
  20         my ($class, $args) = @_;
  21         my $max = $args->{max} || 25;
  22         my $top = $args->{top}; # bool
  23
  24         local $ENV{GIT_DIR} = $args->{git_dir};
  25         my $feed_opts = get_feedopts($args);
  26
  27         my $feed = XML::Atom::SimpleFeed->new(
  28                 title => $feed_opts->{description} || "unnamed feed",
  29                 link => $feed_opts->{url} || "http://example.com/",
  30                 link => {
  31                         rel => 'self',
  32                         href => $feed_opts->{atomurl} ||
  33                                 "http://example.com/atom",
  34                 },
  35                 id => $feed_opts->{address} || 'public-inbox@example.com',
  36                 updated => strftime(DATEFMT, gmtime),
  37         );
  38
  39         each_recent_blob($max, sub {
  40                 my ($add) = @_;
  41                 add_to_feed($feed_opts, $feed, $add, $top);
  42         });
  43         $feed->as_string;
  44
  45 }
  46
  47 sub each_recent_blob {
  48         my ($max, $cb) = @_;
  49
  50         # get recent messages
  51         # we could use git log -z, but, we already know ssoma will not
  52         # leave us with filenames with spaces in them..
  53         my $cmd = "git log --no-notes --no-color --raw -r --no-abbrev HEAD |";
  54         my $pid = open my $log, $cmd or die "open `$cmd' pipe failed: $!\n";
  55         my %deleted;
  56         my $nr = 0;
  57         foreach my $line (<$log>) {
  58                 if ($line =~ /^:000000 100644 0{40} ([a-f0-9]{40})/) {
  59                         my $add = $1;
  60                         next if $deleted{$add};
  61                         $nr += $cb->($add);
  62                         last if $nr >= $max;
  63                 } elsif ($line =~ /^:100644 000000 ([a-f0-9]{40}) 0{40}/) {
  64                         $deleted{$1} = 1;
  65                 }
  66         }
  67
  68         close $log;
  69 }
  70
  71 # private functions below
  72 sub get_feedopts {
  73         my ($args) = @_;
  74         my $pi_config = $args->{pi_config};
  75         my $listname = $args->{listname};
  76         my $cgi = $args->{cgi};
  77         my %rv;
  78
  79         if ($pi_config && defined $listname && length $listname) {
  80                 foreach my $key (qw(description address)) {
  81                         $rv{$key} = $pi_config->get($listname, $key);
  82                 }
  83         }
  84         if ($cgi) {
  85                 my $cgi_url = $cgi->self_url;
  86                 my $url_base = $cgi_url;
  87                 $url_base =~ s!/?(?:index|all)\.atom\.xml\z!!;
  88                 $rv{url} ||= "$url_base/";
  89                 $rv{midurl} = "$url_base/mid/";
  90                 $rv{fullurl} = "$url_base/full/";
  91                 $rv{atomurl} = $cgi_url;
  92         }
  93
  94         \%rv;
  95 }
  96
  97 sub utf8_header {
  98         my ($mime, $name) = @_;
  99         encode('utf8', decode('MIME-Header', $mime->header($name)));
 100 }
 101
 102 sub feed_date {
 103         my ($date) = @_;
 104         my @t = eval { strptime($date) };
 105
 106         scalar(@t) ? strftime(DATEFMT, @t) : 0;
 107 }
 108
 109 # returns 0 (skipped) or 1 (added)
 110 sub add_to_feed {
 111         my ($feed_opts, $feed, $add, $top) = @_;
 112
 113         # we can use git cat-file --batch if performance becomes a
 114         # problem, but I doubt it...
 115         my $str = `git cat-file blob $add`;
 116         return 0 if $? != 0;
 117         my $mime = Email::MIME->new($str);
 118
 119         if ($top && $mime->header("In-Reply-To")) {
 120                 return 0;
 121         }
 122
 123         my $midurl = $feed_opts->{midurl} || 'http://example.com/mid/';
 124         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/full/';
 125
 126         my $content = PublicInbox::View->as_feed_entry($mime, $fullurl);
 127         defined($content) or return 0;
 128
 129         my $mid = utf8_header($mime, "Message-ID") or return 0;
 130         $mid =~ s/\A<//;
 131         $mid =~ s/>\z//;
 132
 133         my $subject = utf8_header($mime, "Subject") || "";
 134         defined($subject) && length($subject) or return 0;
 135
 136         my $from = utf8_header($mime, "From") or return 0;
 137
 138         my @from = Email::Address->parse($from);
 139         my $name = $from[0]->name;
 140         defined $name or $name = "";
 141         my $email = $from[0]->address;
 142         defined $email or $email = "";
 143
 144         my $url = $midurl . uri_escape($mid);
 145         my $date = utf8_header($mime, "Date");
 146         $date or return 0;
 147         $date = feed_date($date) or return 0;
 148         $feed->add_entry(
 149                 author => { name => $name, email => $email },
 150                 title => $subject,
 151                 updated => $date,
 152                 content => { type => "html", content => $content },
 153                 link => $url,
 154                 id => $add,
 155         );
 156         1;
 157 }
 158
 159 1;