lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for generating Atom feeds for web-accessible mailing list archives.
   5 package PublicInbox::Feed;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::MIME;
   9 use PublicInbox::View;
  10 use PublicInbox::WwwAtomStream;
  11 use PublicInbox::SearchMsg; # this loads w/o Search::Xapian
  12
  13 # main function
  14 sub generate {
  15         my ($ctx) = @_;
  16         my $msgs = recent_msgs($ctx);
  17         return _no_thread() unless @$msgs;
  18
  19         my $ibx = $ctx->{-inbox};
  20         PublicInbox::WwwAtomStream->response($ctx, 200, sub {
  21                 while (my $smsg = shift @$msgs) {
  22                         $ibx->smsg_mime($smsg) and return $smsg;
  23                 }
  24         });
  25 }
  26
  27 sub generate_thread_atom {
  28         my ($ctx) = @_;
  29         my $mid = $ctx->{mid};
  30         my $msgs = $ctx->{srch}->get_thread($mid);
  31         return _no_thread() unless @$msgs;
  32
  33         my $ibx = $ctx->{-inbox};
  34         my $html_url = $ibx->base_url($ctx->{env});
  35         $html_url .= PublicInbox::Hval->new_msgid($mid)->{href};
  36         $ctx->{-html_url} = $html_url;
  37         PublicInbox::WwwAtomStream->response($ctx, 200, sub {
  38                 while (my $smsg = shift @$msgs) {
  39                         $ibx->smsg_mime($smsg) and return $smsg;
  40                 }
  41         });
  42 }
  43
  44 sub generate_html_index {
  45         my ($ctx) = @_;
  46         # if the 'r' query parameter is given, it is a legacy permalink
  47         # which we must continue supporting:
  48         my $qp = $ctx->{qp};
  49         if ($qp && !$qp->{r} && $ctx->{srch}) {
  50                 return PublicInbox::View::index_topics($ctx);
  51         }
  52
  53         my $env = $ctx->{env};
  54         my $url = $ctx->{-inbox}->base_url($env) . 'new.html';
  55         my $qs = $env->{QUERY_STRING};
  56         $url .= "?$qs" if $qs ne '';
  57         [302, [ 'Location', $url, 'Content-Type', 'text/plain'],
  58                 [ "Redirecting to $url\n" ] ];
  59 }
  60
  61 sub new_html {
  62         my ($ctx) = @_;
  63         my $msgs = recent_msgs($ctx);
  64         if (!@$msgs) {
  65                 return [404, ['Content-Type', 'text/plain'],
  66                         ["No messages, yet\n"] ];
  67         }
  68         $ctx->{-html_tip} = '<pre>';
  69         $ctx->{-upfx} = '';
  70         $ctx->{-hr} = 1;
  71         my $ibx = $ctx->{-inbox};
  72         PublicInbox::WwwStream->response($ctx, 200, sub {
  73                 while (my $smsg = shift @$msgs) {
  74                         my $m = $ibx->smsg_mime($smsg) or next;
  75                         my $more = scalar @$msgs;
  76                         return PublicInbox::View::index_entry($m, $ctx, $more);
  77                 }
  78                 PublicInbox::View::pagination_footer($ctx, './new.html');
  79         });
  80 }
  81
  82 # private subs
  83
  84 sub _no_thread () {
  85         [404, ['Content-Type', 'text/plain'], ["No feed found for thread\n"]];
  86 }
  87
  88 sub recent_msgs {
  89         my ($ctx) = @_;
  90         my $ibx = $ctx->{-inbox};
  91         my $max = $ibx->{feedmax};
  92         my $qp = $ctx->{qp};
  93         my $v = $ibx->{version} || 1;
  94         if ($v > 2) {
  95                 die "BUG: unsupported inbox version: $v\n";
  96         }
  97         if (my $srch = $ibx->search) {
  98                 return PublicInbox::View::paginate_recent($ctx, $max);
  99         }
 100
 101         my $hex = '[a-f0-9]';
 102         my $addmsg = qr!^:000000 100644 \S+ (\S+) A\t${hex}{2}/${hex}{38}$!;
 103         my $delmsg = qr!^:100644 000000 (\S+) \S+ D\t(${hex}{2}/${hex}{38})$!;
 104         my $refhex = qr/(?:HEAD|${hex}{4,40})(?:~\d+)?/;
 105
 106         # revision ranges may be specified
 107         my $range = 'HEAD';
 108         my $r = $qp->{r} if $qp;
 109         if ($r && ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o)) {
 110                 $range = $r;
 111         }
 112
 113         # get recent messages
 114         # we could use git log -z, but, we already know ssoma will not
 115         # leave us with filenames with spaces in them..
 116         my $log = $ibx->git->popen(qw/log
 117                                 --no-notes --no-color --raw -r
 118                                 --no-abbrev --abbrev-commit/,
 119                                 "--format=%h", $range);
 120         my %deleted; # only an optimization at this point
 121         my $last;
 122         my $last_commit;
 123         local $/ = "\n";
 124         my @oids;
 125         while (defined(my $line = <$log>)) {
 126                 if ($line =~ /$addmsg/o) {
 127                         my $add = $1;
 128                         next if $deleted{$add}; # optimization-only
 129                         push @oids, $add;
 130                         if (scalar(@oids) >= $max) {
 131                                 $last = 1;
 132                                 last;
 133                         }
 134                 } elsif ($line =~ /$delmsg/o) {
 135                         $deleted{$1} = 1;
 136                 }
 137         }
 138
 139         if ($last) {
 140                 local $/ = "\n";
 141                 while (my $line = <$log>) {
 142                         if ($line =~ /^(${hex}{7,40})/) {
 143                                 $last_commit = $1;
 144                                 last;
 145                         }
 146                 }
 147         }
 148
 149         $ctx->{next_page} = "r=$last_commit" if $last_commit;
 150         [ map { bless {blob => $_ }, 'PublicInbox::SearchMsg' } @oids ];
 151 }
 152
 153 1;