lib/PublicInbox/Git.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: GPLv2 or later (https://www.gnu.org/licenses/gpl-2.0.txt)
   3 #
   4 # Used to read files from a git repository without excessive forking.
   5 # Used in our web interfaces as well as our -nntpd server.
   6 # This is based on code in Git.pm which is GPLv2+, but modified to avoid
   7 # dependence on environment variables for compatibility with mod_perl.
   8 # There are also API changes to simplify our usage and data set.
   9 package PublicInbox::Git;
  10 use strict;
  11 use warnings;
  12 use POSIX qw(dup2);
  13 require IO::Handle;
  14 use PublicInbox::Spawn qw(spawn popen_rd);
  15
  16 sub new {
  17         my ($class, $git_dir) = @_;
  18         bless { git_dir => $git_dir }, $class
  19 }
  20
  21 sub _bidi_pipe {
  22         my ($self, $batch, $in, $out, $pid) = @_;
  23         return if $self->{$pid};
  24         my ($in_r, $in_w, $out_r, $out_w);
  25
  26         pipe($in_r, $in_w) or fail($self, "pipe failed: $!");
  27         pipe($out_r, $out_w) or fail($self, "pipe failed: $!");
  28
  29         my @cmd = ('git', "--git-dir=$self->{git_dir}", qw(cat-file), $batch);
  30         my $redir = { 0 => fileno($out_r), 1 => fileno($in_w) };
  31         my $p = spawn(\@cmd, undef, $redir);
  32         defined $p or fail($self, "spawn failed: $!");
  33         $self->{$pid} = $p;
  34         $out_w->autoflush(1);
  35         $self->{$out} = $out_w;
  36         $self->{$in} = $in_r;
  37 }
  38
  39 sub cat_file {
  40         my ($self, $obj, $ref) = @_;
  41
  42         batch_prepare($self);
  43         $self->{out}->print($obj, "\n") or fail($self, "write error: $!");
  44
  45         my $in = $self->{in};
  46         local $/ = "\n";
  47         my $head = $in->getline;
  48         $head =~ / missing$/ and return undef;
  49         $head =~ /^[0-9a-f]{40} \S+ (\d+)$/ or
  50                 fail($self, "Unexpected result from git cat-file: $head");
  51
  52         my $size = $1;
  53         my $ref_type = $ref ? ref($ref) : '';
  54
  55         my $rv;
  56         my $left = $size;
  57         $$ref = $size if ($ref_type eq 'SCALAR');
  58         my $cb_err;
  59
  60         if ($ref_type eq 'CODE') {
  61                 $rv = eval { $ref->($in, \$left) };
  62                 $cb_err = $@;
  63                 # drain the rest
  64                 my $max = 8192;
  65                 while ($left > 0) {
  66                         my $r = read($in, my $x, $left > $max ? $max : $left);
  67                         defined($r) or fail($self, "read failed: $!");
  68                         $r == 0 and fail($self, 'exited unexpectedly');
  69                         $left -= $r;
  70                 }
  71         } else {
  72                 my $offset = 0;
  73                 my $buf = '';
  74                 while ($left > 0) {
  75                         my $r = read($in, $buf, $left, $offset);
  76                         defined($r) or fail($self, "read failed: $!");
  77                         $r == 0 and fail($self, 'exited unexpectedly');
  78                         $left -= $r;
  79                         $offset += $r;
  80                 }
  81                 $rv = \$buf;
  82         }
  83
  84         my $r = read($in, my $buf, 1);
  85         defined($r) or fail($self, "read failed: $!");
  86         fail($self, 'newline missing after blob') if ($r != 1 || $buf ne "\n");
  87         die $cb_err if $cb_err;
  88
  89         $rv;
  90 }
  91
  92 sub batch_prepare ($) { _bidi_pipe($_[0], qw(--batch in out pid)) }
  93
  94 sub check {
  95         my ($self, $obj) = @_;
  96         $self->_bidi_pipe(qw(--batch-check in_c out_c pid_c));
  97         $self->{out_c}->print($obj, "\n") or fail($self, "write error: $!");
  98         local $/ = "\n";
  99         chomp(my $line = $self->{in_c}->getline);
 100         my ($hex, $type, $size) = split(' ', $line);
 101         return if $type eq 'missing';
 102         ($hex, $type, $size);
 103 }
 104
 105 sub _destroy {
 106         my ($self, $in, $out, $pid) = @_;
 107         my $p = delete $self->{$pid} or return;
 108         foreach my $f ($in, $out) {
 109                 delete $self->{$f};
 110         }
 111         waitpid $p, 0;
 112 }
 113
 114 sub fail {
 115         my ($self, $msg) = @_;
 116         cleanup($self);
 117         die $msg;
 118 }
 119
 120 sub popen {
 121         my ($self, @cmd) = @_;
 122         @cmd = ('git', "--git-dir=$self->{git_dir}", @cmd);
 123         popen_rd(\@cmd);
 124 }
 125
 126 sub qx {
 127         my ($self, @cmd) = @_;
 128         my $fh = $self->popen(@cmd);
 129         defined $fh or return;
 130         local $/ = "\n";
 131         return <$fh> if wantarray;
 132         local $/;
 133         <$fh>
 134 }
 135
 136 sub cleanup {
 137         my ($self) = @_;
 138         _destroy($self, qw(in out pid));
 139         _destroy($self, qw(in_c out_c pid_c));
 140 }
 141
 142 sub DESTROY { cleanup(@_) }
 143
 144 1;
 145 __END__
 146 =pod
 147
 148 =head1 NAME
 149
 150 PublicInbox::Git - git wrapper
 151
 152 =head1 VERSION
 153
 154 version 1.0
 155
 156 =head1 SYNOPSIS
 157
 158         use PublicInbox::Git;
 159         chomp(my $git_dir = `git rev-parse --git-dir`);
 160         $git_dir or die "GIT_DIR= must be specified\n";
 161         my $git = PublicInbox::Git->new($git_dir);
 162
 163 =head1 DESCRIPTION
 164
 165 Unstable API outside of the L</new> method.
 166 It requires L<git(1)> to be installed.
 167
 168 =head1 METHODS
 169
 170 =cut
 171
 172 =head2 new
 173
 174         my $git = PublicInbox::Git->new($git_dir);
 175
 176 Initialize a new PublicInbox::Git object for use with L<PublicInbox::Import>
 177 This is the only public API method we support.  Everything else
 178 in this module is subject to change.
 179
 180 =head1 SEE ALSO
 181
 182 L<Git>, L<PublicInbox::Import>
 183
 184 =head1 CONTACT
 185
 186 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 187
 188 The mail archives are hosted at L<https://public-inbox.org/meta/>
 189
 190 =head1 COPYRIGHT
 191
 192 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 193
 194 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 195
 196 =cut