lib/PublicInbox/Fetch.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # Wrapper to "git fetch" remote public-inboxes
   4 package PublicInbox::Fetch;
   5 use v5.12;
   6 use parent qw(PublicInbox::IPC);
   7 use URI ();
   8 use PublicInbox::Spawn qw(popen_rd run_die spawn);
   9 use PublicInbox::Admin;
  10 use PublicInbox::LEI;
  11 use PublicInbox::LeiCurl;
  12 use PublicInbox::LeiMirror;
  13 use File::Temp ();
  14
  15 sub new { bless {}, __PACKAGE__ }
  16
  17 sub remote_url ($$) {
  18         my ($lei, $dir) = @_;
  19         my $rn = $lei->{opt}->{'try-remote'} // [ 'origin', '_grokmirror' ];
  20         for my $r (@$rn) {
  21                 my $cmd = [ qw(git config), "remote.$r.url" ];
  22                 my $fh = popen_rd($cmd, undef, { -C => $dir, 2 => $lei->{2} });
  23                 my $url = <$fh>;
  24                 close $fh or next;
  25                 $url =~ s!/*\n!!s;
  26                 return $url;
  27         }
  28         undef
  29 }
  30
  31 # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
  32 # TODO: remove, handle multi-inbox fetch
  33 sub deduce_epochs ($$) {
  34         my ($m, $path) = @_;
  35         my ($v1_ent, @v2_epochs);
  36         my $path_pfx = '';
  37         $path =~ s!/+\z!!;
  38         do {
  39                 $v1_ent = $m->{$path};
  40                 @v2_epochs = grep(m!\A\Q$path\E/git/[0-9]+\.git\z!, keys %$m);
  41         } while (!defined($v1_ent) && !@v2_epochs &&
  42                 $path =~ s!\A(/[^/]+)/!/! and $path_pfx .= $1);
  43         ($path_pfx, $v1_ent ? $path : undef, @v2_epochs);
  44 }
  45
  46 sub do_manifest ($$$) {
  47         my ($lei, $dir, $ibx_uri) = @_;
  48         my $muri = URI->new("$ibx_uri/manifest.js.gz");
  49         my $ft = File::Temp->new(TEMPLATE => 'm-XXXX',
  50                                 UNLINK => 1, DIR => $dir, SUFFIX => '.tmp');
  51         my $mf = "$dir/manifest.js.gz";
  52         my $m0; # current manifest.js.gz contents
  53         if (open my $fh, '<', $mf) {
  54                 $m0 = eval {
  55                         PublicInbox::LeiMirror::decode_manifest($fh, $mf, $mf)
  56                 };
  57                 warn($@) if $@;
  58         }
  59         my ($bn) = ($ft->filename =~ m!/([^/]+)\z!);
  60         my $curl_cmd = $lei->{curl}->for_uri($lei, $muri, qw(-R -o), $bn);
  61         my $opt = { -C => $dir };
  62         $opt->{$_} = $lei->{$_} for (0..2);
  63         my $cerr = PublicInbox::LeiMirror::run_reap($lei, $curl_cmd, $opt);
  64         if ($cerr) {
  65                 return [ 404, $muri ] if ($cerr >> 8) == 22; # 404 Missing
  66                 $lei->child_error($cerr, "@$curl_cmd failed");
  67                 return;
  68         }
  69         my $m1 = eval {
  70                 PublicInbox::LeiMirror::decode_manifest($ft, $ft, $muri);
  71         } or return [ 404, $muri ];
  72         my $mdiff = { %$m1 };
  73
  74         # filter out unchanged entries.  We check modified, too, since
  75         # fingerprints are SHA-1, so there's a teeny chance they'll collide
  76         while (my ($k, $v0) = each %{$m0 // {}}) {
  77                 my $cur = $m1->{$k} // next;
  78                 my $f0 = $v0->{fingerprint} // next;
  79                 my $f1 = $cur->{fingerprint} // next;
  80                 my $t0 = $v0->{modified} // next;
  81                 my $t1 = $cur->{modified} // next;
  82                 delete($mdiff->{$k}) if $f0 eq $f1 && $t0 == $t1;
  83         }
  84         unless (keys %$mdiff) {
  85                 $lei->child_error(127 << 8) if $lei->{opt}->{'exit-code'};
  86                 return;
  87         }
  88         my (undef, $v1_path, @v2_epochs) =
  89                 deduce_epochs($mdiff, $ibx_uri->path);
  90         [ 200, $muri, $v1_path, \@v2_epochs, $ft, $mf, $m1 ];
  91 }
  92
  93 sub get_fingerprint2 {
  94         my ($git_dir) = @_;
  95         require PublicInbox::SHA;
  96         my $rd = popen_rd([qw(git show-ref)], undef, { -C => $git_dir });
  97         PublicInbox::SHA::sha256(do { local $/; <$rd> });
  98 }
  99
 100 sub writable_dir ($) {
 101         my ($dir) = @_;
 102         return unless -d $dir && -w _;
 103         my @st = stat($dir);
 104         $st[2] & 0222; # any writable bits set? (in case of root)
 105 }
 106
 107 sub do_fetch { # main entry point
 108         my ($cls, $lei, $cd) = @_;
 109         my $ibx_ver;
 110         $lei->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 111         my $dir = PublicInbox::Admin::resolve_inboxdir($cd, \$ibx_ver);
 112         my ($ibx_uri, @git_dir, @epochs, $mg, @new_epoch, $skip);
 113         if ($ibx_ver == 1) {
 114                 my $url = remote_url($lei, $dir) //
 115                         die "E: $dir missing remote.*.url\n";
 116                 $ibx_uri = URI->new($url);
 117         } else { # v2:
 118                 require PublicInbox::MultiGit;
 119                 $mg = PublicInbox::MultiGit->new($dir, 'all.git', 'git');
 120                 @epochs = $mg->git_epochs;
 121                 my ($git_url, $epoch);
 122                 for my $nr (@epochs) { # try newest epoch, first
 123                         my $edir = "$dir/git/$nr.git";
 124                         if (!writable_dir($edir)) {
 125                                 $skip->{$nr} = 1;
 126                                 next;
 127                         }
 128                         next if defined $git_url;
 129                         if (defined(my $url = remote_url($lei, $edir))) {
 130                                 $git_url = $url;
 131                                 $epoch = $nr;
 132                         } else {
 133                                 warn "W: $edir missing remote.*.url\n";
 134                                 my $pid = spawn([qw(git config -l)], undef,
 135                                         { 1 => $lei->{2}, 2 => $lei->{2} });
 136                                 waitpid($pid, 0);
 137                                 $lei->child_error($?) if $?;
 138                         }
 139                 }
 140                 @epochs = grep { !$skip->{$_} } @epochs if $skip;
 141                 $skip //= {}; # makes code below easier
 142                 $git_url or die "Unable to determine git URL\n";
 143                 my $inbox_url = $git_url;
 144                 $inbox_url =~ s!/git/$epoch(?:\.git)?/?\z!! or
 145                         $inbox_url =~ s!/$epoch(?:\.git)?/?\z!! or die <<EOM;
 146 Unable to infer inbox URL from <$git_url>
 147 EOM
 148                 $ibx_uri = URI->new($inbox_url);
 149         }
 150         PublicInbox::LeiMirror::write_makefile($dir, $ibx_ver);
 151         $lei->qerr("# inbox URL: $ibx_uri/");
 152         my $res = do_manifest($lei, $dir, $ibx_uri) or return;
 153         my ($code, $muri, $v1_path, $v2_epochs, $ft, $mf, $m1) = @$res;
 154         if ($code == 404) {
 155                 # any pre-manifest.js.gz instances running? Just fetch all
 156                 # existing ones and unconditionally try cloning the next
 157                 $v2_epochs = [ map { "$dir/git/$_.git" } @epochs ];
 158                 if (@epochs) {
 159                         my $n = $epochs[-1] + 1;
 160                         push @$v2_epochs, "$dir/git/$n.git" if !$skip->{$n};
 161                 }
 162         } else {
 163                 $code == 200 or die "BUG unexpected code $code\n";
 164         }
 165         my $mculled;
 166         if ($ibx_ver == 2) {
 167                 defined($v1_path) and warn <<EOM;
 168 E: got v1 `$v1_path' when expecting v2 epoch(s) in <$muri>, WTF?
 169 EOM
 170                 @git_dir = map { "$dir/git/$_.git" } sort { $a <=> $b } map {
 171                                 my ($nr) = (m!/([0-9]+)\.git\z!g);
 172                                 $skip->{$nr} ? () : $nr;
 173                         } @$v2_epochs;
 174                 if ($m1 && scalar keys %$skip) {
 175                         my $re = join('|', keys %$skip);
 176                         my @del = grep(m!/git/$re\.git\z!, keys %$m1);
 177                         delete @$m1{@del};
 178                         $mculled = 1;
 179                 }
 180         } else {
 181                 $git_dir[0] = $dir;
 182         }
 183         # n.b. this expects all epochs are from the same host
 184         my $torsocks = $lei->{curl}->torsocks($lei, $muri);
 185         my $fp2 = $lei->{opt}->{'exit-code'} ? [] : undef;
 186         my $xit = 127;
 187         for my $d (@git_dir) {
 188                 my $cmd;
 189                 my $opt = {}; # for spawn
 190                 if (-d $d) {
 191                         $fp2->[0] = get_fingerprint2($d) if $fp2;
 192                         $cmd = [ @$torsocks, 'git', "--git-dir=$d",
 193                                PublicInbox::LeiMirror::fetch_args($lei, $opt)];
 194                 } else {
 195                         my $e_uri = $ibx_uri->clone;
 196                         my ($epath) = ($d =~ m!(/git/[0-9]+\.git)\z!);
 197                         defined($epath) or
 198                                 die "BUG: $d is not an epoch to clone\n";
 199                         $e_uri->path($ibx_uri->path.$epath);
 200                         $cmd = [ @$torsocks,
 201                                 PublicInbox::LeiMirror::clone_cmd($lei, $opt),
 202                                 $$e_uri, $d];
 203                         push @new_epoch, substr($epath, 5, -4) + 0;
 204                         $xit = 0;
 205                 }
 206                 my $cerr = PublicInbox::LeiMirror::run_reap($lei, $cmd, $opt);
 207                 # do not bail on clone failure if we didn't have a manifest
 208                 if ($cerr && ($code == 200 || -d $d)) {
 209                         $lei->child_error($cerr, "@$cmd failed");
 210                         return;
 211                 }
 212                 if ($fp2 && $xit) {
 213                         $fp2->[1] = get_fingerprint2($d);
 214                         $xit = 0 if $fp2->[0] ne $fp2->[1];
 215                 }
 216         }
 217         for my $i (@new_epoch) { $mg->epoch_cfg_set($i) }
 218         if ($ft) {
 219                 PublicInbox::LeiMirror::dump_manifest($m1 => $ft) if $mculled;
 220                 PublicInbox::LeiMirror::ft_rename($ft, $mf, 0666);
 221         }
 222         $lei->child_error($xit << 8) if $fp2 && $xit;
 223 }
 224
 225 1;