lib/PublicInbox/Git.pm

   1 # Copyright (C) 2014-2018 all contributors <meta@public-inbox.org>
   2 # License: GPLv2 or later <https://www.gnu.org/licenses/gpl-2.0.txt>
   3 #
   4 # Used to read files from a git repository without excessive forking.
   5 # Used in our web interfaces as well as our -nntpd server.
   6 # This is based on code in Git.pm which is GPLv2+, but modified to avoid
   7 # dependence on environment variables for compatibility with mod_perl.
   8 # There are also API changes to simplify our usage and data set.
   9 package PublicInbox::Git;
  10 use strict;
  11 use warnings;
  12 use POSIX qw(dup2);
  13 require IO::Handle;
  14 use PublicInbox::Spawn qw(spawn popen_rd);
  15 use base qw(Exporter);
  16 our @EXPORT_OK = qw(git_unquote git_quote);
  17
  18 my %GIT_ESC = (
  19         a => "\a",
  20         b => "\b",
  21         f => "\f",
  22         n => "\n",
  23         r => "\r",
  24         t => "\t",
  25         v => "\013",
  26         '"' => '"',
  27         '\\' => '\\',
  28 );
  29 my %ESC_GIT = map { $GIT_ESC{$_} => $_ } keys %GIT_ESC;
  30
  31
  32 # unquote pathnames used by git, see quote.c::unquote_c_style.c in git.git
  33 sub git_unquote ($) {
  34         return $_[0] unless ($_[0] =~ /\A"(.*)"\z/);
  35         $_[0] = $1;
  36         $_[0] =~ s/\\([\\"abfnrtv])/$GIT_ESC{$1}/g;
  37         $_[0] =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  38         $_[0];
  39 }
  40
  41 sub git_quote ($) {
  42         if ($_[0] =~ s/([\\"\a\b\f\n\r\t\013]|[^[:print:]])/
  43                       '\\'.($ESC_GIT{$1}||sprintf("%0o",ord($1)))/egs) {
  44                 return qq{"$_[0]"};
  45         }
  46         $_[0];
  47 }
  48
  49 sub new {
  50         my ($class, $git_dir) = @_;
  51         my @st;
  52         $st[7] = $st[10] = 0;
  53         # may contain {-tmp} field for File::Temp::Dir
  54         bless { git_dir => $git_dir, st => \@st, -git_path => {} }, $class
  55 }
  56
  57 sub git_path ($$) {
  58         my ($self, $path) = @_;
  59         $self->{-git_path}->{$path} ||= do {
  60                 local $/ = "\n";
  61                 chomp(my $str = $self->qx(qw(rev-parse --git-path), $path));
  62                 $str;
  63         };
  64 }
  65
  66 sub alternates_changed {
  67         my ($self) = @_;
  68         my $alt = git_path($self, 'objects/info/alternates');
  69         my @st = stat($alt) or return 0;
  70         my $old_st = $self->{st};
  71         # 10 - ctime, 7 - size
  72         return 0 if ($st[10] == $old_st->[10] && $st[7] == $old_st->[7]);
  73         $self->{st} = \@st;
  74 }
  75
  76 sub last_check_err {
  77         my ($self) = @_;
  78         my $fh = $self->{err_c} or return;
  79         sysseek($fh, 0, 0) or fail($self, "sysseek failed: $!");
  80         defined(sysread($fh, my $buf, -s $fh)) or
  81                         fail($self, "sysread failed: $!");
  82         $buf;
  83 }
  84
  85 sub _bidi_pipe {
  86         my ($self, $batch, $in, $out, $pid, $err) = @_;
  87         if ($self->{$pid}) {
  88                 if (defined $err) { # "err_c"
  89                         my $fh = $self->{$err};
  90                         sysseek($fh, 0, 0) or fail($self, "sysseek failed: $!");
  91                         truncate($fh, 0) or fail($self, "truncate failed: $!");
  92                 }
  93                 return;
  94         }
  95         my ($in_r, $in_w, $out_r, $out_w);
  96
  97         pipe($in_r, $in_w) or fail($self, "pipe failed: $!");
  98         pipe($out_r, $out_w) or fail($self, "pipe failed: $!");
  99         if ($^O eq 'linux') { # 1031: F_SETPIPE_SZ
 100                 fcntl($out_w, 1031, 4096);
 101                 fcntl($in_w, 1031, 4096) if $batch eq '--batch-check';
 102         }
 103
 104         my @cmd = (qw(git), "--git-dir=$self->{git_dir}",
 105                         qw(-c core.abbrev=40 cat-file), $batch);
 106         my $redir = { 0 => fileno($out_r), 1 => fileno($in_w) };
 107         if ($err) {
 108                 open(my $fh, '+>', undef) or fail($self, "open.err failed: $!");
 109                 $self->{$err} = $fh;
 110                 $redir->{2} = fileno($fh);
 111         }
 112         my $p = spawn(\@cmd, undef, $redir);
 113         defined $p or fail($self, "spawn failed: $!");
 114         $self->{$pid} = $p;
 115         $out_w->autoflush(1);
 116         $self->{$out} = $out_w;
 117         $self->{$in} = $in_r;
 118 }
 119
 120 sub cat_file {
 121         my ($self, $obj, $ref) = @_;
 122         my ($retried, $in, $head);
 123
 124 again:
 125         batch_prepare($self);
 126         $self->{out}->print($obj, "\n") or fail($self, "write error: $!");
 127
 128         $in = $self->{in};
 129         local $/ = "\n";
 130         $head = $in->getline;
 131         if ($head =~ / missing$/) {
 132                 if (!$retried && alternates_changed($self)) {
 133                         $retried = 1;
 134                         cleanup($self);
 135                         goto again;
 136                 }
 137                 return;
 138         }
 139         $head =~ /^[0-9a-f]{40} \S+ (\d+)$/ or
 140                 fail($self, "Unexpected result from git cat-file: $head");
 141
 142         my $size = $1;
 143         my $ref_type = $ref ? ref($ref) : '';
 144
 145         my $rv;
 146         my $left = $size;
 147         $$ref = $size if ($ref_type eq 'SCALAR');
 148         my $cb_err;
 149
 150         if ($ref_type eq 'CODE') {
 151                 $rv = eval { $ref->($in, \$left) };
 152                 $cb_err = $@;
 153                 # drain the rest
 154                 my $max = 8192;
 155                 while ($left > 0) {
 156                         my $r = read($in, my $x, $left > $max ? $max : $left);
 157                         defined($r) or fail($self, "read failed: $!");
 158                         $r == 0 and fail($self, 'exited unexpectedly');
 159                         $left -= $r;
 160                 }
 161         } else {
 162                 my $offset = 0;
 163                 my $buf = '';
 164                 while ($left > 0) {
 165                         my $r = read($in, $buf, $left, $offset);
 166                         defined($r) or fail($self, "read failed: $!");
 167                         $r == 0 and fail($self, 'exited unexpectedly');
 168                         $left -= $r;
 169                         $offset += $r;
 170                 }
 171                 $rv = \$buf;
 172         }
 173
 174         my $r = read($in, my $buf, 1);
 175         defined($r) or fail($self, "read failed: $!");
 176         fail($self, 'newline missing after blob') if ($r != 1 || $buf ne "\n");
 177         die $cb_err if $cb_err;
 178
 179         $rv;
 180 }
 181
 182 sub batch_prepare ($) { _bidi_pipe($_[0], qw(--batch in out pid)) }
 183
 184 sub check {
 185         my ($self, $obj) = @_;
 186         _bidi_pipe($self, qw(--batch-check in_c out_c pid_c err_c));
 187         $self->{out_c}->print($obj, "\n") or fail($self, "write error: $!");
 188         local $/ = "\n";
 189         chomp(my $line = $self->{in_c}->getline);
 190         my ($hex, $type, $size) = split(' ', $line);
 191
 192         # Future versions of git.git may show 'ambiguous', but for now,
 193         # we must handle 'dangling' below (and maybe some other oddball
 194         # stuff):
 195         # https://public-inbox.org/git/20190118033845.s2vlrb3wd3m2jfzu@dcvr/T/
 196         return if $type eq 'missing' || $type eq 'ambiguous';
 197
 198         if ($hex eq 'dangling' || $hex eq 'notdir' || $hex eq 'loop') {
 199                 $size = $type + length("\n");
 200                 my $r = read($self->{in_c}, my $buf, $size);
 201                 defined($r) or fail($self, "read failed: $!");
 202                 return;
 203         }
 204
 205         ($hex, $type, $size);
 206 }
 207
 208 sub _destroy {
 209         my ($self, $in, $out, $pid) = @_;
 210         my $p = delete $self->{$pid} or return;
 211         foreach my $f ($in, $out) {
 212                 delete $self->{$f};
 213         }
 214         waitpid $p, 0;
 215 }
 216
 217 sub fail {
 218         my ($self, $msg) = @_;
 219         cleanup($self);
 220         die $msg;
 221 }
 222
 223 sub popen {
 224         my ($self, @cmd) = @_;
 225         @cmd = ('git', "--git-dir=$self->{git_dir}", @cmd);
 226         popen_rd(\@cmd);
 227 }
 228
 229 sub qx {
 230         my ($self, @cmd) = @_;
 231         my $fh = $self->popen(@cmd);
 232         defined $fh or return;
 233         local $/ = "\n";
 234         return <$fh> if wantarray;
 235         local $/;
 236         <$fh>
 237 }
 238
 239 sub cleanup {
 240         my ($self) = @_;
 241         _destroy($self, qw(in out pid));
 242         _destroy($self, qw(in_c out_c pid_c));
 243 }
 244
 245 # assuming a well-maintained repo, this should be a somewhat
 246 # accurate estimation of its size
 247 # TODO: show this in the WWW UI as a hint to potential cloners
 248 sub packed_bytes {
 249         my ($self) = @_;
 250         my $n = 0;
 251         my $pack_dir = git_path($self, 'objects/pack');
 252         foreach my $p (glob("$pack_dir/*.pack")) {
 253                 $n += -s $p;
 254         }
 255         $n
 256 }
 257
 258 sub DESTROY { cleanup(@_) }
 259
 260 sub local_nick ($) {
 261         my ($self) = @_;
 262         my $ret = '???';
 263         # don't show full FS path, basename should be OK:
 264         if ($self->{git_dir} =~ m!/([^/]+)(?:/\.git)?\z!) {
 265                 $ret = "/path/to/$1";
 266         }
 267         wantarray ? ($ret) : $ret;
 268 }
 269
 270 # show the blob URL for cgit/gitweb/whatever
 271 sub src_blob_url {
 272         my ($self, $oid) = @_;
 273         # blob_url_format = "https://example.com/foo.git/blob/%s"
 274         if (my $bfu = $self->{blob_url_format}) {
 275                 return map { sprintf($_, $oid) } @$bfu if wantarray;
 276                 return sprintf($bfu->[0], $oid);
 277         }
 278         local_nick($self);
 279 }
 280
 281 sub pub_urls {
 282         my ($self) = @_;
 283         if (my $urls = $self->{cgit_url}) {
 284                 return @$urls;
 285         }
 286         local_nick($self);
 287 }
 288
 289 1;
 290 __END__
 291 =pod
 292
 293 =head1 NAME
 294
 295 PublicInbox::Git - git wrapper
 296
 297 =head1 VERSION
 298
 299 version 1.0
 300
 301 =head1 SYNOPSIS
 302
 303         use PublicInbox::Git;
 304         chomp(my $git_dir = `git rev-parse --git-dir`);
 305         $git_dir or die "GIT_DIR= must be specified\n";
 306         my $git = PublicInbox::Git->new($git_dir);
 307
 308 =head1 DESCRIPTION
 309
 310 Unstable API outside of the L</new> method.
 311 It requires L<git(1)> to be installed.
 312
 313 =head1 METHODS
 314
 315 =cut
 316
 317 =head2 new
 318
 319         my $git = PublicInbox::Git->new($git_dir);
 320
 321 Initialize a new PublicInbox::Git object for use with L<PublicInbox::Import>
 322 This is the only public API method we support.  Everything else
 323 in this module is subject to change.
 324
 325 =head1 SEE ALSO
 326
 327 L<Git>, L<PublicInbox::Import>
 328
 329 =head1 CONTACT
 330
 331 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 332
 333 The mail archives are hosted at L<https://public-inbox.org/meta/>
 334
 335 =head1 COPYRIGHT
 336
 337 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 338
 339 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 340
 341 =cut