lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use Email::Address;
   7 use Email::MIME;
   8 use Date::Parse qw(strptime str2time);
   9 use PublicInbox::Hval;
  10 eval { require Git }; # this is GPLv2+, so we are OK to use it
  11 use constant {
  12         DATEFMT => '%Y-%m-%dT%H:%M:%SZ',
  13         MAX_PER_PAGE => 25,
  14 };
  15
  16 # FIXME: workaround https://rt.cpan.org/Public/Bug/Display.html?id=22817
  17
  18 # main function
  19 sub generate {
  20         my ($class, $args) = @_;
  21         require XML::Atom::SimpleFeed;
  22         require PublicInbox::View;
  23         require POSIX;
  24         my $max = $args->{max} || MAX_PER_PAGE;
  25         my $top = $args->{top}; # bool
  26
  27         local $ENV{GIT_DIR} = $args->{git_dir};
  28         my $feed_opts = get_feedopts($args);
  29         my $addr = $feed_opts->{address};
  30         $addr = $addr->[0] if ref($addr);
  31         my $feed = XML::Atom::SimpleFeed->new(
  32                 title => $feed_opts->{description} || "unnamed feed",
  33                 link => $feed_opts->{url} || "http://example.com/",
  34                 link => {
  35                         rel => 'self',
  36                         href => $feed_opts->{atomurl} ||
  37                                 "http://example.com/atom.xml",
  38                 },
  39                 id => $addr || 'public-inbox@example.com',
  40                 updated => POSIX::strftime(DATEFMT, gmtime),
  41         );
  42
  43         my $git = try_git_pm($args->{git_dir});
  44         each_recent_blob($args, sub {
  45                 my ($add) = @_;
  46                 add_to_feed($feed_opts, $feed, $add, $top, $git);
  47         });
  48         $feed->as_string;
  49 }
  50
  51 sub generate_html_index {
  52         my ($class, $args) = @_;
  53         require Mail::Thread;
  54
  55         my $max = $args->{max} || MAX_PER_PAGE;
  56         my $top = $args->{top}; # bool
  57         local $ENV{GIT_DIR} = $args->{git_dir};
  58         my $feed_opts = get_feedopts($args);
  59
  60         my $title = $feed_opts->{description} || '';
  61         $title = PublicInbox::Hval->new_oneline($title)->as_html;
  62
  63         my @messages;
  64         my $git = try_git_pm($args->{git_dir});
  65         my ($first, $last) = each_recent_blob($args, sub {
  66                 my $mime = do_cat_mail($git, $_[0])
  67                         or return 0;
  68                 if ($top && ($mime->header('In-Reply-To') ||
  69                              $mime->header('References'))) {
  70                         return 0;
  71                 }
  72                 $mime->body_set(''); # save some memory
  73
  74                 my $t = eval { str2time($mime->header('Date')) };
  75                 defined($t) or $t = 0;
  76                 $mime->header_set('X-PI-Date', $t);
  77                 push @messages, $mime;
  78                 1;
  79         });
  80
  81         my $th = Mail::Thread->new(@messages);
  82         $th->thread;
  83         my @out = (
  84                 "<html><head><title>$title</title>" .
  85                 '<link rel=alternate title=Atom.feed href="' .
  86                 $feed_opts->{atomurl} . '" type="application/atom+xml"/>' .
  87                 '</head><body><pre>');
  88         push @out, $feed_opts->{midurl};
  89
  90         # sort by date, most recent at top
  91         $th->order(sub {
  92                 sort {
  93                         $b->topmost->message->header('X-PI-Date') <=>
  94                         $a->topmost->message->header('X-PI-Date')
  95                 } @_;
  96         });
  97         dump_html_line($_, 0, \@out) for $th->rootset;
  98
  99         my $footer = nav_footer($args->{cgi}, $first, $last);
 100         $footer = "<hr /><pre>$footer</pre>" if $footer;
 101         $out[0] . "</pre>$footer</html>";
 102 }
 103
 104 # private subs
 105
 106 sub nav_footer {
 107         my ($cgi, $first, $last) = @_;
 108         $cgi or return '';
 109         my $old_r = $cgi->param('r');
 110         my $prev = '    ';
 111         my $next = '    ';
 112         my %opts = (-path => 1, -query => 1, -relative => 1);
 113
 114         if ($last) {
 115                 $cgi->param('r', $last);
 116                 $next = $cgi->url(%opts);
 117                 $next = qq!<a href="$next">next</a>!;
 118         }
 119         if ($first && $old_r) {
 120                 $cgi->param('r', "$first..");
 121                 $prev = $cgi->url(%opts);
 122                 $prev = qq!<a href="$prev">prev</a>!;
 123         }
 124         "$prev $next";
 125 }
 126
 127 sub each_recent_blob {
 128         my ($args, $cb) = @_;
 129         my $max = $args->{max} || MAX_PER_PAGE;
 130         my $hex = '[a-f0-9]';
 131         my $addmsg = qr!^:000000 100644 \S+ \S+ A\t(${hex}{2}/${hex}{38})$!;
 132         my $delmsg = qr!^:100644 000000 \S+ \S+ D\t(${hex}{2}/${hex}{38})$!;
 133         my $refhex = qr/${hex}{4,40}(?:~\d+)?/;
 134         my $cgi = $args->{cgi};
 135
 136         # revision ranges may be specified
 137         my $reverse;
 138         my $range = 'HEAD';
 139         my $r = $cgi->param('r') if $cgi;
 140         if ($r) {
 141                 if ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o) {
 142                         $range = $r;
 143                 } elsif ($r =~ /\A(?:$refhex\.\.)\z/o) {
 144                         $reverse = 1;
 145                         $range = $r;
 146                 }
 147         }
 148
 149         # get recent messages
 150         # we could use git log -z, but, we already know ssoma will not
 151         # leave us with filenames with spaces in them..
 152         my @cmd = qw/git log --no-notes --no-color --raw -r/;
 153         push @cmd, '--reverse' if $reverse;
 154         push @cmd, $range;
 155         my $first;
 156
 157         my $pid = open(my $log, '-|', @cmd) or
 158                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 159         my %deleted; # only an optimization at this point
 160         my $last;
 161         my $nr = 0;
 162         my @commits = ();
 163         while (my $line = <$log>) {
 164                 if ($line =~ /$addmsg/o) {
 165                         my $add = $1;
 166                         next if $deleted{$add};
 167                         $nr += $cb->($add);
 168                         if ($nr >= $max) {
 169                                 $last = 1;
 170                                 last;
 171                         }
 172                 } elsif ($line =~ /$delmsg/o) {
 173                         $deleted{$1} = 1;
 174                 } elsif ($line =~ /^commit (${hex}{40})/) {
 175                         push @commits, $1;
 176                 }
 177         }
 178
 179         if ($last) {
 180                 while (my $line = <$log>) {
 181                         if ($line =~ /^commit (${hex}{40})/) {
 182                                 push @commits, $1;
 183                                 last;
 184                         }
 185                 }
 186         } elsif ($reverse) {
 187                 unshift @commits, undef
 188         } else {
 189                 push @commits, undef;
 190         }
 191
 192         close $log; # we may EPIPE here
 193         # for pagination
 194         $reverse ? ($commits[-1],$commits[0]) : ($commits[0],$commits[-1]);
 195 }
 196
 197 # private functions below
 198 sub get_feedopts {
 199         my ($args) = @_;
 200         my $pi_config = $args->{pi_config};
 201         my $listname = $args->{listname};
 202         my $cgi = $args->{cgi};
 203         my %rv;
 204         if (open my $fh, '<', "$args->{git_dir}/description") {
 205                 chomp($rv{description} = <$fh>);
 206                 close $fh;
 207         }
 208
 209         if ($pi_config && defined $listname && length $listname) {
 210                 foreach my $key (qw(address)) {
 211                         $rv{$key} = $pi_config->get($listname, $key) || "";
 212                 }
 213         }
 214         my $url_base;
 215         if ($cgi) {
 216                 my $cgi_url = $cgi->url(-path=>1, -relative=>1);
 217                 my $base = $cgi->url(-base);
 218                 $url_base = $cgi_url;
 219                 if ($url_base =~ s!/(?:|index\.html)?\z!!) {
 220                         $rv{atomurl} = "$base$url_base/atom.xml";
 221                 } else {
 222                         $url_base =~ s!/atom\.xml\z!!;
 223                         $rv{atomurl} = $base . $cgi_url;
 224                         $url_base = $base . $url_base; # XXX is this needed?
 225                 }
 226         } else {
 227                 $url_base = "http://example.com";
 228                 $rv{atomurl} = "$url_base/atom.xml";
 229         }
 230         $rv{url} ||= "$url_base/";
 231         $rv{midurl} = "$url_base/m/";
 232         $rv{fullurl} = "$url_base/f/";
 233
 234         \%rv;
 235 }
 236
 237 sub mime_header {
 238         my ($mime, $name) = @_;
 239         PublicInbox::Hval->new_oneline($mime->header($name))->raw;
 240 }
 241
 242 sub feed_date {
 243         my ($date) = @_;
 244         my @t = eval { strptime($date) };
 245
 246         scalar(@t) ? POSIX::strftime(DATEFMT, @t) : 0;
 247 }
 248
 249 # returns 0 (skipped) or 1 (added)
 250 sub add_to_feed {
 251         my ($feed_opts, $feed, $add, $top, $git) = @_;
 252
 253         my $mime = do_cat_mail($git, $add) or return 0;
 254         if ($top && $mime->header('In-Reply-To')) {
 255                 return 0;
 256         }
 257
 258         my $midurl = $feed_opts->{midurl} || 'http://example.com/m/';
 259         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/f/';
 260
 261         my $mid = $mime->header_obj->header_raw('Message-ID');
 262         defined $mid or return 0;
 263         $mid = PublicInbox::Hval->new_msgid($mid);
 264         my $href = $mid->as_href;
 265         my $content = PublicInbox::View->as_feed_entry($mime,
 266                                                         "$fullurl$href.html");
 267         defined($content) or return 0;
 268
 269         my $subject = mime_header($mime, 'Subject') or return 0;
 270
 271         my $from = mime_header($mime, 'From') or return 0;
 272         my @from = Email::Address->parse($from);
 273         my $name = $from[0]->name;
 274         defined $name or $name = "";
 275         my $email = $from[0]->address;
 276         defined $email or $email = "";
 277
 278         my $date = $mime->header('Date');
 279         $date = PublicInbox::Hval->new_oneline($date);
 280         $date = feed_date($date->raw) or return 0;
 281         $feed->add_entry(
 282                 author => { name => $name, email => $email },
 283                 title => $subject,
 284                 updated => $date,
 285                 content => { type => "html", content => $content },
 286                 link => $midurl . $href,
 287                 id => $add,
 288         );
 289         1;
 290 }
 291
 292 sub dump_html_line {
 293         my ($self, $level, $args) = @_; # args => [ $html, $midurl ]
 294         if ($self->message) {
 295                 $args->[0] .= (' ' x $level);
 296                 my $mime = $self->message;
 297                 my $subj = $mime->header('Subject');
 298                 my $mid = $mime->header_obj->header_raw('Message-ID');
 299                 $mid = PublicInbox::Hval->new_msgid($mid);
 300                 my $url = $args->[1] . $mid->as_href;
 301                 my $from = mime_header($mime, 'From');
 302
 303                 my @from = Email::Address->parse($from);
 304                 $from = $from[0]->name;
 305                 (defined($from) && length($from)) or $from = $from[0]->address;
 306
 307                 $from = PublicInbox::Hval->new_oneline($from)->as_html;
 308                 $subj = PublicInbox::Hval->new_oneline($subj)->as_html;
 309                 $args->[0] .= "<a href=\"$url.html\">$subj</a> $from\n";
 310         }
 311         dump_html_line($self->child, $level+1, $args) if $self->child;
 312         dump_html_line($self->next, $level, $args) if $self->next;
 313 }
 314
 315 sub try_git_pm {
 316         my ($dir) = @_;
 317         eval { Git->repository(Directory => $dir) };
 318 };
 319
 320 sub do_cat_mail {
 321         my ($git, $path) = @_;
 322         my $str;
 323         if ($git) {
 324                 open my $fh, '>', \$str or
 325                                 die "failed to setup string handle: $!\n";
 326                 binmode $fh;
 327                 my $err = '';
 328                 my $bytes;
 329                 {
 330                         local $SIG{__WARN__} = sub { $err .= $_[0] };
 331                         $bytes = $git->cat_blob("HEAD:$path", $fh);
 332                 }
 333                 close $fh or die "failed to close string handle: $!\n";
 334
 335                 if ($bytes < 0 && $err &&
 336                                 $err !~ /doesn't exist in the repository/) {
 337                         warn $err;
 338                 }
 339                 return if $bytes <= 0;
 340         } else {
 341                 $str = `git cat-file blob HEAD:$path`;
 342                 return if $? != 0 || length($str) == 0;
 343         }
 344         Email::MIME->new($str);
 345 }
 346
 347 1;