lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for generating Atom feeds for web-accessible mailing list archives.
   5 package PublicInbox::Feed;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::View;
   9 use PublicInbox::WwwAtomStream;
  10 use PublicInbox::Smsg; # this loads w/o Search::Xapian
  11
  12 sub generate_i {
  13         my ($ctx) = @_;
  14         shift @{$ctx->{msgs}};
  15 }
  16
  17 # main function
  18 sub generate {
  19         my ($ctx) = @_;
  20         my $msgs = $ctx->{msgs} = recent_msgs($ctx);
  21         return _no_thread() unless @$msgs;
  22         PublicInbox::WwwAtomStream->response($ctx, 200, \&generate_i);
  23 }
  24
  25 sub generate_thread_atom {
  26         my ($ctx) = @_;
  27         my $msgs = $ctx->{msgs} = $ctx->{-inbox}->over->get_thread($ctx->{mid});
  28         return _no_thread() unless @$msgs;
  29         PublicInbox::WwwAtomStream->response($ctx, 200, \&generate_i);
  30 }
  31
  32 sub generate_html_index {
  33         my ($ctx) = @_;
  34         # if the 'r' query parameter is given, it is a legacy permalink
  35         # which we must continue supporting:
  36         my $qp = $ctx->{qp};
  37         my $ibx = $ctx->{-inbox};
  38         if ($qp && !$qp->{r} && $ibx->over) {
  39                 return PublicInbox::View::index_topics($ctx);
  40         }
  41
  42         my $env = $ctx->{env};
  43         my $url = $ibx->base_url($env) . 'new.html';
  44         my $qs = $env->{QUERY_STRING};
  45         $url .= "?$qs" if $qs ne '';
  46         [302, [ 'Location', $url, 'Content-Type', 'text/plain'],
  47                 [ "Redirecting to $url\n" ] ];
  48 }
  49
  50 sub new_html_i {
  51         my ($ctx, $eml) = @_;
  52         $ctx->zmore($ctx->html_top) if exists $ctx->{-html_tip};
  53
  54         $eml and return PublicInbox::View::eml_entry($ctx, $eml,
  55                                                 scalar @{$ctx->{msgs}});
  56         my $smsg = shift @{$ctx->{msgs}} or
  57                 $ctx->zmore(PublicInbox::View::pagination_footer(
  58                                                 $ctx, './new.html'));
  59         $smsg;
  60 }
  61
  62 sub new_html {
  63         my ($ctx) = @_;
  64         my $msgs = $ctx->{msgs} = recent_msgs($ctx);
  65         if (!@$msgs) {
  66                 return [404, ['Content-Type', 'text/plain'],
  67                         ["No messages, yet\n"] ];
  68         }
  69         $ctx->{-html_tip} = '<pre>';
  70         $ctx->{-upfx} = '';
  71         $ctx->{-hr} = 1;
  72         PublicInbox::WwwStream::aresponse($ctx, 200, \&new_html_i);
  73 }
  74
  75 # private subs
  76
  77 sub _no_thread () {
  78         [404, ['Content-Type', 'text/plain'], ["No feed found for thread\n"]];
  79 }
  80
  81 sub recent_msgs {
  82         my ($ctx) = @_;
  83         my $ibx = $ctx->{-inbox};
  84         my $max = $ibx->{feedmax};
  85         return PublicInbox::View::paginate_recent($ctx, $max) if $ibx->over;
  86
  87         # only for rare v1 inboxes which aren't indexed at all
  88         my $qp = $ctx->{qp};
  89         my $hex = '[a-f0-9]';
  90         my $addmsg = qr!^:000000 100644 \S+ (\S+) A\t${hex}{2}/${hex}{38}$!;
  91         my $delmsg = qr!^:100644 000000 (\S+) \S+ D\t(${hex}{2}/${hex}{38})$!;
  92         my $refhex = qr/(?:HEAD|${hex}{4,40})(?:~[0-9]+)?/;
  93
  94         # revision ranges may be specified
  95         my $range = 'HEAD';
  96         my $r = $qp->{r} if $qp;
  97         if ($r && ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o)) {
  98                 $range = $r;
  99         }
 100
 101         # get recent messages
 102         # we could use git log -z, but, we already know ssoma will not
 103         # leave us with filenames with spaces in them..
 104         my $log = $ibx->git->popen(qw/log
 105                                 --no-notes --no-color --raw -r
 106                                 --no-abbrev --abbrev-commit/,
 107                                 "--format=%H", $range);
 108         my %deleted; # only an optimization at this point
 109         my $last;
 110         my $last_commit;
 111         local $/ = "\n";
 112         my @oids;
 113         while (defined(my $line = <$log>)) {
 114                 if ($line =~ /$addmsg/o) {
 115                         my $add = $1;
 116                         next if $deleted{$add}; # optimization-only
 117                         push @oids, $add;
 118                         if (scalar(@oids) >= $max) {
 119                                 $last = 1;
 120                                 last;
 121                         }
 122                 } elsif ($line =~ /$delmsg/o) {
 123                         $deleted{$1} = 1;
 124                 }
 125         }
 126
 127         if ($last) {
 128                 local $/ = "\n";
 129                 while (my $line = <$log>) {
 130                         if ($line =~ /^(${hex}{7,40})/) {
 131                                 $last_commit = $1;
 132                                 last;
 133                         }
 134                 }
 135         }
 136
 137         $ctx->{next_page} = "r=$last_commit" if $last_commit;
 138         [ map { bless {blob => $_ }, 'PublicInbox::Smsg' } @oids ];
 139 }
 140
 141 1;