lib/PublicInbox/Git.pm

   1 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
   2 # License: GPLv2 or later <https://www.gnu.org/licenses/gpl-2.0.txt>
   3 #
   4 # Used to read files from a git repository without excessive forking.
   5 # Used in our web interfaces as well as our -nntpd server.
   6 # This is based on code in Git.pm which is GPLv2+, but modified to avoid
   7 # dependence on environment variables for compatibility with mod_perl.
   8 # There are also API changes to simplify our usage and data set.
   9 package PublicInbox::Git;
  10 use strict;
  11 use warnings;
  12 use POSIX ();
  13 use IO::Handle; # ->autoflush
  14 use File::Glob qw(bsd_glob GLOB_NOSORT);
  15 use PublicInbox::Spawn qw(popen_rd);
  16 use PublicInbox::Tmpfile;
  17 use base qw(Exporter);
  18 our @EXPORT_OK = qw(git_unquote git_quote);
  19
  20 use constant MAX_INFLIGHT =>
  21         ($^O eq 'linux' ? 4096 : POSIX::_POSIX_PIPE_BUF())
  22         /
  23         65; # SHA-256 hex size + "\n" in preparation for git using non-SHA1
  24
  25 my %GIT_ESC = (
  26         a => "\a",
  27         b => "\b",
  28         f => "\f",
  29         n => "\n",
  30         r => "\r",
  31         t => "\t",
  32         v => "\013",
  33         '"' => '"',
  34         '\\' => '\\',
  35 );
  36 my %ESC_GIT = map { $GIT_ESC{$_} => $_ } keys %GIT_ESC;
  37
  38
  39 # unquote pathnames used by git, see quote.c::unquote_c_style.c in git.git
  40 sub git_unquote ($) {
  41         return $_[0] unless ($_[0] =~ /\A"(.*)"\z/);
  42         $_[0] = $1;
  43         $_[0] =~ s/\\([\\"abfnrtv])/$GIT_ESC{$1}/g;
  44         $_[0] =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  45         $_[0];
  46 }
  47
  48 sub git_quote ($) {
  49         if ($_[0] =~ s/([\\"\a\b\f\n\r\t\013]|[^[:print:]])/
  50                       '\\'.($ESC_GIT{$1}||sprintf("%0o",ord($1)))/egs) {
  51                 return qq{"$_[0]"};
  52         }
  53         $_[0];
  54 }
  55
  56 sub new {
  57         my ($class, $git_dir) = @_;
  58         # may contain {-tmp} field for File::Temp::Dir
  59         bless { git_dir => $git_dir, alt_st => '', -git_path => {} }, $class
  60 }
  61
  62 sub git_path ($$) {
  63         my ($self, $path) = @_;
  64         $self->{-git_path}->{$path} ||= do {
  65                 local $/ = "\n";
  66                 chomp(my $str = $self->qx(qw(rev-parse --git-path), $path));
  67
  68                 # git prior to 2.5.0 did not understand --git-path
  69                 if ($str eq "--git-path\n$path") {
  70                         $str = "$self->{git_dir}/$path";
  71                 }
  72                 $str;
  73         };
  74 }
  75
  76 sub alternates_changed {
  77         my ($self) = @_;
  78         my $alt = git_path($self, 'objects/info/alternates');
  79         my @st = stat($alt) or return 0;
  80
  81         # can't rely on 'q' on some 32-bit builds, but `d' works
  82         my $st = pack('dd', $st[10], $st[7]); # 10: ctime, 7: size
  83         return 0 if $self->{alt_st} eq $st;
  84         $self->{alt_st} = $st; # always a true value
  85 }
  86
  87 sub last_check_err {
  88         my ($self) = @_;
  89         my $fh = $self->{err_c} or return;
  90         sysseek($fh, 0, 0) or fail($self, "sysseek failed: $!");
  91         defined(sysread($fh, my $buf, -s $fh)) or
  92                         fail($self, "sysread failed: $!");
  93         $buf;
  94 }
  95
  96 sub _bidi_pipe {
  97         my ($self, $batch, $in, $out, $pid, $err) = @_;
  98         if ($self->{$pid}) {
  99                 if (defined $err) { # "err_c"
 100                         my $fh = $self->{$err};
 101                         sysseek($fh, 0, 0) or fail($self, "sysseek failed: $!");
 102                         truncate($fh, 0) or fail($self, "truncate failed: $!");
 103                 }
 104                 return;
 105         }
 106         my ($out_r, $out_w);
 107         pipe($out_r, $out_w) or fail($self, "pipe failed: $!");
 108         my @cmd = (qw(git), "--git-dir=$self->{git_dir}",
 109                         qw(-c core.abbrev=40 cat-file), $batch);
 110         my $redir = { 0 => $out_r };
 111         if ($err) {
 112                 my $id = "git.$self->{git_dir}$batch.err";
 113                 my $fh = tmpfile($id) or fail($self, "tmpfile($id): $!");
 114                 $self->{$err} = $fh;
 115                 $redir->{2} = $fh;
 116         }
 117         my ($in_r, $p) = popen_rd(\@cmd, undef, $redir);
 118         $self->{$pid} = $p;
 119         $out_w->autoflush(1);
 120         if ($^O eq 'linux') { # 1031: F_SETPIPE_SZ
 121                 fcntl($out_w, 1031, 4096);
 122                 fcntl($in_r, 1031, 4096) if $batch eq '--batch-check';
 123         }
 124         $self->{$out} = $out_w;
 125         $self->{$in} = $in_r;
 126 }
 127
 128 sub read_cat_in_full ($$) {
 129         my ($self, $len) = @_;
 130         ++$len; # for final "\n" added by git
 131         read($self->{in}, my $buf, $len) == $len or fail($self, 'short read');
 132         chop($buf) eq "\n" or fail($self, 'newline missing after blob');
 133         \$buf;
 134 }
 135
 136 sub _cat_async_step ($$) {
 137         my ($self, $inflight) = @_;
 138         my $pair = shift @$inflight or die 'BUG: inflight empty';
 139         my ($cb, $arg) = @$pair;
 140         local $/ = "\n";
 141         my $head = readline($self->{in});
 142         $head =~ / missing$/ and return
 143                 eval { $cb->(undef, undef, undef, undef, $arg) };
 144
 145         $head =~ /^([0-9a-f]{40}) (\S+) ([0-9]+)$/ or
 146                 fail($self, "Unexpected result from async git cat-file: $head");
 147         my ($oid_hex, $type, $size) = ($1, $2, $3 + 0);
 148         my $bref = read_cat_in_full($self, $size);
 149         eval { $cb->($bref, $oid_hex, $type, $size, $arg) };
 150 }
 151
 152 sub cat_async_wait ($) {
 153         my ($self) = @_;
 154         my $inflight = delete $self->{inflight} or return;
 155         while (scalar(@$inflight)) {
 156                 _cat_async_step($self, $inflight);
 157         }
 158 }
 159
 160 sub cat_file {
 161         my ($self, $obj, $ref) = @_;
 162         my ($retried, $head);
 163         cat_async_wait($self);
 164 again:
 165         batch_prepare($self);
 166         print { $self->{out} } $obj, "\n" or fail($self, "write error: $!");
 167
 168         local $/ = "\n";
 169         $head = readline($self->{in});
 170         if ($head =~ / missing$/) {
 171                 if (!$retried && alternates_changed($self)) {
 172                         $retried = 1;
 173                         cleanup($self);
 174                         goto again;
 175                 }
 176                 return;
 177         }
 178         $head =~ /^[0-9a-f]{40} \S+ ([0-9]+)$/ or
 179                 fail($self, "Unexpected result from git cat-file: $head");
 180
 181         my $size = $1;
 182         $$ref = $size if $ref;
 183         read_cat_in_full($self, $size);
 184 }
 185
 186 sub batch_prepare ($) { _bidi_pipe($_[0], qw(--batch in out pid)) }
 187
 188 sub check {
 189         my ($self, $obj) = @_;
 190         _bidi_pipe($self, qw(--batch-check in_c out_c pid_c err_c));
 191         print { $self->{out_c} } $obj, "\n" or fail($self, "write error: $!");
 192         local $/ = "\n";
 193         chomp(my $line = readline($self->{in_c}));
 194         my ($hex, $type, $size) = split(' ', $line);
 195
 196         # Future versions of git.git may show 'ambiguous', but for now,
 197         # we must handle 'dangling' below (and maybe some other oddball
 198         # stuff):
 199         # https://public-inbox.org/git/20190118033845.s2vlrb3wd3m2jfzu@dcvr/T/
 200         return if $type eq 'missing' || $type eq 'ambiguous';
 201
 202         if ($hex eq 'dangling' || $hex eq 'notdir' || $hex eq 'loop') {
 203                 $size = $type + length("\n");
 204                 my $r = read($self->{in_c}, my $buf, $size);
 205                 defined($r) or fail($self, "read failed: $!");
 206                 return;
 207         }
 208
 209         ($hex, $type, $size);
 210 }
 211
 212 sub _destroy {
 213         my ($self, $in, $out, $pid, $err) = @_;
 214         my $p = delete $self->{$pid} or return;
 215         delete @$self{($in, $out)};
 216         delete $self->{$err} if $err; # `err_c'
 217
 218         # PublicInbox::DS may not be loaded
 219         eval { PublicInbox::DS::dwaitpid($p, undef, undef) };
 220         waitpid($p, 0) if $@; # wait synchronously if not in event loop
 221 }
 222
 223 sub cat_async_abort ($) {
 224         my ($self) = @_;
 225         my $inflight = delete $self->{inflight} or die 'BUG: not in async';
 226         cleanup($self);
 227 }
 228
 229 sub fail {
 230         my ($self, $msg) = @_;
 231         $self->{inflight} ? cat_async_abort($self) : cleanup($self);
 232         die $msg;
 233 }
 234
 235 sub popen {
 236         my ($self, @cmd) = @_;
 237         @cmd = ('git', "--git-dir=$self->{git_dir}", @cmd);
 238         popen_rd(\@cmd);
 239 }
 240
 241 sub qx {
 242         my ($self, @cmd) = @_;
 243         my $fh = $self->popen(@cmd);
 244         local $/ = "\n";
 245         return <$fh> if wantarray;
 246         local $/;
 247         <$fh>
 248 }
 249
 250 # returns true if there are pending "git cat-file" processes
 251 sub cleanup {
 252         my ($self) = @_;
 253         _destroy($self, qw(in out pid));
 254         _destroy($self, qw(in_c out_c pid_c err_c));
 255         !!($self->{pid} || $self->{pid_c});
 256 }
 257
 258 # assuming a well-maintained repo, this should be a somewhat
 259 # accurate estimation of its size
 260 # TODO: show this in the WWW UI as a hint to potential cloners
 261 sub packed_bytes {
 262         my ($self) = @_;
 263         my $n = 0;
 264         my $pack_dir = git_path($self, 'objects/pack');
 265         foreach my $p (bsd_glob("$pack_dir/*.pack", GLOB_NOSORT)) {
 266                 $n += -s $p;
 267         }
 268         $n
 269 }
 270
 271 sub DESTROY { cleanup(@_) }
 272
 273 sub local_nick ($) {
 274         my ($self) = @_;
 275         my $ret = '???';
 276         # don't show full FS path, basename should be OK:
 277         if ($self->{git_dir} =~ m!/([^/]+)(?:/\.git)?\z!) {
 278                 $ret = "/path/to/$1";
 279         }
 280         wantarray ? ($ret) : $ret;
 281 }
 282
 283 sub host_prefix_url ($$) {
 284         my ($env, $url) = @_;
 285         return $url if index($url, '//') >= 0;
 286         my $scheme = $env->{'psgi.url_scheme'};
 287         my $host_port = $env->{HTTP_HOST} //
 288                 "$env->{SERVER_NAME}:$env->{SERVER_PORT}";
 289         "$scheme://$host_port". ($env->{SCRIPT_NAME} || '/') . $url;
 290 }
 291
 292 sub pub_urls {
 293         my ($self, $env) = @_;
 294         if (my $urls = $self->{cgit_url}) {
 295                 return map { host_prefix_url($env, $_) } @$urls;
 296         }
 297         local_nick($self);
 298 }
 299
 300 sub cat_async_begin {
 301         my ($self) = @_;
 302         cleanup($self) if alternates_changed($self);
 303         batch_prepare($self);
 304         die 'BUG: already in async' if $self->{inflight};
 305         $self->{inflight} = [];
 306 }
 307
 308 sub cat_async ($$$;$) {
 309         my ($self, $oid, $cb, $arg) = @_;
 310         my $inflight = $self->{inflight} or die 'BUG: not in async';
 311         if (scalar(@$inflight) >= MAX_INFLIGHT) {
 312                 _cat_async_step($self, $inflight);
 313         }
 314
 315         print { $self->{out} } $oid, "\n" or fail($self, "write error: $!");
 316         push(@$inflight, [ $cb, $arg ]);
 317 }
 318
 319 sub extract_cmt_time {
 320         my ($bref, undef, undef, undef, $modified) = @_;
 321
 322         if ($$bref =~ /^committer .*?> ([0-9]+) [\+\-]?[0-9]+/sm) {
 323                 my $cmt_time = $1 + 0;
 324                 $$modified = $cmt_time if $cmt_time > $$modified;
 325         }
 326 }
 327
 328 # returns the modified time of a git repo, same as the "modified" field
 329 # of a grokmirror manifest
 330 sub modified ($) {
 331         my ($self) = @_;
 332         my $modified = 0;
 333         my $fh = popen($self, qw(rev-parse --branches));
 334         cat_async_begin($self);
 335         local $/ = "\n";
 336         while (my $oid = <$fh>) {
 337                 chomp $oid;
 338                 cat_async($self, $oid, \&extract_cmt_time, \$modified);
 339         }
 340         cat_async_wait($self);
 341         $modified || time;
 342 }
 343
 344 1;
 345 __END__
 346 =pod
 347
 348 =head1 NAME
 349
 350 PublicInbox::Git - git wrapper
 351
 352 =head1 VERSION
 353
 354 version 1.0
 355
 356 =head1 SYNOPSIS
 357
 358         use PublicInbox::Git;
 359         chomp(my $git_dir = `git rev-parse --git-dir`);
 360         $git_dir or die "GIT_DIR= must be specified\n";
 361         my $git = PublicInbox::Git->new($git_dir);
 362
 363 =head1 DESCRIPTION
 364
 365 Unstable API outside of the L</new> method.
 366 It requires L<git(1)> to be installed.
 367
 368 =head1 METHODS
 369
 370 =cut
 371
 372 =head2 new
 373
 374         my $git = PublicInbox::Git->new($git_dir);
 375
 376 Initialize a new PublicInbox::Git object for use with L<PublicInbox::Import>
 377 This is the only public API method we support.  Everything else
 378 in this module is subject to change.
 379
 380 =head1 SEE ALSO
 381
 382 L<Git>, L<PublicInbox::Import>
 383
 384 =head1 CONTACT
 385
 386 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 387
 388 The mail archives are hosted at L<https://public-inbox.org/meta/>
 389
 390 =head1 COPYRIGHT
 391
 392 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 393
 394 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 395
 396 =cut