lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use Email::Address;
   7 use Email::MIME;
   8 use Date::Parse qw(strptime str2time);
   9 use PublicInbox::Hval;
  10 eval { require Git }; # this is GPLv2+, so we are OK to use it
  11 use constant {
  12         DATEFMT => '%Y-%m-%dT%H:%M:%SZ',
  13         MAX_PER_PAGE => 25,
  14 };
  15
  16 # FIXME: workaround https://rt.cpan.org/Public/Bug/Display.html?id=22817
  17
  18 # main function
  19 sub generate {
  20         my ($class, $args) = @_;
  21         require XML::Atom::SimpleFeed;
  22         require PublicInbox::View;
  23         require POSIX;
  24         my $max = $args->{max} || MAX_PER_PAGE;
  25         my $top = $args->{top}; # bool
  26
  27         local $ENV{GIT_DIR} = $args->{git_dir};
  28         my $feed_opts = get_feedopts($args);
  29         my $addr = $feed_opts->{address};
  30         $addr = $addr->[0] if ref($addr);
  31         my $feed = XML::Atom::SimpleFeed->new(
  32                 title => $feed_opts->{description} || "unnamed feed",
  33                 link => $feed_opts->{url} || "http://example.com/",
  34                 link => {
  35                         rel => 'self',
  36                         href => $feed_opts->{atomurl} ||
  37                                 "http://example.com/atom.xml",
  38                 },
  39                 id => 'mailto:' . ($addr || 'public-inbox@example.com'),
  40                 updated => POSIX::strftime(DATEFMT, gmtime),
  41         );
  42
  43         my $git = try_git_pm($args->{git_dir});
  44         each_recent_blob($args, sub {
  45                 my ($add) = @_;
  46                 add_to_feed($feed_opts, $feed, $add, $top, $git);
  47         });
  48         $feed->as_string;
  49 }
  50
  51 sub generate_html_index {
  52         my ($class, $args) = @_;
  53         require Mail::Thread;
  54
  55         my $max = $args->{max} || MAX_PER_PAGE;
  56         my $top = $args->{top}; # bool
  57         local $ENV{GIT_DIR} = $args->{git_dir};
  58         my $feed_opts = get_feedopts($args);
  59
  60         my $title = $feed_opts->{description} || '';
  61         $title = PublicInbox::Hval->new_oneline($title)->as_html;
  62
  63         my @messages;
  64         my $git = try_git_pm($args->{git_dir});
  65         my ($first, $last) = each_recent_blob($args, sub {
  66                 my $mime = do_cat_mail($git, $_[0])
  67                         or return 0;
  68                 if ($top && ($mime->header('In-Reply-To') ||
  69                              $mime->header('References'))) {
  70                         return 0;
  71                 }
  72                 $mime->body_set(''); # save some memory
  73
  74                 my $t = eval { str2time($mime->header('Date')) };
  75                 defined($t) or $t = 0;
  76                 $mime->header_set('X-PI-Date', $t);
  77                 push @messages, $mime;
  78                 1;
  79         });
  80
  81         my $th = Mail::Thread->new(@messages);
  82         $th->thread;
  83         my @out = (
  84                 "<html><head><title>$title</title>" .
  85                 '<link rel="alternate" title="Atom feed" href="' .
  86                 $feed_opts->{atomurl} . '" type="application/atom+xml"/>' .
  87                 '</head><body><pre>');
  88         push @out, $feed_opts->{midurl};
  89
  90         # sort by date, most recent at top
  91         $th->order(sub {
  92                 sort {
  93                         $b->topmost->message->header('X-PI-Date') <=>
  94                         $a->topmost->message->header('X-PI-Date')
  95                 } @_;
  96         });
  97         dump_html_line($_, 0, \@out) for $th->rootset;
  98
  99         my $footer = nav_footer($args->{cgi}, $first, $last);
 100         $footer = "<hr /><pre>$footer</pre>" if $footer;
 101         $out[0] . "</pre>$footer</html>";
 102 }
 103
 104 # private subs
 105
 106 sub nav_footer {
 107         my ($cgi, $first, $last) = @_;
 108         $cgi or return '';
 109         my $old_r = $cgi->param('r');
 110         my $prev = '    ';
 111         my $next = '    ';
 112
 113         if ($last) {
 114                 $next = $cgi->path_info . "?r=$last";
 115                 $next = qq!<a href="$next">next</a>!;
 116         }
 117         if ($first && $old_r) {
 118                 $prev = $cgi->path_info . "?r=$first..";
 119                 $prev = qq!<a href="$prev">prev</a>!;
 120         }
 121         "$prev $next";
 122 }
 123
 124 sub each_recent_blob {
 125         my ($args, $cb) = @_;
 126         my $max = $args->{max} || MAX_PER_PAGE;
 127         my $hex = '[a-f0-9]';
 128         my $addmsg = qr!^:000000 100644 \S+ \S+ A\t(${hex}{2}/${hex}{38})$!;
 129         my $delmsg = qr!^:100644 000000 \S+ \S+ D\t(${hex}{2}/${hex}{38})$!;
 130         my $refhex = qr/${hex}{4,40}(?:~\d+)?/;
 131         my $cgi = $args->{cgi};
 132
 133         # revision ranges may be specified
 134         my $reverse;
 135         my $range = 'HEAD';
 136         my $r = $cgi->param('r') if $cgi;
 137         if ($r) {
 138                 if ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o) {
 139                         $range = $r;
 140                 } elsif ($r =~ /\A(?:$refhex\.\.)\z/o) {
 141                         $reverse = 1;
 142                         $range = $r;
 143                 }
 144         }
 145
 146         # get recent messages
 147         # we could use git log -z, but, we already know ssoma will not
 148         # leave us with filenames with spaces in them..
 149         my @cmd = qw/git log --no-notes --no-color --raw -r/;
 150         push @cmd, '--reverse' if $reverse;
 151         push @cmd, $range;
 152         my $first;
 153
 154         my $pid = open(my $log, '-|', @cmd) or
 155                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 156         my %deleted; # only an optimization at this point
 157         my $last;
 158         my $nr = 0;
 159         my @commits = ();
 160         while (my $line = <$log>) {
 161                 if ($line =~ /$addmsg/o) {
 162                         my $add = $1;
 163                         next if $deleted{$add};
 164                         $nr += $cb->($add);
 165                         if ($nr >= $max) {
 166                                 $last = 1;
 167                                 last;
 168                         }
 169                 } elsif ($line =~ /$delmsg/o) {
 170                         $deleted{$1} = 1;
 171                 } elsif ($line =~ /^commit (${hex}{40})/) {
 172                         push @commits, $1;
 173                 }
 174         }
 175
 176         if ($last) {
 177                 while (my $line = <$log>) {
 178                         if ($line =~ /^commit (${hex}{40})/) {
 179                                 push @commits, $1;
 180                                 last;
 181                         }
 182                 }
 183         } elsif ($reverse) {
 184                 unshift @commits, undef
 185         } else {
 186                 push @commits, undef;
 187         }
 188
 189         close $log; # we may EPIPE here
 190         # for pagination
 191         $reverse ? ($commits[-1],$commits[0]) : ($commits[0],$commits[-1]);
 192 }
 193
 194 # private functions below
 195 sub get_feedopts {
 196         my ($args) = @_;
 197         my $pi_config = $args->{pi_config};
 198         my $listname = $args->{listname};
 199         my $cgi = $args->{cgi};
 200         my %rv;
 201         if (open my $fh, '<', "$args->{git_dir}/description") {
 202                 chomp($rv{description} = <$fh>);
 203                 close $fh;
 204         }
 205
 206         if ($pi_config && defined $listname && length $listname) {
 207                 foreach my $key (qw(address)) {
 208                         $rv{$key} = $pi_config->get($listname, $key) || "";
 209                 }
 210         }
 211         my $url_base;
 212         if ($cgi) {
 213                 my $path_info = $cgi->path_info;
 214                 my $base;
 215                 if (ref($cgi) eq 'CGI') {
 216                         $base = $cgi->url(-base);
 217                 } else {
 218                         $base = "${$cgi->base}";
 219                         $base =~ s!/\z!!;
 220                 }
 221                 $url_base = $path_info;
 222                 if ($url_base =~ s!/(?:|index\.html)?\z!!) {
 223                         $rv{atomurl} = "$base$url_base/atom.xml";
 224                 } else {
 225                         $url_base =~ s!/atom\.xml\z!!;
 226                         $rv{atomurl} = $base . $path_info;
 227                         $url_base = $base . $url_base; # XXX is this needed?
 228                 }
 229         } else {
 230                 $url_base = "http://example.com";
 231                 $rv{atomurl} = "$url_base/atom.xml";
 232         }
 233         $rv{url} ||= "$url_base/";
 234         $rv{midurl} = "$url_base/m/";
 235         $rv{fullurl} = "$url_base/f/";
 236
 237         \%rv;
 238 }
 239
 240 sub mime_header {
 241         my ($mime, $name) = @_;
 242         PublicInbox::Hval->new_oneline($mime->header($name))->raw;
 243 }
 244
 245 sub feed_date {
 246         my ($date) = @_;
 247         my @t = eval { strptime($date) };
 248
 249         scalar(@t) ? POSIX::strftime(DATEFMT, @t) : 0;
 250 }
 251
 252 # returns 0 (skipped) or 1 (added)
 253 sub add_to_feed {
 254         my ($feed_opts, $feed, $add, $top, $git) = @_;
 255
 256         my $mime = do_cat_mail($git, $add) or return 0;
 257         if ($top && $mime->header('In-Reply-To')) {
 258                 return 0;
 259         }
 260
 261         my $midurl = $feed_opts->{midurl} || 'http://example.com/m/';
 262         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/f/';
 263
 264         my $mid = $mime->header_obj->header_raw('Message-ID');
 265         defined $mid or return 0;
 266         $mid = PublicInbox::Hval->new_msgid($mid);
 267         my $href = $mid->as_href;
 268         my $content = PublicInbox::View->as_feed_entry($mime,
 269                                                         "$fullurl$href.html");
 270         defined($content) or return 0;
 271
 272         my $subject = mime_header($mime, 'Subject') or return 0;
 273
 274         my $from = mime_header($mime, 'From') or return 0;
 275         my @from = Email::Address->parse($from);
 276         my $name = $from[0]->name;
 277         defined $name or $name = "";
 278         my $email = $from[0]->address;
 279         defined $email or $email = "";
 280
 281         my $date = $mime->header('Date');
 282         $date = PublicInbox::Hval->new_oneline($date);
 283         $date = feed_date($date->raw) or return 0;
 284         $add =~ tr!/!!d;
 285         my $h = '[a-f0-9]';
 286         my (@uuid5) = ($add =~ m!\A($h{8})($h{4})($h{4})($h{4})($h{12})!o);
 287
 288         $feed->add_entry(
 289                 author => { name => $name, email => $email },
 290                 title => $subject,
 291                 updated => $date,
 292                 content => { type => 'xhtml', content => $content },
 293                 link => $midurl . $href,
 294                 id => 'urn:uuid:' . join('-', @uuid5),
 295         );
 296         1;
 297 }
 298
 299 sub dump_html_line {
 300         my ($self, $level, $args) = @_; # args => [ $html, $midurl ]
 301         if ($self->message) {
 302                 $args->[0] .= (' ' x $level);
 303                 my $mime = $self->message;
 304                 my $subj = $mime->header('Subject');
 305                 my $mid = $mime->header_obj->header_raw('Message-ID');
 306                 $mid = PublicInbox::Hval->new_msgid($mid);
 307                 my $url = $args->[1] . $mid->as_href;
 308                 my $from = mime_header($mime, 'From');
 309
 310                 my @from = Email::Address->parse($from);
 311                 $from = $from[0]->name;
 312                 (defined($from) && length($from)) or $from = $from[0]->address;
 313
 314                 $from = PublicInbox::Hval->new_oneline($from)->as_html;
 315                 $subj = PublicInbox::Hval->new_oneline($subj)->as_html;
 316                 $args->[0] .= "<a href=\"$url.html\">$subj</a> $from\n";
 317         }
 318         dump_html_line($self->child, $level+1, $args) if $self->child;
 319         dump_html_line($self->next, $level, $args) if $self->next;
 320 }
 321
 322 sub try_git_pm {
 323         my ($dir) = @_;
 324         eval { Git->repository(Directory => $dir) };
 325 };
 326
 327 sub do_cat_mail {
 328         my ($git, $path) = @_;
 329         my $str;
 330         if ($git) {
 331                 open my $fh, '>', \$str or
 332                                 die "failed to setup string handle: $!\n";
 333                 binmode $fh;
 334                 my $err = '';
 335                 my $bytes;
 336                 {
 337                         local $SIG{__WARN__} = sub { $err .= $_[0] };
 338                         $bytes = $git->cat_blob("HEAD:$path", $fh);
 339                 }
 340                 close $fh or die "failed to close string handle: $!\n";
 341
 342                 if ($bytes < 0 && $err &&
 343                                 $err !~ /doesn't exist in the repository/) {
 344                         warn $err;
 345                 }
 346                 return if $bytes <= 0;
 347         } else {
 348                 $str = `git cat-file blob HEAD:$path`;
 349                 return if $? != 0 || length($str) == 0;
 350         }
 351         Email::MIME->new($str);
 352 }
 353
 354 1;