lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Used for generating Atom feeds for web-accessible mailing list archives.
   5 package PublicInbox::Feed;
   6 use strict;
   7 use warnings;
   8 use Email::MIME;
   9 use Date::Parse qw(strptime);
  10 use PublicInbox::Hval qw/ascii_html/;
  11 use PublicInbox::Git;
  12 use PublicInbox::View;
  13 use PublicInbox::MID qw/mid_clean mid2path/;
  14 use PublicInbox::Address;
  15 use POSIX qw/strftime/;
  16 use constant {
  17         DATEFMT => '%Y-%m-%dT%H:%M:%SZ', # Atom standard
  18         MAX_PER_PAGE => 25, # this needs to be tunable
  19 };
  20
  21 # main function
  22 sub generate {
  23         my ($ctx) = @_;
  24         sub { emit_atom($_[0], $ctx) };
  25 }
  26
  27 sub generate_thread_atom {
  28         my ($ctx) = @_;
  29         sub { emit_atom_thread($_[0], $ctx) };
  30 }
  31
  32 sub generate_html_index {
  33         my ($ctx) = @_;
  34         sub { emit_html_index($_[0], $ctx) };
  35 }
  36
  37 # private subs
  38
  39 sub title_tag {
  40         my ($title) = @_;
  41         $title =~ tr/\t\n / /s; # squeeze spaces
  42         # try to avoid the type attribute in title:
  43         $title = ascii_html($title);
  44         my $type = index($title, '&') >= 0 ? "\ntype=\"html\"" : '';
  45         "<title$type>$title</title>";
  46 }
  47
  48 sub atom_header {
  49         my ($feed_opts, $title) = @_;
  50
  51         $title = title_tag($feed_opts->{description}) unless (defined $title);
  52
  53         qq(<?xml version="1.0" encoding="us-ascii"?>\n) .
  54         qq{<feed\nxmlns="http://www.w3.org/2005/Atom">} .
  55         qq{$title} .
  56         qq(<link\nrel="alternate"\ntype="text/html") .
  57                 qq(\nhref="$feed_opts->{url}"/>) .
  58         qq(<link\nrel="self"\nhref="$feed_opts->{atomurl}"/>) .
  59         qq(<id>mailto:$feed_opts->{id_addr}</id>);
  60 }
  61
  62 sub emit_atom {
  63         my ($cb, $ctx) = @_;
  64         my $feed_opts = get_feedopts($ctx);
  65         my $fh = $cb->([ 200, ['Content-Type' => 'application/atom+xml']]);
  66         my $max = $ctx->{max} || MAX_PER_PAGE;
  67         my $x = atom_header($feed_opts);
  68         my $ibx = $ctx->{-inbox};
  69         each_recent_blob($ctx, sub {
  70                 my ($path, undef, $ts) = @_;
  71                 if (defined $x) {
  72                         $fh->write($x . feed_updated(undef, $ts));
  73                         $x = undef;
  74                 }
  75                 my $s = feed_entry($feed_opts, $path, $ibx) or return 0;
  76                 $fh->write($s);
  77                 1;
  78         });
  79         end_feed($fh);
  80 }
  81
  82 sub _no_thread {
  83         my ($cb) = @_;
  84         $cb->([404, ['Content-Type', 'text/plain'],
  85                 ["No feed found for thread\n"]]);
  86 }
  87
  88 sub end_feed {
  89         my ($fh) = @_;
  90         $fh->write('</feed>');
  91         $fh->close;
  92 }
  93
  94 sub emit_atom_thread {
  95         my ($cb, $ctx) = @_;
  96         my $res = $ctx->{srch}->get_thread($ctx->{mid});
  97         return _no_thread($cb) unless $res->{total};
  98         my $feed_opts = get_feedopts($ctx);
  99         my $fh = $cb->([200, ['Content-Type' => 'application/atom+xml']]);
 100
 101         my $html_url = $feed_opts->{atomurl} = $ctx->{self_url};
 102         $html_url =~ s!/t\.atom\z!/!;
 103         $feed_opts->{url} = $html_url;
 104         $feed_opts->{emit_header} = 1;
 105
 106         my $ibx = $ctx->{-inbox};
 107         foreach my $msg (@{$res->{msgs}}) {
 108                 my $s = feed_entry($feed_opts, mid2path($msg->mid), $ibx);
 109                 $fh->write($s) if defined $s;
 110         }
 111         end_feed($fh);
 112 }
 113
 114 sub _html_index_top {
 115         my ($feed_opts, $srch) = @_;
 116
 117         my $title = ascii_html($feed_opts->{description} || '');
 118         my $top = "<b>$title</b> (<a\nhref=\"new.atom\">Atom feed</a>)";
 119         if ($srch) {
 120                 $top = qq{<form\naction=""><pre>$top} .
 121                           qq{ <input\nname=q\ntype=text />} .
 122                           qq{<input\ntype=submit\nvalue=search />} .
 123                           q{</pre></form><pre>}
 124         } else {
 125                 $top = '<pre>' . $top . "\n";
 126         }
 127
 128         "<html><head><title>$title</title>" .
 129                 "<link\nrel=alternate\ntitle=\"Atom feed\"\n".
 130                 "href=\"new.atom\"\ntype=\"application/atom+xml\"/>" .
 131                 PublicInbox::Hval::STYLE .
 132                 "</head><body>$top";
 133 }
 134
 135 sub emit_html_index {
 136         my ($res, $ctx) = @_;
 137         my $feed_opts = get_feedopts($ctx);
 138         my $fh = $res->([200,['Content-Type'=>'text/html; charset=UTF-8']]);
 139
 140         my $max = $ctx->{max} || MAX_PER_PAGE;
 141
 142         my ($footer, $param, $last);
 143         my $state = { ctx => $ctx, seen => {}, anchor_idx => 0, fh => $fh };
 144         my $srch = $ctx->{srch};
 145         $fh->write(_html_index_top($feed_opts, $srch));
 146
 147         # if the 'r' query parameter is given, it is a legacy permalink
 148         # which we must continue supporting:
 149         my $qp = $ctx->{qp};
 150         if ($qp && !$qp->{r} && $srch) {
 151                 $state->{srch} = $srch;
 152                 $last = PublicInbox::View::emit_index_topics($state);
 153                 $param = 'o';
 154         } else {
 155                 $last = emit_index_nosrch($ctx, $state);
 156                 $param = 'r';
 157         }
 158         $footer = nav_footer($ctx, $last, $feed_opts, $state, $param);
 159         if ($footer) {
 160                 my $list_footer = $ctx->{footer};
 161                 $footer .= "\n\n" . $list_footer if $list_footer;
 162                 $footer = "<hr /><pre>$footer</pre>";
 163         }
 164         $fh->write("$footer</body></html>");
 165         $fh->close;
 166 }
 167
 168 sub emit_index_nosrch {
 169         my ($ctx, $state) = @_;
 170         my $ibx = $ctx->{-inbox};
 171         my (undef, $last) = each_recent_blob($ctx, sub {
 172                 my ($path, $commit, $ts, $u, $subj) = @_;
 173                 $state->{first} ||= $commit;
 174
 175                 my $mime = do_cat_mail($ibx, $path) or return 0;
 176                 PublicInbox::View::index_entry($mime, 0, $state);
 177                 1;
 178         });
 179         $last;
 180 }
 181
 182 sub nav_footer {
 183         my ($ctx, $last, $feed_opts, $state, $param) = @_;
 184         my $qp = $ctx->{qp} or return '';
 185         my $old_r = $qp->{$param};
 186         my $head = '    ';
 187         my $next = '    ';
 188         my $first = $state->{first};
 189         my $anchor = $state->{anchor_idx};
 190
 191         if ($last) {
 192                 $next = qq!<a\nhref="?$param=$last"\nrel=next>next</a>!;
 193         }
 194         if ($old_r) {
 195                 $head = $ctx->{env}->{PATH_INFO};
 196                 $head = qq!<a\nhref="$head">head</a>!;
 197         }
 198         my $atom = "<a\nhref=\"$feed_opts->{atomurl}\">Atom feed</a>";
 199         "<a\nname=\"s$anchor\">page:</a> $next $head $atom";
 200 }
 201
 202 sub each_recent_blob {
 203         my ($ctx, $cb) = @_;
 204         my $max = $ctx->{max} || MAX_PER_PAGE;
 205         my $hex = '[a-f0-9]';
 206         my $addmsg = qr!^:000000 100644 \S+ \S+ A\t(${hex}{2}/${hex}{38})$!;
 207         my $delmsg = qr!^:100644 000000 \S+ \S+ D\t(${hex}{2}/${hex}{38})$!;
 208         my $refhex = qr/(?:HEAD|${hex}{4,40})(?:~\d+)?/;
 209         my $qp = $ctx->{qp};
 210
 211         # revision ranges may be specified
 212         my $range = 'HEAD';
 213         my $r = $qp->{r} if $qp;
 214         if ($r && ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o)) {
 215                 $range = $r;
 216         }
 217
 218         # get recent messages
 219         # we could use git log -z, but, we already know ssoma will not
 220         # leave us with filenames with spaces in them..
 221         my $log = $ctx->{-inbox}->git->popen(qw/log
 222                                 --no-notes --no-color --raw -r
 223                                 --abbrev=16 --abbrev-commit/,
 224                                 "--format=%h%x00%ct%x00%an%x00%s%x00",
 225                                 $range);
 226         my %deleted; # only an optimization at this point
 227         my $last;
 228         my $nr = 0;
 229         my ($cur_commit, $first_commit, $last_commit);
 230         my ($ts, $subj, $u);
 231         local $/ = "\n";
 232         while (defined(my $line = <$log>)) {
 233                 if ($line =~ /$addmsg/o) {
 234                         my $add = $1;
 235                         next if $deleted{$add}; # optimization-only
 236                         $nr += $cb->($add, $cur_commit, $ts, $u, $subj);
 237                         if ($nr >= $max) {
 238                                 $last = 1;
 239                                 last;
 240                         }
 241                 } elsif ($line =~ /$delmsg/o) {
 242                         $deleted{$1} = 1;
 243                 } elsif ($line =~ /^${hex}{7,40}/o) {
 244                         ($cur_commit, $ts, $u, $subj) = split("\0", $line);
 245                         unless (defined $first_commit) {
 246                                 $first_commit = $cur_commit;
 247                         }
 248                 }
 249         }
 250
 251         if ($last) {
 252                 local $/ = "\n";
 253                 while (my $line = <$log>) {
 254                         if ($line =~ /^(${hex}{7,40})/o) {
 255                                 $last_commit = $1;
 256                                 last;
 257                         }
 258                 }
 259         }
 260
 261         # for pagination
 262         ($first_commit, $last_commit);
 263 }
 264
 265 # private functions below
 266 sub get_feedopts {
 267         my ($ctx) = @_;
 268         my $pi_config = $ctx->{pi_config};
 269         my $inbox = $ctx->{inbox};
 270         my $obj = $ctx->{-inbox};
 271         my $cgi = $ctx->{cgi};
 272         my %rv = ( description => $obj->description );
 273
 274         $rv{address} = $obj->{address};
 275         $rv{id_addr} = $obj->{-primary_address};
 276         my $url_base;
 277         $url_base = $obj->base_url($cgi); # CGI may be undef
 278         if (my $mid = $ctx->{mid}) { # per-thread feed:
 279                 $rv{atomurl} = "$url_base$mid/t.atom";
 280         } else {
 281                 $rv{atomurl} = $url_base."new.atom";
 282         }
 283         $rv{url} ||= $url_base;
 284         $rv{midurl} = $url_base;
 285
 286         \%rv;
 287 }
 288
 289 sub feed_updated {
 290         my ($date, $ts) = @_;
 291         my @t = eval { strptime($date) } if defined $date;
 292         @t = gmtime($ts || time) unless scalar @t;
 293
 294         '<updated>' . strftime(DATEFMT, @t) . '</updated>';
 295 }
 296
 297 # returns undef or string
 298 sub feed_entry {
 299         my ($feed_opts, $add, $ibx) = @_;
 300
 301         my $mime = do_cat_mail($ibx, $add) or return;
 302         my $url = $feed_opts->{url};
 303         my $midurl = $feed_opts->{midurl};
 304
 305         my $header_obj = $mime->header_obj;
 306         my $mid = $header_obj->header_raw('Message-ID');
 307         defined $mid or return;
 308         $mid = PublicInbox::Hval->new_msgid($mid);
 309         my $href = $midurl.$mid->as_href;
 310
 311         my $date = $header_obj->header('Date');
 312         my $updated = feed_updated($date);
 313
 314         my $title = $header_obj->header('Subject');
 315         defined $title or return;
 316         $title = title_tag($title);
 317
 318         my $from = $header_obj->header('From') or return;
 319         my ($email) = PublicInbox::Address::emails($from);
 320         my $name = PublicInbox::Address::from_name($from);
 321         $name = ascii_html($name);
 322         $email = ascii_html($email);
 323
 324         my $s = '';
 325         if (delete $feed_opts->{emit_header}) {
 326                 $s .= atom_header($feed_opts, $title) . $updated;
 327         }
 328         $s .= "<entry><author><name>$name</name><email>$email</email>" .
 329                 "</author>$title$updated" .
 330                 qq{<content\ntype="xhtml">} .
 331                 qq{<div\nxmlns="http://www.w3.org/1999/xhtml">} .
 332                 qq(<pre\nstyle="white-space:pre-wrap">) .
 333                 PublicInbox::View::multipart_text_as_html($mime, $href) .
 334                 '</pre>';
 335
 336         $add =~ tr!/!!d;
 337         my $h = '[a-f0-9]';
 338         my (@uuid5) = ($add =~ m!\A($h{8})($h{4})($h{4})($h{4})($h{12})!o);
 339         my $id = 'urn:uuid:' . join('-', @uuid5);
 340         $s .= qq!</div></content><link\nhref="$href/"/>!.
 341                 "<id>$id</id></entry>";
 342 }
 343
 344 sub do_cat_mail {
 345         my ($ibx, $path) = @_;
 346         my $mime = eval { $ibx->msg_by_path($path) } or return;
 347         Email::MIME->new($mime);
 348 }
 349
 350 1;