lib/PublicInbox/Git.pm

   1 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
   2 # License: GPLv2 or later <https://www.gnu.org/licenses/gpl-2.0.txt>
   3 #
   4 # Used to read files from a git repository without excessive forking.
   5 # Used in our web interfaces as well as our -nntpd server.
   6 # This is based on code in Git.pm which is GPLv2+, but modified to avoid
   7 # dependence on environment variables for compatibility with mod_perl.
   8 # There are also API changes to simplify our usage and data set.
   9 package PublicInbox::Git;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(Exporter);
  13 use POSIX ();
  14 use IO::Handle; # ->autoflush
  15 use Errno qw(EINTR EAGAIN);
  16 use File::Glob qw(bsd_glob GLOB_NOSORT);
  17 use File::Spec ();
  18 use Time::HiRes qw(stat);
  19 use PublicInbox::Spawn qw(popen_rd);
  20 use PublicInbox::Tmpfile;
  21 use IO::Poll qw(POLLIN);
  22 use Carp qw(croak);
  23 use Digest::SHA ();
  24 use PublicInbox::DS qw(dwaitpid);
  25 our @EXPORT_OK = qw(git_unquote git_quote);
  26 our $PIPE_BUFSIZ = 65536; # Linux default
  27 our $in_cleanup;
  28 our $RDTIMEO = 60_000; # milliseconds
  29
  30 use constant MAX_INFLIGHT =>
  31         (($^O eq 'linux' ? 4096 : POSIX::_POSIX_PIPE_BUF()) * 3)
  32         /
  33         65; # SHA-256 hex size + "\n" in preparation for git using non-SHA1
  34
  35 my %GIT_ESC = (
  36         a => "\a",
  37         b => "\b",
  38         f => "\f",
  39         n => "\n",
  40         r => "\r",
  41         t => "\t",
  42         v => "\013",
  43         '"' => '"',
  44         '\\' => '\\',
  45 );
  46 my %ESC_GIT = map { $GIT_ESC{$_} => $_ } keys %GIT_ESC;
  47
  48
  49 # unquote pathnames used by git, see quote.c::unquote_c_style.c in git.git
  50 sub git_unquote ($) {
  51         return $_[0] unless ($_[0] =~ /\A"(.*)"\z/);
  52         $_[0] = $1;
  53         $_[0] =~ s/\\([\\"abfnrtv])/$GIT_ESC{$1}/g;
  54         $_[0] =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  55         $_[0];
  56 }
  57
  58 sub git_quote ($) {
  59         if ($_[0] =~ s/([\\"\a\b\f\n\r\t\013]|[^[:print:]])/
  60                       '\\'.($ESC_GIT{$1}||sprintf("%0o",ord($1)))/egs) {
  61                 return qq{"$_[0]"};
  62         }
  63         $_[0];
  64 }
  65
  66 sub new {
  67         my ($class, $git_dir) = @_;
  68         # may contain {-tmp} field for File::Temp::Dir
  69         bless { git_dir => $git_dir, alt_st => '', -git_path => {} }, $class
  70 }
  71
  72 sub git_path ($$) {
  73         my ($self, $path) = @_;
  74         $self->{-git_path}->{$path} ||= do {
  75                 local $/ = "\n";
  76                 chomp(my $str = $self->qx(qw(rev-parse --git-path), $path));
  77
  78                 # git prior to 2.5.0 did not understand --git-path
  79                 if ($str eq "--git-path\n$path") {
  80                         $str = "$self->{git_dir}/$path";
  81                 }
  82                 $str;
  83         };
  84 }
  85
  86 sub alternates_changed {
  87         my ($self) = @_;
  88         my $alt = git_path($self, 'objects/info/alternates');
  89         my @st = stat($alt) or return 0;
  90
  91         # can't rely on 'q' on some 32-bit builds, but `d' works
  92         my $st = pack('dd', $st[10], $st[7]); # 10: ctime, 7: size
  93         return 0 if $self->{alt_st} eq $st;
  94         $self->{alt_st} = $st; # always a true value
  95 }
  96
  97 sub last_check_err {
  98         my ($self) = @_;
  99         my $fh = $self->{err_c} or return;
 100         sysseek($fh, 0, 0) or $self->fail("sysseek failed: $!");
 101         defined(sysread($fh, my $buf, -s $fh)) or
 102                         $self->fail("sysread failed: $!");
 103         $buf;
 104 }
 105
 106 sub _bidi_pipe {
 107         my ($self, $batch, $in, $out, $pid, $err) = @_;
 108         if ($self->{$pid}) {
 109                 if (defined $err) { # "err_c"
 110                         my $fh = $self->{$err};
 111                         sysseek($fh, 0, 0) or $self->fail("sysseek failed: $!");
 112                         truncate($fh, 0) or $self->fail("truncate failed: $!");
 113                 }
 114                 return;
 115         }
 116         my ($out_r, $out_w);
 117         pipe($out_r, $out_w) or $self->fail("pipe failed: $!");
 118         my @cmd = (qw(git), "--git-dir=$self->{git_dir}",
 119                         qw(-c core.abbrev=40 cat-file), $batch);
 120         my $redir = { 0 => $out_r };
 121         if ($err) {
 122                 my $id = "git.$self->{git_dir}$batch.err";
 123                 my $fh = tmpfile($id) or $self->fail("tmpfile($id): $!");
 124                 $self->{$err} = $fh;
 125                 $redir->{2} = $fh;
 126         }
 127         my ($in_r, $p) = popen_rd(\@cmd, undef, $redir);
 128         $self->{$pid} = $p;
 129         $out_w->autoflush(1);
 130         if ($^O eq 'linux') { # 1031: F_SETPIPE_SZ
 131                 fcntl($out_w, 1031, 4096);
 132                 fcntl($in_r, 1031, 4096) if $batch eq '--batch-check';
 133         }
 134         $self->{$out} = $out_w;
 135         $self->{$in} = $in_r;
 136 }
 137
 138 sub poll_in ($) { IO::Poll::_poll($RDTIMEO, fileno($_[0]), my $ev = POLLIN) }
 139
 140 sub my_read ($$$) {
 141         my ($fh, $rbuf, $len) = @_;
 142         my $left = $len - length($$rbuf);
 143         my $r;
 144         while ($left > 0) {
 145                 $r = sysread($fh, $$rbuf, $PIPE_BUFSIZ, length($$rbuf));
 146                 if ($r) {
 147                         $left -= $r;
 148                 } elsif (defined($r)) { # EOF
 149                         return 0;
 150                 } else {
 151                         next if ($! == EAGAIN and poll_in($fh));
 152                         next if $! == EINTR; # may be set by sysread or poll_in
 153                         return; # unrecoverable error
 154                 }
 155         }
 156         \substr($$rbuf, 0, $len, '');
 157 }
 158
 159 sub my_readline ($$) {
 160         my ($fh, $rbuf) = @_;
 161         while (1) {
 162                 if ((my $n = index($$rbuf, "\n")) >= 0) {
 163                         return substr($$rbuf, 0, $n + 1, '');
 164                 }
 165                 my $r = sysread($fh, $$rbuf, $PIPE_BUFSIZ, length($$rbuf))
 166                                                                 and next;
 167
 168                 # return whatever's left on EOF
 169                 return substr($$rbuf, 0, length($$rbuf)+1, '') if defined($r);
 170
 171                 next if ($! == EAGAIN and poll_in($fh));
 172                 next if $! == EINTR; # may be set by sysread or poll_in
 173                 return; # unrecoverable error
 174         }
 175 }
 176
 177 sub cat_async_retry ($$$$$) {
 178         my ($self, $inflight, $req, $cb, $arg) = @_;
 179
 180         # {inflight} may be non-existent, but if it isn't we delete it
 181         # here to prevent cleanup() from waiting:
 182         delete $self->{inflight};
 183         cleanup($self);
 184
 185         $self->{inflight} = $inflight;
 186         batch_prepare($self);
 187         my $buf = "$req\n";
 188         for (my $i = 0; $i < @$inflight; $i += 3) {
 189                 $buf .= "$inflight->[$i]\n";
 190         }
 191         print { $self->{out} } $buf or $self->fail("write error: $!");
 192         unshift(@$inflight, \$req, $cb, $arg); # \$ref to indicate retried
 193
 194         cat_async_step($self, $inflight); # take one step
 195 }
 196
 197 sub cat_async_step ($$) {
 198         my ($self, $inflight) = @_;
 199         die 'BUG: inflight empty or odd' if scalar(@$inflight) < 3;
 200         my ($req, $cb, $arg) = splice(@$inflight, 0, 3);
 201         my $rbuf = delete($self->{cat_rbuf}) // \(my $new = '');
 202         my ($bref, $oid, $type, $size);
 203         my $head = my_readline($self->{in}, $rbuf);
 204         # ->fail may be called via Gcf2Client.pm
 205         if ($head =~ /^([0-9a-f]{40,}) (\S+) ([0-9]+)$/) {
 206                 ($oid, $type, $size) = ($1, $2, $3 + 0);
 207                 $bref = my_read($self->{in}, $rbuf, $size + 1) or
 208                         $self->fail(defined($bref) ? 'read EOF' : "read: $!");
 209                 chop($$bref) eq "\n" or $self->fail('LF missing after blob');
 210         } elsif ($head =~ s/ missing\n//s) {
 211                 $oid = $head;
 212                 # ref($req) indicates it's already been retried
 213                 # -gcf2 retries internally, so it never hits this path:
 214                 if (!ref($req) && !$in_cleanup && $self->alternates_changed) {
 215                         return cat_async_retry($self, $inflight,
 216                                                 $req, $cb, $arg);
 217                 }
 218                 $type = 'missing';
 219                 $oid = ref($req) ? $$req : $req if $oid eq '';
 220         } else {
 221                 my $err = $! ? " ($!)" : '';
 222                 $self->fail("bad result from async cat-file: $head$err");
 223         }
 224         $self->{cat_rbuf} = $rbuf if $$rbuf ne '';
 225         eval { $cb->($bref, $oid, $type, $size, $arg) };
 226         warn "E: $oid: $@\n" if $@;
 227 }
 228
 229 sub cat_async_wait ($) {
 230         my ($self) = @_;
 231         my $inflight = $self->{inflight} or return;
 232         while (scalar(@$inflight)) {
 233                 cat_async_step($self, $inflight);
 234         }
 235 }
 236
 237 sub batch_prepare ($) {
 238         _bidi_pipe($_[0], qw(--batch in out pid));
 239 }
 240
 241 sub _cat_file_cb {
 242         my ($bref, undef, undef, $size, $result) = @_;
 243         @$result = ($bref, $size);
 244 }
 245
 246 sub cat_file {
 247         my ($self, $oid, $sizeref) = @_;
 248         my $result = [];
 249         cat_async($self, $oid, \&_cat_file_cb, $result);
 250         cat_async_wait($self);
 251         $$sizeref = $result->[1] if $sizeref;
 252         $result->[0];
 253 }
 254
 255 sub check_async_step ($$) {
 256         my ($self, $inflight_c) = @_;
 257         die 'BUG: inflight empty or odd' if scalar(@$inflight_c) < 3;
 258         my ($req, $cb, $arg) = splice(@$inflight_c, 0, 3);
 259         my $rbuf = delete($self->{chk_rbuf}) // \(my $new = '');
 260         chomp(my $line = my_readline($self->{in_c}, $rbuf));
 261         my ($hex, $type, $size) = split(/ /, $line);
 262
 263         # Future versions of git.git may have type=ambiguous, but for now,
 264         # we must handle 'dangling' below (and maybe some other oddball
 265         # stuff):
 266         # https://public-inbox.org/git/20190118033845.s2vlrb3wd3m2jfzu@dcvr/T/
 267         if ($hex eq 'dangling' || $hex eq 'notdir' || $hex eq 'loop') {
 268                 my $ret = my_read($self->{in_c}, $rbuf, $type + 1);
 269                 $self->fail(defined($ret) ? 'read EOF' : "read: $!") if !$ret;
 270         }
 271         $self->{chk_rbuf} = $rbuf if $$rbuf ne '';
 272         eval { $cb->($hex, $type, $size, $arg, $self) };
 273         warn "E: check($req) $@\n" if $@;
 274 }
 275
 276 sub check_async_wait ($) {
 277         my ($self) = @_;
 278         my $inflight_c = $self->{inflight_c} or return;
 279         while (scalar(@$inflight_c)) {
 280                 check_async_step($self, $inflight_c);
 281         }
 282 }
 283
 284 sub check_async_begin ($) {
 285         my ($self) = @_;
 286         cleanup($self) if alternates_changed($self);
 287         _bidi_pipe($self, qw(--batch-check in_c out_c pid_c err_c));
 288         die 'BUG: already in async check' if $self->{inflight_c};
 289         $self->{inflight_c} = [];
 290 }
 291
 292 sub check_async ($$$$) {
 293         my ($self, $oid, $cb, $arg) = @_;
 294         my $inflight_c = $self->{inflight_c} // check_async_begin($self);
 295         while (scalar(@$inflight_c) >= MAX_INFLIGHT) {
 296                 check_async_step($self, $inflight_c);
 297         }
 298         print { $self->{out_c} } $oid, "\n" or $self->fail("write error: $!");
 299         push(@$inflight_c, $oid, $cb, $arg);
 300 }
 301
 302 sub _check_cb { # check_async callback
 303         my ($hex, $type, $size, $result) = @_;
 304         @$result = ($hex, $type, $size);
 305 }
 306
 307 sub check {
 308         my ($self, $oid) = @_;
 309         my $result = [];
 310         check_async($self, $oid, \&_check_cb, $result);
 311         check_async_wait($self);
 312         my ($hex, $type, $size) = @$result;
 313
 314         # Future versions of git.git may show 'ambiguous', but for now,
 315         # we must handle 'dangling' below (and maybe some other oddball
 316         # stuff):
 317         # https://public-inbox.org/git/20190118033845.s2vlrb3wd3m2jfzu@dcvr/T/
 318         return if $type eq 'missing' || $type eq 'ambiguous';
 319         return if $hex eq 'dangling' || $hex eq 'notdir' || $hex eq 'loop';
 320         ($hex, $type, $size);
 321 }
 322
 323 sub _destroy {
 324         my ($self, $rbuf, $in, $out, $pid, $err) = @_;
 325         delete @$self{($rbuf, $in, $out)};
 326         delete $self->{$err} if $err; # `err_c'
 327
 328         # GitAsyncCat::event_step may delete {pid}
 329         my $p = delete $self->{$pid} or return;
 330         dwaitpid $p;
 331 }
 332
 333 sub cat_async_abort ($) {
 334         my ($self) = @_;
 335         if (my $inflight = $self->{inflight}) {
 336                 while (@$inflight) {
 337                         my ($req, $cb, $arg) = splice(@$inflight, 0, 3);
 338                         $req =~ s/ .*//; # drop git_dir for Gcf2Client
 339                         eval { $cb->(undef, $req, undef, undef, $arg) };
 340                         warn "E: $req: $@ (in abort)\n" if $@;
 341                 }
 342                 delete $self->{cat_rbuf};
 343                 delete $self->{inflight};
 344         }
 345         cleanup($self);
 346 }
 347
 348 sub fail { # may be augmented in subclasses
 349         my ($self, $msg) = @_;
 350         cat_async_abort($self);
 351         croak(ref($self) . ' ' . ($self->{git_dir} // '') . ": $msg");
 352 }
 353
 354 sub popen {
 355         my ($self, @cmd) = @_;
 356         @cmd = ('git', "--git-dir=$self->{git_dir}", @cmd);
 357         popen_rd(\@cmd);
 358 }
 359
 360 sub qx {
 361         my ($self, @cmd) = @_;
 362         my $fh = $self->popen(@cmd);
 363         local $/ = wantarray ? "\n" : undef;
 364         <$fh>;
 365 }
 366
 367 # check_async and cat_async may trigger the other, so ensure they're
 368 # both completely done by using this:
 369 sub async_wait_all ($) {
 370         my ($self) = @_;
 371         while (scalar(@{$self->{inflight_c} // []}) ||
 372                         scalar(@{$self->{inflight} // []})) {
 373                 $self->check_async_wait;
 374                 $self->cat_async_wait;
 375         }
 376 }
 377
 378 # returns true if there are pending "git cat-file" processes
 379 sub cleanup {
 380         my ($self) = @_;
 381         local $in_cleanup = 1;
 382         delete $self->{async_cat};
 383         async_wait_all($self);
 384         delete $self->{inflight};
 385         delete $self->{inflight_c};
 386         _destroy($self, qw(cat_rbuf in out pid));
 387         _destroy($self, qw(chk_rbuf in_c out_c pid_c err_c));
 388         !!($self->{pid} || $self->{pid_c});
 389 }
 390
 391
 392 # assuming a well-maintained repo, this should be a somewhat
 393 # accurate estimation of its size
 394 # TODO: show this in the WWW UI as a hint to potential cloners
 395 sub packed_bytes {
 396         my ($self) = @_;
 397         my $n = 0;
 398         my $pack_dir = git_path($self, 'objects/pack');
 399         foreach my $p (bsd_glob("$pack_dir/*.pack", GLOB_NOSORT)) {
 400                 $n += -s $p;
 401         }
 402         $n
 403 }
 404
 405 sub DESTROY { cleanup(@_) }
 406
 407 sub local_nick ($) {
 408         my ($self) = @_;
 409         my $ret = '???';
 410         # don't show full FS path, basename should be OK:
 411         if ($self->{git_dir} =~ m!/([^/]+)(?:/\.git)?\z!) {
 412                 $ret = "/path/to/$1";
 413         }
 414         wantarray ? ($ret) : $ret;
 415 }
 416
 417 sub host_prefix_url ($$) {
 418         my ($env, $url) = @_;
 419         return $url if index($url, '//') >= 0;
 420         my $scheme = $env->{'psgi.url_scheme'};
 421         my $host_port = $env->{HTTP_HOST} //
 422                 "$env->{SERVER_NAME}:$env->{SERVER_PORT}";
 423         "$scheme://$host_port". ($env->{SCRIPT_NAME} || '/') . $url;
 424 }
 425
 426 sub pub_urls {
 427         my ($self, $env) = @_;
 428         if (my $urls = $self->{cgit_url}) {
 429                 return map { host_prefix_url($env, $_) } @$urls;
 430         }
 431         local_nick($self);
 432 }
 433
 434 sub cat_async_begin {
 435         my ($self) = @_;
 436         cleanup($self) if $self->alternates_changed;
 437         $self->batch_prepare;
 438         die 'BUG: already in async' if $self->{inflight};
 439         $self->{inflight} = [];
 440 }
 441
 442 sub cat_async ($$$;$) {
 443         my ($self, $oid, $cb, $arg) = @_;
 444         my $inflight = $self->{inflight} // cat_async_begin($self);
 445         while (scalar(@$inflight) >= MAX_INFLIGHT) {
 446                 cat_async_step($self, $inflight);
 447         }
 448         print { $self->{out} } $oid, "\n" or $self->fail("write error: $!");
 449         push(@$inflight, $oid, $cb, $arg);
 450 }
 451
 452 sub async_prefetch {
 453         my ($self, $oid, $cb, $arg) = @_;
 454         if (my $inflight = $self->{inflight}) {
 455                 # we could use MAX_INFLIGHT here w/o the halving,
 456                 # but lets not allow one client to monopolize a git process
 457                 if (scalar(@$inflight) < int(MAX_INFLIGHT/2)) {
 458                         print { $self->{out} } $oid, "\n" or
 459                                                 $self->fail("write error: $!");
 460                         return push(@$inflight, $oid, $cb, $arg);
 461                 }
 462         }
 463         undef;
 464 }
 465
 466 sub extract_cmt_time {
 467         my ($bref, undef, undef, undef, $modified) = @_;
 468
 469         if ($$bref =~ /^committer .*?> ([0-9]+) [\+\-]?[0-9]+/sm) {
 470                 my $cmt_time = $1 + 0;
 471                 $$modified = $cmt_time if $cmt_time > $$modified;
 472         }
 473 }
 474
 475 # returns the modified time of a git repo, same as the "modified" field
 476 # of a grokmirror manifest
 477 sub modified ($) {
 478         my ($self) = @_;
 479         my $modified = 0;
 480         my $fh = popen($self, qw(rev-parse --branches));
 481         local $/ = "\n";
 482         while (my $oid = <$fh>) {
 483                 chomp $oid;
 484                 cat_async($self, $oid, \&extract_cmt_time, \$modified);
 485         }
 486         cat_async_wait($self);
 487         $modified || time;
 488 }
 489
 490 # for grokmirror, which doesn't read gitweb.description
 491 # templates/hooks--update.sample and git-multimail in git.git
 492 # only match "Unnamed repository", not the full contents of
 493 # templates/this--description in git.git
 494 sub manifest_entry {
 495         my ($self, $epoch, $default_desc) = @_;
 496         my ($fh, $pid) = $self->popen('show-ref');
 497         my $dig = Digest::SHA->new(1);
 498         while (read($fh, my $buf, 65536)) {
 499                 $dig->add($buf);
 500         }
 501         close $fh;
 502         waitpid($pid, 0);
 503         return if $?; # empty, uninitialized git repo
 504         my $git_dir = $self->{git_dir};
 505         my $ent = {
 506                 fingerprint => $dig->hexdigest,
 507                 reference => undef,
 508                 modified => modified($self),
 509         };
 510         chomp(my $owner = $self->qx('config', 'gitweb.owner'));
 511         utf8::decode($owner);
 512         $ent->{owner} = $owner eq '' ? undef : $owner;
 513         my $desc = '';
 514         if (open($fh, '<', "$git_dir/description")) {
 515                 local $/ = "\n";
 516                 chomp($desc = <$fh>);
 517                 utf8::decode($desc);
 518         }
 519         $desc = 'Unnamed repository' if $desc eq '';
 520         if (defined $epoch && $desc =~ /\AUnnamed repository/) {
 521                 $desc = "$default_desc [epoch $epoch]";
 522         }
 523         $ent->{description} = $desc;
 524         if (open($fh, '<', "$git_dir/objects/info/alternates")) {
 525                 # n.b.: GitPython doesn't seem to handle comments or C-quoted
 526                 # strings like native git does; and we don't for now, either.
 527                 local $/ = "\n";
 528                 chomp(my @alt = <$fh>);
 529
 530                 # grokmirror only supports 1 alternate for "reference",
 531                 if (scalar(@alt) == 1) {
 532                         my $objdir = "$git_dir/objects";
 533                         my $ref = File::Spec->rel2abs($alt[0], $objdir);
 534                         $ref =~ s!/[^/]+/?\z!!; # basename
 535                         $ent->{reference} = $ref;
 536                 }
 537         }
 538         $ent;
 539 }
 540
 541 1;
 542 __END__
 543 =pod
 544
 545 =head1 NAME
 546
 547 PublicInbox::Git - git wrapper
 548
 549 =head1 VERSION
 550
 551 version 1.0
 552
 553 =head1 SYNOPSIS
 554
 555         use PublicInbox::Git;
 556         chomp(my $git_dir = `git rev-parse --git-dir`);
 557         $git_dir or die "GIT_DIR= must be specified\n";
 558         my $git = PublicInbox::Git->new($git_dir);
 559
 560 =head1 DESCRIPTION
 561
 562 Unstable API outside of the L</new> method.
 563 It requires L<git(1)> to be installed.
 564
 565 =head1 METHODS
 566
 567 =cut
 568
 569 =head2 new
 570
 571         my $git = PublicInbox::Git->new($git_dir);
 572
 573 Initialize a new PublicInbox::Git object for use with L<PublicInbox::Import>
 574 This is the only public API method we support.  Everything else
 575 in this module is subject to change.
 576
 577 =head1 SEE ALSO
 578
 579 L<Git>, L<PublicInbox::Import>
 580
 581 =head1 CONTACT
 582
 583 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 584
 585 The mail archives are hosted at L<https://public-inbox.org/meta/>
 586
 587 =head1 COPYRIGHT
 588
 589 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 590
 591 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 592
 593 =cut