lib/PublicInbox/Git.pm

   1 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
   2 # License: GPLv2 or later <https://www.gnu.org/licenses/gpl-2.0.txt>
   3 #
   4 # Used to read files from a git repository without excessive forking.
   5 # Used in our web interfaces as well as our -nntpd server.
   6 # This is based on code in Git.pm which is GPLv2+, but modified to avoid
   7 # dependence on environment variables for compatibility with mod_perl.
   8 # There are also API changes to simplify our usage and data set.
   9 package PublicInbox::Git;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(Exporter);
  13 use POSIX ();
  14 use IO::Handle; # ->autoflush
  15 use Errno qw(EINTR);
  16 use File::Glob qw(bsd_glob GLOB_NOSORT);
  17 use Time::HiRes qw(stat);
  18 use PublicInbox::Spawn qw(popen_rd);
  19 use PublicInbox::Tmpfile;
  20 use Carp qw(croak);
  21 our @EXPORT_OK = qw(git_unquote git_quote);
  22 our $PIPE_BUFSIZ = 65536; # Linux default
  23 our $in_cleanup;
  24
  25 use constant MAX_INFLIGHT =>
  26         (($^O eq 'linux' ? 4096 : POSIX::_POSIX_PIPE_BUF()) * 3)
  27         /
  28         65; # SHA-256 hex size + "\n" in preparation for git using non-SHA1
  29
  30 my %GIT_ESC = (
  31         a => "\a",
  32         b => "\b",
  33         f => "\f",
  34         n => "\n",
  35         r => "\r",
  36         t => "\t",
  37         v => "\013",
  38         '"' => '"',
  39         '\\' => '\\',
  40 );
  41 my %ESC_GIT = map { $GIT_ESC{$_} => $_ } keys %GIT_ESC;
  42
  43
  44 # unquote pathnames used by git, see quote.c::unquote_c_style.c in git.git
  45 sub git_unquote ($) {
  46         return $_[0] unless ($_[0] =~ /\A"(.*)"\z/);
  47         $_[0] = $1;
  48         $_[0] =~ s/\\([\\"abfnrtv])/$GIT_ESC{$1}/g;
  49         $_[0] =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  50         $_[0];
  51 }
  52
  53 sub git_quote ($) {
  54         if ($_[0] =~ s/([\\"\a\b\f\n\r\t\013]|[^[:print:]])/
  55                       '\\'.($ESC_GIT{$1}||sprintf("%0o",ord($1)))/egs) {
  56                 return qq{"$_[0]"};
  57         }
  58         $_[0];
  59 }
  60
  61 sub new {
  62         my ($class, $git_dir) = @_;
  63         # may contain {-tmp} field for File::Temp::Dir
  64         bless { git_dir => $git_dir, alt_st => '', -git_path => {} }, $class
  65 }
  66
  67 sub git_path ($$) {
  68         my ($self, $path) = @_;
  69         $self->{-git_path}->{$path} ||= do {
  70                 local $/ = "\n";
  71                 chomp(my $str = $self->qx(qw(rev-parse --git-path), $path));
  72
  73                 # git prior to 2.5.0 did not understand --git-path
  74                 if ($str eq "--git-path\n$path") {
  75                         $str = "$self->{git_dir}/$path";
  76                 }
  77                 $str;
  78         };
  79 }
  80
  81 sub alternates_changed {
  82         my ($self) = @_;
  83         my $alt = git_path($self, 'objects/info/alternates');
  84         my @st = stat($alt) or return 0;
  85
  86         # can't rely on 'q' on some 32-bit builds, but `d' works
  87         my $st = pack('dd', $st[10], $st[7]); # 10: ctime, 7: size
  88         return 0 if $self->{alt_st} eq $st;
  89         $self->{alt_st} = $st; # always a true value
  90 }
  91
  92 sub last_check_err {
  93         my ($self) = @_;
  94         my $fh = $self->{err_c} or return;
  95         sysseek($fh, 0, 0) or fail($self, "sysseek failed: $!");
  96         defined(sysread($fh, my $buf, -s $fh)) or
  97                         fail($self, "sysread failed: $!");
  98         $buf;
  99 }
 100
 101 sub _bidi_pipe {
 102         my ($self, $batch, $in, $out, $pid, $err) = @_;
 103         if ($self->{$pid}) {
 104                 if (defined $err) { # "err_c"
 105                         my $fh = $self->{$err};
 106                         sysseek($fh, 0, 0) or fail($self, "sysseek failed: $!");
 107                         truncate($fh, 0) or fail($self, "truncate failed: $!");
 108                 }
 109                 return;
 110         }
 111         my ($out_r, $out_w);
 112         pipe($out_r, $out_w) or fail($self, "pipe failed: $!");
 113         my @cmd = (qw(git), "--git-dir=$self->{git_dir}",
 114                         qw(-c core.abbrev=40 cat-file), $batch);
 115         my $redir = { 0 => $out_r };
 116         if ($err) {
 117                 my $id = "git.$self->{git_dir}$batch.err";
 118                 my $fh = tmpfile($id) or fail($self, "tmpfile($id): $!");
 119                 $self->{$err} = $fh;
 120                 $redir->{2} = $fh;
 121         }
 122         my ($in_r, $p) = popen_rd(\@cmd, undef, $redir);
 123         $self->{$pid} = $p;
 124         $out_w->autoflush(1);
 125         if ($^O eq 'linux') { # 1031: F_SETPIPE_SZ
 126                 fcntl($out_w, 1031, 4096);
 127                 fcntl($in_r, 1031, 4096) if $batch eq '--batch-check';
 128         }
 129         $self->{$out} = $out_w;
 130         $self->{$in} = $in_r;
 131 }
 132
 133 sub my_read ($$$) {
 134         my ($fh, $rbuf, $len) = @_;
 135         my $left = $len - length($$rbuf);
 136         my $r;
 137         while ($left > 0) {
 138                 $r = sysread($fh, $$rbuf, $PIPE_BUFSIZ, length($$rbuf));
 139                 if ($r) {
 140                         $left -= $r;
 141                 } else {
 142                         next if (!defined($r) && $! == EINTR);
 143                         return $r;
 144                 }
 145         }
 146         \substr($$rbuf, 0, $len, '');
 147 }
 148
 149 sub my_readline ($$) {
 150         my ($fh, $rbuf) = @_;
 151         while (1) {
 152                 if ((my $n = index($$rbuf, "\n")) >= 0) {
 153                         return substr($$rbuf, 0, $n + 1, '');
 154                 }
 155                 my $r = sysread($fh, $$rbuf, $PIPE_BUFSIZ, length($$rbuf));
 156                 next if $r || (!defined($r) && $! == EINTR);
 157                 return defined($r) ? '' : undef; # EOF or error
 158         }
 159 }
 160
 161 sub cat_async_retry ($$$$$) {
 162         my ($self, $inflight, $req, $cb, $arg) = @_;
 163
 164         # {inflight} may be non-existent, but if it isn't we delete it
 165         # here to prevent cleanup() from waiting:
 166         delete $self->{inflight};
 167         cleanup($self);
 168
 169         $self->{inflight} = $inflight;
 170         batch_prepare($self);
 171         my $buf = "$req\n";
 172         for (my $i = 0; $i < @$inflight; $i += 3) {
 173                 $buf .= "$inflight->[$i]\n";
 174         }
 175         print { $self->{out} } $buf or fail($self, "write error: $!");
 176         unshift(@$inflight, \$req, $cb, $arg); # \$ref to indicate retried
 177
 178         cat_async_step($self, $inflight); # take one step
 179 }
 180
 181 sub cat_async_step ($$) {
 182         my ($self, $inflight) = @_;
 183         die 'BUG: inflight empty or odd' if scalar(@$inflight) < 3;
 184         my ($req, $cb, $arg) = splice(@$inflight, 0, 3);
 185         my $rbuf = delete($self->{cat_rbuf}) // \(my $new = '');
 186         my ($bref, $oid, $type, $size);
 187         my $head = my_readline($self->{in}, $rbuf);
 188         if ($head =~ /^([0-9a-f]{40,}) (\S+) ([0-9]+)$/) {
 189                 ($oid, $type, $size) = ($1, $2, $3 + 0);
 190                 $bref = my_read($self->{in}, $rbuf, $size + 1) or
 191                         fail($self, defined($bref) ? 'read EOF' : "read: $!");
 192                 chop($$bref) eq "\n" or fail($self, 'LF missing after blob');
 193         } elsif ($head =~ s/ missing\n//s) {
 194                 $oid = $head;
 195                 # ref($req) indicates it's already been retried
 196                 # -gcf2 retries internally, so it never hits this path:
 197                 if (!ref($req) && !$in_cleanup && $self->alternates_changed) {
 198                         return cat_async_retry($self, $inflight,
 199                                                 $req, $cb, $arg);
 200                 }
 201                 $type = 'missing';
 202                 $oid = ref($req) ? $$req : $req if $oid eq '';
 203         } else {
 204                 fail($self, "Unexpected result from async git cat-file: $head");
 205         }
 206         eval { $cb->($bref, $oid, $type, $size, $arg) };
 207         $self->{cat_rbuf} = $rbuf if $$rbuf ne '';
 208         warn "E: $oid: $@\n" if $@;
 209 }
 210
 211 sub cat_async_wait ($) {
 212         my ($self) = @_;
 213         my $inflight = delete $self->{inflight} or return;
 214         while (scalar(@$inflight)) {
 215                 cat_async_step($self, $inflight);
 216         }
 217 }
 218
 219 sub batch_prepare ($) {
 220         _bidi_pipe($_[0], qw(--batch in out pid));
 221 }
 222
 223 sub _cat_file_cb {
 224         my ($bref, undef, undef, $size, $result) = @_;
 225         @$result = ($bref, $size);
 226 }
 227
 228 sub cat_file {
 229         my ($self, $oid, $sizeref) = @_;
 230         my $result = [];
 231         cat_async($self, $oid, \&_cat_file_cb, $result);
 232         cat_async_wait($self);
 233         $$sizeref = $result->[1] if $sizeref;
 234         $result->[0];
 235 }
 236
 237 sub check_async_step ($$) {
 238         my ($self, $inflight_c) = @_;
 239         die 'BUG: inflight empty or odd' if scalar(@$inflight_c) < 3;
 240         my ($req, $cb, $arg) = splice(@$inflight_c, 0, 3);
 241         my $rbuf = delete($self->{rbuf_c}) // \(my $new = '');
 242         chomp(my $line = my_readline($self->{in_c}, $rbuf));
 243         my ($hex, $type, $size) = split(/ /, $line);
 244
 245         # Future versions of git.git may have type=ambiguous, but for now,
 246         # we must handle 'dangling' below (and maybe some other oddball
 247         # stuff):
 248         # https://public-inbox.org/git/20190118033845.s2vlrb3wd3m2jfzu@dcvr/T/
 249         if ($hex eq 'dangling' || $hex eq 'notdir' || $hex eq 'loop') {
 250                 my $ret = my_read($self->{in_c}, $rbuf, $type + 1);
 251                 fail($self, defined($ret) ? 'read EOF' : "read: $!") if !$ret;
 252         }
 253         eval { $cb->($hex, $type, $size, $arg, $self) };
 254         warn "E: check($req) $@\n" if $@;
 255         $self->{rbuf_c} = $rbuf if $$rbuf ne '';
 256 }
 257
 258 sub check_async_wait ($) {
 259         my ($self) = @_;
 260         my $inflight_c = delete $self->{inflight_c} or return;
 261         while (scalar(@$inflight_c)) {
 262                 check_async_step($self, $inflight_c);
 263         }
 264 }
 265
 266 sub check_async_begin ($) {
 267         my ($self) = @_;
 268         cleanup($self) if alternates_changed($self);
 269         _bidi_pipe($self, qw(--batch-check in_c out_c pid_c err_c));
 270         die 'BUG: already in async check' if $self->{inflight_c};
 271         $self->{inflight_c} = [];
 272 }
 273
 274 sub check_async ($$$$) {
 275         my ($self, $oid, $cb, $arg) = @_;
 276         my $inflight_c = $self->{inflight_c} // check_async_begin($self);
 277         if (scalar(@$inflight_c) >= MAX_INFLIGHT) {
 278                 check_async_step($self, $inflight_c);
 279         }
 280         print { $self->{out_c} } $oid, "\n" or fail($self, "write error: $!");
 281         push(@$inflight_c, $oid, $cb, $arg);
 282 }
 283
 284 sub _check_cb { # check_async callback
 285         my ($hex, $type, $size, $result) = @_;
 286         @$result = ($hex, $type, $size);
 287 }
 288
 289 sub check {
 290         my ($self, $oid) = @_;
 291         my $result = [];
 292         check_async($self, $oid, \&_check_cb, $result);
 293         check_async_wait($self);
 294         my ($hex, $type, $size) = @$result;
 295
 296         # Future versions of git.git may show 'ambiguous', but for now,
 297         # we must handle 'dangling' below (and maybe some other oddball
 298         # stuff):
 299         # https://public-inbox.org/git/20190118033845.s2vlrb3wd3m2jfzu@dcvr/T/
 300         return if $type eq 'missing' || $type eq 'ambiguous';
 301         return if $hex eq 'dangling' || $hex eq 'notdir' || $hex eq 'loop';
 302         ($hex, $type, $size);
 303 }
 304
 305 sub _destroy {
 306         my ($self, $rbuf, $in, $out, $pid, $err) = @_;
 307         my $p = delete $self->{$pid} or return;
 308         delete @$self{($rbuf, $in, $out)};
 309         delete $self->{$err} if $err; # `err_c'
 310
 311         # PublicInbox::DS may not be loaded
 312         eval { PublicInbox::DS::dwaitpid($p, undef, undef) };
 313         waitpid($p, 0) if $@; # wait synchronously if not in event loop
 314 }
 315
 316 sub cat_async_abort ($) {
 317         my ($self) = @_;
 318         my $inflight = delete $self->{inflight} or die 'BUG: not in async';
 319         cleanup($self);
 320 }
 321
 322 sub fail {
 323         my ($self, $msg) = @_;
 324         $self->{inflight} ? cat_async_abort($self) : cleanup($self);
 325         croak("git $self->{git_dir}: $msg");
 326 }
 327
 328 sub popen {
 329         my ($self, @cmd) = @_;
 330         @cmd = ('git', "--git-dir=$self->{git_dir}", @cmd);
 331         popen_rd(\@cmd);
 332 }
 333
 334 sub qx {
 335         my ($self, @cmd) = @_;
 336         my $fh = $self->popen(@cmd);
 337         local $/ = "\n";
 338         return <$fh> if wantarray;
 339         local $/;
 340         <$fh>
 341 }
 342
 343 # returns true if there are pending "git cat-file" processes
 344 sub cleanup {
 345         my ($self) = @_;
 346         local $in_cleanup = 1;
 347         delete $self->{async_cat};
 348         check_async_wait($self);
 349         cat_async_wait($self);
 350         _destroy($self, qw(cat_rbuf in out pid));
 351         _destroy($self, qw(chk_rbuf in_c out_c pid_c err_c));
 352         !!($self->{pid} || $self->{pid_c});
 353 }
 354
 355 # assuming a well-maintained repo, this should be a somewhat
 356 # accurate estimation of its size
 357 # TODO: show this in the WWW UI as a hint to potential cloners
 358 sub packed_bytes {
 359         my ($self) = @_;
 360         my $n = 0;
 361         my $pack_dir = git_path($self, 'objects/pack');
 362         foreach my $p (bsd_glob("$pack_dir/*.pack", GLOB_NOSORT)) {
 363                 $n += -s $p;
 364         }
 365         $n
 366 }
 367
 368 sub DESTROY { cleanup(@_) }
 369
 370 sub local_nick ($) {
 371         my ($self) = @_;
 372         my $ret = '???';
 373         # don't show full FS path, basename should be OK:
 374         if ($self->{git_dir} =~ m!/([^/]+)(?:/\.git)?\z!) {
 375                 $ret = "/path/to/$1";
 376         }
 377         wantarray ? ($ret) : $ret;
 378 }
 379
 380 sub host_prefix_url ($$) {
 381         my ($env, $url) = @_;
 382         return $url if index($url, '//') >= 0;
 383         my $scheme = $env->{'psgi.url_scheme'};
 384         my $host_port = $env->{HTTP_HOST} //
 385                 "$env->{SERVER_NAME}:$env->{SERVER_PORT}";
 386         "$scheme://$host_port". ($env->{SCRIPT_NAME} || '/') . $url;
 387 }
 388
 389 sub pub_urls {
 390         my ($self, $env) = @_;
 391         if (my $urls = $self->{cgit_url}) {
 392                 return map { host_prefix_url($env, $_) } @$urls;
 393         }
 394         local_nick($self);
 395 }
 396
 397 sub cat_async_begin {
 398         my ($self) = @_;
 399         cleanup($self) if $self->alternates_changed;
 400         batch_prepare($self);
 401         die 'BUG: already in async' if $self->{inflight};
 402         $self->{inflight} = [];
 403 }
 404
 405 sub cat_async ($$$;$) {
 406         my ($self, $oid, $cb, $arg) = @_;
 407         my $inflight = $self->{inflight} // cat_async_begin($self);
 408         if (scalar(@$inflight) >= MAX_INFLIGHT) {
 409                 cat_async_step($self, $inflight);
 410         }
 411
 412         print { $self->{out} } $oid, "\n" or fail($self, "write error: $!");
 413         push(@$inflight, $oid, $cb, $arg);
 414 }
 415
 416 # this is safe to call inside $cb, but not guaranteed to enqueue
 417 # returns true if successful, undef if not.
 418 sub async_prefetch {
 419         my ($self, $oid, $cb, $arg) = @_;
 420         if (defined($self->{async_cat}) && (my $inflight = $self->{inflight})) {
 421                 # we could use MAX_INFLIGHT here w/o the halving,
 422                 # but lets not allow one client to monopolize a git process
 423                 if (scalar(@$inflight) < int(MAX_INFLIGHT/2)) {
 424                         print { $self->{out} } $oid, "\n" or
 425                                                 fail($self, "write error: $!");
 426                         return push(@$inflight, $oid, $cb, $arg);
 427                 }
 428         }
 429         undef;
 430 }
 431
 432 sub extract_cmt_time {
 433         my ($bref, undef, undef, undef, $modified) = @_;
 434
 435         if ($$bref =~ /^committer .*?> ([0-9]+) [\+\-]?[0-9]+/sm) {
 436                 my $cmt_time = $1 + 0;
 437                 $$modified = $cmt_time if $cmt_time > $$modified;
 438         }
 439 }
 440
 441 # returns the modified time of a git repo, same as the "modified" field
 442 # of a grokmirror manifest
 443 sub modified ($) {
 444         my ($self) = @_;
 445         my $modified = 0;
 446         my $fh = popen($self, qw(rev-parse --branches));
 447         local $/ = "\n";
 448         while (my $oid = <$fh>) {
 449                 chomp $oid;
 450                 cat_async($self, $oid, \&extract_cmt_time, \$modified);
 451         }
 452         cat_async_wait($self);
 453         $modified || time;
 454 }
 455
 456 1;
 457 __END__
 458 =pod
 459
 460 =head1 NAME
 461
 462 PublicInbox::Git - git wrapper
 463
 464 =head1 VERSION
 465
 466 version 1.0
 467
 468 =head1 SYNOPSIS
 469
 470         use PublicInbox::Git;
 471         chomp(my $git_dir = `git rev-parse --git-dir`);
 472         $git_dir or die "GIT_DIR= must be specified\n";
 473         my $git = PublicInbox::Git->new($git_dir);
 474
 475 =head1 DESCRIPTION
 476
 477 Unstable API outside of the L</new> method.
 478 It requires L<git(1)> to be installed.
 479
 480 =head1 METHODS
 481
 482 =cut
 483
 484 =head2 new
 485
 486         my $git = PublicInbox::Git->new($git_dir);
 487
 488 Initialize a new PublicInbox::Git object for use with L<PublicInbox::Import>
 489 This is the only public API method we support.  Everything else
 490 in this module is subject to change.
 491
 492 =head1 SEE ALSO
 493
 494 L<Git>, L<PublicInbox::Import>
 495
 496 =head1 CONTACT
 497
 498 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 499
 500 The mail archives are hosted at L<https://public-inbox.org/meta/>
 501
 502 =head1 COPYRIGHT
 503
 504 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 505
 506 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 507
 508 =cut