lib/PublicInbox/Filter.pm

   1 # Copyright (C) 2013-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # This only exposes one function: run
   5 # Note: the settings here are highly opinionated.  Obviously, this is
   6 # Free Software (AGPLv3), so you may change it if you host yourself.
   7 package PublicInbox::Filter;
   8 use strict;
   9 use warnings;
  10 use Email::MIME;
  11 use Email::MIME::ContentType qw/parse_content_type/;
  12 use Email::Filter;
  13 use IPC::Run;
  14 our $VERSION = '0.0.1';
  15 use constant NO_HTML => '*** We only accept plain-text email, no HTML ***';
  16 use constant TEXT_ONLY => '*** We only accept plain-text email ***';
  17
  18 # start with the same defaults as mailman
  19 our $BAD_EXT = qr/\.(exe|bat|cmd|com|pif|scr|vbs|cpl|zip)\s*\z/i;
  20 our $MIME_HTML = qr!\btext/x?html\b!i;
  21 our $MIME_TEXT_ANY = qr!\btext/[a-z0-9\+\._-]+\b!i;
  22
  23 # this is highly opinionated delivery
  24 # returns 0 only if there is nothing to deliver
  25 sub run {
  26         my ($class, $mime, $filter) = @_;
  27
  28         my $content_type = $mime->header('Content-Type') || 'text/plain';
  29
  30         # kill potentially bad/confusing headers
  31         # Note: ssoma already does this, but since we mangle the message,
  32         # we should do this before it gets to ssoma.
  33         # We also kill Mail-{Followup,Reply}-To headers due to
  34         # the nature of public-inbox having no real subscribers.
  35         foreach my $d (qw(status lines content-length
  36                         mail-followup-to mail-reply-to)) {
  37                 $mime->header_set($d);
  38         }
  39
  40         if ($content_type =~ m!\btext/plain\b!i) {
  41                 return 1; # yay, nothing to do
  42         } elsif ($content_type =~ $MIME_HTML) {
  43                 $filter->reject(NO_HTML) if $filter;
  44                 # HTML-only, non-multipart
  45                 my $body = $mime->body;
  46                 my $ct_parsed = parse_content_type($content_type);
  47                 dump_html(\$body, $ct_parsed->{attributes}->{charset});
  48                 replace_body($mime, $body);
  49                 return 1;
  50         } elsif ($content_type =~ m!\bmultipart/!i) {
  51                 return strip_multipart($mime, $content_type, $filter);
  52         } else {
  53                 $filter->reject(TEXT_ONLY) if $filter;
  54                 replace_body($mime, "$content_type message scrubbed");
  55                 return 0;
  56         }
  57 }
  58
  59 sub replace_part {
  60         my ($mime, $part, $type) = ($_[0], $_[1], $_[3]);
  61         # don't copy $_[2], that's the body (it may be huge)
  62
  63         # Email::MIME insists on setting Date:, so just set it consistently
  64         # to avoid conflicts to avoid git merge conflicts in a split brain
  65         # situation.
  66         unless (defined $part->header('Date')) {
  67                 my $date = $mime->header('Date') ||
  68                            'Thu, 01 Jan 1970 00:00:00 +0000';
  69                 $part->header_set('Date', $date);
  70         }
  71
  72         $part->charset_set(undef);
  73         $part->name_set(undef);
  74         $part->filename_set(undef);
  75         $part->format_set(undef);
  76         $part->encoding_set('8bit');
  77         $part->disposition_set(undef);
  78         $part->content_type_set($type);
  79         $part->body_set($_[2]);
  80 }
  81
  82 # converts one part of a multipart message to text
  83 sub html_part_to_text {
  84         my ($mime, $part) = @_;
  85         my $body = $part->body;
  86         my $ct_parsed = parse_content_type($part->content_type);
  87         dump_html(\$body, $ct_parsed->{attributes}->{charset});
  88         replace_part($mime, $part, $body, 'text/plain');
  89 }
  90
  91 # modifies $_[0] in place
  92 sub dump_html {
  93         my ($body, $charset) = @_;
  94         $charset ||= 'US-ASCII';
  95         my @cmd = qw(lynx -stdin -stderr -dump);
  96         my $out = "";
  97         my $err = "";
  98
  99         # be careful about remote command injection!
 100         if ($charset =~ /\A([A-Za-z0-9\-]+)\z/) {
 101                 push @cmd, "-assume_charset=$charset";
 102         }
 103         if (IPC::Run::run(\@cmd, $body, \$out, \$err)) {
 104                 $out =~ s/\r\n/\n/sg;
 105                 $$body = $out;
 106         } else {
 107                 # give them an ugly version:
 108                 $$body = "public-inbox HTML conversion failed: $err\n" .
 109                          $$body . "\n";
 110         }
 111 }
 112
 113 # this is to correct old archives during import.
 114 sub strip_multipart {
 115         my ($mime, $content_type, $filter) = @_;
 116
 117         my (@html, @keep);
 118         my $rejected = 0;
 119         my $ok = 1;
 120
 121         # scan through all parts once
 122         $mime->walk_parts(sub {
 123                 my ($part) = @_;
 124                 return if $part->subparts; # walk_parts already recurses
 125
 126                 # some extensions are just bad, reject them outright
 127                 my $fn = $part->filename;
 128                 if (defined($fn) && $fn =~ $BAD_EXT) {
 129                         $filter->reject("Bad file type: $1") if $filter;
 130                         $rejected++;
 131                         return;
 132                 }
 133
 134                 my $part_type = $part->content_type || '';
 135                 if ($part_type =~ m!\btext/plain\b!i) {
 136                         push @keep, $part;
 137                 } elsif ($part_type =~ $MIME_HTML) {
 138                         $filter->reject(NO_HTML) if $filter;
 139                         push @html, $part;
 140                 } elsif ($part_type =~ $MIME_TEXT_ANY) {
 141                         # Give other text attachments the benefit of the doubt,
 142                         # here?  Could be source code or script the user wants
 143                         # help with.
 144
 145                         push @keep, $part;
 146                 } elsif ($part_type eq '' ||
 147                          $part_type =~ m!\bapplication/octet-stream\b!i) {
 148                         # unfortunately, some mailers don't set correct types,
 149                         # let messages of unknown type through but do not
 150                         # change the sender-specified type
 151                         if (recheck_type_ok($part)) {
 152                                 push @keep, $part;
 153                         } elsif ($filter) {
 154                                 $filter->reject(TEXT_ONLY);
 155                         } else {
 156                                 $rejected++;
 157                         }
 158                 } elsif ($part_type =~ m!\bapplication/pgp-signature\b!i) {
 159                         # PGP signatures are not huge, we may keep them.
 160                         # They can only be valid if it's the last element,
 161                         # so we keep them iff the message is unmodified:
 162                         if ($rejected == 0 && !@html) {
 163                                 push @keep, $part;
 164                         }
 165                 } else {
 166                         $filter->reject(TEXT_ONLY) if $filter;
 167                         # reject everything else, including non-PGP signatures
 168                         $rejected++;
 169                 }
 170         });
 171
 172         if ($content_type =~ m!\bmultipart/alternative\b!i) {
 173                 if (scalar @keep == 1) {
 174                         return collapse($mime, $keep[0]);
 175                 }
 176         } else { # convert HTML parts to plain text
 177                 foreach my $part (@html) {
 178                         html_part_to_text($mime, $part);
 179                         push @keep, $part;
 180                 }
 181         }
 182
 183         if (@keep == 0) {
 184                 @keep = (Email::MIME->create(
 185                         attributes => {
 186                                 content_type => 'text/plain',
 187                                 charset => 'US-ASCII',
 188                                 encoding => '8bit',
 189                         },
 190                         body_str => 'all attachments scrubbed by '. __PACKAGE__
 191                 ));
 192                 $ok = 0;
 193         }
 194         if (scalar(@html) || $rejected) {
 195                 $mime->parts_set(\@keep);
 196                 $mime->body_set($mime->body_raw);
 197                 mark_changed($mime);
 198         } # else: no changes
 199
 200         return $ok;
 201 }
 202
 203 sub mark_changed {
 204         my ($mime) = @_;
 205         $mime->header_set('X-Content-Filtered-By', __PACKAGE__ ." $VERSION");
 206 }
 207
 208 sub collapse {
 209         my ($mime, $part) = @_;
 210         $mime->header_set('Content-Type', $part->content_type);
 211         $mime->body_set($part->body_raw);
 212         my $cte = $part->header('Content-Transfer-Encoding');
 213         if (defined($cte) && $cte ne '') {
 214                 $mime->header_set('Content-Transfer-Encoding', $cte);
 215         }
 216         mark_changed($mime);
 217         return 1;
 218 }
 219
 220 sub replace_body {
 221         my $mime = $_[0];
 222         $mime->body_set($_[1]);
 223         $mime->header_set('Content-Type', 'text/plain');
 224         if ($mime->header('Content-Transfer-Encoding')) {
 225                 $mime->header_set('Content-Transfer-Encoding', undef);
 226         }
 227         mark_changed($mime);
 228 }
 229
 230 # Check for display-able text, no messed up binaries
 231 # Note: we can not rewrite the message with the detected mime type
 232 sub recheck_type_ok {
 233         my ($part) = @_;
 234         my $s = $part->body;
 235         ((length($s) < 0x10000) &&
 236                 ($s =~ /\A([\P{XPosixPrint}\f\n\r\t]+)\z/))
 237 }
 238
 239 1;