lib/PublicInbox/Filter/RubyLang.pm

   1 # Copyright (C) 2017-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Filter for lists.ruby-lang.org trailers
   5 package PublicInbox::Filter::RubyLang;
   6 use base qw(PublicInbox::Filter::Base);
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MID qw(mids);
  10
  11 my $l1 = qr/Unsubscribe:\s
  12         <mailto:ruby-\w+-request\@ruby-lang\.org\?subject=unsubscribe>/x;
  13 my $l2 = qr{<http://lists\.ruby-lang\.org/cgi-bin/mailman/options/ruby-\w+>};
  14
  15 sub new {
  16         my ($class, %opts) = @_;
  17         my $altid = delete $opts{-altid};
  18         my $self = $class->SUPER::new(%opts);
  19         my $ibx = $self->{-inbox};
  20         # altid = serial:ruby-core:file=msgmap.sqlite3
  21         if (!$altid && $ibx && $ibx->{altid}) {
  22                 $altid ||= $ibx->{altid}->[0];
  23         }
  24         if ($altid) {
  25                 require PublicInbox::MID; # mid_clean
  26                 require PublicInbox::AltId;
  27                 $self->{-altid} = PublicInbox::AltId->new($ibx, $altid, 1);
  28         }
  29         $self;
  30 }
  31
  32 sub scrub {
  33         my ($self, $mime, $for_remove) = @_;
  34         # no msg_iter here, that is only for read-only access
  35         $mime->walk_parts(sub {
  36                 my ($part) = $_[0];
  37                 my $ct = $part->content_type;
  38                 if (!$ct || $ct =~ m{\btext/plain\b}i) {
  39                         my $s = eval { $part->body_str };
  40                         if (defined $s && $s =~ s/\n?$l1\n$l2\n\z//os) {
  41                                 $part->body_str_set($s);
  42                         }
  43                 }
  44         });
  45         my $altid = $self->{-altid};
  46         if ($altid && !$for_remove) {
  47                 my $hdr = $mime->header_obj;
  48                 my $mids = mids($hdr);
  49                 return $self->REJECT('Message-ID missing') unless (@$mids);
  50                 my @v = $hdr->header_raw('X-Mail-Count');
  51                 my $n;
  52                 foreach (@v) {
  53                         /\A\s*([0-9]+)\s*\z/ or next;
  54                         $n = $1;
  55                         last;
  56                 }
  57                 unless (defined $n) {
  58                         return $self->REJECT('X-Mail-Count not numeric');
  59                 }
  60                 foreach my $mid (@$mids) {
  61                         my $r = $altid->mm_alt->mid_set($n, $mid);
  62                         next if $r == 0;
  63                         last;
  64                 }
  65         }
  66         $self->ACCEPT($mime);
  67 }
  68
  69 sub delivery {
  70         my ($self, $mime) = @_;
  71         $self->scrub($mime);
  72 }
  73
  74 1;