lib/PublicInbox/Filter/RubyLang.pm

   1 # Copyright (C) 2017-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Filter for lists.ruby-lang.org trailers
   5 package PublicInbox::Filter::RubyLang;
   6 use base qw(PublicInbox::Filter::Base);
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MID qw(mids);
  10
  11 my $l1 = qr/Unsubscribe:\s
  12         <mailto:ruby-\w+-request\@ruby-lang\.org\?subject=unsubscribe>/x;
  13 my $l2 = qr{<http://lists\.ruby-lang\.org/cgi-bin/mailman/options/ruby-\w+>};
  14
  15 sub new {
  16         my ($class, %opts) = @_;
  17         my $altid = delete $opts{-altid};
  18         my $self = $class->SUPER::new(%opts);
  19         my $ibx = $self->{-inbox};
  20         # altid = serial:ruby-core:file=msgmap.sqlite3
  21         if (!$altid && $ibx && $ibx->{altid}) {
  22                 $altid ||= $ibx->{altid}->[0];
  23         }
  24         if ($altid) {
  25                 require PublicInbox::AltId;
  26                 $self->{-altid} = PublicInbox::AltId->new($ibx, $altid, 1);
  27         }
  28         $self;
  29 }
  30
  31 sub scrub {
  32         my ($self, $mime, $for_remove) = @_;
  33         # no msg_iter here, that is only for read-only access
  34         $mime->walk_parts(sub {
  35                 my ($part) = $_[0];
  36                 my $ct = $part->content_type;
  37                 if (!$ct || $ct =~ m{\btext/plain\b}i) {
  38                         my $s = eval { $part->body_str };
  39                         if (defined $s && $s =~ s/\n?$l1\n$l2\n\z//os) {
  40                                 $part->body_str_set($s);
  41                         }
  42                 }
  43         });
  44         my $altid = $self->{-altid};
  45         if ($altid && !$for_remove) {
  46                 my $hdr = $mime->header_obj;
  47                 my $mids = mids($hdr);
  48                 return $self->REJECT('Message-ID missing') unless (@$mids);
  49                 my @v = $hdr->header_raw('X-Mail-Count');
  50                 my $n;
  51                 foreach (@v) {
  52                         /\A\s*([0-9]+)\s*\z/ or next;
  53                         $n = $1;
  54                         last;
  55                 }
  56                 unless (defined $n) {
  57                         return $self->REJECT('X-Mail-Count not numeric');
  58                 }
  59                 foreach my $mid (@$mids) {
  60                         my $r = $altid->mm_alt->mid_set($n, $mid);
  61                         next if $r == 0;
  62                         last;
  63                 }
  64         }
  65         $self->ACCEPT($mime);
  66 }
  67
  68 sub delivery {
  69         my ($self, $mime) = @_;
  70         $self->scrub($mime);
  71 }
  72
  73 1;