lib/PublicInbox/Feed.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for generating Atom feeds for web-accessible mailing list archives.
   5 package PublicInbox::Feed;
   6 use strict;
   7 use v5.10.1;
   8 use PublicInbox::View;
   9 use PublicInbox::WwwAtomStream;
  10 use PublicInbox::Smsg; # this loads w/o Search::Xapian
  11
  12 sub generate_i {
  13         my ($ctx) = @_;
  14         shift @{$ctx->{msgs}};
  15 }
  16
  17 # main function
  18 sub generate {
  19         my ($ctx) = @_;
  20         my $msgs = $ctx->{msgs} = recent_msgs($ctx);
  21         return _no_thread() unless @$msgs;
  22         PublicInbox::WwwAtomStream->response($ctx, 200, \&generate_i);
  23 }
  24
  25 sub generate_thread_atom {
  26         my ($ctx) = @_;
  27         my $msgs = $ctx->{msgs} = $ctx->{ibx}->over->get_thread($ctx->{mid});
  28         return _no_thread() unless @$msgs;
  29         PublicInbox::WwwAtomStream->response($ctx, 200, \&generate_i);
  30 }
  31
  32 sub generate_html_index {
  33         my ($ctx) = @_;
  34         # if the 'r' query parameter is given, it is a legacy permalink
  35         # which we must continue supporting:
  36         my $qp = $ctx->{qp};
  37         my $ibx = $ctx->{ibx};
  38         if ($qp && !$qp->{r} && $ibx->over) {
  39                 return PublicInbox::View::index_topics($ctx);
  40         }
  41
  42         my $env = $ctx->{env};
  43         my $url = $ibx->base_url($env) . 'new.html';
  44         my $qs = $env->{QUERY_STRING};
  45         $url .= "?$qs" if $qs ne '';
  46         [302, [ 'Location', $url, 'Content-Type', 'text/plain'],
  47                 [ "Redirecting to $url\n" ] ];
  48 }
  49
  50 sub new_html_i {
  51         my ($ctx, $eml) = @_;
  52         $ctx->zmore($ctx->html_top) if exists $ctx->{-html_tip};
  53
  54         if ($eml) {
  55                 $ctx->{smsg}->populate($eml) if !$ctx->{ibx}->{over};
  56                 return PublicInbox::View::eml_entry($ctx, $eml);
  57         }
  58         my $smsg = shift @{$ctx->{msgs}} or
  59                 $ctx->zmore(PublicInbox::View::pagination_footer(
  60                                                 $ctx, './new.html'));
  61         $smsg;
  62 }
  63
  64 sub new_html {
  65         my ($ctx) = @_;
  66         my $msgs = $ctx->{msgs} = recent_msgs($ctx);
  67         if (!@$msgs) {
  68                 return [404, ['Content-Type', 'text/plain'],
  69                         ["No messages, yet\n"] ];
  70         }
  71         $ctx->{-html_tip} = '<pre>';
  72         $ctx->{-upfx} = '';
  73         $ctx->{-hr} = 1;
  74         PublicInbox::WwwStream::aresponse($ctx, 200, \&new_html_i);
  75 }
  76
  77 # private subs
  78
  79 sub _no_thread () {
  80         [404, ['Content-Type', 'text/plain'], ["No feed found for thread\n"]];
  81 }
  82
  83 sub recent_msgs {
  84         my ($ctx) = @_;
  85         my $ibx = $ctx->{ibx};
  86         my $max = $ibx->{feedmax} // 25;
  87         return PublicInbox::View::paginate_recent($ctx, $max) if $ibx->over;
  88
  89         # only for rare v1 inboxes which aren't indexed at all
  90         my $qp = $ctx->{qp};
  91         my $hex = '[a-f0-9]';
  92         my $addmsg = qr!^:000000 100644 \S+ (\S+) A\t${hex}{2}/${hex}{38}$!;
  93         my $delmsg = qr!^:100644 000000 (\S+) \S+ D\t(${hex}{2}/${hex}{38})$!;
  94         my $refhex = qr/(?:HEAD|${hex}{4,})(?:~[0-9]+)?/;
  95
  96         # revision ranges may be specified
  97         my $range = 'HEAD';
  98         my $r = $qp->{r} if $qp;
  99         if ($r && ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o)) {
 100                 $range = $r;
 101         }
 102
 103         # get recent messages
 104         # we could use git log -z, but, we already know ssoma will not
 105         # leave us with filenames with spaces in them..
 106         my $log = $ibx->git->popen(qw/log
 107                                 --no-notes --no-color --raw -r
 108                                 --no-abbrev --abbrev-commit/,
 109                                 "--format=%H", $range);
 110         my %deleted; # only an optimization at this point
 111         my $last;
 112         my $last_commit;
 113         local $/ = "\n";
 114         my @ret;
 115         while (defined(my $line = <$log>)) {
 116                 if ($line =~ /$addmsg/o) {
 117                         my $add = $1;
 118                         next if $deleted{$add}; # optimization-only
 119                         push(@ret, bless { blob => $add }, 'PublicInbox::Smsg');
 120                         if (scalar(@ret) >= $max) {
 121                                 $last = 1;
 122                                 last;
 123                         }
 124                 } elsif ($line =~ /$delmsg/o) {
 125                         $deleted{$1} = 1;
 126                 }
 127         }
 128
 129         if ($last) {
 130                 local $/ = "\n";
 131                 while (my $line = <$log>) {
 132                         if ($line =~ /^(${hex}{7,})/) {
 133                                 $last_commit = $1;
 134                                 last;
 135                         }
 136                 }
 137         }
 138
 139         $last_commit and
 140                 $ctx->{next_page} = qq[<a\nhref="?r=$last_commit"\nrel=next>] .
 141                                         'next (older)</a>';
 142         \@ret;
 143 }
 144
 145 1;