lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use XML::Atom::SimpleFeed;
   7 use Email::MIME;
   8 use Email::Address;
   9 use URI::Escape qw/uri_escape/;
  10 use Encode qw/find_encoding/;
  11 use Encode::MIME::Header;
  12 use CGI qw(escapeHTML);
  13 use POSIX qw(strftime);
  14 use Date::Parse qw(strptime str2time);
  15 eval { require Git }; # this is GPLv2+, so we are OK to use it
  16 use constant {
  17         DATEFMT => '%Y-%m-%dT%H:%M:%SZ',
  18         MAX_PER_PAGE => 25,
  19 };
  20 use PublicInbox::View;
  21 use Mail::Thread;
  22 my $enc_utf8 = find_encoding('utf8');
  23 my $enc_ascii = find_encoding('us-ascii');
  24 my $enc_mime = find_encoding('MIME-Header');
  25
  26 # FIXME: workaround https://rt.cpan.org/Public/Bug/Display.html?id=22817
  27
  28 # main function
  29 sub generate {
  30         my ($class, $args) = @_;
  31         my $max = $args->{max} || MAX_PER_PAGE;
  32         my $top = $args->{top}; # bool
  33
  34         local $ENV{GIT_DIR} = $args->{git_dir};
  35         my $feed_opts = get_feedopts($args);
  36
  37         my $feed = XML::Atom::SimpleFeed->new(
  38                 title => $feed_opts->{description} || "unnamed feed",
  39                 link => $feed_opts->{url} || "http://example.com/",
  40                 link => {
  41                         rel => 'self',
  42                         href => $feed_opts->{atomurl} ||
  43                                 "http://example.com/atom",
  44                 },
  45                 id => $feed_opts->{address} || 'public-inbox@example.com',
  46                 updated => strftime(DATEFMT, gmtime),
  47         );
  48
  49         my $git = try_git_pm($args->{git_dir});
  50         each_recent_blob($args, sub {
  51                 my ($add) = @_;
  52                 add_to_feed($feed_opts, $feed, $add, $top, $git);
  53         });
  54         $feed->as_string;
  55 }
  56
  57 sub generate_html_index {
  58         my ($class, $args) = @_;
  59         my $max = $args->{max} || MAX_PER_PAGE;
  60         my $top = $args->{top}; # bool
  61         local $ENV{GIT_DIR} = $args->{git_dir};
  62         my $feed_opts = get_feedopts($args);
  63         my $title = xs_html($feed_opts->{description} || "");
  64         my @messages;
  65         my $git = try_git_pm($args->{git_dir});
  66         my ($first, $last) = each_recent_blob($args, sub {
  67                 my $simple = do_cat_mail($git, 'Email::Simple', $_[0])
  68                         or return 0;
  69                 if ($top && ($simple->header("In-Reply-To") ||
  70                              $simple->header("References"))) {
  71                         return 0;
  72                 }
  73                 $simple->body_set(""); # save some memory
  74
  75                 my $t = eval { str2time($simple->header('Date')) };
  76                 defined($t) or $t = 0;
  77                 $simple->header_set('X-PI-Date', $t);
  78                 push @messages, $simple;
  79                 1;
  80         });
  81
  82         my $th = Mail::Thread->new(@messages);
  83         $th->thread;
  84         my @out = (
  85                 "<html><head><title>$title</title>" .
  86                 '<link rel=alternate title=Atom.feed href="' .
  87                 $feed_opts->{atomurl} . '" type="application/atom+xml"/>' .
  88                 '</head><body><pre>');
  89         push @out, $feed_opts->{midurl};
  90
  91         # sort by date, most recent at top
  92         $th->order(sub {
  93                 sort {
  94                         $b->topmost->message->header('X-PI-Date') <=>
  95                         $a->topmost->message->header('X-PI-Date')
  96                 } @_;
  97         });
  98         dump_html_line($_, 0, \@out) for $th->rootset;
  99
 100         my $footer = nav_footer($args->{cgi}, $first, $last);
 101         $footer = "<hr /><pre>$footer</pre>" if $footer;
 102         $out[0] . "</pre>$footer</html>";
 103 }
 104
 105 # private subs
 106
 107 sub nav_footer {
 108         my ($cgi, $first, $last) = @_;
 109         $cgi or return '';
 110         my $old_r = $cgi->param('r');
 111         my $prev = '    ';
 112         my $next = '    ';
 113         my %opts = (-path => 1, -query => 1, -relative => 1);
 114
 115         if ($last) {
 116                 $cgi->param('r', $last);
 117                 $next = $cgi->url(%opts);
 118                 $next = qq!<a href="$next">next</a>!;
 119         }
 120         if ($first && $old_r) {
 121                 $cgi->param('r', "$first..");
 122                 $prev = $cgi->url(%opts);
 123                 $prev = qq!<a href="$prev">prev</a>!;
 124         }
 125         "$prev $next";
 126 }
 127
 128 sub each_recent_blob {
 129         my ($args, $cb) = @_;
 130         my $max = $args->{max} || MAX_PER_PAGE;
 131         my $refhex = qr/[a-f0-9]{4,40}(?:~\d+)?/;
 132         my $cgi = $args->{cgi};
 133
 134         # revision ranges may be specified
 135         my $reverse;
 136         my $range = 'HEAD';
 137         my $r = $cgi->param('r') if $cgi;
 138         if ($r) {
 139                 if ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o) {
 140                         $range = $r;
 141                 } elsif ($r =~ /\A(?:$refhex\.\.)\z/o) {
 142                         $reverse = 1;
 143                         $range = $r;
 144                 }
 145         }
 146
 147         # get recent messages
 148         # we could use git log -z, but, we already know ssoma will not
 149         # leave us with filenames with spaces in them..
 150         my @cmd = qw/git log --no-notes --no-color --raw -r --no-abbrev/;
 151         push @cmd, '--reverse' if $reverse;
 152         push @cmd, $range;
 153         my $first;
 154
 155         my $pid = open(my $log, '-|', @cmd) or
 156                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 157         my %deleted;
 158         my $last;
 159         my $nr = 0;
 160         my @commits = ();
 161         while (my $line = <$log>) {
 162                 if ($line =~ /^:000000 100644 0{40} ([a-f0-9]{40})/) {
 163                         my $add = $1;
 164                         next if $deleted{$add};
 165                         $nr += $cb->($add);
 166                         if ($nr >= $max) {
 167                                 $last = 1;
 168                                 last;
 169                         }
 170                 } elsif ($line =~ /^:100644 000000 ([a-f0-9]{40}) 0{40}/) {
 171                         $deleted{$1} = 1;
 172                 } elsif ($line =~ /^commit ([a-f0-9]{40})/) {
 173                         push @commits, $1;
 174                 }
 175         }
 176
 177         if ($last) {
 178                 while (my $line = <$log>) {
 179                         if ($line =~ /^commit ([a-f0-9]{40})/) {
 180                                 push @commits, $1;
 181                                 last;
 182                         }
 183                 }
 184         }
 185
 186         close $log; # we may EPIPE here
 187         # for pagination
 188         $reverse ? ($commits[-1],$commits[0]) : ($commits[0],$commits[-1]);
 189 }
 190
 191 # private functions below
 192 sub get_feedopts {
 193         my ($args) = @_;
 194         my $pi_config = $args->{pi_config};
 195         my $listname = $args->{listname};
 196         my $cgi = $args->{cgi};
 197         my %rv;
 198
 199         if ($pi_config && defined $listname && length $listname) {
 200                 foreach my $key (qw(description address)) {
 201                         $rv{$key} = $pi_config->get($listname, $key) || "";
 202                 }
 203         }
 204         my $url_base;
 205         if ($cgi) {
 206                 my $cgi_url = $cgi->url(-path=>1, -relative=>1);
 207                 my $base = $cgi->url(-base);
 208                 $url_base = $cgi_url;
 209                 if ($url_base =~ s!/(?:|index\.html)?\z!!) {
 210                         $rv{atomurl} = "$base$url_base/index.atom.xml";
 211                 } else {
 212                         $url_base =~ s!/?(?:index|all)\.atom\.xml\z!!;
 213                         $rv{atomurl} = $base . $cgi_url;
 214                         $url_base = $base . $url_base; # XXX is this needed?
 215                 }
 216         } else {
 217                 $url_base = "http://example.com";
 218                 $rv{atomurl} = "$url_base/index.atom.xml";
 219         }
 220         $rv{url} ||= "$url_base/";
 221         $rv{midurl} = "$url_base/m/";
 222         $rv{fullurl} = "$url_base/f/";
 223
 224         \%rv;
 225 }
 226
 227 sub utf8_header {
 228         my ($simple, $name) = @_;
 229         my $val = $simple->header($name);
 230         return "" unless defined $val;
 231         $val =~ tr/\t\n / /s;
 232         $val =~ tr/\r//d;
 233         $enc_utf8->encode($enc_mime->decode($val));
 234 }
 235
 236 sub feed_date {
 237         my ($date) = @_;
 238         my @t = eval { strptime($date) };
 239
 240         scalar(@t) ? strftime(DATEFMT, @t) : 0;
 241 }
 242
 243 # returns 0 (skipped) or 1 (added)
 244 sub add_to_feed {
 245         my ($feed_opts, $feed, $add, $top, $git) = @_;
 246
 247         my $mime = do_cat_mail($git, 'Email::MIME', $add) or return 0;
 248         if ($top && $mime->header("In-Reply-To")) {
 249                 return 0;
 250         }
 251
 252         my $midurl = $feed_opts->{midurl} || 'http://example.com/m/';
 253         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/f/';
 254
 255         my $content = PublicInbox::View->as_feed_entry($mime, $fullurl);
 256         defined($content) or return 0;
 257
 258         my $mid = utf8_header($mime, "Message-ID") or return 0;
 259         $mid =~ s/\A<//; $mid =~ s/>\z//;
 260
 261         my $subject = utf8_header($mime, "Subject") || "";
 262         length($subject) or return 0;
 263
 264         my $from = utf8_header($mime, "From") or return 0;
 265
 266         my @from = Email::Address->parse($from);
 267         my $name = $from[0]->name;
 268         defined $name or $name = "";
 269         my $email = $from[0]->address;
 270         defined $email or $email = "";
 271
 272         my $url = $midurl . uri_escape($mid);
 273         my $date = utf8_header($mime, "Date");
 274         $date or return 0;
 275         $date = feed_date($date) or return 0;
 276         $feed->add_entry(
 277                 author => { name => $name, email => $email },
 278                 title => $subject,
 279                 updated => $date,
 280                 content => { type => "html", content => $content },
 281                 link => $url,
 282                 id => $add,
 283         );
 284         1;
 285 }
 286
 287 sub dump_html_line {
 288         my ($self, $level, $args) = @_; # args => [ $html, $midurl ]
 289         $args->[0] .= (' ' x $level);
 290         if ($self->message) {
 291                 my $simple = $self->message;
 292                 my $subj = utf8_header($simple, "Subject");
 293                 my $mid = utf8_header($simple, "Message-ID");
 294                 $mid =~ s/\A<//;
 295                 $mid =~ s/>\z//;
 296                 my $url = $args->[1] . uri_escape($mid);
 297                 my $from = utf8_header($simple, "From");
 298                 my @from = Email::Address->parse($from);
 299                 $from = $from[0]->name;
 300                 (defined($from) && length($from)) or $from = $from[0]->address;
 301                 $from = xs_html($from);
 302                 $subj = xs_html($subj);
 303                 $args->[0] .= "<a href=\"$url.html\">$subj</a> $from\n";
 304         } else {
 305                 $args->[0] .= "[ Message not available ]\n";
 306         }
 307         dump_html_line($self->child, $level+1, $args) if $self->child;
 308         dump_html_line($self->next, $level, $args) if $self->next;
 309 }
 310
 311 sub xs_html {
 312         $enc_ascii->encode(escapeHTML($enc_utf8->decode($_[0])),
 313                         Encode::HTMLCREF);
 314 }
 315
 316 sub try_git_pm {
 317         my ($dir) = @_;
 318         eval { Git->repository(Directory => $dir) };
 319 };
 320
 321 sub do_cat_mail {
 322         my ($git, $class, $sha1) = @_;
 323         my $str;
 324         if ($git) {
 325                 open my $fh, '>', \$str or
 326                                 die "failed to setup string handle: $!\n";
 327                 binmode $fh;
 328                 my $bytes = $git->cat_blob($sha1, $fh);
 329                 return if $bytes <= 0;
 330                 close $fh or die "failed to close string handle: $!\n";
 331         } else {
 332                 $str = `git cat-file blob $sha1`;
 333                 return if $? != 0 || length($str) == 0;
 334         }
 335         $class->new($str);
 336 }
 337
 338 1;