lib/PublicInbox/Git.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: GPLv2 or later (https://www.gnu.org/licenses/gpl-2.0.txt)
   3 #
   4 # Used to read files from a git repository without excessive forking.
   5 # Used in our web interfaces as well as our -nntpd server.
   6 # This is based on code in Git.pm which is GPLv2+, but modified to avoid
   7 # dependence on environment variables for compatibility with mod_perl.
   8 # There are also API changes to simplify our usage and data set.
   9 package PublicInbox::Git;
  10 use strict;
  11 use warnings;
  12 use POSIX qw(dup2);
  13 require IO::Handle;
  14 use PublicInbox::Spawn qw(spawn popen_rd);
  15
  16 sub new {
  17         my ($class, $git_dir) = @_;
  18         bless { git_dir => $git_dir }, $class
  19 }
  20
  21 sub _bidi_pipe {
  22         my ($self, $batch, $in, $out, $pid) = @_;
  23         return if $self->{$pid};
  24         my ($in_r, $in_w, $out_r, $out_w);
  25
  26         pipe($in_r, $in_w) or fail($self, "pipe failed: $!");
  27         pipe($out_r, $out_w) or fail($self, "pipe failed: $!");
  28
  29         my @cmd = ('git', "--git-dir=$self->{git_dir}", qw(cat-file), $batch);
  30         my $redir = { 0 => fileno($out_r), 1 => fileno($in_w) };
  31         $self->{$pid} = spawn(\@cmd, undef, $redir);
  32         $out_w->autoflush(1);
  33         $self->{$out} = $out_w;
  34         $self->{$in} = $in_r;
  35 }
  36
  37 sub cat_file {
  38         my ($self, $obj, $ref) = @_;
  39
  40         $self->_bidi_pipe(qw(--batch in out pid));
  41         $self->{out}->print($obj, "\n") or fail($self, "write error: $!");
  42
  43         my $in = $self->{in};
  44         my $head = $in->getline;
  45         $head =~ / missing$/ and return undef;
  46         $head =~ /^[0-9a-f]{40} \S+ (\d+)$/ or
  47                 fail($self, "Unexpected result from git cat-file: $head");
  48
  49         my $size = $1;
  50         my $ref_type = $ref ? ref($ref) : '';
  51
  52         my $rv;
  53         my $left = $size;
  54         $$ref = $size if ($ref_type eq 'SCALAR');
  55         my $cb_err;
  56
  57         if ($ref_type eq 'CODE') {
  58                 $rv = eval { $ref->($in, \$left) };
  59                 $cb_err = $@;
  60                 # drain the rest
  61                 my $max = 8192;
  62                 while ($left > 0) {
  63                         my $r = read($in, my $x, $left > $max ? $max : $left);
  64                         defined($r) or fail($self, "read failed: $!");
  65                         $r == 0 and fail($self, 'exited unexpectedly');
  66                         $left -= $r;
  67                 }
  68         } else {
  69                 my $offset = 0;
  70                 my $buf = '';
  71                 while ($left > 0) {
  72                         my $r = read($in, $buf, $left, $offset);
  73                         defined($r) or fail($self, "read failed: $!");
  74                         $r == 0 and fail($self, 'exited unexpectedly');
  75                         $left -= $r;
  76                         $offset += $r;
  77                 }
  78                 $rv = \$buf;
  79         }
  80
  81         my $r = read($in, my $buf, 1);
  82         defined($r) or fail($self, "read failed: $!");
  83         fail($self, 'newline missing after blob') if ($r != 1 || $buf ne "\n");
  84         die $cb_err if $cb_err;
  85
  86         $rv;
  87 }
  88
  89 sub check {
  90         my ($self, $obj) = @_;
  91         $self->_bidi_pipe(qw(--batch-check in_c out_c pid_c));
  92         $self->{out_c}->print($obj, "\n") or fail($self, "write error: $!");
  93         chomp(my $line = $self->{in_c}->getline);
  94         my ($hex, $type, $size) = split(' ', $line);
  95         return if $type eq 'missing';
  96         ($hex, $type, $size);
  97 }
  98
  99 sub _destroy {
 100         my ($self, $in, $out, $pid) = @_;
 101         my $p = delete $self->{$pid} or return;
 102         foreach my $f ($in, $out) {
 103                 delete $self->{$f};
 104         }
 105         waitpid $p, 0;
 106 }
 107
 108 sub fail {
 109         my ($self, $msg) = @_;
 110         cleanup($self);
 111         die $msg;
 112 }
 113
 114 sub popen {
 115         my ($self, @cmd) = @_;
 116         @cmd = ('git', "--git-dir=$self->{git_dir}", @cmd);
 117         popen_rd(\@cmd);
 118 }
 119
 120 sub qx {
 121         my ($self, @cmd) = @_;
 122         my $fh = $self->popen(@cmd);
 123         return <$fh> if wantarray;
 124         local $/;
 125         <$fh>
 126 }
 127
 128 sub cleanup {
 129         my ($self) = @_;
 130         _destroy($self, qw(in out pid));
 131         _destroy($self, qw(in_c out_c pid_c));
 132 }
 133
 134 sub DESTROY { cleanup(@_) }
 135
 136 1;
 137 __END__
 138 =pod
 139
 140 =head1 NAME
 141
 142 PublicInbox::Git - git wrapper
 143
 144 =head1 VERSION
 145
 146 version 1.0
 147
 148 =head1 SYNOPSIS
 149
 150         use PublicInbox::Git;
 151         chomp(my $git_dir = `git rev-parse --git-dir`);
 152         $git_dir or die "GIT_DIR= must be specified\n";
 153         my $git = PublicInbox::Git->new($git_dir);
 154
 155 =head1 DESCRIPTION
 156
 157 Unstable API outside of the L</new> method.
 158 It requires L<git(1)> to be installed.
 159
 160 =head1 METHODS
 161
 162 =cut
 163
 164 =head2 new
 165
 166         my $git = PublicInbox::Git->new($git_dir);
 167
 168 Initialize a new PublicInbox::Git object for use with L<PublicInbox::Import>
 169 This is the only public API method we support.  Everything else
 170 in this module is subject to change.
 171
 172 =head1 SEE ALSO
 173
 174 L<Git>, L<PublicInbox::Import>
 175
 176 =head1 CONTACT
 177
 178 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 179
 180 The mail archives are hosted at L<https://public-inbox.org/meta/>
 181
 182 =head1 COPYRIGHT
 183
 184 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 185
 186 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 187
 188 =cut