lib/PublicInbox/Gcf2.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # backend for a git-cat-file-workalike based on libgit2,
   5 # other libgit2 stuff may go here, too.
   6 package PublicInbox::Gcf2;
   7 use strict;
   8 use v5.10.1;
   9 use PublicInbox::Spawn qw(which popen_rd); # may set PERL_INLINE_DIRECTORY
  10 use Fcntl qw(LOCK_EX);
  11 use IO::Handle; # autoflush
  12 my (%CFG, $c_src, $lockfh);
  13 BEGIN {
  14         # PublicInbox::Spawn will set PERL_INLINE_DIRECTORY
  15         # to ~/.cache/public-inbox/inline-c if it exists
  16         my $inline_dir = $ENV{PERL_INLINE_DIRECTORY} //
  17                 die 'PERL_INLINE_DIRECTORY not defined';
  18         my $f = "$inline_dir/.public-inbox.lock";
  19         open $lockfh, '>', $f or die "failed to open $f: $!\n";
  20         my $pc = which($ENV{PKG_CONFIG} // 'pkg-config') //
  21                 die "pkg-config missing for libgit2";
  22         my ($dir) = (__FILE__ =~ m!\A(.+?)/[^/]+\z!);
  23         my $rdr = {};
  24         open $rdr->{2}, '>', '/dev/null' or die "open /dev/null: $!";
  25         for my $x (qw(libgit2)) {
  26                 my $l = popen_rd([$pc, '--libs', $x], undef, $rdr);
  27                 $l = do { local $/; <$l> };
  28                 next if $?;
  29                 my $c = popen_rd([$pc, '--cflags', $x], undef, $rdr);
  30                 $c = do { local $/; <$c> };
  31                 next if $?;
  32
  33                 # note: we name C source files .h to prevent
  34                 # ExtUtils::MakeMaker from automatically trying to
  35                 # build them.
  36                 my $f = "$dir/gcf2_$x.h";
  37                 if (open(my $fh, '<', $f)) {
  38                         chomp($l, $c);
  39                         local $/;
  40                         defined($c_src = <$fh>) or die "read $f: $!\n";
  41                         $CFG{LIBS} = $l;
  42                         $CFG{CCFLAGSEX} = $c;
  43                         last;
  44                 } else {
  45                         die "E: $f: $!\n";
  46                 }
  47         }
  48         die "E: libgit2 not installed\n" unless $c_src;
  49
  50         # CentOS 7.x ships Inline 0.53, 0.64+ has built-in locking
  51         flock($lockfh, LOCK_EX) or die "LOCK_EX failed on $f: $!\n";
  52 }
  53
  54 # we use Capitalized and ALLCAPS for compatibility with old Inline::C
  55 use Inline C => Config => %CFG, BOOT => 'git_libgit2_init();';
  56 use Inline C => $c_src;
  57 undef $c_src;
  58 undef %CFG;
  59 undef $lockfh;
  60
  61 sub add_alt ($$) {
  62         my ($gcf2, $objdir) = @_;
  63
  64         # libgit2 (tested 0.27.7+dfsg.1-0.2 and 0.28.3+dfsg.1-1~bpo10+1
  65         # in Debian) doesn't handle relative epochs properly when nested
  66         # multiple levels.  Add all the absolute paths to workaround it,
  67         # since $EXTINDEX_DIR/ALL.git/objects/info/alternates uses absolute
  68         # paths to reference $V2INBOX_DIR/all.git/objects and
  69         # $V2INBOX_DIR/all.git/objects/info/alternates uses relative paths
  70         # to refer to $V2INBOX_DIR/git/$EPOCH.git/objects
  71         #
  72         # See https://bugs.debian.org/975607
  73         if (open(my $fh, '<', "$objdir/info/alternates")) {
  74                 chomp(my @abs_alt = grep(m!^/!, <$fh>));
  75                 $gcf2->add_alternate($_) for @abs_alt;
  76         }
  77         $gcf2->add_alternate($objdir);
  78         1;
  79 }
  80
  81 # Usage: $^X -MPublicInbox::Gcf2 -e PublicInbox::Gcf2::loop
  82 # (see lib/PublicInbox/Gcf2Client.pm)
  83 sub loop () {
  84         my $gcf2 = new();
  85         my %seen;
  86         STDERR->autoflush(1);
  87         STDOUT->autoflush(1);
  88
  89         while (<STDIN>) {
  90                 chomp;
  91                 my ($oid, $git_dir) = split(/ /, $_, 2);
  92                 $seen{$git_dir} //= add_alt($gcf2, "$git_dir/objects");
  93                 if (!$gcf2->cat_oid(1, $oid)) {
  94                         # retry once if missing.  We only get unabbreviated OIDs
  95                         # from SQLite or Xapian DBs, here, so malicious clients
  96                         # can't trigger excessive retries:
  97                         warn "I: $$ $oid missing, retrying in $git_dir\n";
  98
  99                         $gcf2 = new();
 100                         %seen = ($git_dir => add_alt($gcf2,"$git_dir/objects"));
 101
 102                         if ($gcf2->cat_oid(1, $oid)) {
 103                                 warn "I: $$ $oid found after retry\n";
 104                         } else {
 105                                 warn "W: $$ $oid missing after retry\n";
 106                                 print "$oid missing\n"; # mimic git-cat-file
 107                         }
 108                 }
 109         }
 110 }
 111
 112 1;