lib/PublicInbox/Filter/RubyLang.pm

   1 # Copyright (C) 2017-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Filter for lists.ruby-lang.org trailers
   5 package PublicInbox::Filter::RubyLang;
   6 use base qw(PublicInbox::Filter::Base);
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MID qw(mids);
  10
  11 my $l1 = qr/Unsubscribe:\s
  12         <mailto:ruby-\w+-request\@ruby-lang\.org\?subject=unsubscribe>/x;
  13 my $l2 = qr{<http://lists\.ruby-lang\.org/cgi-bin/mailman/options/ruby-\w+>};
  14
  15 sub new {
  16         my ($class, %opts) = @_;
  17         my $altid = delete $opts{-altid};
  18         my $self = $class->SUPER::new(%opts);
  19         my $ibx = $self->{ibx};
  20         # altid = serial:ruby-core:file=msgmap.sqlite3
  21         if (!$altid && $ibx && $ibx->{altid}) {
  22                 $altid ||= $ibx->{altid}->[0];
  23         }
  24         if ($altid) {
  25                 require PublicInbox::AltId;
  26                 $self->{-altid} = PublicInbox::AltId->new($ibx, $altid, 1);
  27         }
  28         $self;
  29 }
  30
  31 sub scrub_part ($) {
  32         my ($part) = @_;
  33         my $ct = $part->content_type;
  34         if (!$ct || $ct =~ m{\btext/plain\b}i) {
  35                 my $s = eval { $part->body_str };
  36                 if (defined $s && $s =~ s/\n?$l1\n$l2\n\z//os) {
  37                         $part->body_str_set($s);
  38                         return 1;
  39                 }
  40         }
  41         0;
  42 }
  43
  44 sub scrub {
  45         my ($self, $mime, $for_remove) = @_;
  46         # no msg_iter here, msg_iter is only for read-only access
  47         if (my @sub = $mime->subparts) {
  48                 my $changed = 0;
  49                 $changed |= scrub_part($_) for @sub;
  50                 $mime->parts_set(\@sub) if $changed;
  51         } else {
  52                 scrub_part($mime);
  53         }
  54         my $altid = $self->{-altid};
  55         if ($altid && !$for_remove) {
  56                 my $hdr = $mime->header_obj;
  57                 my $mids = mids($hdr);
  58                 return $self->REJECT('Message-ID missing') unless (@$mids);
  59                 my @v = $hdr->header_raw('X-Mail-Count');
  60                 my $n;
  61                 foreach (@v) {
  62                         /\A\s*([0-9]+)\s*\z/ or next;
  63                         $n = $1;
  64                         last;
  65                 }
  66                 unless (defined $n) {
  67                         return $self->REJECT('X-Mail-Count not numeric');
  68                 }
  69                 foreach my $mid (@$mids) {
  70                         my $r = $altid->mm_alt->mid_set($n, $mid);
  71                         next if $r == 0;
  72                         last;
  73                 }
  74         }
  75         $self->ACCEPT($mime);
  76 }
  77
  78 sub delivery {
  79         my ($self, $mime) = @_;
  80         $self->scrub($mime);
  81 }
  82
  83 1;